Учим се да пишем смарт-контракти за Waves на RIDE и RIDE4DAPPS. Част 2 (DAO — Децентрализирана автономна организация)

Здравейте на всички!

В първата части ние подробно разгледахме как да създаваме и работим с dApp (децентрализирано приложение) в Waves RIDE IDE.

Нека сега малко тестваме разгледаното пример.

Етап 3. Тестиране на dApp акаунта

Кои проблеми веднага се набиват на очи с Alice dApp Акаунт?
На първо място:
Boob и Cooper могат случайно да изпратят средства на адреса на dApp, използвайки обикновен превод и по този начин няма да могат да получат достъп обратно до тях.

На второ място:
Ние по никакъв начин не ограничаваме Alice в изтеглянето на средства без съгласие с Boob или(и) Cooper. Обърнете внимание, че всички транзакции от Alice ще се изпълняват.

Нека поправим втория, като забраним на Alice превод транзакции. Разполагаме с коригирания скрипт:


Опитваме да изтеглим монети от dApp на Alice с нейния подпис. Получаваме грешка:

Опитваме да изтеглим чрез изтегляне:

broadcast(invokeScript({dappAddress: address(env.accounts[1]), call:{function:"withdraw",args:[{type:"integer", value: 1000000}]}, payment: []}))

Скриптът работи и с втория пункт разбрахме!

Етап 4. Създаваме DAO с гласуване

За съжаление, в езика RIDE все още не са предвидени възможности за работа с колекции (словари-словари, итератори, редюсери и др.). Въпреки това, за всякакви операции с плоски колекции ключ-стойност можем да проектираме система за работа с низове, съответно с ключове и тяхното декодиране.

Низовете са много лесно за конкатенция, низовете могат да се разделят по индекси.
Нека в качеството на тестов пример съберем и разгледаме низ и проверим как това ще повлияе на резултата от транзакцията.
Спираме на това, че Alice не е могла да подпише транзакция Transfer, тъй като тази възможност е била блокирана в @verifier за такъв тип транзакции.

Нека да поупражняваме низовете, а след това да разрешим това.

RIDE Низове

Транзакцията отново е възможна, знаем как да работим с низове.


Следователно, имаме всичко необходимо за написване на сложна логика DAO dApp.

Данни за транзакции

Данни за транзакции:
“Максималният размер за ключ е 100 символа, а ключът може да съдържа произволни символи на Unicode, включително интервали и други непринтиращи символи. Стойностите на низовете имат лимит от 32,768 байта и максималният брой възможни записи в данъчната транзакция е 100. Общият максимален размер на данъчната транзакция е около 140kb — за справка, почти точно дължината на пиесата на Шекспир 'Ромео и Жулиета'.”

Създаваме DAO при следните условия:
За да може стартиращото предприятие да получи финансиране, извиквайки getFunds() необходима е подкрепата на минимум 2 участници — инвеститори в DAO. Извеждане на може да бъде точно толкова, колкото общо са посочили на гласуването собствениците на DAO.

Нека създадем 3 типа ключове и добавим логика за работа с балансите в 2 нови функции vote и getFunds:
xx…xx_ia = инвеститори, наличен баланс (vote, deposit, withdrawal)
xx…xx_sv = стартиращи компании, брой гласове (vote, getFunds)
xx…xx_sf = стартиращи компании, брой гласове (vote, getFunds)
xx…xx = публичен адрес (35 символа)

Обърнете внимание, че в Vote ни се наложи да актуализираме веднага няколко полета:

WriteSet([DataEntry(key1, value1), DataEntry(key2, value2)]),

WriteSet ни позволява да направим няколко записа в рамките на една invokeScript транзакция.

Ето как изглежда в хранилището на ключ-стойност DAO dApp, след като Боб и Купър направиха вноските си ia-вноски:

Функцията за депозит малко се промени:

Сега настъпва най-важният момент в дейността на DAO — гласуването за проекти за финансиране.

Боб гласува за проект Нели на 500000 wavelets:

broadcast(invokeScript({dappAddress: address(env.accounts[1]), call:{function:"vote",args:[{type:"integer", value: 500000}, {type:"string", value: "3MrXEKJr9nDLNyVZ1d12Mq4jjeUYwxNjMsH"}]}, payment: []}))

В хранилището на данни виждаме всички необходими записи за адреса на Нели:

Купър също гласува за проект Нели.

Нека погледнем кода на функцията getFunds. Нели трябва да събере минимум 2 гласа, за да има възможност да изтегли средства от DAO.

Нели планира да изтегли половината от поверената ѝ сума:

broadcast(invokeScript({dappAddress: address(env.accounts[1]), call:{function:"getFunds",args:[{type:"integer", value: 500000}]}, payment: []}))

Тя успява, т.е. DAO работи!

Разгледахме процеса на създаване на DAO на езика RIDE4DAPPS.
В следващите части ще се запознаем по-подробно с рефакторирането на кода и тестването на случаи.

Пълната версия на кода в Waves RIDE IDE:

# In this example multiple accounts can deposit their funds to DAO and safely take them back, no one can interfere with this.
# DAO participants can also vote for particular addresses and let them withdraw invested funds then quorum has reached.
# An inner state is maintained as mapping `address=>waves`.
# https://medium.com/waves-lab/waves-announces-funding-for-ride-for-dapps-developers-f724095fdbe1

# You can try this contract by following commands in the IDE (ide.wavesplatform.com)
# Run commands as listed below
# From account #0:
#      deploy()
# From account #1: deposit funds
#      broadcast(invokeScript({dappAddress: address(env.accounts[1]), call:{function:"deposit",args:[]}, payment: [{amount: 100000000, asset:null }]}))
# From account #2: deposit funds
#      broadcast(invokeScript({dappAddress: address(env.accounts[1]), call:{function:"deposit",args:[]}, payment: [{amount: 100000000, asset:null }]}))
# From account #1: vote for startup
#      broadcast(invokeScript({dappAddress: address(env.accounts[1]), call:{function:"vote",args:[{type:"integer", value: 500000}, {type:"string", value: "3MrXEKJr9nDLNyVZ1d12Mq4jjeUYwxNjMsH"}]}, payment: []}))
# From account #2: vote for startup
#      broadcast(invokeScript({dappAddress: address(env.accounts[1]), call:{function:"vote",args:[{type:"integer", value: 500000}, {type:"string", value: "3MrXEKJr9nDLNyVZ1d12Mq4jjeUYwxNjMsH"}]}, payment: []}))
# From account #3: get invested funds
#      broadcast(invokeScript({dappAddress: address(env.accounts[1]), call:{function:"getFunds",args:[{type:"integer", value: 500000}]}, payment: []}))

{-# STDLIB_VERSION 3 #-}
{-# CONTENT_TYPE DAPP #-}
{-# SCRIPT_TYPE ACCOUNT #-}

@Callable(i)
func deposit() = {
   let pmt = extract(i.payment)
   if (isDefined(pmt.assetId)) then throw("can hodl waves only at the moment")
   else {
        let currentKey = toBase58String(i.caller.bytes)
        let xxxInvestorBalance = currentKey + "_" + "ib"
        let currentAmount = match getInteger(this, xxxInvestorBalance) {
            case a:Int => a
            case _ => 0
        }
        let newAmount = currentAmount + pmt.amount
        WriteSet([DataEntry(xxxInvestorBalance, newAmount)])
   }
}
@Callable(i)
func withdraw(amount: Int) = {
        let currentKey = toBase58String(i.caller.bytes)
        let xxxInvestorBalance = currentKey + "_" + "ib"
        let currentAmount = match getInteger(this, xxxInvestorBalance) {
            case a:Int => a
            case _ => 0
        }
        let newAmount = currentAmount - amount
     if (amount < 0)
            then throw("Can't withdraw negative amount")
    else if (newAmount < 0)
            then throw("Not enough balance")
            else ScriptResult(
                    WriteSet([DataEntry(xxxInvestorBalance, newAmount)]),
                    TransferSet([ScriptTransfer(i.caller, amount, unit)])
                )
    }
@Callable(i)
func getFunds(amount: Int) = {
        let quorum = 2
        let currentKey = toBase58String(i.caller.bytes)
        let xxxStartupFund = currentKey + "_" + "sf"
        let xxxStartupVotes = currentKey + "_" + "sv"
        let currentAmount = match getInteger(this, xxxStartupFund) {
            case a:Int => a
            case _ => 0
        }
        let totalVotes = match getInteger(this, xxxStartupVotes) {
            case a:Int => a
            case _ => 0
        }
        let newAmount = currentAmount - amount
    if (amount < 0)
            then throw("Can't withdraw negative amount")
    else if (newAmount < 0)
            then throw("Not enough balance")
    else if (totalVotes < quorum)
            then throw("Not enough votes. At least 2 votes required!")
    else ScriptResult(
                    WriteSet([
                        DataEntry(xxxStartupFund, newAmount)
                        ]),
                    TransferSet([ScriptTransfer(i.caller, amount, unit)])
                )
    }
@Callable(i)
func vote(amount: Int, address: String) = {
        let currentKey = toBase58String(i.caller.bytes)
        let xxxInvestorBalance = currentKey + "_" + "ib"
        let xxxStartupFund = address + "_" + "sf"
        let xxxStartupVotes = address + "_" + "sv"
        let currentAmount = match getInteger(this, xxxInvestorBalance) {
            case a:Int => a
            case _ => 0
        }
        let currentVotes = match getInteger(this, xxxStartupVotes) {
            case a:Int => a
            case _ => 0
        }
        let currentFund = match getInteger(this, xxxStartupFund) {
            case a:Int => a
            case _ => 0
        }
    if (amount <= 0)
            then throw("Can't withdraw negative amount")
    else if (amount > currentAmount)
            then throw("Not enough balance")
    else ScriptResult(
                    WriteSet([
                        DataEntry(xxxInvestorBalance, currentAmount - amount),
                        DataEntry(xxxStartupVotes, currentVotes + 1),
                        DataEntry(xxxStartupFund, currentFund + amount)
                        ]),
                    TransferSet([ScriptTransfer(i.caller, amount, unit)])
            )
    }
@Verifier(tx)
func verify() = {
    match tx {
        case t: TransferTransaction =>false
        case _ => true
    }
}

Първа част
Кодът в GitHub
Waves RIDE IDE
Анонс на грантовата програма

Източник: habr.com