Esp8266 управление през интернет по протокол MQTT

Здравейте на всички! В тази статия ще бъде подробно обяснено и показано как буквално за 20 минути свободно време да настроите дистанционно управление на модула esp8266 с помощта на приложение за Android по протокол MQTT.

Идеята за дистанционно управление и мониторинг винаги е вълнувала умовете на запалените по електроника и програмиране. Възможността да получите или изпратите нужните данни по всяко време, независимо от вашето местоположение, предлага широки възможности. В предишните си статии ( Статия 1 и Статия 2) се опитах да разгледам няколко достъпни и относително простички варианта за реализация на дистанционно управление на микроконтролери през интернет. Но времето и светът не стоят на място – прогресът продължава своето неумолимо движение напред. За този кратък период модулът esp8266 придоби широка популярност, тъй като, благодарение на ниската си цена и вграденото wi-fi, стана един от основните компоненти на "Умния дом".

В момента MQTT е най-съвременният и най-популярният протокол за предаване на данни между отделните устройства в рамките на системите "Умен дом". Той предлага редица предимства пред другите протоколи:
— ниска консумация на трафик;
— връзката между клиента и сървъра винаги е отворена;
— не натоварва интернет канала;
— липса на забавяне при предаване на данни;
— удобна система за абонаменти за теми;
Всичко това позволява мониторинг и управление в реално време. Въпреки това MQTT изисква наличието на собствен сървър, който да играе ролята на посредник между клиентите в мрежата. Тук има два варианта: или да създадете свой собствен сървър, или да използвате външни услуги.

Описваната система за управление се състои от две основни части: MQTT сървър (който обикновено е един) и клиенти, които могат да бъдат доста много. В нашия случай като клиенти ще действа приложението на Android и самият модул esp8266.

Алгоритъмът на работа на системата е следният. Клиентите се свързват със сървъра и веднага след свързването всеки от тях извършва абонамент за интересуващите го теми. Всичкото общуване между клиентите преминава транзитом през сървъра, който пренасочва данни към другите клиенти с оглед на техните абонаменти.

MQTT сървър.

В нашия случай ще използваме изключително удобен сервис www.cloudmqtt.com който предлага безплатен тарифен план (Cute Cat), който напълно ще покрие нуждите за реализиране на малка собствена система за "умния дом".

Нека се регистрираме на сайта и да получим необходимите данни за достъп до сървъра. При настройката на клиентите е необходимо да се използва стандартен порт (без SSL и TLS).


Приложение за Android.

Нашето приложение ще служи като дистанционно управление за микроконтролера, а също така ще приема и показва цялата информация получена от esp8266.

Приложението се нарича IoT MQTT Dashboard и представлява готов mqtt клиент с малко количество много удобни джаджи. По-подробно за работата с приложението можете да видите във видеото.

Esp8266.

Модулът се програмира в среда Arduino, обаче искам да отбележа, че модулът има проблеми с флашването в последните версии на Arduino, затова препоръчвам да се използва версия 1.6.4.
За пример, към esp8266 са свързани светодиод (5-ти пин) и сензор за температура ds18b20 (2-ри пин).
Тъй като за управление на светодиода е необходимо да получаваме данни, след свързването esp трябва да се абонира за съответния топик "test/led", в противен случай всички изпратени данни ще преминат покрай нашия микроконтролер.
За изпращане на данни за температура, абонамент не е нужен, но при предаването на стойности на температурата е необходимо да се посочи топика, в който тези данни ще отидат.

По-долу е даден скетч с подробни коментари.

Скетч Esp8266_mqtt.ino// Светодиод подлкючен к 5 пину
// Датчик температуры ds18b20 к 2 пину

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <OneWire.h>
#include <DallasTemperature.h>

#define ONE_WIRE_BUS 2
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);

const char *ssid = "AIRPORT"; // Име на WiFi мрежата
const char *pass = "PASSWORD"; // Паролата за мрежата

const char *mqtt_server = "server"; // Име на MQTT сървера
const int mqtt_port = 11140; // Порт за свързване с MQTT сървера
const char *mqtt_user = "Login"; // Логин за сървера
const char *mqtt_pass = "Pass"; // Паролата за сървера

#define BUFFER_SIZE 100

bool LedState = false;
int tm=300;
float temp=0;

// Функция получения данных от сервера

void callback(const MQTT::Publish& pub)
{
Serial.print(pub.topic()); // извеждаме в сериен порт името на топика
Serial.print(" => ");
Serial.print(pub.payload_string()); // извеждаме в сериен порт стойността на получените данни

String payload = pub.payload_string();

if(String(pub.topic()) == "test/led") // проверяваме дали данните идват от нужния ни топик
{
int stled = payload.toInt(); // преобразуваме получените данни в тип integer
digitalWrite(5,stled); // включваме или изключваме светодиода в зависимост от получените стойности
}
}

WiFiClient wclient;
PubSubClient client(wclient, mqtt_server, mqtt_port);

void setup() {

sensors.begin();
Serial.begin(115200);
delay(10);
Serial.println();
Serial.println();
pinMode(5, OUTPUT);
}

void loop() {
// подключаемся к wi-fi
if (WiFi.status() != WL_CONNECTED) {
Serial.print("Свързване с ");
Serial.print(ssid);
Serial.println("...");
WiFi.begin(ssid, pass);

if (WiFi.waitForConnectResult() != WL_CONNECTED)
return;
Serial.println("WiFi връзката е установена");
}

// подключаемся к MQTT серверу
if (WiFi.status() == WL_CONNECTED) {
if (!client.connected()) {
Serial.println("Свързване с MQTT сървъра");
if (client.connect(MQTT::Connect("arduinoClient2")
.set_auth(mqtt_user, mqtt_pass))) {
Serial.println("Свързани с MQTT сървъра");
client.set_callback(callback);
client.subscribe("test/led"); // подписваме се по топик с данни за светодиода
} else {
Serial.println("Не успяхме да се свържем с MQTT сървъра");
}
}

if (client.connected()){
client.loop();
TempSend();
}

}
} // край на основния цикъл

// Функция отправки показаний с термодатчика
void TempSend(){
if (tm==0)
{
sensors.requestTemperatures(); // от датчика получаваме стойността на температурата
float temp = sensors.getTempCByIndex(0);
client.publish("test/temp",String(temp)); // изпращаме в топик за термодатчика стойността на температурата
Serial.println(temp);
tm = 300; // пауза между изпращанията на стойности на температурата около 3 секунди
}
tm--;
delay(10);
}

В резултат получаваме удобен инструмент за дистанционно управление и мониторинг на данни, който е доста прост за овладяване и ще бъде по силите дори на начинаещи.

Видео с демонстрация на работата на управлението

Подробна видеоинструкция за настройка на системата

Един от вариантите за управление на esp8266 чрез MQTT протокол

Управление на светодиодната лента през интернет

Ако имате въпроси относно този материал, ви препоръчвам да гледате втората част на видеото, където материалът е изложен по-ясно.

В архива се намират скечът и всички необходими библиотеки за флашване на микроконтролера със скеча от примера.
Обърнете внимание, че библиотеката ESP8266WiFi.h не е включена в този архив, тя се инсталира чрез Boards manager в средата на Arduino.

АРХИВ

MQTT сървър — www.cloudmqtt.com

Връзка към приложението IoT MQTT Dashboard — play.google.com/store/apps/details?id=com.thn.iotmqttdashboard&hl=ru

Благодаря на всички за вниманието.

Източник: habr.com