পুতুল একটি কনফিগারেশন ম্যানেজমেন্ট সিস্টেম। এটি হোস্টকে পছন্দসই অবস্থায় আনতে এবং এই অবস্থা বজায় রাখতে ব্যবহৃত হয়।

আমি এখন পাঁচ বছরেরও বেশি সময় ধরে পুতুলের সাথে কাজ করছি। এই পাঠ্যটি মূলত অফিসিয়াল ডকুমেন্টেশন থেকে মূল পয়েন্টগুলির একটি অনুবাদিত এবং পুনর্বিন্যাস সংকলন, যা নতুনদের দ্রুত পুতুলের সারমর্ম বুঝতে সাহায্য করবে।

মৌলিক তথ্য

পুতুলের অপারেটিং সিস্টেম হল ক্লায়েন্ট-সার্ভার, যদিও এটি সীমিত কার্যকারিতার সাথে সার্ভারহীন অপারেশনকেও সমর্থন করে।

অপারেশনের একটি টান মডেল ব্যবহার করা হয়: ডিফল্টরূপে, প্রতি আধ ঘন্টায় একবার, ক্লায়েন্টরা একটি কনফিগারেশনের জন্য সার্ভারের সাথে যোগাযোগ করে এবং এটি প্রয়োগ করে। আপনি যদি Ansible এর সাথে কাজ করে থাকেন তবে তারা একটি ভিন্ন পুশ মডেল ব্যবহার করে: প্রশাসক কনফিগারেশন প্রয়োগ করার প্রক্রিয়া শুরু করেন, ক্লায়েন্টরা নিজেরাই কিছু প্রয়োগ করবে না।

নেটওয়ার্ক যোগাযোগের সময়, দ্বি-মুখী TLS এনক্রিপশন ব্যবহার করা হয়: সার্ভার এবং ক্লায়েন্টের নিজস্ব ব্যক্তিগত কী এবং সংশ্লিষ্ট শংসাপত্র রয়েছে। সাধারণত সার্ভার ক্লায়েন্টদের জন্য সার্টিফিকেট জারি করে, কিন্তু নীতিগতভাবে এটি একটি বহিরাগত CA ব্যবহার করা সম্ভব।

ইশতেহারের ভূমিকা

পুতুল পরিভাষায় পুতুল সার্ভারে সংযোগ নোড (নোড)। নোডের জন্য কনফিগারেশন লেখা আছে ইশতেহারে একটি বিশেষ প্রোগ্রামিং ভাষায় - পুতুল ডিএসএল।

পুতুল ডিএসএল একটি ঘোষণামূলক ভাষা। এটি পৃথক সংস্থানগুলির ঘোষণার আকারে নোডের পছন্দসই অবস্থা বর্ণনা করে, উদাহরণস্বরূপ:

• ফাইলটি বিদ্যমান এবং এতে নির্দিষ্ট বিষয়বস্তু রয়েছে।
• প্যাকেজ ইনস্টল করা হয়.
• সেবা শুরু হয়েছে।

সম্পদ আন্তঃসংযুক্ত হতে পারে:

• নির্ভরতা আছে, তারা সম্পদ ব্যবহার করা হয় যে ক্রম প্রভাবিত.
  উদাহরণস্বরূপ, "প্রথমে প্যাকেজটি ইনস্টল করুন, তারপরে কনফিগারেশন ফাইলটি সম্পাদনা করুন, তারপরে পরিষেবাটি শুরু করুন।"
• বিজ্ঞপ্তি আছে - যদি একটি সংস্থান পরিবর্তিত হয় তবে এটি সদস্যতা নেওয়া সংস্থানগুলিতে বিজ্ঞপ্তি পাঠায়।
  উদাহরণস্বরূপ, কনফিগারেশন ফাইল পরিবর্তন হলে, আপনি স্বয়ংক্রিয়ভাবে পরিষেবাটি পুনরায় চালু করতে পারেন।

অতিরিক্তভাবে, পাপেট ডিএসএলের ফাংশন এবং ভেরিয়েবলের পাশাপাশি শর্তসাপেক্ষ বিবৃতি এবং নির্বাচক রয়েছে। বিভিন্ন টেমপ্লেটিং প্রক্রিয়াও সমর্থিত - EPP এবং ERB।

পাপেট রুবিতে লেখা, তাই অনেকগুলো গঠন ও পদ সেখান থেকে নেওয়া হয়েছে। রুবি আপনাকে পাপেট প্রসারিত করতে দেয় - জটিল যুক্তি, নতুন ধরনের সংস্থান, ফাংশন যোগ করুন।

যখন পাপেট চলছে, সার্ভারে প্রতিটি নির্দিষ্ট নোডের জন্য ম্যানিফেস্টগুলি একটি ডিরেক্টরিতে সংকলিত হয়। ডাইরেক্টরি ফাংশন, ভেরিয়েবল এবং কন্ডিশনাল স্টেটমেন্টের প্রসারণের মান গণনা করার পরে সম্পদ এবং তাদের সম্পর্কের একটি তালিকা।

সিনট্যাক্স এবং কোডস্টাইল

এখানে অফিসিয়াল ডকুমেন্টেশনের কিছু অংশ রয়েছে যা আপনাকে সিনট্যাক্স বুঝতে সাহায্য করবে যদি প্রদত্ত উদাহরণগুলি যথেষ্ট না হয়:

• বিভিন্ন ভাষার গঠনের সিনট্যাক্স।
• রিসোর্স সিনট্যাক্স।
• নোড বর্ণনা করার জন্য সিনট্যাক্স।

ম্যানিফেস্টটি কেমন দেখাচ্ছে তার একটি উদাহরণ এখানে দেওয়া হল:

# Комментарии пишутся, как и много где, после решётки.
#
# Описание конфигурации ноды начинается с ключевого слова node,
# за которым следует селектор ноды — хостнейм (с доменом или без)
# или регулярное выражение для хостнеймов, или ключевое слово default.
#
# После этого в фигурных скобках описывается собственно конфигурация ноды.
#
# Одна и та же нода может попасть под несколько селекторов. Про приоритет
# селекторов написано в статье про синтаксис описания нод.
node 'hostname', 'f.q.d.n', /regexp/ {
  # Конфигурация по сути является перечислением ресурсов и их параметров.
  #
  # У каждого ресурса есть тип и название.
  #
  # Внимание: не может быть двух ресурсов одного типа с одинаковыми названиями!
  #
  # Описание ресурса начинается с его типа. Тип пишется в нижнем регистре.
  # Про разные типы ресурсов написано ниже.
  #
  # После типа в фигурных скобках пишется название ресурса, потом двоеточие,
  # дальше идёт опциональное перечисление параметров ресурса и их значений.
  # Значения параметров указываются через т.н. hash rocket (=>).
  resource { 'title':
    param1 => value1,
    param2 => value2,
    param3 => value3,
  }
}

ইন্ডেন্টেশন এবং লাইন ব্রেক ম্যানিফেস্টের একটি প্রয়োজনীয় অংশ নয়, তবে একটি সুপারিশ করা হয়েছে শৈলী গাইড. সারসংক্ষেপ:

• টু-স্পেস ইন্ডেন্ট, ট্যাব ব্যবহার করা হয় না।
• কোঁকড়া ধনুর্বন্ধনী একটি স্থান দ্বারা পৃথক করা হয়; কোলন একটি স্থান দ্বারা পৃথক করা হয় না।
• প্রতিটি প্যারামিটারের পরে কমা, শেষটি সহ। প্রতিটি পরামিতি একটি পৃথক লাইনে রয়েছে। প্যারামিটার এবং একটি প্যারামিটার ছাড়া ক্ষেত্রে একটি ব্যতিক্রম তৈরি করা হয়েছে: আপনি একটি লাইনে এবং একটি কমা ছাড়াই লিখতে পারেন (যেমন resource { 'title': } и resource { 'title': param => value }).
• পরামিতিগুলির তীরগুলি একই স্তরে হওয়া উচিত।
• সম্পদ সম্পর্ক তীর তাদের সামনে লেখা হয়.

প্যাপেটসার্ভারে ফাইলের অবস্থান

আরও ব্যাখ্যার জন্য, আমি "রুট ডিরেক্টরি" ধারণাটি চালু করব। রুট ডিরেক্টরি হল সেই ডিরেক্টরি যাতে একটি নির্দিষ্ট নোডের জন্য পুতুল কনফিগারেশন থাকে।

রুট ডিরেক্টরিটি পাপেটের সংস্করণ এবং ব্যবহৃত পরিবেশের উপর নির্ভর করে পরিবর্তিত হয়। পরিবেশ হল স্বতন্ত্র কনফিগারেশনের সেট যা আলাদা ডিরেক্টরিতে সংরক্ষিত থাকে। সাধারণত গিট-এর সংমিশ্রণে ব্যবহৃত হয়, যে ক্ষেত্রে গিট শাখা থেকে পরিবেশ তৈরি করা হয়। তদনুসারে, প্রতিটি নোড এক বা অন্য পরিবেশে অবস্থিত। এটি নোড বা ENC-তে কনফিগার করা যেতে পারে, যা আমি পরবর্তী নিবন্ধে বলব।

• তৃতীয় সংস্করণে ("পুরানো পুতুল") বেস ডিরেক্টরি ছিল /etc/puppet. পরিবেশের ব্যবহার ঐচ্ছিক - উদাহরণস্বরূপ, আমরা তাদের পুরানো পুতুলের সাথে ব্যবহার করি না। পরিবেশ ব্যবহার করা হলে, তারা সাধারণত সংরক্ষণ করা হয় /etc/puppet/environments, রুট ডিরেক্টরিটি পরিবেশ ডিরেক্টরি হবে। এনভায়রনমেন্ট ব্যবহার না করা হলে, রুট ডিরেক্টরি হবে বেস ডিরেক্টরি।
• চতুর্থ সংস্করণ ("নতুন পুতুল") থেকে শুরু করে, পরিবেশের ব্যবহার বাধ্যতামূলক হয়ে ওঠে এবং বেস ডিরেক্টরিটি এখানে সরানো হয় /etc/puppetlabs/code. তদনুসারে, পরিবেশে সংরক্ষণ করা হয় /etc/puppetlabs/code/environments, রুট ডিরেক্টরি হল পরিবেশ ডিরেক্টরি।

রুট ডিরেক্টরিতে অবশ্যই একটি সাবডিরেক্টরি থাকতে হবে manifests, যা নোড বর্ণনা করে এক বা একাধিক ম্যানিফেস্ট ধারণ করে। উপরন্তু, একটি সাবডিরেক্টরি থাকতে হবে modules, যা মডিউল ধারণ করে। মডিউল কি তা একটু পরে বলব। এছাড়াও, পুরানো পুতুলের একটি সাবডিরেক্টরিও থাকতে পারে files, এতে বিভিন্ন ফাইল রয়েছে যা আমরা নোডগুলিতে অনুলিপি করি। নতুন পাপেটে, সমস্ত ফাইল মডিউলে স্থাপন করা হয়।

ম্যানিফেস্ট ফাইলের এক্সটেনশন আছে .pp.

কয়েকটি যুদ্ধের উদাহরণ

এটিতে নোড এবং সংস্থানের বিবরণ

নোড উপর server1.testdomain একটি ফাইল তৈরি করতে হবে /etc/issue বিষয়বস্তু সহ Debian GNU/Linux n l. ফাইলটি অবশ্যই একজন ব্যবহারকারী এবং গোষ্ঠীর মালিকানাধীন হতে হবে root, অ্যাক্সেস অধিকার হতে হবে 644.

আমরা একটি ইশতেহার লিখি:

node 'server1.testdomain' {   # блок конфигурации, относящийся к ноде server1.testdomain
    file { '/etc/issue':   # описываем файл /etc/issue
        ensure  => present,   # этот файл должен существовать
        content => 'Debian GNU/Linux n l',   # у него должно быть такое содержимое
        owner   => root,   # пользователь-владелец
        group   => root,   # группа-владелец
        mode    => '0644',   # права на файл. Они заданы в виде строки (в кавычках), потому что иначе число с 0 в начале будет воспринято как записанное в восьмеричной системе, и всё пойдёт не так, как задумано
    }
}

একটি নোডে সম্পদের মধ্যে সম্পর্ক

নোড উপর server2.testdomain nginx চলমান থাকতে হবে, পূর্বে প্রস্তুত কনফিগারেশনের সাথে কাজ করে।

আসুন সমস্যাটি পচন করা যাক:

• প্যাকেজ ইনস্টল করা প্রয়োজন nginx.
• কনফিগারেশন ফাইলগুলি সার্ভার থেকে অনুলিপি করা আবশ্যক।
• পরিষেবা চালু করা প্রয়োজন nginx.
• কনফিগারেশন আপডেট করা হলে, পরিষেবাটি পুনরায় চালু করতে হবে।

আমরা একটি ইশতেহার লিখি:

node 'server2.testdomain' {   # блок конфигурации, относящийся к ноде server2.testdomain
    package { 'nginx':   # описываем пакет nginx
        ensure => installed,   # он должен быть установлен
    }
  # Прямая стрелка (->) говорит о том, что ресурс ниже должен
  # создаваться после ресурса, описанного выше.
  # Такие зависимости транзитивны.
    -> file { '/etc/nginx':   # описываем файл /etc/nginx
        ensure  => directory,   # это должна быть директория
        source  => 'puppet:///modules/example/nginx-conf',   # её содержимое нужно брать с паппет-сервера по указанному адресу
        recurse => true,   # копировать файлы рекурсивно
        purge   => true,   # нужно удалять лишние файлы (те, которых нет в источнике)
        force   => true,   # удалять лишние директории
    }
  # Волнистая стрелка (~>) говорит о том, что ресурс ниже должен
  # подписаться на изменения ресурса, описанного выше.
  # Волнистая стрелка включает в себя прямую (->).
    ~> service { 'nginx':   # описываем сервис nginx
        ensure => running,   # он должен быть запущен
        enable => true,   # его нужно запускать автоматически при старте системы
    }
  # Когда ресурс типа service получает уведомление,
  # соответствующий сервис перезапускается.
}

এটি কাজ করার জন্য, আপনার পুতুল সার্ভারে প্রায় নিম্নলিখিত ফাইল অবস্থানের প্রয়োজন:

/etc/puppetlabs/code/environments/production/ # (это для нового Паппета, для старого корневой директорией будет /etc/puppet)
├── manifests/
│   └── site.pp
└── modules/
    └── example/
        └── files/
            └── nginx-conf/
                ├── nginx.conf
                ├── mime.types
                └── conf.d/
                    └── some.conf

সম্পদের ধরন

সমর্থিত সম্পদ প্রকারের একটি সম্পূর্ণ তালিকা এখানে পাওয়া যাবে ডকুমেন্টেশনে, এখানে আমি পাঁচটি মৌলিক প্রকার বর্ণনা করব, যা আমার অনুশীলনে বেশিরভাগ সমস্যা সমাধানের জন্য যথেষ্ট।

ফাইল

ফাইল, ডিরেক্টরি, সিমলিঙ্ক, তাদের বিষয়বস্তু এবং অ্যাক্সেস অধিকার পরিচালনা করে।

বিকল্প:

• সম্পদের নাম — ফাইলের পথ (ঐচ্ছিক)
• পথ — ফাইলের পথ (যদি এটি নামে নির্দিষ্ট করা না থাকে)
• নিশ্চিত করা - ফাইলের ধরন:
  • absent - একটি ফাইল মুছে দিন
  • present - যেকোন ধরণের ফাইল থাকতে হবে (যদি কোন ফাইল না থাকে তবে একটি নিয়মিত ফাইল তৈরি করা হবে)
  • file - নিয়মিত ফাইল
  • directory - ডিরেক্টরি
  • link - সিমলিংক
• বিষয়বস্তু — ফাইল বিষয়বস্তু (শুধুমাত্র নিয়মিত ফাইলের জন্য উপযুক্ত, এর সাথে একসাথে ব্যবহার করা যাবে না উৎস বা লক্ষ্য)
• উৎস — যে পথ থেকে আপনি ফাইলের বিষয়বস্তু অনুলিপি করতে চান তার একটি লিঙ্ক (এর সাথে একসাথে ব্যবহার করা যাবে না বিষয়বস্তু বা লক্ষ্য) একটি স্কিম সহ একটি URI হিসাবে নির্দিষ্ট করা যেতে পারে puppet: (তারপর পুতুল সার্ভার থেকে ফাইল ব্যবহার করা হবে), এবং স্কিম সহ http: (আমি আশা করি এই ক্ষেত্রে কী ঘটবে তা পরিষ্কার), এবং এমনকি চিত্রের সাথেও file: অথবা একটি স্কিমা ছাড়া একটি পরম পথ হিসাবে (তারপরে নোডে স্থানীয় FS থেকে ফাইল ব্যবহার করা হবে)
• লক্ষ্য — যেখানে সিমলিংক নির্দেশ করা উচিত (এর সাথে একসাথে ব্যবহার করা যাবে না বিষয়বস্তু বা উৎস)
• মালিক — যে ব্যবহারকারীর ফাইলের মালিক হওয়া উচিত
• গ্রুপ — ফাইলটি যে গ্রুপের অন্তর্ভুক্ত
• মোড — ফাইল অনুমতি (একটি স্ট্রিং হিসাবে)
• পুনরাবৃত্তি - পুনরাবৃত্ত ডিরেক্টরি প্রক্রিয়াকরণ সক্ষম করে
• রেচক পদার্থ - পুতুলে বর্ণনা করা হয়নি এমন ফাইলগুলি মুছে ফেলা সক্ষম করে
• বল - পাপেটে বর্ণনা করা হয়নি এমন ডিরেক্টরি মুছে ফেলা সক্ষম করে

প্যাকেজ

প্যাকেজগুলি ইনস্টল করে এবং সরিয়ে দেয়। বিজ্ঞপ্তিগুলি পরিচালনা করতে সক্ষম - প্যাকেজটি পুনরায় ইনস্টল করে যদি প্যারামিটারটি নির্দিষ্ট করা থাকে reinstall_on_refresh.

বিকল্প:

• সম্পদের নাম - প্যাকেজের নাম (ঐচ্ছিক)
• নাম - প্যাকেজের নাম (নামে উল্লেখ না থাকলে)
• প্রদানকারী - ব্যবহার করার জন্য প্যাকেজ ম্যানেজার
• নিশ্চিত করা - প্যাকেজের পছন্দসই অবস্থা:
  • present, installed - যে কোনো সংস্করণ ইনস্টল করা হয়েছে
  • latest - সর্বশেষ সংস্করণ ইনস্টল করা হয়েছে
  • absent - মুছে ফেলা হয়েছে (apt-get remove)
  • purged — কনফিগারেশন ফাইল সহ মুছে ফেলা হয়েছে (apt-get purge)
  • held - প্যাকেজ সংস্করণ লক করা হয়েছে (apt-mark hold)
  • любая другая строка - নির্দিষ্ট সংস্করণ ইনস্টল করা হয়
• reinstall_on_refresh - যদি true, তারপর বিজ্ঞপ্তি প্রাপ্তির পরে প্যাকেজটি পুনরায় ইনস্টল করা হবে৷ উৎস-ভিত্তিক বিতরণের জন্য দরকারী, যেখানে বিল্ড প্যারামিটার পরিবর্তন করার সময় প্যাকেজ পুনর্নির্মাণের প্রয়োজন হতে পারে। ডিফল্ট false.

সেবা

পরিষেবাগুলি পরিচালনা করে। বিজ্ঞপ্তিগুলি প্রক্রিয়া করতে সক্ষম - পরিষেবাটি পুনরায় চালু করে৷

বিকল্প:

• সম্পদের নাম - পরিষেবা পরিচালনা করা হবে (ঐচ্ছিক)
• নাম — যে পরিষেবাটি পরিচালনা করা দরকার (যদি নামে উল্লেখ না থাকে)
• নিশ্চিত করা - পরিষেবার পছন্দসই অবস্থা:
  • running - চালু হয়েছে
  • stopped - বন্ধ
• সক্ষম করা - পরিষেবা শুরু করার ক্ষমতা নিয়ন্ত্রণ করে:
  • true - অটোরান সক্ষম করা হয়েছে (systemctl enable)
  • mask - ছদ্মবেশে (systemctl mask)
  • false - অটোরান নিষ্ক্রিয় (systemctl disable)
• আবার শুরু - পরিষেবা পুনরায় চালু করার জন্য কমান্ড
• অবস্থা - পরিষেবার স্থিতি পরীক্ষা করার জন্য কমান্ড
• পুনরায় আরম্ভ — পরিষেবা initscript পুনরায় চালু করা সমর্থন করে কিনা তা নির্দেশ করুন। যদি false এবং পরামিতি নির্দিষ্ট করা হয় আবার শুরু — এই প্যারামিটারের মান ব্যবহার করা হয়। যদি false এবং প্যারামিটার আবার শুরু নির্দিষ্ট করা নেই - পরিষেবাটি বন্ধ করা হয়েছে এবং পুনরায় চালু করা শুরু হয়েছে (কিন্তু systemd কমান্ড ব্যবহার করে systemctl restart).
• আছে স্ট্যাটাস — পরিষেবা initscript কমান্ড সমর্থন করে কিনা তা নির্দেশ করুন status। যদি false, তারপর প্যারামিটার মান ব্যবহার করা হয় অবস্থা. ডিফল্ট true.

Exec

বাহ্যিক কমান্ড চালায়। আপনি যদি পরামিতি নির্দিষ্ট না করেন সৃষ্টি, শুধু যদি, যদি না বা সতেজভাবে, প্রতিবার পাপেট চালানো হলে কমান্ডটি চালানো হবে। বিজ্ঞপ্তিগুলি প্রক্রিয়া করতে সক্ষম - একটি কমান্ড চালায়।

বিকল্প:

• সম্পদের নাম - আদেশ কার্যকর করা হবে (ঐচ্ছিক)
• হুকুম - কার্যকর করার আদেশ (যদি এটি নামে নির্দিষ্ট করা না থাকে)
• পথ — পাথ যেখানে এক্সিকিউটেবল ফাইলের সন্ধান করতে হবে
• শুধু যদি — যদি এই প্যারামিটারে নির্দিষ্ট কমান্ডটি শূন্য রিটার্ন কোড দিয়ে সম্পন্ন হয়, তাহলে প্রধান কমান্ডটি কার্যকর করা হবে
• যদি না — যদি এই প্যারামিটারে নির্দিষ্ট কমান্ডটি একটি নন-জিরো রিটার্ন কোড দিয়ে সম্পন্ন হয়, তাহলে প্রধান কমান্ডটি কার্যকর করা হবে
• সৃষ্টি — এই প্যারামিটারে উল্লেখিত ফাইলটি বিদ্যমান না থাকলে, প্রধান কমান্ডটি কার্যকর করা হবে
• সতেজভাবে - যদি true, তারপর কমান্ডটি তখনই চালানো হবে যখন এই exec অন্যান্য সংস্থান থেকে বিজ্ঞপ্তি পায়
• cwd — যে ডিরেক্টরি থেকে কমান্ড চালাতে হবে
• ব্যবহারকারী — যে ব্যবহারকারীর কাছ থেকে কমান্ড চালাতে হবে
• প্রদানকারী - কিভাবে কমান্ড চালাতে হয়:
  • posix — একটি শিশু প্রক্রিয়া সহজভাবে তৈরি করা হয়, নির্দিষ্ট করতে ভুলবেন না পথ
  • খোল - কমান্ডটি শেলে চালু হয় /bin/sh, নির্দিষ্ট করা নাও হতে পারে পথ, আপনি গ্লোবিং, পাইপ এবং অন্যান্য শেল বৈশিষ্ট্য ব্যবহার করতে পারেন। কোন বিশেষ অক্ষর থাকলে সাধারণত স্বয়ংক্রিয়ভাবে সনাক্ত করা হয় (|, ;, &&, || ইত্যাদি)।

জন্য cron

ক্রোনজব নিয়ন্ত্রণ করে।

বিকল্প:

• সম্পদের নাম - শুধুমাত্র এক ধরনের শনাক্তকারী
• নিশ্চিত করা - ক্রাউনজব স্টেট:
  • present - বিদ্যমান না থাকলে তৈরি করুন
  • absent - বিদ্যমান থাকলে মুছুন
• হুকুম - কি কমান্ড চালাতে হবে
• পরিবেশ — কোন পরিবেশে কমান্ড চালাতে হবে (পরিবেশ ভেরিয়েবলের তালিকা এবং এর মাধ্যমে তাদের মান =)
• ব্যবহারকারী — কোন ব্যবহারকারীর কাছ থেকে কমান্ড চালাতে হবে
• মিনিট, ঘন্টা, সপ্তাহের দিন, মাস, মাস দিন — কখন ক্রোন চালাতে হবে। যদি এই বৈশিষ্ট্যগুলির মধ্যে কোনটি নির্দিষ্ট করা না থাকে, তাহলে ক্রনটবে এর মান হবে *.

পুতুল 6.0-এ জন্য cron হিসাবে যদি বাক্স থেকে সরানো হয়েছে puppetserver এ, তাই সাধারণ সাইটে কোন ডকুমেন্টেশন নেই। কিন্তু সে বাক্সে আছে পুতুল-এজেন্ট, তাই আলাদাভাবে এটি ইনস্টল করার প্রয়োজন নেই। আপনি এটির জন্য ডকুমেন্টেশন দেখতে পারেন পুতুলের পঞ্চম সংস্করণের ডকুমেন্টেশনে, বা গিটহাবে.

সাধারণভাবে সম্পদ সম্পর্কে

সম্পদ স্বতন্ত্রতার জন্য প্রয়োজনীয়তা

আমরা সম্মুখীন সবচেয়ে সাধারণ ভুল হয় ডুপ্লিকেট ঘোষণা. এই ত্রুটিটি ঘটে যখন একই নামের একই ধরণের দুটি বা ততোধিক সংস্থান ডিরেক্টরিতে উপস্থিত হয়।

অতএব, আমি আবার লিখব: একই নোডের জন্য ম্যানিফেস্টে একই শিরোনাম সহ একই ধরণের সংস্থান থাকা উচিত নয়!

কখনও কখনও একই নামের সাথে প্যাকেজ ইনস্টল করার প্রয়োজন হয়, কিন্তু বিভিন্ন প্যাকেজ পরিচালকের সাথে। এই ক্ষেত্রে, আপনাকে পরামিতি ব্যবহার করতে হবে nameত্রুটি এড়াতে:

package { 'ruby-mysql':
  ensure   => installed,
  name     => 'mysql',
  provider => 'gem',
}
package { 'python-mysql':
  ensure   => installed,
  name     => 'mysql',
  provider => 'pip',
}

নকল এড়াতে সাহায্য করার জন্য অন্যান্য রিসোর্স প্রকারের অনুরূপ বিকল্প রয়েছে - name у সেবা, command у Exec, এবং তাই।

মেটাপ্যারামিটার

প্রতিটি রিসোর্স টাইপের কিছু বিশেষ প্যারামিটার আছে, তার প্রকৃতি নির্বিশেষে।

মেটা প্যারামিটারের সম্পূর্ণ তালিকা পুতুল ডকুমেন্টেশনে.

সংক্ষিপ্ত তালিকা:

• প্রয়োজন — এই পরামিতি নির্দেশ করে যে এই সংস্থানটি কোন সম্পদের উপর নির্ভর করে।
• আগে - এই পরামিতি নির্দিষ্ট করে যে কোন সম্পদ এই সম্পদের উপর নির্ভর করে।
• সাবস্ক্রাইব — এই পরামিতিটি নির্দিষ্ট করে যে কোন সংস্থান থেকে এই সংস্থানটি বিজ্ঞপ্তি গ্রহণ করে।
• অবহিত — এই পরামিতিটি নির্দিষ্ট করে যে কোন সংস্থানগুলি এই সংস্থান থেকে বিজ্ঞপ্তি গ্রহণ করে।

তালিকাভুক্ত সমস্ত মেটাপ্যারামিটার হয় একটি একক সংস্থান লিঙ্ক বা বর্গাকার বন্ধনীতে লিঙ্কগুলির একটি অ্যারে গ্রহণ করে।

সম্পদ লিঙ্ক

একটি রিসোর্স লিঙ্ক হল রিসোর্সের একটি উল্লেখ। এগুলি প্রধানত নির্ভরতা নির্দেশ করতে ব্যবহৃত হয়। একটি অস্তিত্বহীন সম্পদ উল্লেখ করা একটি সংকলন ত্রুটির কারণ হবে.

লিঙ্কটির সিনট্যাক্স নিম্নরূপ: একটি বড় অক্ষর সহ সম্পদের ধরন (যদি টাইপের নামের ডবল কোলন থাকে, তাহলে কোলনের মধ্যে নামের প্রতিটি অংশ বড় করা হয়), তারপর বর্গাকার বন্ধনীতে সম্পদের নাম (নামের ক্ষেত্রে) পরিবর্তন করা হয় না!). কোন স্পেস থাকা উচিত নয়; বর্গাকার বন্ধনীগুলি টাইপের নামের পরেই লেখা হয়।

উদাহরণ:

file { '/file1': ensure => present }
file { '/file2':
  ensure => directory,
  before => File['/file1'],
}
file { '/file3': ensure => absent }
File['/file1'] -> File['/file3']

নির্ভরতা এবং বিজ্ঞপ্তি

এখানে ডকুমেন্টেশন.

আগেই বলা হয়েছে, সম্পদের মধ্যে সহজ নির্ভরতা ট্রানজিটিভ। যাইহোক, নির্ভরতা যোগ করার সময় সতর্কতা অবলম্বন করুন - আপনি চক্রীয় নির্ভরতা তৈরি করতে পারেন, যা একটি সংকলন ত্রুটির কারণ হবে।

নির্ভরতা থেকে ভিন্ন, বিজ্ঞপ্তিগুলি ট্রানজিটিভ নয়। নিম্নলিখিত নিয়ম বিজ্ঞপ্তির জন্য প্রযোজ্য:

• যদি সম্পদ একটি বিজ্ঞপ্তি পায়, এটি আপডেট করা হয়. আপডেট ক্রিয়াগুলি সম্পদের প্রকারের উপর নির্ভর করে - Exec কমান্ড চালায়, সেবা পরিষেবা পুনরায় আরম্ভ করে, প্যাকেজ প্যাকেজ পুনরায় ইনস্টল করে। যদি রিসোর্সটির একটি আপডেট অ্যাকশন সংজ্ঞায়িত না থাকে, তাহলে কিছুই হবে না।
• পাপেটের এক দৌড়ের সময়, সংস্থানটি একবারের বেশি আপডেট করা হয় না। এটি সম্ভব কারণ বিজ্ঞপ্তিগুলিতে নির্ভরতা অন্তর্ভুক্ত থাকে এবং নির্ভরতা গ্রাফে চক্র থাকে না।
• যদি পুতুল একটি সম্পদের অবস্থা পরিবর্তন করে, সম্পদটি এটিতে সদস্যতা নেওয়া সমস্ত সংস্থানগুলিতে বিজ্ঞপ্তি পাঠায়।
• যদি একটি সংস্থান আপডেট করা হয় তবে এটি সদস্যতা নেওয়া সমস্ত সংস্থানগুলিতে বিজ্ঞপ্তি পাঠায়৷

অনির্দিষ্ট পরামিতি পরিচালনা করা

একটি নিয়ম হিসাবে, যদি কিছু রিসোর্স প্যারামিটারের একটি ডিফল্ট মান না থাকে এবং এই প্যারামিটারটি ম্যানিফেস্টে নির্দিষ্ট করা না থাকে, তাহলে Puppet নোডে সংশ্লিষ্ট রিসোর্সের জন্য এই বৈশিষ্ট্যটি পরিবর্তন করবে না। উদাহরণস্বরূপ, যদি টাইপ একটি সম্পদ ফাইল পরামিতি নির্দিষ্ট করা হয়নি owner, তাহলে Puppet সংশ্লিষ্ট ফাইলের মালিক পরিবর্তন করবে না।

ক্লাস, ভেরিয়েবল এবং সংজ্ঞার ভূমিকা

ধরুন আমাদের বেশ কয়েকটি নোড রয়েছে যেগুলির কনফিগারেশনের একই অংশ রয়েছে, তবে পার্থক্যও রয়েছে - অন্যথায় আমরা এটিকে এক ব্লকে বর্ণনা করতে পারি node {}. অবশ্যই, আপনি কেবল কনফিগারেশনের অভিন্ন অংশগুলি অনুলিপি করতে পারেন, তবে সাধারণভাবে এটি একটি খারাপ সমাধান - কনফিগারেশন বাড়তে থাকে এবং আপনি যদি কনফিগারেশনের সাধারণ অংশটি পরিবর্তন করেন তবে আপনাকে অনেক জায়গায় একই জিনিস সম্পাদনা করতে হবে। একই সময়ে, ভুল করা সহজ, এবং সাধারণভাবে, DRY (নিজেকে পুনরাবৃত্তি করবেন না) নীতিটি একটি কারণে উদ্ভাবিত হয়েছিল।

এই সমস্যা সমাধানের জন্য যেমন একটি নকশা আছে বর্গ.

ক্লাস

Класс পপেট কোডের একটি নামকৃত ব্লক। কোড পুনরায় ব্যবহার করার জন্য ক্লাস প্রয়োজন।

প্রথমে ক্লাস বর্ণনা করতে হবে। বর্ণনা নিজেই কোথাও কোন সম্পদ যোগ করে না. ক্লাসটি ম্যানিফেস্টে বর্ণনা করা হয়েছে:

# Описание класса начинается с ключевого слова class и его названия.
# Дальше идёт тело класса в фигурных скобках.
class example_class {
    ...
}

এর পরে ক্লাসটি ব্যবহার করা যেতে পারে:

# первый вариант использования — в стиле ресурса с типом class
class { 'example_class': }
# второй вариант использования — с помощью функции include
include example_class
# про отличие этих двух вариантов будет рассказано дальше

পূর্ববর্তী টাস্ক থেকে একটি উদাহরণ - আসুন nginx এর ইনস্টলেশন এবং কনফিগারেশনটিকে একটি ক্লাসে সরিয়ে নেওয়া যাক:

class nginx_example {
    package { 'nginx':
        ensure => installed,
    }
    -> file { '/etc/nginx':
        ensure => directory,
        source => 'puppet:///modules/example/nginx-conf',
        recure => true,
        purge  => true,
        force  => true,
    }
    ~> service { 'nginx':
        ensure => running,
        enable => true,
    }
}

node 'server2.testdomain' {
    include nginx_example
}

পরিবর্তনশীল

পূর্ববর্তী উদাহরণের ক্লাসটি মোটেও নমনীয় নয় কারণ এটি সর্বদা একই nginx কনফিগারেশন নিয়ে আসে। আসুন কনফিগারেশন ভেরিয়েবলের পথ তৈরি করি, তাহলে এই ক্লাসটি যেকোনো কনফিগারেশনের সাথে nginx ইনস্টল করতে ব্যবহার করা যেতে পারে।

এটা হতে পারে ভেরিয়েবল ব্যবহার করে.

মনোযোগ: পুতুলের ভেরিয়েবলগুলি অপরিবর্তনীয়!

উপরন্তু, একটি ভেরিয়েবল শুধুমাত্র এটি ঘোষণা করার পরে অ্যাক্সেস করা যেতে পারে, অন্যথায় ভেরিয়েবলের মান হবে undef.

ভেরিয়েবলের সাথে কাজ করার উদাহরণ:

# создание переменных
$variable = 'value'
$var2 = 1
$var3 = true
$var4 = undef
# использование переменных
$var5 = $var6
file { '/tmp/text': content => $variable }
# интерполяция переменных — раскрытие значения переменных в строках. Работает только в двойных кавычках!
$var6 = "Variable with name variable has value ${variable}"

পুতুল আছে নামস্থান, এবং ভেরিয়েবল, সেই অনুযায়ী, আছে দৃশ্যমানতার এলাকা: একই নামের একটি পরিবর্তনশীল বিভিন্ন নামস্থানে সংজ্ঞায়িত করা যেতে পারে। একটি ভেরিয়েবলের মান সমাধান করার সময়, ভেরিয়েবলটি বর্তমান নামস্থানে অনুসন্ধান করা হয়, তারপরে আবদ্ধ নামস্থানে এবং আরও অনেক কিছু।

নেমস্পেস উদাহরণ:

• গ্লোবাল - ক্লাস বা নোডের বিবরণের বাইরের ভেরিয়েবল সেখানে যায়;
• নোডের বিবরণে নোড নামস্থান;
• ক্লাসের বর্ণনায় ক্লাসের নামস্থান।

একটি ভেরিয়েবল অ্যাক্সেস করার সময় অস্পষ্টতা এড়াতে, আপনি পরিবর্তনশীল নামের নামস্থান নির্দিষ্ট করতে পারেন:

# переменная без пространства имён
$var
# переменная в глобальном пространстве имён
$::var
# переменная в пространстве имён класса
$classname::var
$::classname::var

আসুন সম্মত হই যে nginx কনফিগারেশনের পথটি ভেরিয়েবলের মধ্যে রয়েছে $nginx_conf_source. তারপর ক্লাস এই মত দেখাবে:

class nginx_example {
    package { 'nginx':
        ensure => installed,
    }
    -> file { '/etc/nginx':
        ensure => directory,
        source => $nginx_conf_source,   # здесь используем переменную вместо фиксированной строки
        recure => true,
        purge  => true,
        force  => true,
    }
    ~> service { 'nginx':
        ensure => running,
        enable => true,
    }
}

node 'server2.testdomain' {
    $nginx_conf_source = 'puppet:///modules/example/nginx-conf'
    include nginx_example
}

যাইহোক, প্রদত্ত উদাহরণটি খারাপ কারণ কিছু "গোপন জ্ঞান" রয়েছে যা ক্লাসের ভিতরে কোথাও অমুক এবং অমুক নামের একটি ভেরিয়েবল ব্যবহার করা হয়েছে। এই জ্ঞান সাধারণ করা অনেক বেশি সঠিক - ক্লাসের পরামিতি থাকতে পারে।

ক্লাস প্যারামিটার ক্লাস নেমস্পেসে ভেরিয়েবল, এগুলি ক্লাস হেডারে নির্দিষ্ট করা হয় এবং ক্লাস বডিতে নিয়মিত ভেরিয়েবলের মতো ব্যবহার করা যেতে পারে। ম্যানিফেস্টে ক্লাস ব্যবহার করার সময় প্যারামিটারের মানগুলি নির্দিষ্ট করা হয়।

প্যারামিটার একটি ডিফল্ট মান সেট করা যেতে পারে. যদি একটি প্যারামিটারের একটি ডিফল্ট মান না থাকে এবং ব্যবহার করার সময় মান সেট না করা হয়, এটি একটি সংকলন ত্রুটি সৃষ্টি করবে।

আসুন উপরের উদাহরণ থেকে ক্লাসটিকে প্যারামিটারাইজ করি এবং দুটি প্যারামিটার যোগ করি: প্রথমটি, প্রয়োজনীয়, কনফিগারেশনের পথ এবং দ্বিতীয়টি, ঐচ্ছিক, nginx সহ প্যাকেজের নাম (ডেবিয়ানে, উদাহরণস্বরূপ, প্যাকেজ রয়েছে nginx, nginx-light, nginx-full).

# переменные описываются сразу после имени класса в круглых скобках
class nginx_example (
  $conf_source,
  $package_name = 'nginx-light', # параметр со значением по умолчанию
) {
  package { $package_name:
    ensure => installed,
  }
  -> file { '/etc/nginx':
    ensure  => directory,
    source  => $conf_source,
    recurse => true,
    purge   => true,
    force   => true,
  }
  ~> service { 'nginx':
    ensure => running,
    enable => true,
  }
}

node 'server2.testdomain' {
  # если мы хотим задать параметры класса, функция include не подойдёт* — нужно использовать resource-style declaration
  # *на самом деле подойдёт, но про это расскажу в следующей серии. Ключевое слово "Hiera".
  class { 'nginx_example':
    conf_source => 'puppet:///modules/example/nginx-conf',   # задаём параметры класса точно так же, как параметры для других ресурсов
  }
}

পাপেটে ভেরিয়েবল টাইপ করা হয়। খাওয়া অনেক তথ্য প্রকার. ডেটা প্রকারগুলি সাধারণত ক্লাস এবং সংজ্ঞাগুলিতে পাস করা প্যারামিটার মানগুলিকে যাচাই করতে ব্যবহৃত হয়। যদি পাস করা প্যারামিটারটি নির্দিষ্ট ধরণের সাথে মেলে না, তাহলে একটি সংকলন ত্রুটি ঘটবে।

পরামিতি নামের আগে টাইপটি লেখা হয়:

class example (
  String $param1,
  Integer $param2,
  Array $param3,
  Hash $param4,
  Hash[String, String] $param5,
) {
  ...
}

ক্লাস: ক্লাসের নাম বনাম ক্লাস{'classname':} অন্তর্ভুক্ত

প্রতিটি ক্লাস টাইপের একটি সম্পদ শ্রেণী. অন্য কোনো ধরনের সম্পদের মতো, একই নোডে একই শ্রেণীর দুটি উদাহরণ থাকতে পারে না।

আপনি যদি একই নোডে দুবার ব্যবহার করে একটি ক্লাস যুক্ত করার চেষ্টা করেন class { 'classname':} (কোন পার্থক্য নেই, ভিন্ন বা অভিন্ন পরামিতি সহ), একটি সংকলন ত্রুটি থাকবে। কিন্তু আপনি যদি রিসোর্স শৈলীতে একটি ক্লাস ব্যবহার করেন, আপনি অবিলম্বে ম্যানিফেস্টে এর সমস্ত প্যারামিটার স্পষ্টভাবে সেট করতে পারেন।

তবে ব্যবহার করলে include, তারপর ক্লাস যতবার ইচ্ছা যোগ করা যেতে পারে। ব্যাপারটি হলো include একটি idempotent ফাংশন যা পরীক্ষা করে যে ডিরেক্টরিতে একটি ক্লাস যোগ করা হয়েছে কিনা। যদি ক্লাসটি ডিরেক্টরিতে না থাকে তবে এটি এটি যোগ করে এবং যদি এটি ইতিমধ্যেই বিদ্যমান থাকে তবে এটি কিছুই করে না। কিন্তু ব্যবহারের ক্ষেত্রে include ক্লাস ঘোষণার সময় আপনি ক্লাস প্যারামিটার সেট করতে পারবেন না - সমস্ত প্রয়োজনীয় প্যারামিটার অবশ্যই একটি বাহ্যিক ডেটা উত্স - Hiera বা ENC-তে সেট করতে হবে। আমরা পরবর্তী নিবন্ধে তাদের সম্পর্কে কথা বলব।

সংজ্ঞায়িত করে

আগের ব্লকে যেমন বলা হয়েছিল, একই ক্লাস একটি নোডে একাধিকবার উপস্থিত থাকতে পারে না। যাইহোক, কিছু ক্ষেত্রে আপনাকে একই নোডে বিভিন্ন পরামিতি সহ কোডের একই ব্লক ব্যবহার করতে সক্ষম হতে হবে। অন্য কথায়, নিজস্ব একটি সম্পদ ধরনের প্রয়োজন আছে।

উদাহরণস্বরূপ, পিএইচপি মডিউল ইনস্টল করার জন্য, আমরা অ্যাভিটোতে নিম্নলিখিতগুলি করি:

1. এই মডিউল দিয়ে প্যাকেজটি ইনস্টল করুন।
2. এই মডিউলটির জন্য একটি কনফিগারেশন ফাইল তৈরি করা যাক।
3. আমরা php-fpm-এর জন্য কনফিগারেশনে একটি সিমলিঙ্ক তৈরি করি।
4. আমরা php cli-এর জন্য কনফিগারেশনে একটি সিমলিঙ্ক তৈরি করি।

এই ধরনের ক্ষেত্রে, যেমন একটি নকশা সংজ্ঞায়িত করা (সংজ্ঞায়িত, সংজ্ঞায়িত প্রকার, সংজ্ঞায়িত সম্পদ প্রকার)। একটি সংজ্ঞা একটি শ্রেণীর অনুরূপ, কিন্তু পার্থক্য আছে: প্রথমত, প্রতিটি সংজ্ঞা একটি সম্পদ প্রকার, একটি সম্পদ নয়; দ্বিতীয়ত, প্রতিটি সংজ্ঞা একটি অন্তর্নিহিত পরামিতি আছে $title, যখন এটি ঘোষণা করা হয় তখন সম্পদের নাম যেখানে যায়। ঠিক যেমন ক্লাসের ক্ষেত্রে, একটি সংজ্ঞা প্রথমে বর্ণনা করতে হবে, তারপরে এটি ব্যবহার করা যেতে পারে।

PHP এর জন্য একটি মডিউল সহ একটি সরলীকৃত উদাহরণ:

define php74::module (
  $php_module_name = $title,
  $php_package_name = "php7.4-${title}",
  $version = 'installed',
  $priority = '20',
  $data = "extension=${title}.son",
  $php_module_path = '/etc/php/7.4/mods-available',
) {
  package { $php_package_name:
    ensure          => $version,
    install_options => ['-o', 'DPkg::NoTriggers=true'],  # триггеры дебиановских php-пакетов сами создают симлинки и перезапускают сервис php-fpm - нам это не нужно, так как и симлинками, и сервисом мы управляем с помощью Puppet
  }
  -> file { "${php_module_path}/${php_module_name}.ini":
    ensure  => $ensure,
    content => $data,
  }
  file { "/etc/php/7.4/cli/conf.d/${priority}-${php_module_name}.ini":
    ensure  => link,
    target  => "${php_module_path}/${php_module_name}.ini",
  }
  file { "/etc/php/7.4/fpm/conf.d/${priority}-${php_module_name}.ini":
    ensure  => link,
    target  => "${php_module_path}/${php_module_name}.ini",
  }
}

node server3.testdomain {
  php74::module { 'sqlite3': }
  php74::module { 'amqp': php_package_name => 'php-amqp' }
  php74::module { 'msgpack': priority => '10' }
}

ডুপ্লিকেট ঘোষণা ত্রুটি ধরার সবচেয়ে সহজ উপায় হল Define. এটি ঘটবে যদি একটি সংজ্ঞায় একটি ধ্রুবক নাম সহ একটি সংস্থান থাকে এবং কিছু নোডে এই সংজ্ঞাটির দুটি বা তার বেশি উদাহরণ থাকে।

এটি থেকে নিজেকে রক্ষা করা সহজ: সংজ্ঞার ভিতরে থাকা সমস্ত সংস্থানগুলির উপর নির্ভর করে একটি নাম থাকতে হবে $title. একটি বিকল্প হ'ল সম্পদের অদম্য সংযোজন; সহজ ক্ষেত্রে, সংজ্ঞার সমস্ত উদাহরণে সাধারণ সংস্থানগুলিকে একটি পৃথক শ্রেণিতে স্থানান্তর করা এবং এই শ্রেণিটিকে সংজ্ঞায় অন্তর্ভুক্ত করা যথেষ্ট - ফাংশন include অক্ষমতা

সম্পদ যোগ করার সময় বুদ্ধিমত্তা অর্জনের অন্যান্য উপায় রয়েছে, যেমন ফাংশন ব্যবহার করে defined и ensure_resources, তবে আমি আপনাকে পরের পর্বে এটি সম্পর্কে বলব।

ক্লাস এবং সংজ্ঞাগুলির জন্য নির্ভরতা এবং বিজ্ঞপ্তি

ক্লাস এবং সংজ্ঞাগুলি নির্ভরতা এবং বিজ্ঞপ্তিগুলি পরিচালনা করতে নিম্নলিখিত নিয়মগুলি যুক্ত করে:

• একটি শ্রেণী/সংজ্ঞায়িত উপর নির্ভরতা ক্লাস/সংজ্ঞায়িত সমস্ত সম্পদের উপর নির্ভরতা যোগ করে;
• একটি শ্রেণি/সংজ্ঞায়িত নির্ভরতা সমস্ত শ্রেণি/সংজ্ঞায়িত সংস্থানে নির্ভরতা যুক্ত করে;
• ক্লাস/ডিফাইন নোটিফিকেশন ক্লাস/ডিফাইনের সমস্ত রিসোর্সকে অবহিত করে;
• ক্লাস/ডিফাইন সাবস্ক্রিপশন ক্লাস/ডিফাইনের সমস্ত রিসোর্সে সাবস্ক্রাইব করে।

শর্তসাপেক্ষ বিবৃতি এবং নির্বাচক

এখানে ডকুমেন্টেশন.

if

এখানে সবকিছু সহজ:

if ВЫРАЖЕНИЕ1 {
  ...
} elsif ВЫРАЖЕНИЕ2 {
  ...
} else {
  ...
}

যদি না

যদি না হয় একটি if বিপরীতে: এক্সপ্রেশনটি মিথ্যা হলে কোডের ব্লকটি কার্যকর করা হবে।

unless ВЫРАЖЕНИЕ {
  ...
}

কেস

এখানেও জটিল কিছু নেই। আপনি মান হিসাবে নিয়মিত মান (স্ট্রিং, সংখ্যা, ইত্যাদি), নিয়মিত এক্সপ্রেশন এবং ডেটা প্রকারগুলি ব্যবহার করতে পারেন।

case ВЫРАЖЕНИЕ {
  ЗНАЧЕНИЕ1: { ... }
  ЗНАЧЕНИЕ2, ЗНАЧЕНИЕ3: { ... }
  default: { ... }
}

নির্বাচক

একটি নির্বাচক একটি ভাষা অনুরূপ নির্মাণ case, কিন্তু কোডের একটি ব্লক কার্যকর করার পরিবর্তে, এটি একটি মান প্রদান করে।

$var = $othervar ? { 'val1' => 1, 'val2' => 2, default => 3 }

Модули

কনফিগারেশন ছোট হলে, এটি সহজেই একটি ম্যানিফেস্টে রাখা যেতে পারে। কিন্তু আমরা যত বেশি কনফিগারেশন বর্ণনা করি, ম্যানিফেস্টে তত বেশি শ্রেণী এবং নোড থাকে, এটি বৃদ্ধি পায় এবং এটির সাথে কাজ করা অসুবিধাজনক হয়ে ওঠে।

এছাড়াও, কোড পুনঃব্যবহারের সমস্যা রয়েছে - যখন সমস্ত কোড একটি ম্যানিফেস্টে থাকে, তখন এই কোডটি অন্যদের সাথে ভাগ করা কঠিন। এই দুটি সমস্যা সমাধানের জন্য, পুতুলের মডিউল নামে একটি সত্তা রয়েছে।

Модули - এগুলি ক্লাস, সংজ্ঞা এবং অন্যান্য পুতুল সত্তার সেটগুলি একটি পৃথক ডিরেক্টরিতে স্থাপন করা হয়েছে। অন্য কথায়, একটি মডিউল হল পুতুল যুক্তির একটি স্বাধীন অংশ। উদাহরণস্বরূপ, nginx-এর সাথে কাজ করার জন্য একটি মডিউল থাকতে পারে এবং এতে nginx-এর সাথে কাজ করার জন্য কী এবং শুধুমাত্র কী প্রয়োজন তা থাকবে, অথবা PHP-এর সাথে কাজ করার জন্য একটি মডিউল থাকতে পারে ইত্যাদি।

মডিউলগুলি সংস্করণ করা হয়, এবং একে অপরের উপর মডিউলগুলির নির্ভরতাও সমর্থিত। মডিউলগুলির একটি খোলা ভান্ডার রয়েছে - পাপেট ফরজ.

পুতুল সার্ভারে, মডিউলগুলি রুট ডিরেক্টরির মডিউল সাবডিরেক্টরিতে অবস্থিত। প্রতিটি মডিউলের ভিতরে একটি স্ট্যান্ডার্ড ডিরেক্টরি স্কিম রয়েছে - ম্যানিফেস্ট, ফাইল, টেমপ্লেট, lib এবং আরও অনেক কিছু।

একটি মডিউলে ফাইলের গঠন

মডিউলের মূলে বর্ণনামূলক নাম সহ নিম্নলিখিত ডিরেক্টরি থাকতে পারে:

• manifests - এতে ইশতেহার রয়েছে
• files - এতে ফাইল রয়েছে
• templates - এটিতে টেমপ্লেট রয়েছে
• lib - এতে রুবি কোড রয়েছে

এটি ডিরেক্টরি এবং ফাইলগুলির একটি সম্পূর্ণ তালিকা নয়, তবে আপাতত এই নিবন্ধটির জন্য এটি যথেষ্ট।

সম্পদের নাম এবং মডিউলে ফাইলের নাম

এখানে ডকুমেন্টেশন.

একটি মডিউলে সম্পদ (শ্রেণী, সংজ্ঞা) আপনি যা খুশি নামকরণ করা যাবে না. উপরন্তু, একটি সম্পদের নাম এবং ফাইলের নামের মধ্যে একটি সরাসরি চিঠিপত্র রয়েছে যেখানে পুতুল সেই সম্পদের একটি বিবরণ খুঁজবে। আপনি নামকরণের নিয়ম ভঙ্গ করলে, পুতুল কেবল সম্পদের বিবরণ খুঁজে পাবে না এবং আপনি একটি সংকলন ত্রুটি পাবেন।

নিয়মগুলি সহজ:

• একটি মডিউলের সমস্ত সংস্থান অবশ্যই মডিউল নামস্থানে থাকতে হবে। যদি মডিউল বলা হয় foo, তারপর এটির সমস্ত সংস্থান নামকরণ করা উচিত foo::<anything>, অথবা শুধুই foo.
• মডিউলের নামের সাথে রিসোর্স ফাইলে থাকতে হবে init.pp.
• অন্যান্য সংস্থানগুলির জন্য, ফাইলের নামকরণের স্কিমটি নিম্নরূপ:
  • মডিউল নামের উপসর্গটি বাতিল করা হয়েছে
  • সমস্ত ডাবল কোলন, যদি থাকে, স্ল্যাশ দিয়ে প্রতিস্থাপিত হয়
  • এক্সটেনশন যোগ করা হয় .pp

আমি একটি উদাহরণ দিয়ে দেখাব। ধরা যাক আমি একটি মডিউল লিখছি nginx. এটিতে নিম্নলিখিত সংস্থান রয়েছে:

• বর্গ nginx ম্যানিফেস্টে বর্ণিত init.pp;
• বর্গ nginx::service ম্যানিফেস্টে বর্ণিত service.pp;
• সংজ্ঞায়িত করা nginx::server ম্যানিফেস্টে বর্ণিত server.pp;
• সংজ্ঞায়িত করা nginx::server::location ম্যানিফেস্টে বর্ণিত server/location.pp.

টেমপ্লেট

অবশ্যই আপনি নিজেই জানেন যে টেমপ্লেটগুলি কী; আমি সেগুলি এখানে বিশদভাবে বর্ণনা করব না। কিন্তু আমি শুধু ক্ষেত্রে এটা ছেড়ে দেব উইকিপিডিয়ার লিঙ্ক.

টেমপ্লেটগুলি কীভাবে ব্যবহার করবেন: একটি ফাংশন ব্যবহার করে একটি টেমপ্লেটের অর্থ প্রসারিত করা যেতে পারে template, যা টেমপ্লেটের পাথ পাস করা হয়। ধরনের সম্পদ জন্য ফাইল প্যারামিটারের সাথে একসাথে ব্যবহার করা হয় content. উদাহরণস্বরূপ, এই মত:

file { '/tmp/example': content => template('modulename/templatename.erb')

পথ দেখুন <modulename>/<filename> ফাইল বোঝায় <rootdir>/modules/<modulename>/templates/<filename>.

উপরন্তু, একটি ফাংশন আছে inline_template — এটি ইনপুট হিসাবে টেমপ্লেট পাঠ্য গ্রহণ করে, ফাইলের নাম নয়।

টেমপ্লেটের মধ্যে, আপনি বর্তমান সুযোগে সমস্ত পুতুল ভেরিয়েবল ব্যবহার করতে পারেন।

পুতুল ERB এবং EPP ফর্ম্যাটে টেমপ্লেট সমর্থন করে:

• ইপিপি ডকুমেন্টেশন।
• ERB ডকুমেন্টেশন।

সংক্ষেপে ERB সম্পর্কে

নিয়ন্ত্রণ কাঠামো:

• <%= ВЫРАЖЕНИЕ %> — অভিব্যক্তির মান সন্নিবেশ করান
• <% ВЫРАЖЕНИЕ %> - একটি অভিব্যক্তির মান গণনা করুন (এটি সন্নিবেশ না করে)। শর্তসাপেক্ষ বিবৃতি (যদি) এবং লুপ (প্রতিটি) সাধারণত এখানে যায়।
• <%# КОММЕНТАРИЙ %>

ইআরবি-তে এক্সপ্রেশনগুলি রুবিতে লেখা হয় (ইআরবি আসলে এমবেডেড রুবি)।

ম্যানিফেস্ট থেকে ভেরিয়েবল অ্যাক্সেস করতে, আপনাকে যোগ করতে হবে @ পরিবর্তনশীল নামের কাছে। একটি নিয়ন্ত্রণ নির্মাণের পরে প্রদর্শিত একটি লাইন বিরতি অপসারণ করতে, আপনাকে একটি ক্লোজিং ট্যাগ ব্যবহার করতে হবে -%>.

টেমপ্লেট ব্যবহারের উদাহরণ

ধরা যাক আমি ZooKeeper নিয়ন্ত্রণ করতে একটি মডিউল লিখছি। কনফিগারেশন তৈরির জন্য দায়ী ক্লাসটি এইরকম কিছু দেখায়:

class zookeeper::configure (
  Array[String] $nodes,
  Integer $port_client,
  Integer $port_quorum,
  Integer $port_leader,
  Hash[String, Any] $properties,
  String $datadir,
) {
  file { '/etc/zookeeper/conf/zoo.cfg':
    ensure  => present,
    content => template('zookeeper/zoo.cfg.erb'),
  }
}

এবং সংশ্লিষ্ট টেমপ্লেট zoo.cfg.erb - তাই:

<% if @nodes.length > 0 -%>
<% @nodes.each do |node, id| -%>
server.<%= id %>=<%= node %>:<%= @port_leader %>:<%= @port_quorum %>;<%= @port_client %>
<% end -%>
<% end -%>

dataDir=<%= @datadir %>

<% @properties.each do |k, v| -%>
<%= k %>=<%= v %>
<% end -%>

তথ্য এবং অন্তর্নির্মিত ভেরিয়েবল

প্রায়শই কনফিগারেশনের নির্দিষ্ট অংশটি বর্তমানে নোডে কী ঘটছে তার উপর নির্ভর করে। উদাহরণস্বরূপ, ডেবিয়ান রিলিজ কিসের উপর নির্ভর করে, আপনাকে প্যাকেজের এক বা অন্য সংস্করণ ইনস্টল করতে হবে। আপনি ম্যানুয়ালি এই সব নিরীক্ষণ করতে পারেন, নোড পরিবর্তন হলে পুনঃলিখন প্রকাশ। তবে এটি একটি গুরুতর পদ্ধতি নয়; অটোমেশন অনেক ভাল।

নোড সম্পর্কে তথ্য প্রাপ্ত করার জন্য, পাপেটের ফ্যাক্টস নামে একটি প্রক্রিয়া রয়েছে। তথ্য - এটি নোড সম্পর্কে তথ্য, গ্লোবাল নেমস্পেসে সাধারণ ভেরিয়েবলের আকারে ম্যানিফেস্টে উপলব্ধ। উদাহরণস্বরূপ, হোস্টের নাম, অপারেটিং সিস্টেম সংস্করণ, প্রসেসর আর্কিটেকচার, ব্যবহারকারীদের তালিকা, নেটওয়ার্ক ইন্টারফেস এবং তাদের ঠিকানাগুলির তালিকা এবং আরও অনেক কিছু। তথ্যগুলি ম্যানিফেস্ট এবং টেমপ্লেটগুলিতে নিয়মিত ভেরিয়েবল হিসাবে উপলব্ধ।

তথ্য নিয়ে কাজ করার একটি উদাহরণ:

notify { "Running OS ${facts['os']['name']} version ${facts['os']['release']['full']}": }
# ресурс типа notify просто выводит сообщение в лог

আনুষ্ঠানিকভাবে বলতে গেলে, একটি সত্যের একটি নাম (স্ট্রিং) এবং একটি মান রয়েছে (বিভিন্ন প্রকার উপলব্ধ: স্ট্রিং, অ্যারে, অভিধান)। খাওয়া অন্তর্নির্মিত তথ্যের সেট. আপনি আপনার নিজের লিখতে পারেন. ফ্যাক্ট সংগ্রাহকদের বর্ণনা করা হয় রুবি ফাংশন মতহয় হিসাবে এক্সিকিউটেবল ফাইল. তথ্য আকারেও উপস্থাপন করা যেতে পারে ডেটা সহ পাঠ্য ফাইল নোড উপর.

অপারেশন চলাকালীন, পুতুল এজেন্ট প্রথমে প্যাপেটসার্ভার থেকে নোডে সমস্ত উপলব্ধ ফ্যাক্ট সংগ্রাহক কপি করে, তারপরে এটি তাদের চালু করে এবং সংগৃহীত তথ্যগুলি সার্ভারে পাঠায়; এর পরে, সার্ভার ক্যাটালগ কম্পাইল করা শুরু করে।

এক্সিকিউটেবল ফাইল আকারে তথ্য

এই ধরনের তথ্য ডিরেক্টরির মডিউলে স্থাপন করা হয় facts.d. অবশ্যই, ফাইলগুলি নির্বাহযোগ্য হতে হবে। চালানোর সময়, তাদের অবশ্যই YAML বা key=value বিন্যাসে স্ট্যান্ডার্ড আউটপুটে তথ্য আউটপুট করতে হবে।

ভুলে যাবেন না যে তথ্যগুলি সমস্ত নোডের ক্ষেত্রে প্রযোজ্য যা পপেট সার্ভার দ্বারা নিয়ন্ত্রিত হয় যেখানে আপনার মডিউল স্থাপন করা হয়েছে। অতএব, স্ক্রিপ্টে, সিস্টেমে আপনার সত্য কাজ করার জন্য প্রয়োজনীয় সমস্ত প্রোগ্রাম এবং ফাইল আছে কিনা তা পরীক্ষা করার যত্ন নিন।

#!/bin/sh
echo "testfact=success"

#!/bin/sh
echo '{"testyamlfact":"success"}'

রুবি ঘটনা

এই ধরনের তথ্য ডিরেক্টরির মডিউলে স্থাপন করা হয় lib/facter.

# всё начинается с вызова функции Facter.add с именем факта и блоком кода
Facter.add('ladvd') do
# в блоках confine описываются условия применимости факта — код внутри блока должен вернуть true, иначе значение факта не вычисляется и не возвращается
  confine do
    Facter::Core::Execution.which('ladvdc') # проверим, что в PATH есть такой исполняемый файл
  end
  confine do
    File.socket?('/var/run/ladvd.sock') # проверим, что есть такой UNIX-domain socket
  end
# в блоке setcode происходит собственно вычисление значения факта
  setcode do
    hash = {}
    if (out = Facter::Core::Execution.execute('ladvdc -b'))
      out.split.each do |l|
        line = l.split('=')
        next if line.length != 2
        name, value = line
        hash[name.strip.downcase.tr(' ', '_')] = value.strip.chomp(''').reverse.chomp(''').reverse
      end
    end
    hash  # значение последнего выражения в блоке setcode является значением факта
  end
end

টেক্সট তথ্য

এই ধরনের তথ্য ডিরেক্টরিতে নোডগুলিতে স্থাপন করা হয় /etc/facter/facts.d পুরানো পুতুলে বা /etc/puppetlabs/facts.d নতুন পুতুলে।

examplefact=examplevalue

---
examplefact2: examplevalue2
anotherfact: anothervalue

তথ্য পাওয়া

তথ্যের কাছে যাওয়ার দুটি উপায় রয়েছে:

• অভিধানের মাধ্যমে $facts: $facts['fqdn'];
• পরিবর্তনশীল নাম হিসাবে ফ্যাক্ট নাম ব্যবহার করে: $fqdn.

একটি অভিধান ব্যবহার করা ভাল $facts, অথবা আরও ভাল, বিশ্বব্যাপী নামস্থান নির্দেশ করুন ($::facts).

এখানে ডকুমেন্টেশনের প্রাসঙ্গিক বিভাগ আছে.

অন্তর্নির্মিত ভেরিয়েবল

ঘটনা ছাড়াও, আছে কিছু ভেরিয়েবল, বিশ্বব্যাপী নামস্থানে উপলব্ধ।

• বিশ্বস্ত তথ্য — ভেরিয়েবলগুলি যা ক্লায়েন্টের শংসাপত্র থেকে নেওয়া হয় (যেহেতু শংসাপত্রটি সাধারণত একটি পপেট সার্ভারে জারি করা হয়, তাই এজেন্ট কেবল তার শংসাপত্র নিতে এবং পরিবর্তন করতে পারে না, তাই ভেরিয়েবলগুলি "বিশ্বস্ত"): শংসাপত্রের নাম, এর নাম হোস্ট এবং ডোমেন, সার্টিফিকেট থেকে এক্সটেনশন।
• সার্ভার তথ্য — সার্ভার সম্পর্কে তথ্য সম্পর্কিত ভেরিয়েবল—সংস্করণ, নাম, সার্ভারের আইপি ঠিকানা, পরিবেশ।
• এজেন্ট তথ্য — ভেরিয়েবলগুলি সরাসরি পুতুল-এজেন্ট দ্বারা যোগ করা হয়েছে, এবং ফ্যাক্টর দ্বারা নয় — শংসাপত্রের নাম, এজেন্ট সংস্করণ, পুতুল সংস্করণ।
• মাস্টার ভেরিয়েবল - প্যাপেটমাস্টার ভেরিয়েবল (sic!) এটা প্রায় একই হিসাবে সার্ভার তথ্য, প্লাস কনফিগারেশন প্যারামিটার মান উপলব্ধ।
• কম্পাইলার ভেরিয়েবল — কম্পাইলার ভেরিয়েবল যা প্রতিটি স্কোপের মধ্যে আলাদা: বর্তমান মডিউলের নাম এবং মডিউলের নাম যেখানে বর্তমান অবজেক্টটি অ্যাক্সেস করা হয়েছিল। সেগুলি ব্যবহার করা যেতে পারে, উদাহরণস্বরূপ, আপনার ব্যক্তিগত ক্লাসগুলি অন্য মডিউলগুলি থেকে সরাসরি ব্যবহার করা হচ্ছে না তা পরীক্ষা করতে।

সংযোজন 1: কীভাবে এই সমস্ত চালাবেন এবং ডিবাগ করবেন?

নিবন্ধটিতে পুতুল কোডের অনেক উদাহরণ রয়েছে, কিন্তু এই কোডটি কীভাবে চালাতে হয় তা আমাদের একেবারেই বলেনি। আচ্ছা, আমি নিজেকে সংশোধন করছি।

পাপেট চালানোর জন্য একজন এজেন্টই যথেষ্ট, তবে বেশিরভাগ ক্ষেত্রে আপনার একটি সার্ভারেরও প্রয়োজন হবে।

দালাল

অন্তত সংস্করণ XNUMX থেকে, থেকে পুতুল-এজেন্ট প্যাকেজ অফিসিয়াল Puppetlabs সংগ্রহস্থল সমস্ত নির্ভরতা (রুবি এবং সংশ্লিষ্ট রত্ন) ধারণ করে, তাই কোনও ইনস্টলেশন অসুবিধা নেই (আমি ডেবিয়ান-ভিত্তিক বিতরণের কথা বলছি - আমরা আরপিএম-ভিত্তিক বিতরণগুলি ব্যবহার করি না)।

সবচেয়ে সহজ ক্ষেত্রে, পুতুল কনফিগারেশন ব্যবহার করার জন্য, সার্ভারহীন মোডে এজেন্ট চালু করা যথেষ্ট: যদি পুতুল কোডটি নোডে অনুলিপি করা হয়, লঞ্চ করা হয় puppet apply <путь к манифесту>:

atikhonov@atikhonov ~/puppet-test $ cat helloworld.pp 
node default {
    notify { 'Hello world!': }
}
atikhonov@atikhonov ~/puppet-test $ puppet apply helloworld.pp 
Notice: Compiled catalog for atikhonov.localdomain in environment production in 0.01 seconds
Notice: Hello world!
Notice: /Stage[main]/Main/Node[default]/Notify[Hello world!]/message: defined 'message' as 'Hello world!'
Notice: Applied catalog in 0.01 seconds

অবশ্যই, সার্ভার সেট আপ করা এবং ডেমন মোডে নোডগুলিতে এজেন্ট চালানো আরও ভাল - তারপরে প্রতি আধ ঘন্টায় একবার তারা সার্ভার থেকে ডাউনলোড করা কনফিগারেশন প্রয়োগ করবে।

আপনি কাজের পুশ মডেল অনুকরণ করতে পারেন - আপনি আগ্রহী নোডে যান এবং শুরু করুন sudo puppet agent -t. চাবি -t (--test) আসলে বেশ কয়েকটি বিকল্প অন্তর্ভুক্ত করে যা পৃথকভাবে সক্ষম করা যেতে পারে। এই বিকল্পগুলির মধ্যে নিম্নলিখিতগুলি অন্তর্ভুক্ত রয়েছে:

• ডেমন মোডে চালাবেন না (ডিফল্টরূপে এজেন্ট ডেমন মোডে শুরু হয়);
• ক্যাটালগ প্রয়োগ করার পরে বন্ধ করুন (ডিফল্টরূপে, এজেন্ট কাজ চালিয়ে যাবে এবং প্রতি আধ ঘন্টায় একবার কনফিগারেশন প্রয়োগ করবে);
• একটি বিস্তারিত কাজের লগ লিখুন;
• ফাইলে পরিবর্তন দেখান।

এজেন্টের পরিবর্তন ছাড়াই একটি অপারেটিং মোড রয়েছে - আপনি যখন নিশ্চিত নন যে আপনি সঠিক কনফিগারেশন লিখেছেন এবং অপারেশন চলাকালীন এজেন্টটি ঠিক কী পরিবর্তন করবে তা পরীক্ষা করতে চাইলে আপনি এটি ব্যবহার করতে পারেন। এই মোড প্যারামিটার দ্বারা সক্রিয় করা হয় --noop কমান্ড লাইনে: sudo puppet agent -t --noop.

এছাড়াও, আপনি কাজের ডিবাগিং লগ সক্ষম করতে পারেন - এতে, পুতুল এটি যে সমস্ত ক্রিয়া সম্পাদন করে সে সম্পর্কে লেখে: এটি যে সংস্থানটি বর্তমানে প্রক্রিয়া করছে সে সম্পর্কে, এই সংস্থানের পরামিতিগুলি সম্পর্কে, এটি কোন প্রোগ্রামগুলি চালু করে সে সম্পর্কে। অবশ্যই এটি একটি পরামিতি --debug.

সার্ভার

আমি এই নিবন্ধে প্যাপেটসার্ভারের সম্পূর্ণ সেটআপ এবং এতে কোড স্থাপনের বিষয়টি বিবেচনা করব না; আমি কেবল বলব যে বাক্সের বাইরে সার্ভারের একটি সম্পূর্ণ কার্যকরী সংস্করণ রয়েছে যা একটি ছোট সাথে কাজ করার জন্য অতিরিক্ত কনফিগারেশনের প্রয়োজন হয় না। নোডের সংখ্যা (বলুন, একশ পর্যন্ত)। একটি বৃহত্তর সংখ্যক নোডের জন্য টিউনিং প্রয়োজন হবে - ডিফল্টরূপে, পাপেটসার্ভার চারজনের বেশি কর্মী চালু করে না, বৃহত্তর কর্মক্ষমতার জন্য আপনাকে তাদের সংখ্যা বাড়াতে হবে এবং মেমরির সীমা বাড়াতে ভুলবেন না, অন্যথায় সার্ভার বেশিরভাগ সময় আবর্জনা সংগ্রহ করবে।

কোড স্থাপনা - আপনার যদি দ্রুত এবং সহজে এটির প্রয়োজন হয় তবে দেখুন (r10k এ)[https://github.com/puppetlabs/r10k], ছোট ইনস্টলেশনের জন্য এটি যথেষ্ট হওয়া উচিত।

সংযোজন 2: কোডিং নির্দেশিকা

1. ক্লাস এবং সংজ্ঞায় সমস্ত যুক্তি রাখুন।
2. ক্লাস এবং সংজ্ঞা মডিউলে রাখুন, নোড বর্ণনাকারী ম্যানিফেস্টে নয়।
3. তথ্য ব্যবহার করুন.
4. হোস্টনামের উপর ভিত্তি করে ifs তৈরি করবেন না।
5. ক্লাস এবং সংজ্ঞার জন্য নির্দ্বিধায় পরামিতি যোগ করুন - এটি ক্লাস/সংজ্ঞায়িতের মূল অংশে লুকানো অন্তর্নিহিত যুক্তির চেয়ে ভাল।

কেন আমি পরবর্তী নিবন্ধে এটি করার পরামর্শ দিচ্ছি তা আমি ব্যাখ্যা করব।

উপসংহার

ভূমিকা দিয়ে শেষ করা যাক। পরবর্তী নিবন্ধে আমি আপনাকে Hiera, ENC এবং PuppetDB সম্পর্কে বলব।

শুধুমাত্র নিবন্ধিত ব্যবহারকারীরা জরিপে অংশগ্রহণ করতে পারবেন। সাইন ইন করুনকরুন।

আসলে, আরও অনেক উপাদান রয়েছে - আমি নিম্নলিখিত বিষয়গুলিতে নিবন্ধ লিখতে পারি, আপনি কোন বিষয়ে পড়তে আগ্রহী হবেন সে বিষয়ে ভোট দিন:

• 59,1%উন্নত পুতুল নির্মাণ - কিছু পরবর্তী স্তরের বিষ্ঠা: লুপ, ম্যাপিং এবং অন্যান্য ল্যাম্বডা এক্সপ্রেশন, রিসোর্স সংগ্রাহক, রপ্তানি করা সম্পদ এবং পাপেট, ট্যাগ, প্রদানকারী, বিমূর্ত ডেটা প্রকারের মাধ্যমে আন্তঃ-হোস্ট যোগাযোগ।13
• 31,8%"আমি আমার মায়ের প্রশাসক" বা কীভাবে আমরা আভিটোতে বিভিন্ন সংস্করণের বেশ কয়েকটি পপেট সার্ভারের সাথে বন্ধুত্ব করেছি, এবং নীতিগতভাবে, পপেট সার্ভার পরিচালনার অংশ।7
• 81,8%আমরা কিভাবে পুতুল কোড লিখি: ইন্সট্রুমেন্টেশন, ডকুমেন্টেশন, টেস্টিং, CI/CD.18

22 জন ব্যবহারকারী ভোট দিয়েছেন। 9 জন ব্যবহারকারী বিরত ছিলেন।

উত্স: www.habr.com