টেলিগ্রাম v 2.0 থেকে Mikrotik স্ক্রিপ্টগুলির দূরবর্তী সক্রিয়করণ

সব গত ছুটির সঙ্গে. এই থিম আরও ভাল 2016 সালে আমি যা লিখেছিলাম তার সংস্করণ এখানে.

সাধারণভাবে, অপারেশনের নীতিটি পরিবর্তিত হয়নি, শুধুমাত্র পার্থক্য হল যে এখন এটি দেরি না করে তাত্ক্ষণিকভাবে কাজ করে।

আমরা স্ক্রিপ্টটি Mikrotik এ আপলোড করি, BotID এবং ChatID আমাদের নিজস্ব পরিবর্তন করি এবং এর জন্য একটি সময়সূচী তৈরি করি। স্টার্টআপে "স্টার্ট টাইম" প্যারামিটার সেট করুন (স্টার্টআপে স্ক্রিপ্টটি চালান।)
ব্যবধান: 00:00:00
বাকি সব যেমন ছিল.

টেলিগ্রাম-v2

:delay 10
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;
:local chatId 0;
:local messageId 0;


:local parse do={
  :local startLoc ([:find $content $variable -1] + [:len $variable] + 2);
  :local commaLoc ([:find $content "," $startLoc] - 1 + 1);
  :local braceLoc ([:find $content "}" $startLoc] - 1 + 1);
  :local endLoc $commaLoc;
  :local startSymbol [:pick $content $startLoc]
  :if ($braceLoc != 0 and ($commaLoc = 0 or $braceLoc < $commaLoc)) do={
    :set endLoc $braceLoc;
  };
  :if ($startSymbol = "{") do={
    :set endLoc ($braceLoc + 1);
  };
  :if ($quotas = true) do={
    :set startLoc ($startLoc + 1);
    :set endLoc ($endLoc - 1);
  }
  :if ($endLoc < $startLoc) do={
    :set endLoc ($startLoc + 1);
  };
  :local message [:pick $content $startLoc $endLoc]
  #:log info $message;
  :return $message;
}


:while ( true ) do={
  :do {
    #:log info "https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60";
    :tool fetch url=("https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60") dst-path="getUpdates";
    :local content [/file get [/file find name=getUpdates] contents] ;
    #:log info $content;
    :if ([:len $content] > 30) do={
      :set messageId ([$parse content=$content variable="update_id"] + 1)
      :local message [$parse content=$content variable="text" quotas=true]
      :local chat [$parse content=$content variable="chat"]
      :local chatId [$parse content=$chat variable="id"]      
      
      :if (($chatId = $myChatID) and ([/system script find name=$message] != "")) do={
        :system script run $message;
      } else={
        :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$chatId&text=$mtIdentity: Unknown command: $message") keep-result=no
      }
    }
  } on-error={}
};

কয়েক বছরের ব্যবহারের জন্য, একটি বাগ প্রকাশিত হয়েছিল, কিছু কারণে, দুর্বল মিক্রোটিক কোনও কারণে স্ক্রিপ্টটি বন্ধ করে দেয়, আরও শক্তিশালীগুলির উপর এটি অবিরাম কাজ করে।

এই উদ্দেশ্যে, আমি একটি ওয়াচডগ ক্রাচ নিক্ষেপ করেছি। এখানে আমরা স্ক্রিপ্টের নামটি উপরে নির্দেশিত একটিতে পরিবর্তন করি। এবং রিস্টার্টের ব্যবধান 5 মিনিটে সেট করুন। প্রতি 5 মিনিটে, আমাদের "ওয়াচ ডগ" স্ক্রিপ্টটি পরীক্ষা করবে এবং যদি এটি কাজ না করে তবে এটি চালাবে।

WatchDogT.me

:global scriptname "t.me"
:if ([:len [/system script job find script=$"scriptname"]] > 0) do={
:log info "$scriptname Already Running - killing old script before continuing"
:foreach counter in=[/system script job find script=$"scriptname"] do={
/system script job remove $counter
}
}
/system script run $scriptname

এবং ডেজার্টের জন্য, স্ক্রিপ্টটি Mikrotik ফোরাম থেকে নেওয়া হয়েছে।
লগ থেকে আমাদের কার্টে গুরুত্বপূর্ণ বিষয় পাঠায়।

স্ক্রিপ্টটি সময়সূচীতে নিক্ষেপ করুন এবং প্রতি 5 মিনিটে পুনঃসূচনা ব্যবধান নির্দিষ্ট করুন, BotID এবং ChatID আপনার নিজের মত পরিবর্তন করুন।

notify-log

:global lastTime
:global output
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;

:local LogGet [ :toarray [ /log find topics~"critical" || message~"login failure" || message~"[Ff]ailure" ] ] ;
:local LogtLineCount [ :len $LogGet ] ;
if ($LogtLineCount > 0) do={
   :local currentTime "$[ /log get [ :pick $LogGet ($LogtLineCount -1) ] time ]";
   :if ([:len $currentTime] = 10 ) do={
      :set currentTime [ :pick $currentTime 0 10 ];
   }
   :set output "$currentTime - $[/log get [ :pick $LogGet ($LogtLineCount-1) ] message ]";
   :if (([:len $lastTime] < 1) || (([:len $lastTime] > 0) && ($lastTime != $currentTime))) do={
      :set lastTime $currentTime ;
         :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$myChatID&text="$mtIdentity" :  $output") keep-result=no
   }
}

আমরা ফলাফল পাই:

উত্স: www.habr.com