Лесно наблюдение на DFS репликация в Zabbix

въведение

При достатъчно голяма и разпределена инфраструктура, която използва DFS като единична точка за достъп до данни и DFSR за репликация на данни между центъра за данни и клоновите сървъри, възниква въпросът за наблюдение на състоянието на тази репликация.
По стечение на обстоятелствата, почти веднага след началото на използването на DFSR, ние започнахме да прилагаме Zabbix, за да заменим съществуващата зоологическа градина от различни инструменти и да приведем мониторинга на инфраструктурата в по-информативна, пълна и логична форма. Ще говорим за използването на Zabbix за наблюдение на DFS репликация.

На първо място, трябва да решим какви данни за репликацията на DFS трябва да получим, за да наблюдаваме състоянието му. Най-подходящият показател е изоставането. Той съдържа файлове, които не са синхронизирани с други членове на групата за репликация. Можете да видите размера му с помощната програма dfsrdiagинсталиран с ролята на DFSR. В нормално състояние на репликация размерът на изоставането трябва да клони към нула. Съответно големият брой файлове в натрупаните файлове показват проблеми с репликацията.

Сега за практическата страна на въпроса.

За да наблюдаваме размера на изоставането чрез Zabbix Agent, имаме нужда от:

• Скрипт, който ще анализира изхода dfsrdiag за предоставяне на окончателни стойности на размера на изоставането на Zabbix,
• Скрипт, който ще определи колко групи за репликация има на сървъра, какви папки репликират и какви други сървъри включват (не искаме да въвеждаме всичко това в Zabbix на ръка за всеки сървър, нали?),
• Въвеждане на тези скриптове като UserParameter в конфигурацията на Zabbix агент за последващо извикване от сървъра за наблюдение,
• Стартиране на агентската услуга на Zabbix като потребител с права за четене на изоставането,
• Шаблон за Zabbix, в който ще се конфигурира групово откриване, обработка на получените данни и издаване на предупреждения за тях.

Анализатор на скриптове

За да напиша парсера, избрах VBS като най-универсалния език, присъстващ във всички версии на Windows Server. Логиката на скрипта е проста: той получава името на групата за репликация, репликираната папка и имената на изпращащия и получаващия сървър чрез командния ред. След това тези параметри се предават на dfsrdiagи в зависимост от изхода му:
Брой файлове - ако се получи съобщение за наличие на файлове в неизпълнените задачи,
0 - ако е получено съобщение за липсата на файлове в натрупания файл („Няма натрупан файл“),
-1 - ако е получено съобщение за грешка dfsrdiag при изпълнение на заявката ("[ГРЕШКА]").

get-Backlog.vbs

strReplicationGroup=WScript.Arguments.Item(0)
strReplicatedFolder=WScript.Arguments.Item(1)
strSending=WScript.Arguments.Item(2)
strReceiving=WScript.Arguments.Item(3)

Set WshShell = CreateObject ("Wscript.shell")
Set objExec = WSHshell.Exec("dfsrdiag.exe Backlog /RGName:""" & strReplicationGroup & """ /RFName:""" & strReplicatedFolder & """ /SendingMember:" & strSending & " /ReceivingMember:" & strReceiving)
strResult = ""
Do While Not objExec.StdOut.AtEndOfStream
	strResult = strResult & objExec.StdOut.ReadLine() & "\"
Loop

If InStr(strResult, "No Backlog") > 0 then
	intBackLog = 0
ElseIf  InStr(strResult, "[ERROR]") > 0 Then
    intBackLog = -1
Else
	arrLines = Split(strResult, "\")
	arrResult = Split(arrLines(1), ":")
	intBackLog = arrResult(1)
End If

WScript.echo intBackLog

Скрипт за откриване

За да може Zabbix да определи всички групи за репликация, присъстващи на самия сървър и да открие всички параметри, необходими за заявката (име на папка, имена на съседни сървъри), ние трябва да получим тази информация, първо, и второ, да я представим в формат, който Zabbix разбира. Форматът, който инструментът за откриване разбира, изглежда така:

        "data":[
                {
                        "{#GROUP}":"Share1",
                        "{#FOLDER}":"Folder1",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"Server2"}

...

                        "{#GROUP}":"ShareN",
                        "{#FOLDER}":"FolderN",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"ServerN"}]}

Най-лесният начин да получим информацията, която ни интересува, е чрез WMI, като я извадим от съответните секции на DfsrReplicationGroupConfig. В резултат на това се роди скрипт, който генерира заявка към WMI и извежда списък с групи, техните папки и сървъри в необходимия формат.

DFSRDiscovery.vbs

dim strComputer, strLine, n, k, i

Set wshNetwork = WScript.CreateObject( "WScript.Network" )
strComputer = wshNetwork.ComputerName

Set oWMIService = GetObject("winmgmts:\" & strComputer & "rootMicrosoftDFS")
Set colRGroups = oWMIService.ExecQuery("SELECT * FROM DfsrReplicationGroupConfig")
wscript.echo "{"
wscript.echo "        ""data"":["
n=0
k=0
i=0
For Each oGroup in colRGroups
  n=n+1
  Set colRGFolders = oWMIService.ExecQuery("SELECT * FROM DfsrReplicatedFolderConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
  For Each oFolder in colRGFolders
    k=k+1
    Set colRGConnections = oWMIService.ExecQuery("SELECT * FROM DfsrConnectionConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
    For Each oConnection in colRGConnections
      i=i+1
      binInbound = oConnection.Inbound
      strPartner = oConnection.PartnerName
      strRGName = oGroup.ReplicationGroupName
      strRFName = oFolder.ReplicatedFolderName
      If oConnection.Enabled = True and binInbound = False Then
        strSendingComputer = strComputer
        strReceivingComputer = strPartner
        strLine1="                {"    
        strLine2="                        ""{#GROUP}"":""" & strRGName & """," 
        strLine3="                        ""{#FOLDER}"":""" & strRFName & """," 
        strLine4="                        ""{#SENDING}"":""" & strSendingComputer & ""","                  
        if (n < colRGroups.Count) or (k < colRGFolders.count) or (i < colRGConnections.Count) then
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """},"
        else
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """}]}"       
        end if		
        wscript.echo strLine1
        wscript.echo strLine2
        wscript.echo strLine3
        wscript.echo strLine4
        wscript.echo strLine5	   
      End If
    Next
  Next
Next

Съгласен съм, скриптът може да не блести с елегантността на кода и нещо в него със сигурност може да бъде опростено, но основната му функция - да дава информация за параметрите на групите за репликация във формат, разбираем за Zabbix - изпълнява успешно.

Добавяне на скриптове към конфигурацията на Zabbix агент

Тук всичко е изключително просто. Добавете следните редове в края на конфигурационния файл на агента:

UserParameter=check_dfsr[*],cscript /nologo "C:Program FilesZabbix Agentget-Backlog.vbs" $1 $2 $3 $4
UserParameter=discovery_dfsr[*],cscript /nologo "C:Program FilesZabbix AgentDFSRDiscovery.vbs"

Разбира се, ние коригираме пътищата към тези, където имаме скриптове. Слагам ги в същата папка, където е инсталиран агентът.

След като направите промени, рестартирайте услугата на Zabbix агент.

Промяна на потребителя, под който се изпълнява услугата Zabbix Agent

За да получавате информация чрез dfsrdiag, помощната програма трябва да се изпълнява от името на акаунт, който има административни права както за изпращане, така и за получаване на членове на групата за репликация. Агентската услуга на Zabbix, работеща по подразбиране под системния акаунт, няма да може да изпълни такава заявка. Създадох отделен акаунт в домейна, дадох му административни права на необходимите сървъри и конфигурирах тези сървъри да стартират услугата от него.

Можете също така да отидете по друг начин: тъй като dfsrdiag, всъщност работи през същия WMI, който можете да използвате описание, как да дадем на домейн акаунт правото да го използва без издаване на административни права, но ако имаме много групи за репликация, тогава ще бъде трудно да издадем права на всяка група. Въпреки това, в случай, че искаме да наблюдаваме репликацията на Domain System Volume на домейн контролери, това може да е единствената приемлива опция, тъй като даването на администраторски права на домейн на акаунта на услугата за наблюдение не е най-добрата идея.

Шаблон за наблюдение

Въз основа на данните, които получих, създадох шаблон, който:

• Изпълнява автоматично откриване на репликационни групи веднъж на час,
• Веднъж на всеки 5 минути проверява размера на изоставането за всяка група,
• Съдържа тригер, който издава предупреждение, когато размерът на изоставането за която и да е група е повече от 100 за 30 минути. Тригерът е описан като прототип, който автоматично се добавя към откритите групи,
• Начертава размера на изоставането за всяка група за репликация.

Можете да изтеглите шаблона за Zabbix 2.2 тук.

Общо

След като импортираме шаблона в Zabbix и създадем акаунт с необходимите права, трябва само да копираме скриптовете на файловите сървъри, които искаме да наблюдаваме за DFSR, да добавим два реда към конфигурацията на агента върху тях и да рестартираме услугата на Zabbix агент, конфигуриране да работи от името на желания акаунт. Не са необходими други ръчни настройки за наблюдение на DFSR.

Източник: www.habr.com