ولفرام ماثيماتيكا في الجيوفيزياء

شكرا لمؤلف المدونة انطون إيكيمينكو لتقريره

مقدمة

وقد كتبت هذه المذكرة في أعقاب المؤتمر مؤتمر ولفرام للتكنولوجيا الروسية ويحتوي على ملخص للتقرير الذي قدمته. أقيم الحدث في يونيو في سان بطرسبرج. وبالنظر إلى أنني أعمل على بعد مبنى واحد من موقع المؤتمر، لا يسعني إلا أن أحضر هذا الحدث. وفي عامي 2016 و2017، استمعت إلى تقارير المؤتمر، وفي هذا العام قدمت عرضًا تقديميًا. أولاً، ظهر موضوع مثير للاهتمام (يبدو لي) والذي نعمل على تطويره كيريل بيلوفوثانيًا، بعد دراسة طويلة لتشريعات الاتحاد الروسي فيما يتعلق بسياسة العقوبات، في المؤسسة التي أعمل فيها، ظهر ما يصل إلى ترخيصين ولفرام ماثيماتيكا.

قبل أن أنتقل إلى موضوع كلمتي، أود أن أشير إلى التنظيم الجيد لهذا الحدث. تستخدم صفحة زيارة المؤتمر صورة لكاتدرائية كازان. تعد الكاتدرائية إحدى مناطق الجذب الرئيسية في سانت بطرسبرغ ويمكن رؤيتها بوضوح شديد من القاعة التي انعقد فيها المؤتمر.

عند مدخل جامعة سانت بطرسبرغ الحكومية الاقتصادية، التقى المشاركون بمساعدين من بين الطلاب - ولم يسمحوا لهم بالضياع. أثناء التسجيل، تم توزيع الهدايا التذكارية الصغيرة (لعبة - ارتفاع وامض، قلم، ملصقات مع رموز Wolfram). كما تم تضمين الغداء واستراحات القهوة في جدول المؤتمر. لقد لاحظت بالفعل القهوة والفطائر اللذيذة على حائط المجموعة - الطهاة رائعون. من خلال هذا الجزء التمهيدي، أود التأكيد على أن الحدث نفسه وشكله وموقعه يجلب بالفعل مشاعر إيجابية.

التقرير الذي أعددته أنا وكيريل بيلوف يسمى "استخدام Wolfram Mathematica لحل المسائل في الجيوفيزياء التطبيقية". التحليل الطيفي للبيانات الزلزالية أو "مكان جريان الأنهار القديمة". يغطي محتوى التقرير جزأين: أولاً، استخدام الخوارزميات المتوفرة في ولفرام ماثيماتيكا لتحليل البيانات الجيوفيزيائية، وثانيًا، هذه هي كيفية وضع البيانات الجيوفيزيائية في Wolfram Mathematica.

الاستكشاف الزلزالي

تحتاج أولاً إلى القيام برحلة قصيرة إلى الجيوفيزياء. الجيوفيزياء هو العلم الذي يدرس الخصائص الفيزيائية للصخور. حسنًا، نظرًا لأن الصخور لها خصائص مختلفة: كهربائية، ومغناطيسية، ومرنة، فهناك طرق جيوفيزيائية مقابلة: التنقيب الكهربائي، والتنقيب المغناطيسي، والتنقيب الزلزالي... في سياق هذه المقالة، سنناقش فقط التنقيب الزلزالي بمزيد من التفصيل. التنقيب الزلزالي هو الطريقة الرئيسية للبحث عن النفط والغاز. تعتمد الطريقة على إثارة الاهتزازات المرنة ثم التسجيل اللاحق للاستجابة من الصخور المكونة لمنطقة الدراسة. يتم إثارة الاهتزازات على الأرض (باستخدام الديناميت أو مصادر الاهتزاز غير المتفجرة للاهتزازات المرنة) أو في البحر (باستخدام البنادق الهوائية). تنتشر الاهتزازات المرنة عبر الكتلة الصخرية، حيث تنكسر وتنعكس عند حدود الطبقات ذات الخصائص المختلفة. تعود الموجات المنعكسة إلى السطح ويتم تسجيلها بواسطة الجيوفونات الموجودة على الأرض (عادةً أجهزة كهروديناميكية تعتمد على حركة المغناطيس المعلق في ملف) أو الهيدروفونات في البحر (استنادًا إلى التأثير الكهرضغطي). وبحلول وقت وصول الأمواج يمكن الحكم على أعماق الطبقات الجيولوجية.

معدات سحب السفن الزلزالية


يثير مسدس الهواء اهتزازات مرنة


تمر الموجات عبر الكتلة الصخرية ويتم تسجيلها بواسطة الهيدروفونات


سفينة أبحاث المسح الجيوفيزيائي "إيفان جوبكين" عند الرصيف بالقرب من جسر بلاغوفيشتشينسكي في سانت بطرسبرغ

نموذج الإشارة الزلزالية

الصخور لها خصائص فيزيائية مختلفة. بالنسبة للاستكشاف السيزمي، تعتبر الخصائص المرنة مهمة في المقام الأول - سرعة انتشار الاهتزازات المرنة والكثافة. إذا كانت هناك طبقتان لهما نفس الخصائص أو خصائص متشابهة، فإن الموجة "لن تلاحظ" الحدود بينهما. إذا اختلفت سرعات الموجة في الطبقات، فسيحدث الانعكاس عند حدود الطبقات. كلما زاد الفرق في الخصائص، كلما كان الانعكاس أكثر كثافة. سيتم تحديد شدتها بواسطة معامل الانعكاس (rc):

حيث ρ هي كثافة الصخور، ν هي سرعة الموجة، 1 و 2 تشير إلى الطبقات العليا والسفلى.

أحد أبسط نماذج الإشارات الزلزالية وأكثرها استخدامًا هو نموذج الالتفاف، عندما يتم تمثيل الأثر الزلزالي المسجل كنتيجة لالتفاف سلسلة من معاملات الانعكاس مع نبضة استقصاء:

حيث ق (ر) - الأثر الزلزالي، أي. كل ما تم تسجيله بواسطة الهيدروفون أو الجيوفون خلال فترة تسجيل ثابتة، ث (ر) - الإشارة الصادرة عن بندقية الهواء، ن (ر) - ضوضاء عشوائية.

دعونا نحسب الأثر الزلزالي الاصطناعي كمثال. سوف نستخدم نبض ريكر، المستخدم على نطاق واسع في الاستكشاف السيزمي، كإشارة أولية.

length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]

الدافع الزلزالي الأولي


سوف نقوم بوضع حدين على عمق 300 مللي ثانية و600 مللي ثانية، وستكون معاملات الانعكاس أرقام عشوائية

rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]

تسلسل معاملات الانعكاس


دعونا نحسب ونعرض الأثر الزلزالي. وبما أن معاملات الانعكاس لها إشارات مختلفة، فإننا نحصل على انعكاسين متناوبين على الأثر الزلزالي.

traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]

مسار مقلد


في هذا المثال، من الضروري إجراء حجز - في الواقع، يتم تحديد عمق الطبقات، بالطبع، بالأمتار، ويتم حساب الأثر الزلزالي للمجال الزمني. والأصح تحديد الأعماق بالأمتار وحساب أوقات الوصول بمعرفة السرعات في الطبقات. في هذه الحالة، قمت على الفور بتعيين الطبقات على محور الوقت.

إذا تحدثنا عن البحث الميداني، فنتيجة لهذه الملاحظات يتم تسجيل عدد كبير من السلاسل الزمنية المماثلة (الآثار الزلزالية). على سبيل المثال، عند دراسة موقع يبلغ طوله 25 كم وعرضه 15 كم، حيث، نتيجة للعمل، يميز كل أثر خلية بحجم 25 × 25 مترًا (تسمى هذه الخلية بن)، ستحتوي مصفوفة البيانات النهائية على 600000 أثر. مع وقت أخذ العينات 1 مللي ثانية ووقت التسجيل 5 ثوانٍ، سيكون ملف البيانات النهائي أكثر من 11 جيجابايت، ويمكن أن يصل حجم المادة "الخام" الأصلية إلى مئات الجيجابايت.

كيفية العمل معهم ولفرام ماثيماتيكا?

صفقة الجيولوجياIO

بدأ تطوير الحزمة سؤال على جدار VK لمجموعة الدعم الناطقة باللغة الروسية. وبفضل ردود المجتمع، تم العثور على حل بسرعة كبيرة. ونتيجة لذلك، تطورت إلى تطور خطير. مُتَجَانِس مشاركة حائط مجتمع Wolfram حتى أنه تم وضع علامة عليه من قبل المشرفين. حاليًا، تدعم الحزمة العمل مع أنواع البيانات التالية المستخدمة بنشاط في الصناعة الجيولوجية:

1. استيراد بيانات الخرائط بتنسيقات ZMAP وIRAP
2. استيراد القياسات في الآبار تنسيق LAS
3. إدخال وإخراج تنسيق الملفات الزلزالية سيجي

لتثبيت الحزمة، يجب عليك اتباع التعليمات الموجودة على صفحة تنزيل الحزمة المجمعة، أي. قم بتنفيذ الكود التالي في أي دفتر الرياضيات:

If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
    "https://wolfr.am/FiQ5oFih", 
    FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]

وبعد ذلك سيتم تثبيت الحزمة في المجلد الافتراضي، ويمكن الحصول على المسار إليها كما يلي:

FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]

على سبيل المثال، سوف نعرض القدرات الرئيسية للحزمة. يتم إجراء الاستدعاء بشكل تقليدي للحزم بلغة Wolfram:

Get["GeologyIO`"]

تم تطوير الحزمة باستخدام منضدة ولفرام. يسمح لك هذا بإرفاق الوظيفة الرئيسية للحزمة بالوثائق، والتي لا تختلف من حيث تنسيق العرض التقديمي عن وثائق Wolfram Mathematica نفسها، وتزويد الحزمة بملفات اختبار للتعارف الأول.

مثل هذا الملف، على وجه الخصوص، هو ملف "Marmousi.segy" - وهو نموذج اصطناعي لقسم جيولوجي، تم تطويره من قبل معهد البترول الفرنسي. باستخدام هذا النموذج، يختبر المطورون خوارزمياتهم الخاصة لنمذجة المجال الموجي، ومعالجة البيانات، وانعكاس التتبع الزلزالي، وما إلى ذلك. يتم تخزين نموذج Marmosi نفسه في المستودع الذي تم تنزيل الحزمة نفسها منه. للحصول على الملف قم بتشغيل الكود التالي:

If[Not[FileExistsQ["Marmousi.segy"]], 
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]

نتيجة الاستيراد - كائن SEGYData


يتضمن تنسيق SEGY تخزين معلومات متنوعة حول الملاحظات. أولاً، هذه تعليقات نصية. يتضمن ذلك معلومات حول موقع العمل، وأسماء الشركات التي قامت بالقياسات، وما إلى ذلك. في حالتنا، يتم استدعاء هذا الرأس من خلال طلب باستخدام مفتاح TextHeader. إليك رأس النص المختصر:

Short[marmousi["TextHeader"]]

"تم إنشاء مجموعة بيانات مرموسي في المعهد...بسرعة لا تقل عن 1500 م/ث وبحد أقصى 5500 م/ث)"

يمكنك عرض النموذج الجيولوجي الفعلي عن طريق الوصول إلى الآثار الزلزالية باستخدام مفتاح "الآثار" (أحد ميزات الحزمة هو أن المفاتيح غير حساسة لحالة الأحرف):

ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]

الموديل مرموسي


حاليًا، تتيح لك الحزمة أيضًا تحميل البيانات في أجزاء من ملفات كبيرة، مما يجعل من الممكن معالجة الملفات التي يمكن أن يصل حجمها إلى عشرات الجيجابايت. تتضمن وظائف الحزمة أيضًا وظائف لتصدير البيانات إلى .segy وإلحاقها جزئيًا بنهاية الملف.

بشكل منفصل، تجدر الإشارة إلى وظيفة الحزمة عند العمل مع البنية المعقدة لملفات .segy. نظرًا لأنه لا يسمح لك فقط بالوصول إلى الآثار والرؤوس الفردية باستخدام المفاتيح والفهارس، بل يسمح لك أيضًا بتغييرها ثم كتابتها في ملف. العديد من التفاصيل الفنية لتطبيق GeologyIO تقع خارج نطاق هذه المقالة وربما تستحق وصفًا منفصلاً.

أهمية التحليل الطيفي في الاستكشاف السيزمي

تتيح لك القدرة على استيراد البيانات الزلزالية إلى Wolfram Mathematica استخدام وظيفة معالجة الإشارات المضمنة للبيانات التجريبية. وبما أن كل أثر زلزالي يمثل سلسلة زمنية، فإن إحدى الأدوات الرئيسية لدراستها هي التحليل الطيفي. ومن المتطلبات الأساسية لتحليل التركيبة الترددية للبيانات الزلزالية، يمكننا أن نذكر على سبيل المثال ما يلي:

1. تتميز الأنواع المختلفة من الموجات بتكوين ترددات مختلف. يتيح لك ذلك إبراز الموجات المفيدة وقمع موجات التداخل.
2. خصائص الصخور مثل المسامية والتشبع يمكن أن تؤثر على تكوين التردد. وهذا يجعل من الممكن التعرف على الصخور ذات أفضل الخصائص.
3. تتسبب الطبقات ذات السماكات المختلفة في حدوث حالات شاذة في نطاقات تردد مختلفة.

النقطة الثالثة هي النقطة الرئيسية في سياق هذه المقالة. يوجد أدناه جزء من الكود لحساب الآثار الزلزالية في حالة الطبقة ذات السماكة المتفاوتة - نموذج الإسفين. تتم دراسة هذا النموذج تقليديًا في الاستكشاف السيزمي لتحليل تأثيرات التداخل عندما تتراكب الموجات المنعكسة من طبقات عديدة على بعضها البعض.

nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]

نموذج للتشكيل المتعرج


تبلغ سرعة الموجة داخل الإسفين 4500 م/ث، وخارج الإسفين 4000 م/ث، ويفترض أن تكون الكثافة ثابتة 2200 جم/سمXNUMX. لمثل هذا النموذج، نحسب معاملات الانعكاس والآثار الزلزالية.

rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
	ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
		{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]

الآثار الزلزالية لنموذج الوتد


يسمى تسلسل الآثار الزلزالية الموضح في هذا الشكل بالقسم الزلزالي. كما ترون، يمكن أيضًا تنفيذ تفسيرها على مستوى بديهي، نظرًا لأن هندسة الموجات المنعكسة تتوافق بوضوح مع النموذج الذي تم تحديده مسبقًا. إذا قمت بتحليل الآثار بمزيد من التفصيل، ستلاحظ أن الآثار من 1 إلى 30 تقريبًا لا تختلف - فالانعكاس من سقف التكوين ومن الأسفل لا يتداخلان مع بعضهما البعض. بدءًا من المسار الحادي والثلاثين، تبدأ الانعكاسات بالتداخل. وعلى الرغم من أن معاملات الانعكاس في النموذج لا تتغير أفقيًا - فإن الآثار الزلزالية تغير شدتها مع تغير سمك التكوين.

دعونا نفكر في سعة الانعكاس من الحد العلوي للتكوين. بدءًا من المسار الستين، تبدأ شدة الانعكاس في الزيادة وعند المسار السبعين تصبح الحد الأقصى. وهكذا يتجلى تداخل الموجات من السقف وأسفل الطبقات، مما يؤدي في بعض الحالات إلى شذوذات كبيرة في السجل الزلزالي.

ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]

رسم بياني لسعة الموجة المنعكسة من الحافة العلوية للإسفين


ومن المنطقي أنه عندما تكون الإشارة ذات تردد منخفض، يبدأ التداخل في الظهور عند سماكات التكوين الكبيرة، وفي حالة الإشارة عالية التردد، يحدث التداخل عند سماكات أصغر. يقوم مقتطف الكود التالي بإنشاء إشارة بترددات 35 هرتز و55 هرتز و85 هرتز.

waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]

مجموعة من إشارات المصدر بترددات 35 هرتز، 55 هرتز، 85 هرتز


من خلال حساب الآثار الزلزالية ورسم الرسوم البيانية لسعة الموجة المنعكسة، يمكننا أن نرى أنه بالنسبة للترددات المختلفة، يتم ملاحظة حدوث شذوذ عند سماكات تكوين مختلفة.

tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];

lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];

Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]

رسوم بيانية لسعات الموجة المنعكسة من الحافة العلوية للإسفين لترددات مختلفة


إن القدرة على استخلاص استنتاجات حول سمك التكوين من نتائج الملاحظات الزلزالية مفيدة للغاية، لأن إحدى المهام الرئيسية في التنقيب عن النفط هي تقييم النقاط الواعدة لحفر بئر (أي تلك المناطق التي يوجد فيها التكوين). أكثر سمكا). بالإضافة إلى ذلك، قد تكون هناك كائنات في القسم الجيولوجي يتسبب تكوينها في تغيير حاد في سمك التكوين. وهذا يجعل التحليل الطيفي أداة فعالة لدراستها. في الجزء التالي من المقالة سننظر في هذه الأشياء الجيولوجية بمزيد من التفصيل.

بيانات تجريبية. من أين حصلت عليهم وما الذي تبحث عنه؟

تم الحصول على المواد التي تم تحليلها في المقال في غرب سيبيريا. والمنطقة، كما يعلم الجميع دون استثناء، هي المنطقة الرئيسية المنتجة للنفط في بلدنا. بدأ التطوير النشط للودائع في المنطقة في الستينيات من القرن الماضي. الطريقة الرئيسية للبحث عن رواسب النفط هي التنقيب الزلزالي. ومن المثير للاهتمام أن ننظر إلى صور الأقمار الصناعية لهذه المنطقة. على نطاق صغير، يمكنك ملاحظة عدد كبير من المستنقعات والبحيرات؛ من خلال توسيع الخريطة، يمكنك رؤية مواقع حفر الآبار العنقودية، ومن خلال توسيع الخريطة إلى الحد الأقصى، يمكنك أيضًا تمييز خلوص الملامح التي يتم على طولها الزلزالية تم إجراء الملاحظات.

صورة القمر الصناعي لخرائط ياندكس - منطقة مدينة نويابرسك


شبكة من منصات الآبار في أحد الحقول


توجد الصخور الحاملة للنفط في غرب سيبيريا في نطاق واسع من الأعماق - من 1 كم إلى 5 كم. تم تشكيل الحجم الرئيسي للصخور المحتوية على النفط في العصر الجوراسي والطباشيري. ربما يكون العصر الجوراسي معروفًا للكثيرين من الفيلم الذي يحمل نفس الاسم. المناخ الجوراسي كان مختلفا بشكل كبير عن الحديث. تحتوي الموسوعة البريطانية على سلسلة من الخرائط القديمة التي تميز كل عصر هيلوجي.

حاليا،

العصر الجوراسي


يرجى ملاحظة أنه في العصر الجوراسي، كانت أراضي سيبيريا الغربية عبارة عن ساحل بحري (أرض تعبرها الأنهار وبحر ضحل). وبما أن المناخ كان مريحا، يمكننا أن نفترض أن المناظر الطبيعية النموذجية في ذلك الوقت كانت تبدو كما يلي:

سيبيريا الجوراسية


في هذه الصورة، ما يهمنا ليس الحيوانات والطيور بقدر ما يهمنا صورة النهر في الخلفية. النهر هو نفس الكائن الجيولوجي الذي توقفنا عنده سابقًا. والحقيقة هي أن نشاط الأنهار يسمح بتراكم الحجارة الرملية المصنفة جيدًا، والتي ستصبح بعد ذلك خزانًا للنفط. يمكن أن يكون لهذه الخزانات شكل غريب ومعقد (مثل قاع النهر) ولها سماكة متغيرة - بالقرب من الضفاف يكون السماكة صغيرًا، ولكنه يزداد بالقرب من مركز القناة أو في المناطق المتعرجة. لذلك، فإن الأنهار التي تشكلت في العصر الجوراسي هي الآن على عمق حوالي ثلاثة كيلومترات وهي موضوع البحث عن خزانات النفط.

بيانات تجريبية. المعالجة والتصور

دعونا نبدي تحفظًا على الفور فيما يتعلق بالمواد الزلزالية الموضحة في المقالة - نظرًا لحقيقة أن كمية البيانات المستخدمة للتحليل كبيرة - لم يتم تضمين سوى جزء من المجموعة الأصلية من الآثار الزلزالية في نص المقالة. سيسمح هذا لأي شخص بإعادة إنتاج الحسابات المذكورة أعلاه.

عند العمل مع البيانات الزلزالية، يستخدم الجيوفيزيائي عادة برامج متخصصة (هناك العديد من قادة الصناعة الذين يتم استخدام تطوراتهم بنشاط، على سبيل المثال Petrel أو Paradigm)، والذي يسمح لك بتحليل أنواع مختلفة من البيانات ولديه واجهة رسومية مريحة. على الرغم من كل الراحة، فإن هذه الأنواع من البرامج لها عيوبها - على سبيل المثال، يستغرق تنفيذ الخوارزميات الحديثة في الإصدارات المستقرة الكثير من الوقت، وعادة ما تكون إمكانيات أتمتة الحسابات محدودة. في مثل هذه الحالة، يصبح من الملائم جدًا استخدام أنظمة الرياضيات الحاسوبية ولغات البرمجة عالية المستوى، والتي تسمح باستخدام قاعدة خوارزمية واسعة، وفي الوقت نفسه، تأخذ الكثير من الروتين. هذا هو المبدأ المستخدم في التعامل مع البيانات الزلزالية في Wolfram Mathematica. ليس من المناسب كتابة وظائف غنية للعمل التفاعلي مع البيانات - فمن الأهم ضمان التحميل من تنسيق مقبول بشكل عام، وتطبيق الخوارزميات المطلوبة عليها وتحميلها مرة أخرى إلى تنسيق خارجي.

باتباع المخطط المقترح، سنقوم بتحميل البيانات الزلزالية الأصلية وعرضها ولفرام ماثيماتيكا:

Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]

البيانات التي تم تنزيلها واستيرادها بهذه الطريقة هي المسارات المسجلة على مساحة 10 × 5 كيلومترات. إذا تم الحصول على البيانات باستخدام طريقة المسح الزلزالي ثلاثي الأبعاد (لا يتم تسجيل الموجات على طول الملامح الجيوفيزيائية الفردية، ولكن على المنطقة بأكملها في وقت واحد)، يصبح من الممكن الحصول على مكعبات البيانات الزلزالية. هذه كائنات ثلاثية الأبعاد، تتيح المقاطع الرأسية والأفقية منها إجراء دراسة تفصيلية للبيئة الجيولوجية. في المثال المذكور، نحن نتعامل مع بيانات ثلاثية الأبعاد. يمكننا الحصول على بعض المعلومات من رأس النص، مثل هذا

StringPartition[seismic3DSEGY["textheader"], 80] // TableForm

C 1 هذا ملف تجريبي لاختبار حزمة الجيولوجيا
C 2
C 3
C 4
C 5 تاريخ اسم المستخدم: مستخدم WOLFRAM
ج6 اسم الاستطلاع: في مكان ما في سيبيريا
C 7 نوع الملف حجم زلزالي ثلاثي الأبعاد
C 8
C 9
نطاق C10 Z: أول 2200 متر وآخر 2400 متر

ستكون مجموعة البيانات هذه كافية بالنسبة لنا لتوضيح المراحل الرئيسية لتحليل البيانات. يتم تسجيل الآثار الموجودة في الملف بشكل تسلسلي وكل منها يشبه الشكل التالي - وهذا هو توزيع سعات الموجات المنعكسة على طول المحور الرأسي (محور العمق).

ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2, 
 PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
 LabelStyle -> Directive[Black, Italic], PlotRange -> All, 
 Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]

أحد آثار المقطع الزلزالي


بمعرفة عدد الآثار الموجودة في كل اتجاه للمنطقة المدروسة، يمكنك إنشاء مصفوفة بيانات ثلاثية الأبعاد وعرضها باستخدام وظيفة Image3D[]

traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1;   (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1;   (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]

صورة ثلاثية الأبعاد لمكعب البيانات الزلزالية (المحور الرأسي - العمق)


إذا كانت السمات الجيولوجية محل الاهتمام تخلق شذوذات زلزالية شديدة، فيمكن استخدام أدوات التصور ذات الشفافية. يمكن جعل المناطق "غير المهمة" من التسجيل غير مرئية، مع ترك الحالات الشاذة فقط مرئية. في Wolfram Mathematica يمكن القيام بذلك باستخدام العتامة[] и النقطية3D[].

data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]}, 
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]

صورة مكعب البيانات الزلزالية باستخدام وظائف Opacity[] وRaster3D[].

كما هو الحال في المثال الاصطناعي، يمكن تحديد بعض الحدود الجيولوجية (الطبقات) في أجزاء من المكعب الأصلي مع تضاريس متغيرة.

الأداة الرئيسية للتحليل الطيفي هي تحويل فورييه. بمساعدتها، يمكنك تقييم طيف السعة والتردد لكل أثر أو مجموعة من الآثار. ومع ذلك، بعد نقل البيانات إلى مجال التردد، يتم فقدان المعلومات حول الأوقات (اقرأ في أي أعماق) يتغير التردد. من أجل أن تكون قادرة على توطين تغييرات الإشارة على محور الوقت (العمق)، يتم استخدام تحويل فورييه ذو النوافذ وتحلل المويجات. تستخدم هذه المقالة تحليل المويجات. بدأ استخدام تقنية تحليل المويجات بنشاط في الاستكشاف السيزمي في التسعينيات. تعتبر الميزة على تحويل فورييه ذو النوافذ أفضل دقة للوقت.

باستخدام جزء التعليمات البرمجية التالي، يمكنك تحليل أحد الآثار الزلزالية إلى مكونات فردية:

cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]

تحلل الأثر إلى مكونات


لتقييم كيفية توزيع طاقة الانعكاس في أوقات وصول الموجة المختلفة، يتم استخدام المخططات البيانية (المشابهة للمخطط الطيفي). كقاعدة عامة، ليست هناك حاجة عمليا لتحليل جميع المكونات. عادة، يتم اختيار مكونات التردد المنخفض والمتوسطة والعالية.

freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]

مقياس. نتيجة الوظيفة مخطط المويجات[]


تستخدم لغة Wolfram وظيفة تحويل المويجات تحويل المويجات المستمرة[]. وسيتم تطبيق هذه الوظيفة على مجموعة الآثار بأكملها باستخدام الوظيفة طاولة[]. تجدر الإشارة هنا إلى إحدى نقاط القوة في Wolfram Mathematica - القدرة على استخدام الموازاة باراليلتاب[]. في المثال أعلاه، ليست هناك حاجة للتوازي - حجم البيانات ليس كبيرًا، ولكن عند العمل مع مجموعات البيانات التجريبية التي تحتوي على مئات الآلاف من الآثار، فهذا أمر ضروري.

tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}]; 

بعد تطبيق الدالة تحويل المويجات المستمرة[] تظهر مجموعات البيانات الجديدة المقابلة للترددات المحددة. في المثال أعلاه، هذه الترددات هي: 38 هرتز، 33 هرتز، 27 هرتز. غالبًا ما يتم اختيار الترددات على أساس الاختبار - حيث يحصلون على خرائط فعالة لمجموعات ترددات مختلفة ويختارون الأكثر إفادة من وجهة نظر الجيولوجي.

إذا كنت بحاجة إلى مشاركة النتائج مع الزملاء أو تقديمها إلى العميل، فيمكنك استخدام وظيفة SEGYExport[] الخاصة بحزمة GeologyIO

outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];

مع ثلاثة من هذه المكعبات (مكونات منخفضة التردد ومتوسطة التردد وعالية التردد)، يتم استخدام مزج RGB عادةً لتصور البيانات معًا. يتم تعيين لون خاص لكل مكون - الأحمر والأخضر والأزرق. في Wolfram Mathematica يمكن القيام بذلك باستخدام الوظيفة كولوركومبين[].

والنتيجة هي صور يمكن من خلالها إجراء التفسير الجيولوجي. تتيح التعرجات المسجلة في القسم تحديد القنوات القديمة، والتي من المرجح أن تكون خزانات وتحتوي على احتياطيات نفطية. إن البحث والتحليل عن نظائرها الحديثة لنظام النهر هذا يسمح لنا بتحديد الأجزاء الواعدة من التعرجات. وتتميز القنوات نفسها بطبقات سميكة من الحجر الرملي جيد الفرز، وهي بمثابة خزان جيد للنفط. المناطق الواقعة خارج شذوذ "الدانتيل" تشبه رواسب السهول الفيضية الحديثة. وتتمثل رواسب السهول الفيضية بشكل رئيسي في الصخور الطينية، وسيكون الحفر في هذه المناطق غير فعال.

شريحة RGB لمكعب البيانات. في المركز (إلى يسار المركز قليلاً) يمكنك تتبع النهر المتعرج.

شريحة RGB لمكعب البيانات. على الجانب الأيسر يمكنك تتبع النهر المتعرج.


وفي بعض الحالات، تسمح جودة البيانات الزلزالية بالحصول على صور أكثر وضوحًا بشكل ملحوظ. ويعتمد ذلك على منهجية العمل الميداني، والمعدات المستخدمة بواسطة خوارزمية تقليل الضوضاء. في مثل هذه الحالات، لا تكون أجزاء من أنظمة الأنهار مرئية فحسب، بل تظهر أيضًا أنهار قديمة ممتدة بأكملها.

خلط RGB لثلاثة مكونات لمكعب البيانات الزلزالية (شريحة أفقية). العمق حوالي 2 كم.

صورة القمر الصناعي لنهر الفولغا بالقرب من ساراتوف

اختتام

يمكن لـ Wolfram Mathematica تحليل البيانات الزلزالية وحل المشكلات التطبيقية المتعلقة بالبحث عن المعادن، كما أن حزمة GeologyIO تجعل هذه العملية أكثر ملاءمة. إن بنية البيانات الزلزالية هي التي تستخدم الأساليب المضمنة لتسريع العمليات الحسابية (باراليلتاب[], عمل متوازي[]،…) فعال للغاية ويسمح لك بمعالجة كميات كبيرة من البيانات. يتم تسهيل ذلك إلى حد كبير من خلال ميزات تخزين البيانات الموجودة في حزمة GeologyIO. بالمناسبة، يمكن استخدام الحزمة ليس فقط في مجال الاستكشاف الزلزالي التطبيقي. يتم استخدام نفس أنواع البيانات تقريبًا في الرادار المخترق للأرض وعلم الزلازل. إذا كانت لديك اقتراحات حول كيفية تحسين النتيجة، أو ما هي خوارزميات تحليل الإشارات من ترسانة Wolfram Mathematica التي تنطبق على هذه البيانات، أو إذا كانت لديك أي تعليقات نقدية، من فضلك اترك تعليقا.

المصدر: www.habr.com