এই নিবন্ধে, আমি গ্রেডল বিল্ডার ব্যবহার করে সোনাটাইপ মাভেন সেন্ট্রাল রিপোজিটরিতে গিথুব অ্যাকশনের মাধ্যমে স্ক্র্যাচ থেকে জাভা আর্টিফ্যাক্ট প্রকাশ করার প্রক্রিয়াটি ঘনিষ্ঠভাবে দেখতে চাই।

এক জায়গায় স্বাভাবিক টিউটোরিয়াল না থাকার কারণে আমি এই নিবন্ধটি লেখার সিদ্ধান্ত নিয়েছি। সমস্ত তথ্য বিভিন্ন উত্স থেকে টুকরো টুকরো সংগ্রহ করতে হয়েছিল, উপরন্তু, সম্পূর্ণ তাজা নয়। কে যত্ন করে, বিড়ালের নীচে স্বাগতম।

সোনাটাইপে একটি সংগ্রহস্থল তৈরি করা হচ্ছে

প্রথম ধাপ হল সোনাটাইপ মাভেন সেন্ট্রালে একটি সংগ্রহস্থল তৈরি করা। এই জন্য আমরা যাই এখানে, নিবন্ধন করুন এবং একটি নতুন টাস্ক তৈরি করুন, আমাদের একটি সংগ্রহস্থল তৈরি করতে বলুন। আমরা আমাদের মধ্যে ড্রাইভ গ্রুপআইডি প্রকল্প, প্রকল্প URL প্রকল্প লিঙ্ক এবং SCM url সংস্করণ নিয়ন্ত্রণ সিস্টেমের একটি লিঙ্ক যেখানে প্রকল্পটি অবস্থিত। গ্রুপআইডি এখানে com.example, com.example.domain, com.example.testsupport ফর্মের হওয়া উচিত এবং আপনার গিথুবের লিঙ্কের আকারেও হতে পারে: github.com/yourusername -> io.github.yourusername. যে কোনো ক্ষেত্রে, আপনাকে এই ডোমেন বা প্রোফাইলের মালিকানা যাচাই করতে হবে। আপনি যদি একটি গিথুব প্রোফাইল নির্দিষ্ট করেন, তাহলে আপনাকে পছন্দসই নামের একটি সর্বজনীন সংগ্রহস্থল তৈরি করতে বলা হবে।

নিশ্চিতকরণের কিছু সময় পরে, আপনার GroupId তৈরি করা হবে এবং আমরা পরবর্তী ধাপে, Gradle কনফিগারেশনে যেতে পারি।

Gradle কনফিগার করা হচ্ছে

লেখার সময়, আমি গ্রেডল প্লাগইনগুলি খুঁজে পাইনি যা আর্টিফ্যাক্ট প্রকাশ করতে সাহায্য করতে পারে। এই একমাত্র প্লাগইন যা আমি পেয়েছি, তবে লেখক এটিকে আরও সমর্থন করতে অস্বীকার করেছেন। অতএব, আমি নিজেই সবকিছু করার সিদ্ধান্ত নিয়েছি, যেহেতু এটি করা খুব কঠিন নয়।

প্রকাশের জন্য সোনাটাইপের প্রয়োজনীয়তাগুলি বের করার জন্য প্রথম জিনিসটি। তারা নিম্নলিখিত:

• সোর্স কোড এবং JavaDoc এর প্রাপ্যতা, যেমন। অবশ্যই আসবে -sources.jar и-javadoc.jar নথি পত্র. ডকুমেন্টেশনে বলা হয়েছে, যদি সোর্স কোড বা ডকুমেন্টেশন প্রদান করা সম্ভব না হয়, আপনি একটি ডামি তৈরি করতে পারেন -sources.jar বা -javadoc.jar পরীক্ষা পাস করার জন্য ভিতরে একটি সাধারণ README সহ।
• সমস্ত ফাইল সাইন ইন করা আবশ্যক GPG/PGPএবং .asc স্বাক্ষর ধারণকারী ফাইল প্রতিটি ফাইলের জন্য অন্তর্ভুক্ত করা আবশ্যক.
• উপস্থিতি pom ফাইল
• সঠিক মান groupId, artifactId и version. সংস্করণটি একটি নির্বিচারে স্ট্রিং হতে পারে এবং এর সাথে শেষ হতে পারে না -SNAPSHOT
• উপস্থিতি আবশ্যক name, description и url
• লাইসেন্স, বিকাশকারী এবং সংস্করণ নিয়ন্ত্রণ সিস্টেম সম্পর্কে তথ্যের উপস্থিতি

এগুলি হল মৌলিক নিয়ম যা প্রকাশ করার সময় অবশ্যই মেনে চলতে হবে৷ সম্পূর্ণ তথ্য উপলব্ধ এখানে.

আমরা এই প্রয়োজনীয়তাগুলি বাস্তবায়ন করি build.gradle ফাইল প্রথমে ডেভেলপার, লাইসেন্স, ভার্সন কন্ট্রোল সিস্টেম সম্পর্কে সমস্ত প্রয়োজনীয় তথ্য যোগ করা যাক এবং প্রকল্পের url, নাম এবং বিবরণ সেট করি। এর জন্য একটি সহজ পদ্ধতি লিখুন:

def customizePom(pom) {
    pom.withXml {
        def root = asNode()

        root.dependencies.removeAll { dep ->
            dep.scope == "test"
        }

        root.children().last() + {
            resolveStrategy = DELEGATE_FIRST

            description 'Some description of artifact'
            name 'Artifct name'
            url 'https://github.com/login/projectname'
            organization {
                name 'com.github.login'
                url 'https://github.com/login'
            }
            issueManagement {
                system 'GitHub'
                url 'https://github.com/login/projectname/issues'
            }
            licenses {
                license {
                    name 'The Apache License, Version 2.0'
                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                }
            }
            scm {
                url 'https://github.com/login/projectname'
                connection 'scm:https://github.com/login/projectname.git'
                developerConnection 'scm:git://github.com/login/projectname.git'
            }
            developers {
                developer {
                    id 'dev'
                    name 'DevName'
                    email '[email protected]'
                }
            }
        }
    }
}

পরবর্তী, আপনি উত্পন্ন সমাবেশ সময় যে নির্দিষ্ট করতে হবে -sources.jar и-javadoc.jar নথি পত্র. এই বিভাগের জন্য java আপনাকে নিম্নলিখিত যোগ করতে হবে:

java {
    withJavadocJar()
    withSourcesJar()
}

চলুন শেষ প্রয়োজনে এগিয়ে যাই, একটি GPG/PGP স্বাক্ষর সেট আপ করুন। এটি করতে, প্লাগইনটি সংযুক্ত করুন signing:

plugins {
    id 'signing'
}

এবং একটি বিভাগ যোগ করুন:

signing {
    sign publishing.publications
}

অবশেষে, এর একটি বিভাগ যোগ করা যাক publishing:

publishing {
    publications {
        mavenJava(MavenPublication) {
            customizePom(pom)
            groupId group
            artifactId archivesBaseName
            version version

            from components.java
        }
    }
    repositories {
        maven {
            url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            credentials {
                username sonatypeUsername
                password sonatypePassword
            }
        }
    }
}

এটা হল sonatype ব্যবহারকারীর নাম и sonatypeপাসওয়ার্ড লগইন এবং পাসওয়ার্ড ধারণকারী ভেরিয়েবল অন নিবন্ধনের সময় তৈরি sonatype.org.

এভাবেই ফাইনাল build.gradle এটি দেখতে হবে:

সম্পূর্ণ বিল্ড.গ্রেডল কোড

plugins {
    id 'java'
    id 'maven-publish'
    id 'signing'
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
    withJavadocJar()
    withSourcesJar()
}

group 'io.github.githublogin'
archivesBaseName = 'projectname'
version = System.getenv('RELEASE_VERSION') ?: "0.0.1"

repositories {
    mavenCentral()
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.5.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.5.2'
}

test {
    useJUnitPlatform()
}

jar {
    from sourceSets.main.output
    from sourceSets.main.allJava
}

signing {
    sign publishing.publications
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            customizePom(pom)
            groupId group
            artifactId archivesBaseName
            version version

            from components.java
        }
    }
    repositories {
        maven {
            url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            credentials {
                username sonatypeUsername
                password sonatypePassword
            }
        }
    }
}

def customizePom(pom) {
    pom.withXml {
        def root = asNode()

        root.dependencies.removeAll { dep ->
            dep.scope == "test"
        }

        root.children().last() + {
            resolveStrategy = DELEGATE_FIRST

            description 'Some description of artifact'
            name 'Artifct name'
            url 'https://github.com/login/projectname'
            organization {
                name 'com.github.login'
                url 'https://github.com/githublogin'
            }
            issueManagement {
                system 'GitHub'
                url 'https://github.com/githublogin/projectname/issues'
            }
            licenses {
                license {
                    name 'The Apache License, Version 2.0'
                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                }
            }
            scm {
                url 'https://github.com/githublogin/projectname'
                connection 'scm:https://github.com/githublogin/projectname.git'
                developerConnection 'scm:git://github.com/githublogin/projectname.git'
            }
            developers {
                developer {
                    id 'dev'
                    name 'DevName'
                    email '[email protected]'
                }
            }
        }
    }
}

আমি নোট করতে চাই যে আমরা পরিবেশ পরিবর্তনশীল থেকে সংস্করণটি পাই: System.getenv('RELEASE_VERSION'). আমরা সমাবেশের সময় এটি প্রকাশ করব এবং ট্যাগ নাম থেকে এটি গ্রহণ করব।

PGP কী প্রজন্ম

Sonatype-এর প্রয়োজনীয়তাগুলির মধ্যে একটি হল যে সমস্ত ফাইল একটি GPG/PGP কী দিয়ে স্বাক্ষর করা উচিত। এই জন্য আমরা যাই এখানে এবং আপনার অপারেটিং সিস্টেমের জন্য GnuPG ইউটিলিটি ডাউনলোড করুন।

• আমরা একটি মূল জোড়া তৈরি করি: gpg --gen-key, একটি ব্যবহারকারীর নাম, ই-মেইল লিখুন এবং একটি পাসওয়ার্ড সেট করুন।
• আমরা খুজে বের করব id কমান্ড সহ আমাদের কী: gpg --list-secret-keys --keyid-format short. স্ল্যাশের পরে আইডি নির্দিষ্ট করা হবে, উদাহরণস্বরূপ: rsa2048/9B695056
• সার্ভারে সর্বজনীন কী প্রকাশ করা হচ্ছে https://keys.openpgp.org কমান্ড সহ: gpg --keyserver [https://keys.openpgp.org](https://keys.openpgp.org/) --send-keys 9B695056
• আমরা গোপন কীটি একটি নির্বিচারে রপ্তানি করি, ভবিষ্যতে আমাদের এটির প্রয়োজন হবে: gpg --export-secret-key 9B695056 > D:\gpg\9B695056.gpg

Github অ্যাকশন সেট আপ করা হচ্ছে

আসুন চূড়ান্ত পর্যায়ে চলে যাই, বিল্ড সেট আপ করি এবং Github অ্যাকশন ব্যবহার করে স্বয়ংক্রিয়-প্রকাশ করি।
Github অ্যাকশন হল এমন একটি বৈশিষ্ট্য যা আপনাকে একটি সম্পূর্ণ CI/CD চক্র প্রয়োগ করে কর্মপ্রবাহ স্বয়ংক্রিয় করতে দেয়। বিল্ড, পরীক্ষা এবং স্থাপনা বিভিন্ন ইভেন্ট দ্বারা ট্রিগার করা যেতে পারে: কোড পুশ, রিলিজ তৈরি বা সমস্যা। এই কার্যকারিতা সর্বজনীন সংগ্রহস্থলের জন্য একেবারে বিনামূল্যে।

এই বিভাগে, আমি আপনাকে দেখাব কিভাবে বিল্ড এবং পুশ কোড সেট আপ করতে হয় এবং রিলিজের সময় সোনাটাইপ রিপোজিটরিতে স্থাপন করতে হয়, সেইসাথে সিক্রেট সেট আপ করতে হয়।

আমরা গোপন সেট

স্বয়ংক্রিয় সমাবেশ এবং স্থাপনার জন্য, আমাদের বেশ কয়েকটি গোপন মান প্রয়োজন, যেমন কী আইডি, কী তৈরি করার সময় আমরা যে পাসওয়ার্ডটি দিয়েছিলাম, PGP কী নিজেই, এবং সোনাটাইপ লগইন/পাসওয়ার্ড। আপনি তাদের সংগ্রহস্থল সেটিংসে একটি বিশেষ বিভাগে সেট করতে পারেন:

আমরা নিম্নলিখিত ভেরিয়েবল সেট করি:

• SONATYPE_USERNAME / SONATYPE_PASSWORD - লগইন / পাসওয়ার্ড যা আমরা সোনাটাইপের সাথে নিবন্ধন করার সময় প্রবেশ করিয়েছিলাম
• SIGNING_KEYID/SIGNING_PASSWORD — PGP কী আইডি এবং পাসওয়ার্ড প্রজন্মের সময় সেট করা হয়।

আমি আরও বিস্তারিতভাবে GPG_KEY_CONTENTS ভেরিয়েবলে থাকতে চাই। আসল বিষয়টি হল প্রকাশনার জন্য আমাদের একটি ব্যক্তিগত PGP কী প্রয়োজন৷ এটি গোপনে পোস্ট করার জন্য, আমি ব্যবহার করেছি নির্দেশাবলী এবং উপরন্তু কর্ম একটি সংখ্যা তৈরি.

• আসুন gpg দিয়ে আমাদের কী এনক্রিপ্ট করি: gpg --symmetric --cipher-algo AES256 9B695056.gpgএকটি পাসওয়ার্ড প্রবেশ করে। এটি একটি ভেরিয়েবলে স্থাপন করা উচিত: SECRET_PASSPHRASE৷
• আসুন বেস64 ব্যবহার করে প্রাপ্ত এনক্রিপ্ট করা কীটিকে একটি পাঠ্য আকারে অনুবাদ করি: base64 9B695056.gpg.gpg > 9B695056.txt. বিষয়বস্তু ভেরিয়েবলে স্থাপন করা হবে: GPG_KEY_CONTENTS।

কোড পুশ করার সময় এবং পিআর তৈরি করার সময় সেটআপ তৈরি করুন

প্রথমে আপনাকে আপনার প্রকল্পের রুটে একটি ফোল্ডার তৈরি করতে হবে: .github/workflows.

এটিতে, ফাইলটি চিহ্নিত করুন, উদাহরণস্বরূপ, gradle-ci-build.yml নিম্নলিখিত বিষয়বস্তু সহ:

name: build

on:
  push:
    branches:
      - master
      - dev
      - testing
  pull_request:

jobs:
  build:
    runs-on: ubuntu-latest
    steps:
      - uses: actions/checkout@v1
      - name: Set up JDK 8
        uses: actions/setup-java@v1
        with:
          java-version: 8

      - name: Build with Gradle
        uses: eskatos/gradle-command-action@v1
        with:
          gradle-version: current
          arguments: build -PsonatypeUsername=${{secrets.SONATYPE_USERNAME}} -PsonatypePassword=${{secrets.SONATYPE_PASSWORD}}

শাখাগুলিতে ঠেলে দেওয়ার সময় এই কর্মপ্রবাহটি কার্যকর করা হবে master, dev и testing, এছাড়াও পুল অনুরোধ তৈরি করার সময়।

কাজের বিভাগটি নির্দিষ্ট ইভেন্টগুলিতে কার্যকর করার পদক্ষেপগুলি নির্দিষ্ট করে। এই ক্ষেত্রে, আমরা উবুন্টুর সর্বশেষ সংস্করণ তৈরি করব, জাভা 8 ব্যবহার করব এবং গ্রেডলের জন্য প্লাগইন ব্যবহার করব। eskatos/gradle-command-action@v1যা, নির্মাতার সর্বশেষ সংস্করণ ব্যবহার করে, নির্দেশিত কমান্ড চালাবে arguments. ভেরিয়েবল secrets.SONATYPE_USERNAME и secrets.SONATYPE_PASSWORD এই গোপন আমরা আগে জিজ্ঞাসা.

বিল্ড ফলাফল অ্যাকশন ট্যাবে প্রতিফলিত হবে:

একটি নতুন রিলিজ প্রকাশিত হলে স্বয়ংক্রিয়ভাবে স্থাপন করুন

অটোডিপ্লয়ের জন্য একটি পৃথক ওয়ার্কফ্লো ফাইল তৈরি করা যাক gradle-ci-publish.yml:

name: publish

on:
  push:
    tags:
      - 'v*'

jobs:
  publish:
    runs-on: ubuntu-latest
    steps:
      - uses: actions/checkout@v1
      - name: Set up JDK 8
        uses: actions/setup-java@v1
        with:
          java-version: 8

      - name: Prepare to publish
        run: |
          echo '${{secrets.GPG_KEY_CONTENTS}}' | base64 -d > publish_key.gpg
          gpg --quiet --batch --yes --decrypt --passphrase="${{secrets.SECRET_PASSPHRASE}}" 
          --output secret.gpg publish_key.gpg
          echo "::set-env name=RELEASE_VERSION::${GITHUB_REF:11}"

      - name: Publish with Gradle
        uses: eskatos/gradle-command-action@v1
        with:
          gradle-version: current
          arguments: test publish -Psigning.secretKeyRingFile=secret.gpg -Psigning.keyId=${{secrets.SIGNING_KEYID}} -Psigning.password=${{secrets.SIGNING_PASSWORD}} -PsonatypeUsername=${{secrets.SONATYPE_USERNAME}} -PsonatypePassword=${{secrets.SONATYPE_PASSWORD}}

ফাইলটি আগেরটির সাথে প্রায় অভিন্ন, যে ইভেন্টে এটি ট্রিগার করা হবে বাদে৷ এই ক্ষেত্রে, এটি v দিয়ে শুরু হওয়া একটি নাম দিয়ে একটি ট্যাগ তৈরি করার ঘটনা।

স্থাপনের আগে, আমাদের গোপনীয়তা থেকে PGP কী বের করে প্রকল্পের মূলে স্থাপন করতে হবে, সেইসাথে এটিকে ডিক্রিপ্ট করতে হবে। পরবর্তী, আমাদের একটি বিশেষ পরিবেশ পরিবর্তনশীল সেট করতে হবে RELEASE_VERSION যা আমরা উল্লেখ করি gradle.build ফাইল এই সব বিভাগে করা হয় Prepare to publish. আমরা GPG_KEY_CONTENTS ভেরিয়েবল থেকে আমাদের কী পাই, এটিকে একটি gpg ফাইলে অনুবাদ করি, তারপর ফাইলটিতে রেখে এটিকে ডিক্রিপ্ট করি secret.gpg.

পরবর্তী, আমরা একটি বিশেষ পরিবর্তনশীল চালু GITHUB_REF, যা থেকে আমরা ট্যাগ তৈরি করার সময় যে সংস্করণটি সেট করি তা পেতে পারি। এই পরিবর্তনশীল এই ক্ষেত্রে প্রাসঙ্গিক. refs/tags/v0.0.2 যা থেকে আমরা একটি নির্দিষ্ট সংস্করণ পেতে প্রথম 11টি অক্ষর কেটে ফেলেছি। এর পরে, আমরা প্রকাশের জন্য স্ট্যান্ডার্ড গ্রেডল কমান্ড ব্যবহার করি: test publish

সোনাটাইপ সংগ্রহস্থলে স্থাপনার ফলাফল পরীক্ষা করা হচ্ছে

রিলিজ তৈরি হওয়ার পরে, পূর্ববর্তী বিভাগে বর্ণিত ওয়ার্কফ্লো শুরু করা উচিত। এটি করার জন্য, একটি রিলিজ তৈরি করুন:

ট্যাগের নাম অবশ্যই v দিয়ে শুরু হবে। যদি, প্রকাশ প্রকাশ ক্লিক করার পরে, কর্মপ্রবাহ সফলভাবে সম্পন্ন হয়, আমরা যেতে পারি সোনাটাইপ নেক্সাস নিশ্চিত করুন:

শিল্পকর্মটি স্টেজিং ভান্ডারে উপস্থিত হয়েছিল। এটি অবিলম্বে ওপেন স্ট্যাটাসে উপস্থিত হয়, তারপরে উপযুক্ত বোতাম টিপে এটিকে ম্যানুয়ালি ক্লোজ স্ট্যাটাসে স্থানান্তর করতে হবে। সমস্ত প্রয়োজনীয়তা পূরণ হয়েছে কিনা তা পরীক্ষা করার পরে, আর্টিফ্যাক্টটি ক্লোজ স্ট্যাটাসে চলে যায় এবং পরিবর্তনের জন্য আর উপলব্ধ নেই। এই ফর্মে, এটি MavenCentral এ শেষ হবে। সব ঠিক থাকলে, আপনি বোতাম টিপুন করতে পারেন মুক্তি, এবং শিল্পকর্মটি সোনাটাইপ সংগ্রহস্থলে শেষ হবে।

আর্টিফ্যাক্টটি ম্যাভেনসেন্ট্রালে প্রবেশ করার জন্য, আপনাকে এটির জন্য জিজ্ঞাসা করতে হবে যা আমরা একেবারে শুরুতে তৈরি করেছি। আপনাকে শুধুমাত্র একবার এটি করতে হবে, তাই আমরা প্রথমবার প্রকাশ করছি। পরবর্তী সময়ে, এটির প্রয়োজন নেই, সবকিছু স্বয়ংক্রিয়ভাবে সিঙ্ক্রোনাইজ হবে। তারা আমার জন্য দ্রুত সিঙ্ক্রোনাইজেশন চালু করেছে, কিন্তু আর্টিফ্যাক্টটি MavenCentral-এ উপলব্ধ হতে প্রায় 5 দিন সময় লেগেছে।

এই সব, আমরা MavenCentral আমাদের শিল্পকর্ম প্রকাশ করেছি.

দরকারী লিঙ্ক

• অনুরূপ একটি নিবন্ধ, শুধুমাত্র maven মাধ্যমে প্রকাশ
• উপস্থাপনকারী ভান্ডার সোনাটাইপ
• জির সোনাটাইপ যাতে টাস্ক তৈরি করা যায়
• উদাহরণ সংগ্রহস্থল যেখানে এটি সব সেট আপ করা আছে

উত্স: www.habr.com