C++ и CMake — завинаги братя, част II

В предишната част в този увлекателен разказ се говореше за организацията на заглавната библиотека в рамките на генератора на системи за компилация CMake.

Този път ще добавим компилируема библиотека и ще обсъдим как да свържем модулите помежду им.

Както винаги, тези, които не могат да чакат, могат веднага да се насочат към обновения репозиториум и да опитат всичко сами.

Съдържание

1. Разделяй
2. Царувай

Разделяй

Първото нещо, което трябва да направим, за да постигнем нашата висока цел, е да разделим разработваното софтуерно приложение на универсални изолирани блокове, които са унифицирани от гледна точка на потребителя.

В първата част беше описан такъв стандартен блок — проект със заглавна библиотека. Сега ще добавим към нашия проект компилируема библиотека.

За целта ще изнесем реализацията на функцията myfunc в отделен .cpp-файл:

diff --git a/include/mylib/myfeature.hpp b/include/mylib/myfeature.hpp
index 43db388..ba62b4f 100644
--- a/include/mylib/myfeature.hpp
+++ b/include/mylib/myfeature.hpp
@@ -46,8 +46,5 @@ namespace mylib

         ~  виж mystruct
      * /
-    inline bool myfunc (mystruct)
-    {
-        return true;
-    }
+    bool myfunc (mystruct);
 }
diff --git a/src/mylib/myfeature.cpp b/src/mylib/myfeature.cpp
new file mode 100644
index 0000000..abb5004
--- /dev/null
+++ b/src/mylib/myfeature.cpp
@@ -0,0 +1,9 @@
+#include 
+
+namespace mylib
+{
+    bool myfunc (mystruct)
+    {
+        return true;
+    }
+}

След това ще определим компилируема библиотека (myfeature), която ще се състои от получения на предишната стъпка .cpp-файл. Новата библиотека очевидно изисква вече налични заглавия и за да осигурим това, можем и трябва да я свържем с наличната цел mylib. Свързването между тях е публично, което означава, че всичко, което ще бъде свързано с целта myfeature, автоматично ще получи и целта mylib (повече за начините на свързване).

diff --git a/CMakeLists.txt b/CMakeLists.txt
index 108045c..0de77b8 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -64,6 +64,17 @@ target_compile_features(mylib INTERFACE cxx_std_17)

 add_library(Mylib::mylib ALIAS mylib)

+###################################################################################################
+##
+##      Компилируема библиотека
+##
+###################################################################################################
+
+add_library(myfeature src/mylib/myfeature.cpp)
+target_link_libraries(myfeature PUBLIC mylib)
+
+add_library(Mylib::myfeature ALIAS myfeature)
+

След това ще направим новата библиотека също така да бъде инсталирана в системата:

@@ -72,7 +83,7 @@ add_library(Mylib::mylib ALIAS mylib)

 install(DIRECTORY include/mylib DESTINATION include)

-install(TARGETS mylib EXPORT MylibConfig)
+install(TARGETS mylib myfeature EXPORT MylibConfig)
 install(EXPORT MylibConfig NAMESPACE Mylib:: DESTINATION share/Mylib/cmake)

 include(CMakePackageConfigHelpers)

Трябва да се обърне внимание, че за целта myfeature, както и за mylib е създаден псевдоним с префикс Mylib::. Същото е записано и за двете цели при експортиране за инсталация в системата. Това дава възможност за унифицирана работа с целите при всяка схема на свързване.

След това остава да свържем модулните тестове с новата библиотека (функцията myfunc бе изнесена от заглавния файл, така че сега трябва да се линковаме):

diff --git a/test/CMakeLists.txt b/test/CMakeLists.txt
index 5620be4..bc1266c 100644
--- a/test/CMakeLists.txt
+++ b/test/CMakeLists.txt
@@ -4,7 +4,7 @@ add_executable(mylib-unit-tests test_main.cpp)
 target_sources(mylib-unit-tests PRIVATE mylib/myfeature.cpp)
 target_link_libraries(mylib-unit-tests
     PRIVATE
-        Mylib::mylib
+        Mylib::myfeature
         doctest::doctest
 )

Заглавията (Mylib::mylib) вече не трябва да се включват отделно, защото, както вече бе споменато, те автоматично се включват заедно с библиотеката (Mylib::myfeature).

И ще добавим няколко нюанса, за да осигурим измервания на покритието с оглед на новопристигналата библиотека:

@@ -15,11 +15,16 @@ if(MYLIB_COVERAGE AND GCOVR_EXECUTABLE)
     target_compile_options(mylib-unit-tests PRIVATE --coverage)
     target_link_libraries(mylib-unit-tests PRIVATE gcov)

+    target_compile_options(myfeature PRIVATE --coverage)
+    target_link_libraries(myfeature PRIVATE gcov)
+
     add_custom_target(coverage
         COMMAND
             ${GCOVR_EXECUTABLE}
-                --root=${PROJECT_SOURCE_DIR}/include/
-                --object-directory=${CMAKE_CURRENT_BINARY_DIR}
+                --root=${PROJECT_SOURCE_DIR}/
+                --filter=${PROJECT_SOURCE_DIR}/include
+                --filter=${PROJECT_SOURCE_DIR}/src
+                --object-directory=${PROJECT_BINARY_DIR}
         DEPENDS
             check
     )

Може да добавим повече библиотеки, изпълними файлове и т.н. Важно е единствено кои цели са интерфейс на нашия модул, т.е. излизат навън.

Царувай

Сега имаме стандартни модулни блокове и можем да управляем тях: да ги композиране в структура с всякаква сложност, инсталирайки ги в системата или свързвайки ги помежду им в рамките на единна система за сборка.

Инсталация в системата

Един от начините за използване на модула е да инсталираме нашия модул в системата.

cmake --build път/к/сборочната/директория --target install

След това той може да се свърже в всеки друг проект с помощта на командата find_package.

find_package(Mylib 1.0 REQUIRED)

Свързване като подмодул

Друг вариант е да свържем папката с нашия проект с друг проект като подмодул с помощта на командата add_subdirectory.

Използване

Методите за свързване са различни, но резултатът е един и същ. В проекта, който използва нашия модул, целите ще бъдат достъпни и в двата случая. Mylib::myfeature и Mylib::mylib, които могат да се използват, например, така:

add_executable(some_executable some.cpp sources.cpp)
target_link_libraries(some_executable PRIVATE Mylib::myfeature)

В конкретния ни случай библиотеката Mylib::myfeature трябва да се свърже, когато е необходимо да се свърже с библиотеката libmyfeature. Ако има достатъчно заглавни файлове, тогава е по-добре да се използва библиотеката Mylib::mylib.

CMake целите могат да бъдат хитри, например, предназначени само за прокарване на определени свойства, зависимости и т.н. Работата с тях протича по един и същ начин.

Това искахме да постигнем.

Източник: habr.com