স্কুল কম্পিউটার বিজ্ঞানের উপর পর্যায় সারণী

(নিয়ন্ত্রণ কার্ড)
(রাসায়নিক উপাদানগুলির পর্যায় সারণীর আন্তর্জাতিক বছরকে উত্সর্গীকৃত)
(শেষ সংযোজন 8 এপ্রিল, 2019-এ করা হয়েছে। কাটার নীচে সংযোজনের তালিকা)

(মেন্ডেলিভের ফুল, উৎস)

আমি মনে করি আমরা হাঁস পাস. এটি একবারে তিনটি পাঠ ছিল: ভূগোল, প্রাকৃতিক বিজ্ঞান এবং রাশিয়ান। একটি বিজ্ঞান পাঠে, একটি হাঁস হাঁসের মতো অধ্যয়ন করা হয়েছিল, এর কী ডানা আছে, কী পাঞ্জা আছে, কীভাবে সাঁতার কাটে ইত্যাদি। একটি ভূগোল পাঠে, একই হাঁসটিকে পৃথিবীর বাসিন্দা হিসাবে অধ্যয়ন করা হয়েছিল: এটি কোথায় থাকে এবং কোথায় থাকে না তা মানচিত্রে দেখানো প্রয়োজন ছিল। রাশিয়ান ভাষায়, সেরাফিমা পেট্রোভনা আমাদের "উ-টি-কে-এ" লিখতে এবং ব্রেম থেকে হাঁস সম্পর্কে কিছু পড়তে শিখিয়েছিলেন। ক্ষণস্থায়ী, তিনি আমাদের জানান যে জার্মান ভাষায় হাঁস অমুক এবং ফরাসি ভাষায় অমুক। আমি মনে করি তখন এটিকে "জটিল পদ্ধতি" বলা হত। সাধারণভাবে, সবকিছু "পাসিং" বেরিয়ে এসেছিল।

বেঞ্জামিন ক্যাভেরিন, দুই অধিনায়ক

উপরের উদ্ধৃতিতে, ভেনিয়ামিন কাভেরিন দক্ষতার সাথে সমন্বিত শিক্ষাদান পদ্ধতির ত্রুটিগুলি দেখিয়েছেন, তবে, কিছু (সম্ভবত বেশ বিরল) ক্ষেত্রে, এই পদ্ধতির উপাদানগুলি ন্যায়সঙ্গত। এই ক্ষেত্রেগুলির মধ্যে একটি হল স্কুল কম্পিউটার বিজ্ঞানের পাঠে ডি.আই. মেন্ডেলিভের পর্যায় সারণী। পর্যায় সারণীর সাথে সাধারণ ক্রিয়াগুলির সফ্টওয়্যার অটোমেশনের কাজটি স্কুলছাত্রদের জন্য স্পষ্ট যারা রসায়ন অধ্যয়ন শুরু করেছে এবং অনেকগুলি সাধারণ রাসায়নিক কাজগুলিতে বিভক্ত। একই সময়ে, তথ্যবিদ্যার কাঠামোর মধ্যে, এই কাজটি নিয়ন্ত্রণ কার্ডের পদ্ধতি প্রদর্শনের জন্য একটি সহজ আকারে অনুমতি দেয়, যা গ্রাফিকাল প্রোগ্রামিংকে দায়ী করা যেতে পারে, গ্রাফিক উপাদানগুলির সাহায্যে প্রোগ্রামিং হিসাবে শব্দের বিস্তৃত অর্থে বোঝা যায়। .

(এপ্রিল 8, 2019 সংযোজন করা হয়েছে:
সংযোজন 1: রাসায়নিক ক্যালকুলেটর কিভাবে কাজ করে
সংযোজন 2: ফিল্টারগুলির জন্য কাজের উদাহরণ)

একটি মৌলিক কাজ দিয়ে শুরু করা যাক। সবচেয়ে সহজ ক্ষেত্রে, পর্যায় সারণীটি একটি উইন্ডো আকারে পর্দায় প্রদর্শিত হওয়া উচিত, যেখানে প্রতিটি কোষে উপাদানটির রাসায়নিক উপাধি থাকবে: H - হাইড্রোজেন, তিনি - হিলিয়াম ইত্যাদি। যদি মাউস কার্সার একটি কক্ষের দিকে নির্দেশ করে, তাহলে উপাদানটির উপাধি এবং এর সংখ্যা আমাদের ফর্মের একটি বিশেষ ক্ষেত্রে প্রদর্শিত হয়। ব্যবহারকারী যদি LMB চাপেন, তাহলে এই নির্বাচিত উপাদানটির পদবী এবং সংখ্যা ফর্মের অন্য ক্ষেত্রে নির্দেশিত হবে।

সমস্যাটি যেকোনো সার্বজনীন PL-এ সমাধান করা যেতে পারে। আমরা একটি সাধারণ পুরানো Delpi-7 নেব, যা প্রায় সবার কাছে বোধগম্য। কিন্তু PL এ প্রোগ্রামিং করার আগে, আসুন দুটি ছবি আঁকুন, উদাহরণস্বরূপ, ফটোশপে। প্রথমে, পর্যায়ক্রমিক সারণীটি আমরা যেভাবে প্রোগ্রামে দেখতে চাই সেভাবে আঁকুন। একটি গ্রাফিক ফাইলে ফলাফল সংরক্ষণ করুন table01.bmp.

দ্বিতীয় অঙ্কনের জন্য, প্রথমটি ব্যবহার করুন। আমরা ক্রমানুসারে RGB কালার মডেলে অনন্য রং দিয়ে যেকোনো গ্রাফিক্স থেকে সাফ করা টেবিল সেলগুলি পূরণ করব। R এবং G সর্বদা 0 হবে, এবং B=1 হাইড্রোজেনের জন্য, 2 হিলিয়ামের জন্য, ইত্যাদি। এই অঙ্কনটি হবে আমাদের নিয়ন্ত্রণ মানচিত্র, যা আমরা নামের একটি ফাইলে সংরক্ষণ করব। table2.bmp.

ফটোশপে গ্রাফিক প্রোগ্রামিং এর প্রথম ধাপ শেষ। চলুন Delpi-7 IDE-তে GUI প্রোগ্রামিং-এ এগিয়ে যাই। এটি করার জন্য, একটি নতুন প্রকল্প খুলুন, যেখানে আমরা প্রধান ফর্মে একটি ডায়ালগ কল বোতাম রাখি (টেবিলডিএলজি) যেখানে টেবিলের সাথে কাজ হবে। পরবর্তী আমরা ফর্ম সঙ্গে কাজ. টেবিলডিএলজি.

ফর্মে একটি ক্লাস কম্পোনেন্ট রাখুন টাইমেজ। আমরা পাই Image1. নোট করুন যে, সাধারণভাবে, বড় প্রকল্পের জন্য, ফর্মের নাম স্বয়ংক্রিয়ভাবে তৈরি হয় ImageNযেখানে N কয়েক দশ বা তার বেশি পৌঁছতে পারে - সেরা প্রোগ্রামিং শৈলী নয়, এবং আরও অর্থপূর্ণ নাম দেওয়া উচিত। কিন্তু আমাদের ছোট্ট প্রকল্পে কোথায় N 2 এর বেশি হবে না, আপনি এটিকে জেনারেট করা হিসাবে ছেড়ে দিতে পারেন।

সম্পত্তির কাছে ছবি 1. ছবি ফাইল আপলোড করুন table01.bmp. আমরা বানাই Image2 এবং সেখানে আমাদের নিয়ন্ত্রণ কার্ড আপলোড করুন table2.bmp. একই সময়ে, আমরা ফাইলটিকে ছোট এবং ব্যবহারকারীর কাছে অদৃশ্য করে দিই, যেমন ফর্মের নীচের বাম কোণে দেখানো হয়েছে। আমরা অতিরিক্ত নিয়ন্ত্রণ যোগ করি, যার উদ্দেশ্য সুস্পষ্ট। Delpi-7 IDE-তে GUI প্রোগ্রামিংয়ের দ্বিতীয় পর্যায়ের কাজ শেষ হয়েছে।

চলুন তৃতীয় পর্যায়ে চলে যাই - ডেলপি-৭ আইডিই-তে কোড লেখা। মডিউলটিতে শুধুমাত্র পাঁচটি ইভেন্ট হ্যান্ডলার রয়েছে: ফর্ম তৈরি (FormCreate), বরাবর কার্সার আন্দোলন Image1 (Image1MouseMove), একটি কক্ষে LMB ক্লিক করা (Image1 ক্লিক করুন) এবং ঠিক আছে বোতাম ব্যবহার করে ডায়ালগ থেকে প্রস্থান করুন (OKBtn ক্লিক করুন) অথবা বাতিল (CancelBtnClick) এই হ্যান্ডলারগুলির শিরোনামগুলি IDE দ্বারা একটি আদর্শ উপায়ে তৈরি করা হয়।

মডিউল সোর্স কোড:

unit tableUnit;
// Периодическая таблица химических элементов Д.И.Менделеева
//
// third112
// https://habr.com/ru/users/third112/
//
// Оглавление
// 1) создание формы
// 2) работа с таблицей: указание и выбор
// 3) выход из диалога

interface

uses Windows, SysUtils, Classes, Graphics, Forms, Controls, StdCtrls, 
  Buttons, ExtCtrls;

const
 size = 104; // число элементов
 
type
 TtableDlg = class(TForm)
    OKBtn: TButton;
    CancelBtn: TButton;
    Bevel1: TBevel;
    Image1: TImage;  //таблица химических элементов
    Label1: TLabel;
    Image2: TImage;  //управляющая карта
    Label2: TLabel;
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject); // создание формы
    procedure Image1MouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);                        // указание клетки
    procedure Image1Click(Sender: TObject); // выбор клетки
    procedure OKBtnClick(Sender: TObject);  // OK
    procedure CancelBtnClick(Sender: TObject); // Cancel
  private
    { Private declarations }
    TableSymbols : array [1..size] of string [2]; // массив обозначений элементов
  public
    { Public declarations }
    selectedElement : string; // выбранный элемент
    currNo : integer;         // текущий номер элемента
  end;

var
  tableDlg: TtableDlg;

implementation

{$R *.dfm}

const
PeriodicTableStr1=
'HHeLiBeBCNOFNeNaMgAlSiPSClArKCaScTiVCrMnFeCoNiCuZnGaGeAsSeBrKrRbSrYZrNbMoTcRuRhPdAgCdInSnSbTeIXeCsBaLa';
PeriodicTableStr2='CePrNdPmSmEuGdTbDyHoErTmYbLu';
PeriodicTableStr3='HfTaWReOsIrPtAuHgTlPbBiPoAtRnFrRaAc';
PeriodicTableStr4='ThPaUNpPuAmCmBkCfEsFmMdNoLrKu ';

// создание формы  ==================================================

procedure TtableDlg.FormCreate(Sender: TObject);
// создание формы
var
  s : string;
  i,j : integer;
begin
  currNo := 0;
// инициализация массива обозначений элементов:
  s := PeriodicTableStr1+ PeriodicTableStr2+PeriodicTableStr3+PeriodicTableStr4;
  j := 1;
  for i :=1 to size do
   begin
     TableSymbols [i] := s[j];
     inc (j);
     if s [j] in ['a'..'z'] then
      begin
        TableSymbols [i] := TableSymbols [i]+ s [j];
        inc (j);
      end; // if s [j] in
   end; // for i :=1
end; // FormCreate ____________________________________________________

// работа с таблицей: указание и выбор =========================================

procedure TtableDlg.Image1MouseMove(Sender: TObject; Shift: TShiftState;
  X, Y: Integer);
// указание клетки
var
  sl : integer;
begin
  sl := GetBValue(Image2.Canvas.Pixels [x,y]);
  if sl in [1..size] then
   begin
    Label1.Caption := intToStr (sl)+ ' '+TableSymbols [sl];
    currNo := sl;
   end
  else
    Label1.Caption := 'Select element:';
end; // Image1MouseMove   ____________________________________________________

procedure TtableDlg.Image1Click(Sender: TObject);
begin
  if currNo <> 0 then
   begin
    selectedElement := TableSymbols [currNo];
    Label2.Caption := intToStr (currNo)+ ' '+selectedElement+ ' selected';
    Edit1.Text := selectedElement;
   end;
end; // Image1Click  ____________________________________________________

// выход из диалога  ==================================================

procedure TtableDlg.OKBtnClick(Sender: TObject);
begin
    selectedElement := Edit1.Text;
    hide;
end;  // OKBtnClick ____________________________________________________

procedure TtableDlg.CancelBtnClick(Sender: TObject);
begin
  hide;
end;  // CancelBtnClick ____________________________________________________

end.

আমাদের সংস্করণে, আমরা 104টি উপাদানের আকার সহ একটি টেবিল নিয়েছি (ধ্রুবক আয়তন) স্পষ্টতই, এই আকার বাড়ানো যেতে পারে। উপাদান উপাধি (রাসায়নিক প্রতীক) একটি অ্যারেতে লেখা হয় সারণি প্রতীক. যাইহোক, সোর্স কোডের সংক্ষিপ্ততার কারণে, স্ট্রিং ধ্রুবক আকারে এই স্বরলিপিগুলির ক্রম লেখা উপযুক্ত বলে মনে হয়। PeriodicTableStr1..., PeriodicTableStr4যাতে ফর্মটি তৈরি করা হলে, প্রোগ্রাম নিজেই এই উপাধিগুলিকে অ্যারের উপাদানগুলির মধ্যে ছড়িয়ে দেয়। প্রতিটি উপাদান উপাধিতে এক বা দুটি ল্যাটিন অক্ষর থাকে, প্রথম অক্ষরটি বড় হাতের এবং দ্বিতীয়টি (যদি থাকে) ছোট হাতের অক্ষর সহ। একটি অ্যারে লোড করার সময় এই সহজ নিয়মটি প্রয়োগ করা হয়। সুতরাং, স্বরলিপির ক্রমটি স্পেস ছাড়াই সংকুচিত উপায়ে লেখা যেতে পারে। ক্রমটিকে চারটি অংশে বিভক্ত করা (ধ্রুবক PeriodicTableStr1..., PeriodicTableStr4) সোর্স কোডের পঠনযোগ্যতার বিবেচনার কারণে, যেহেতু খুব দীর্ঘ একটি স্ট্রিং পর্দায় পুরোপুরি ফিট নাও হতে পারে৷

উপর মাউস কার্সার সরানোর ঘটনা Image1 হ্যান্ডলার Image1MouseMove এই ঘটনাটি নিয়ন্ত্রণ মানচিত্র পিক্সেলের রঙের নীল উপাদানের মান নির্ধারণ করে Image2 বর্তমান কার্সার স্থানাঙ্কের জন্য। নির্মাণ দ্বারা Image2 এই মানটি উপাদান সংখ্যার সমান যদি কার্সারটি ঘরের ভিতরে থাকে; সীমান্তে থাকলে শূন্য, এবং অন্যথায় 255। প্রোগ্রাম দ্বারা সম্পাদিত বাকি কর্মগুলি তুচ্ছ এবং ব্যাখ্যার প্রয়োজন নেই৷

উপরে উল্লিখিত স্টাইলিস্টিক প্রোগ্রামিং কৌশলগুলি ছাড়াও, এটি মন্তব্যের শৈলীটি লক্ষ্য করার মতো। কঠোরভাবে বলতে গেলে, বিবেচিত কোডটি এত ছোট এবং সহজ যে মন্তব্যগুলি বিশেষভাবে প্রয়োজনীয় বলে মনে হয় না। যাইহোক, সেগুলি যোগ করা হয়েছিল, পদ্ধতিগত কারণ সহ - একটি সংক্ষিপ্ত কোড আপনাকে কিছু সাধারণ সিদ্ধান্তকে আরও পরিষ্কার করতে দেয়। উপস্থাপিত কোডে, একটি ক্লাস ঘোষণা করা হয় (TtableDlg) এই ক্লাসের পদ্ধতিগুলি আদান-প্রদান করা যেতে পারে এবং এটি কোনওভাবেই প্রোগ্রামের কার্যকারিতাকে প্রভাবিত করবে না, তবে এর পাঠযোগ্যতাকে প্রভাবিত করতে পারে। উদাহরণস্বরূপ, ক্রমটি কল্পনা করুন:

OKBtnClick, Image1MouseMove, FormCreate, Image1Click, CancelBtnClick.

হয়তো খুব একটা লক্ষণীয় নয়, কিন্তু পড়তে ও বুঝতে একটু বেশি কষ্ট হবে। যদি পাঁচটি পদ্ধতি না থাকে তবে কয়েক ডজন গুণ বেশি এবং বিভাগে বাস্তবায়ন ক্লাসের বর্ণনার তুলনায় তাদের সম্পূর্ণ ভিন্ন ক্রম রয়েছে, তাহলে বিশৃঙ্খলা কেবল বাড়বে। অতএব, যদিও কঠোর প্রমাণ কঠিন এবং এমনকি অসম্ভবও হতে পারে, আশা করা যায় যে অতিরিক্ত অর্ডার প্রবর্তন কোডের পাঠযোগ্যতাকে উন্নত করবে। এই অতিরিক্ত অর্ডারটি অনুরূপ কাজগুলি সম্পাদন করে এমন বেশ কয়েকটি পদ্ধতির যৌক্তিক গ্রুপিং দ্বারা সহজতর হয়। প্রতিটি গ্রুপকে একটি শিরোনাম দেওয়া উচিত, উদাহরণস্বরূপ:

// работа с таблицей: указание и выбор

এই শিরোনামগুলি মডিউলের শুরুতে অনুলিপি করা উচিত এবং বিষয়বস্তুর সারণী হিসাবে ফর্ম্যাট করা উচিত। পর্যাপ্ত দীর্ঘ মডিউলের কিছু ক্ষেত্রে, বিষয়বস্তুর এই ধরনের টেবিল অতিরিক্ত নেভিগেশন বিকল্প প্রদান করে। একইভাবে, একটি পদ্ধতি, পদ্ধতি বা ফাংশনের একটি দীর্ঘ অংশে, এটি মূল্যবান, প্রথমে, এই শরীরের শেষ চিহ্নিত করা:

end; // FormCreate

এবং, দ্বিতীয়ত, প্রোগ্রাম বন্ধনীর সাথে শাখাযুক্ত বিবৃতিতে শুরু - শেষ, বিবৃতিটি চিহ্নিত করুন যা বন্ধ বন্ধনীটি নির্দেশ করে:

      end; // if s [j] in
   end; // for i :=1
end; // FormCreate

গ্রুপ শিরোনাম এবং মেথড বডির প্রান্তগুলি হাইলাইট করতে, আপনি লাইন যোগ করতে পারেন যেগুলি বেশিরভাগ অপারেটরের দৈর্ঘ্য অতিক্রম করে এবং যথাক্রমে "=" এবং "_" অক্ষরগুলির সমন্বয়ে গঠিত।
আবার, আমাদের একটি সংরক্ষণ করতে হবে: আমাদের উদাহরণটি খুব সহজ। এবং যখন একটি পদ্ধতির কোড একটি স্ক্রিনে ফিট না হয়, তখন কোডে পরিবর্তন করার জন্য পরপর ছয়টি প্রান্ত বের করা কঠিন হতে পারে। কিছু পুরানো কম্পাইলারে, উদাহরণস্বরূপ, OS IBM 8000/360 এর জন্য Pascal 370, ফর্মের একটি পরিষেবা কলাম

B5
…
E5

এর মানে হল যে লাইন E5 এর ক্লোজিং ব্রেসটি B5 লাইনের খোলার বন্ধনীর সাথে মিলে গেছে।

অবশ্যই, প্রোগ্রামিং শৈলী একটি খুব বিতর্কিত বিষয়, তাই এখানে প্রকাশিত ধারণাগুলিকে চিন্তার খোরাক ছাড়া আর কিছুই হিসাবে নেওয়া উচিত নয়। দু'জন মোটামুটি অভিজ্ঞ প্রোগ্রামার যারা বহু বছর ধরে কাজ করে বিভিন্ন শৈলীর বিকাশ এবং অভ্যস্ত হয়ে উঠেছে তাদের পক্ষে একমত হওয়া খুব কঠিন হতে পারে। আরেকটি বিষয় হল প্রোগ্রামিংয়ের একজন ছাত্র, একজন স্কুলবয়সী যে এখনও নিজের স্টাইল খুঁজে বের করার সময় পায়নি। আমি মনে করি যে এই ক্ষেত্রে, শিক্ষকের অন্ততপক্ষে তার ছাত্রদের কাছে এত সহজ, কিন্তু তাদের কাছে সুস্পষ্ট ধারণা জানানো উচিত নয় যে প্রোগ্রামের সাফল্য মূলত তার উত্স কোডটি যে শৈলীতে লেখা হয়েছে তার উপর নির্ভর করে। ছাত্রটি প্রস্তাবিত শৈলী অনুসরণ নাও করতে পারে, তবে অন্তত তাকে সোর্স কোডের নকশা উন্নত করার জন্য "অতিরিক্ত" কর্মের প্রয়োজন সম্পর্কে চিন্তা করতে দিন।

পর্যায় সারণীতে আমাদের মূল কাজটিতে ফিরে আসা: আরও উন্নয়ন বিভিন্ন দিকে যেতে পারে। নির্দেশাবলীর মধ্যে একটি রেফারেন্সের জন্য: আপনি যখন একটি টেবিল সেলের উপর মাউস কার্সারটি ঘোরান, একটি তথ্য উইন্ডো প্রদর্শিত হবে যেখানে নির্দিষ্ট উপাদানের অতিরিক্ত তথ্য রয়েছে। আরও উন্নয়ন - ফিল্টার. উদাহরণস্বরূপ, সেটিং এর উপর নির্ভর করে, তথ্য উইন্ডোতে শুধুমাত্র থাকবে: সবচেয়ে গুরুত্বপূর্ণ ভৌত এবং রাসায়নিক তথ্য, আবিষ্কারের ইতিহাসের তথ্য, প্রকৃতিতে বিতরণ সম্পর্কিত তথ্য, সবচেয়ে গুরুত্বপূর্ণ যৌগগুলির একটি তালিকা (যা এই উপাদানটি অন্তর্ভুক্ত করে), শারীরবৃত্তীয় বৈশিষ্ট্য, একটি বিদেশী ভাষায় একটি নাম, ইত্যাদি। যেমন কাভেরিনের "হাঁস" যা দিয়ে এই নিবন্ধটি শুরু হয়েছে, আমরা বলতে পারি যে প্রোগ্রামটির এই জাতীয় বিকাশের সাথে আমরা প্রাকৃতিক বিজ্ঞানে একটি সম্পূর্ণ প্রশিক্ষণ কমপ্লেক্স পাব: উপরন্তু কম্পিউটার বিজ্ঞান, পদার্থবিদ্যা এবং রসায়ন - জীববিজ্ঞান, অর্থনৈতিক ভূগোল, বিজ্ঞানের ইতিহাস এবং এমনকি বিদেশী ভাষা।

কিন্তু স্থানীয় ডাটাবেসের সীমা নেই। প্রোগ্রাম স্বাভাবিকভাবেই ইন্টারনেটের সাথে সংযোগ করে। যখন একটি উপাদান নির্বাচন করা হয়, একটি লিঙ্ক ট্রিগার হয়, এবং এই উপাদান সম্পর্কে একটি উইকিপিডিয়া নিবন্ধ ওয়েব ব্রাউজার উইন্ডোতে খোলা হয়। উইকিপিডিয়া একটি প্রামাণিক উৎস হিসেবে পরিচিত নয়। আপনি প্রামাণিক উত্সগুলির লিঙ্কগুলি সেট করতে পারেন, উদাহরণস্বরূপ, একটি রাসায়নিক বিশ্বকোষ, টিএসবি, বিমূর্ত জার্নাল, এই উপাদানটির জন্য অনুসন্ধান ইঞ্জিনগুলিতে অর্ডার কোয়েরি ইত্যাদি। যে. শিক্ষার্থীরা DBMS এবং ইন্টারনেটের বিষয়গুলিতে সহজ কিন্তু অর্থপূর্ণ কাজগুলি সম্পূর্ণ করতে সক্ষম হবে।

একটি পৃথক উপাদানের প্রশ্নগুলি ছাড়াও, আপনি একটি কার্যকরী করতে পারেন যা চিহ্নিত করবে, উদাহরণস্বরূপ, বিভিন্ন রঙের সাথে, একটি টেবিলের ঘর যা নির্দিষ্ট মানদণ্ড পূরণ করে। যেমন, ধাতু এবং অধাতু। বা কোষ যা স্থানীয় রাসায়নিক উদ্ভিদ দ্বারা জলাশয়ে ডাম্প করা হয়।

আপনি একটি সংগঠক নোটবুকের কার্যাবলী বাস্তবায়ন করতে পারেন। উদাহরণ স্বরূপ, পরীক্ষায় অন্তর্ভুক্ত উপাদানগুলিকে সারণীতে তুলে ধরুন। তারপর পরীক্ষার প্রস্তুতির জন্য শিক্ষার্থী দ্বারা অধ্যয়ন করা/পুনরাবৃত্তি করা উপাদানগুলিকে হাইলাইট করুন।

এবং এখানে, উদাহরণস্বরূপ, স্কুল রসায়নের একটি সাধারণ কাজ:

10 গ্রাম চক দেওয়া। এই সমস্ত চক দ্রবীভূত করতে কতটা হাইড্রোক্লোরিক অ্যাসিড নিতে হবে?

এই সমস্যা সমাধানের জন্য প্রয়োজন, কেম লিখে। প্রতিক্রিয়া এবং এতে সহগ স্থাপন করুন, ক্যালসিয়াম কার্বনেট এবং হাইড্রোজেন ক্লোরাইডের আণবিক ওজন গণনা করুন, তারপর আঁকুন এবং অনুপাতটি সমাধান করুন। আমাদের মৌলিক প্রোগ্রামের উপর ভিত্তি করে একটি ক্যালকুলেটর গণনা এবং সমাধান করতে সক্ষম হবে। সত্য, এটি এখনও বিবেচনায় নেওয়া দরকার যে অ্যাসিডটি অবশ্যই যুক্তিসঙ্গত অতিরিক্ত এবং যুক্তিসঙ্গত ঘনত্বের সাথে নেওয়া উচিত, তবে এটি ইতিমধ্যে রসায়ন, কম্পিউটার বিজ্ঞান নয়।
সংযোজন 1: রাসায়নিক ক্যালকুলেটর কিভাবে কাজ করেচক এবং "হজপজ" এর উপরের সমস্যার উদাহরণ ব্যবহার করে ক্যালকুলেটরের অপারেশন বিশ্লেষণ করা যাক। প্রতিক্রিয়া দিয়ে শুরু করা যাক:

CaCO3 + 2HCl = CaCl2 + H2O

এখান থেকে আমরা দেখতে পাচ্ছি যে আমাদের নিম্নলিখিত উপাদানগুলির পারমাণবিক ওজনের প্রয়োজন হবে: ক্যালসিয়াম (Ca), কার্বন (C), অক্সিজেন (O), হাইড্রোজেন (H) এবং ক্লোরিন (Cl)। সহজ ক্ষেত্রে, আমরা এই ওজনগুলিকে সংজ্ঞায়িত এক-মাত্রিক অ্যারেতে লিখতে পারি

AtomicMass : array [1..size] of real;

যেখানে অ্যারে সূচকটি উপাদান সংখ্যার সাথে মিলে যায়। তখনও ফরমের ফাঁকা জায়গায় টেবিলডিএলজি দুটি ক্ষেত্র রাখুন। প্রথম ক্ষেত্রে এটি মূলত লেখা আছে: "প্রথম বিকারক দেওয়া হয়েছে", দ্বিতীয়টিতে - "দ্বিতীয় বিকারক x খুঁজুন"। এর ক্ষেত্র নির্দেশ করা যাক বিকারক1, বিকারক2 যথাক্রমে প্রোগ্রামের অন্যান্য সংযোজন ক্যালকুলেটরের নিম্নলিখিত উদাহরণ থেকে স্পষ্ট হবে।

আমরা কম্পিউটার কীবোর্ডে টাইপ করি: 10 গ্রাম। ক্ষেত্রের শিলালিপি বিকারক1 পরিবর্তন: "প্রথম বিকারক 10 গ্রাম দেওয়া হয়েছে"। এখন আমরা এই বিকারকটির সূত্রটি প্রবেশ করি, এবং ক্যালকুলেটরটি প্রবেশ করার সাথে সাথে তার আণবিক ওজন গণনা করবে এবং দেখাবে।

Ca চিহ্ন সহ টেবিলের ঘরে LMB-এ ক্লিক করুন। মাঠে শিলালিপি বিকারক1 পরিবর্তন: "প্রথম বিকারক Ca 40.078 দেওয়া হয়েছে 10 গ্রাম"।

সি চিহ্ন সহ টেবিলের ঘরে LMB ক্লিক করুন। ক্ষেত্রের শিলালিপি বিকারক1 পরিবর্তন: "প্রথম বিকারক CaC 52.089 দেওয়া হয়েছে 10 গ্রাম"। সেগুলো. ক্যালকুলেটর ক্যালসিয়াম এবং কার্বনের পারমাণবিক ওজন যোগ করেছে।

টেবিলের ঘরে O চিহ্ন সহ LMB টিপুন। ক্ষেত্রের শিলালিপি বিকারক1 পরিবর্তন: "প্রথম বিকারক CaCO 68.088 দেওয়া হয়েছে 10 গ্রাম"। ক্যালকুলেটর যোগফলের সাথে অক্সিজেনের পারমাণবিক ওজন যোগ করেছে।

টেবিলের ঘরে O চিহ্ন সহ LMB টিপুন। ক্ষেত্রের শিলালিপি বিকারক1 পরিবর্তন: "প্রথম বিকারক CaCO2 84.087 দেওয়া হয়েছে 10 গ্রাম"। ক্যালকুলেটর আবার যোগফলের সাথে অক্সিজেনের পারমাণবিক ওজন যোগ করেছে।

টেবিলের ঘরে O চিহ্ন সহ LMB টিপুন। ক্ষেত্রের শিলালিপি বিকারক1 পরিবর্তন: "প্রথম বিকারক CaCO3 100.086 দেওয়া হয়েছে 10 গ্রাম"। ক্যালকুলেটর আবার যোগফলের সাথে অক্সিজেনের পারমাণবিক ওজন যোগ করে।

কম্পিউটার কীবোর্ডে এন্টার টিপুন। প্রথম রিএজেন্টের ইনপুট সম্পন্ন হয় এবং ক্ষেত্রের দিকে সুইচ করে বিকারক2. মনে রাখবেন যে এই উদাহরণে, আমরা একটি ন্যূনতম সংস্করণ প্রদান করি। আপনি যদি চান, আপনি সহজেই একই ধরণের পরমাণুর গুণকগুলিকে সংগঠিত করতে পারেন, যাতে, উদাহরণস্বরূপ, ক্রোমপিকাল সূত্র (K2Cr2O7) প্রবেশ করার সময় আপনাকে একটি সারিতে সাতবার অক্সিজেন কোষে ক্লিক করতে হবে না।

H চিহ্ন সহ টেবিলের ঘরে LMB ক্লিক করুন। ক্ষেত্রের শিলালিপি বিকারক2 পরিবর্তন: "দ্বিতীয় বিকারক H 1.008 খুঁজে x"।

Cl চিহ্ন সহ টেবিলের ঘরে LMB-এ ক্লিক করুন। মাঠে শিলালিপি বিকারক2 পরিবর্তন: "দ্বিতীয় বিকারক HCl 36.458 ফাইন্ড x"। ক্যালকুলেটর হাইড্রোজেন এবং ক্লোরিনের পারমাণবিক ওজন যোগ করেছে। উপরোক্ত বিক্রিয়া সমীকরণে, হাইড্রোজেন ক্লোরাইড 2 এর সহগ দ্বারা পূর্বে থাকে। তাই, আমরা ক্ষেত্রের উপর LMB টিপুন বিকারক2. আণবিক ওজন দ্বিগুণ হয় (দুবার চাপলে তিনগুণ হয়, ইত্যাদি)। মাঠে শিলালিপি বিকারক2 পরিবর্তন: "সেকেন্ড রিএজেন্ট 2HCl 72.916 ফাইন্ড এক্স"।

কম্পিউটার কীবোর্ডে এন্টার টিপুন। দ্বিতীয় বিকারকটির ইনপুট শেষ হয় এবং ক্যালকুলেটর অনুপাত থেকে x খুঁজে বের করে

যা আপনাকে খুঁজে বের করতে হবে।

নোট 1. ফলস্বরূপ অনুপাতের অর্থ: দ্রবীভূত করার জন্য 100.086 Da চক 72.916 Da অ্যাসিড প্রয়োজন, এবং 10 গ্রাম চক দ্রবীভূত করতে আপনার x অ্যাসিড প্রয়োজন।

নোট 2. অনুরূপ সমস্যার সংগ্রহ:

খোমচেঙ্কো আই. জি., রসায়ন 2009 (গ্রেড 8-11) এর কার্য এবং অনুশীলনের সংগ্রহ।
খোমচেঙ্কো জি.পি., খোমচেঙ্কো আই.জি., বিশ্ববিদ্যালয়ে আবেদনকারীদের জন্য রসায়নে সমস্যার সংগ্রহ, 2019।

নোট 3. কাজটি সহজ করার জন্য, আপনি প্রাথমিক সংস্করণে সূত্রের এন্ট্রি সহজ করতে পারেন এবং সূত্রের লাইনের শেষে উপাদান প্রতীক যোগ করতে পারেন। তারপর ক্যালসিয়াম কার্বনেটের সূত্রটি দেখতে এরকম হবে:
CaCOOO
কিন্তু এই ধরনের রেকর্ড একটি রসায়ন শিক্ষককে খুশি করার সম্ভাবনা কম। সঠিক এন্ট্রি করা কঠিন নয় - এর জন্য আপনাকে একটি অ্যারে যোগ করতে হবে:

formula : array [1..size] of integer;

যেখানে সূচক হল রাসায়নিক উপাদানের সংখ্যা, এবং এই সূচকের মান হল পরমাণুর সংখ্যা (প্রাথমিকভাবে, অ্যারের সমস্ত উপাদান শূন্যে সেট করা হয়)। রসায়নে গৃহীত সূত্রে যে ক্রমানুসারে পরমাণু লেখা হয়, তা বিবেচনায় নিতে হবে। উদাহরণস্বরূপ, খুব কম লোকই O3CaC পছন্দ করবে। এর দায়িত্ব ব্যবহারকারীর উপর স্থানান্তর করা যাক. একটি অ্যারে তৈরি করা হচ্ছে:

 formulaOrder : array [1..size] of integer; // можно взять покороче

যেখানে আমরা সূত্রে তার উপস্থিতির সূচক অনুযায়ী রাসায়নিক উপাদানের সংখ্যা লিখি। একটি পরমাণু যোগ করা হচ্ছে currNo সূত্রের মধ্যে:

if formula [currNo]=0 then //этот атом встретился первый раз
 begin
 orderIndex := orderIndex+1;//в начале ввода формулы orderIndex=0
 formulaOrder [orderIndex] :=  currNo;
 end;
formula [currNo]:=formula [currNo]+1;

একটি স্ট্রিং এ একটি সূত্র লেখা:

s := ''; // пустая строка для формулы
for i:=1 to  orderIndex do // для всех хим.символов в формуле 
 begin
 s:=s+TableSymbols [ formulaOrder[i]];// добавляем хим.символ
 if formula [formulaOrder[i]]<>1 then //добавляем кол-во атомов
  s:=s+ intToStr(formula [formulaOrder[i]]);
 end;

নোট 4. কীবোর্ড থেকে রিএজেন্ট সূত্রের বিকল্প ইনপুট দেওয়ার সম্ভাবনা উপলব্ধ করা যায়। এই ক্ষেত্রে, আপনাকে একটি সাধারণ পার্সার বাস্তবায়ন করতে হবে।

এটা যে মূল্য:

আজ, টেবিলের কয়েকশ সংস্করণ রয়েছে, যখন বিজ্ঞানীরা আরও বেশি নতুন বিকল্প অফার করেন। (উইকিপিডিয়া)

শিক্ষার্থীরা এই দিকেও স্মার্ট হতে পারে, ইতিমধ্যে প্রস্তাবিত বিকল্পগুলির মধ্যে একটি বাস্তবায়ন করতে পারে বা তাদের নিজস্ব আসলটি তৈরি করার চেষ্টা করতে পারে। এটা মনে হতে পারে যে এটি কম্পিউটার বিজ্ঞান পাঠের জন্য সবচেয়ে কম দরকারী দিক। যাইহোক, এই নিবন্ধে বাস্তবায়িত পর্যায় সারণী আকারে, কিছু শিক্ষার্থী স্ট্যান্ডার্ড বোতাম ব্যবহার করে বিকল্প সমাধানের উপর নিয়ন্ত্রণ কার্ডের বিশেষ সুবিধা দেখতে নাও পেতে পারে। টিবাটন. টেবিলের সর্পিল আকৃতি (যেখানে কোষগুলি বিভিন্ন আকারের) এখানে প্রস্তাবিত সমাধানের সুবিধাগুলি আরও স্পষ্টভাবে প্রদর্শন করবে।

(থিওডোর বেনফে দ্বারা উপাদানগুলির বিকল্প ব্যবস্থা, উৎস)

আমরা আরও যোগ করি যে পর্যায় সারণীর জন্য বর্তমানে বিদ্যমান বেশ কয়েকটি কম্পিউটার প্রোগ্রাম হাব্রেতে সম্প্রতি প্রকাশিত প্রবন্ধ.

সংযোজন 2: ফিল্টারগুলির জন্য নমুনা কার্যফিল্টার ব্যবহার করে, আপনি সমাধান করতে পারেন, উদাহরণস্বরূপ, নিম্নলিখিত কাজগুলি:

1) টেবিলে মধ্যযুগে পরিচিত সমস্ত উপাদান নির্বাচন করুন।

2) পর্যায়ক্রমিক আইন আবিষ্কারের সময় পরিচিত সমস্ত উপাদান নির্বাচন করুন।

3) সাতটি উপাদান চিহ্নিত করুন যা আলকেমিস্টরা ধাতু বলে মনে করেন।

4) স্বাভাবিক অবস্থায় (n.s.) বায়বীয় অবস্থায় থাকা সমস্ত উপাদান নির্বাচন করুন।

5) n.o.s এ তরল অবস্থায় থাকা সমস্ত উপাদান নির্বাচন করুন।

6) n.c এ কঠিন অবস্থায় থাকা সমস্ত উপাদান নির্বাচন করুন।

7) n.o.s এ লক্ষণীয় পরিবর্তন ছাড়াই দীর্ঘ সময়ের জন্য বাতাসে থাকতে পারে এমন সমস্ত উপাদান নির্বাচন করুন।

8) হাইড্রোক্লোরিক অ্যাসিডে দ্রবীভূত সমস্ত ধাতু নির্বাচন করুন।

9) সমস্ত ধাতু নির্বাচন করুন যা n.o.s এ সালফিউরিক অ্যাসিডে দ্রবীভূত হয়।

10) উত্তপ্ত হলে সালফিউরিক অ্যাসিডে দ্রবীভূত সমস্ত ধাতু নির্বাচন করুন।

11) নাইট্রিক অ্যাসিডে দ্রবীভূত সমস্ত ধাতু নির্বাচন করুন।

12) সমস্ত ধাতু নির্বাচন করুন যা n.o.s এ জলের সাথে হিংস্রভাবে প্রতিক্রিয়া দেখায়।

13) সমস্ত ধাতু নির্বাচন করুন।

14) প্রকৃতিতে বিস্তৃত উপাদান নির্বাচন করুন।

15) মুক্ত অবস্থায় প্রকৃতিতে ঘটে এমন উপাদান নির্বাচন করুন।

16) মানব এবং প্রাণীদেহে সবচেয়ে গুরুত্বপূর্ণ ভূমিকা পালন করে এমন উপাদান নির্বাচন করুন।

17) দৈনন্দিন জীবনে ব্যাপকভাবে ব্যবহৃত উপাদানগুলি নির্বাচন করুন (মুক্ত আকারে বা যৌগগুলিতে)।

18) উপাদানগুলি নির্বাচন করুন, যার সাথে কাজ করুন সবচেয়ে বিপজ্জনক এবং বিশেষ ব্যবস্থা এবং সুরক্ষার উপায় প্রয়োজন।

19) উপাদানগুলি নির্বাচন করুন যেগুলি মুক্ত আকারে বা যৌগিক আকারে পরিবেশের জন্য সবচেয়ে বড় হুমকি হয়ে দাঁড়ায়।

20) মূল্যবান ধাতু নির্বাচন করুন.

21) মূল্যবান ধাতুর চেয়ে বেশি দামের আইটেম হাইলাইট করুন।

নোট

1) এটি বেশ কয়েকটি ফিল্টারের অপারেশন নিশ্চিত করা বোধগম্য। উদাহরণস্বরূপ, যদি আপনি 1 (মধ্যযুগে পরিচিত সমস্ত উপাদান) এবং 20টি (মূল্যবান ধাতু) সমস্যা সমাধানের জন্য ফিল্টার চালু করেন, তাহলে মধ্যযুগে পরিচিত মূল্যবান ধাতু সহ কোষগুলি হাইলাইট করা হবে (উদাহরণস্বরূপ, রঙ দ্বারা) ( উদাহরণস্বরূপ, প্যালাডিয়াম নির্বাচন করা হবে না। 1803 সালে খোলা)।

2) বেশ কয়েকটি ফিল্টার এমন একটি মোডে কাজ করে তা নিশ্চিত করার জন্য এটি বোধগম্য হয় যে প্রতিটি ফিল্টার তার নিজস্ব রঙ দিয়ে ঘরগুলিকে হাইলাইট করে, কিন্তু অন্য ফিল্টারের নির্বাচন সম্পূর্ণরূপে সরিয়ে দেয় না (একটি রঙের ঘরের অংশ, অন্য রঙের অংশ)। তারপরে, পূর্ববর্তী উদাহরণের ক্ষেত্রে, মধ্যযুগে আবিষ্কৃত সেটগুলির সংযোগস্থলের উপাদান এবং মূল্যবান ধাতুগুলি, সেইসাথে উপাদানগুলি যেগুলি শুধুমাত্র প্রথম এবং শুধুমাত্র দ্বিতীয় সেটগুলির অন্তর্গত, দৃশ্যমান হবে৷ সেগুলো. মধ্যযুগে অজানা মূল্যবান ধাতু এবং মধ্যযুগে পরিচিত উপাদান কিন্তু মূল্যবান ধাতু নয়।

3) প্রাপ্ত ফলাফলের সাথে অন্যান্য কাজের সম্ভাবনা প্রদান করার জন্য ফিল্টার প্রয়োগ করার পরে এটি বোধগম্য হয়। উদাহরণস্বরূপ, মধ্যযুগে পরিচিত নির্বাচিত উপাদান থাকার কারণে, ব্যবহারকারী নির্বাচিত উপাদানটির উপর LMB চাপেন এবং এই উপাদান সম্পর্কে উইকিপিডিয়া নিবন্ধে যান।

4) টেবিলের নির্বাচিত ঘরে LMB ক্লিক করে ব্যবহারকারীকে নির্বাচন সরানোর ক্ষমতা প্রদান করা বোধগম্য। উদাহরণস্বরূপ, ইতিমধ্যে দেখা আইটেম সরাতে.

5) একটি ফাইলে নির্বাচিত ঘরের তালিকা সংরক্ষণ করা এবং সেলগুলির স্বয়ংক্রিয় নির্বাচনের সাথে এই জাতীয় ফাইল লোড করা বোধগম্য। এটি ব্যবহারকারীকে কাজ থেকে বিরতি নেওয়ার সুযোগ দেবে।

আমরা একটি স্থির পূর্বনির্ধারিত নিয়ন্ত্রণ মানচিত্র ব্যবহার করেছি, তবে অনেক গুরুত্বপূর্ণ অ্যাপ্লিকেশন রয়েছে যেখানে গতিশীল নিয়ন্ত্রণ মানচিত্র ব্যবহার করা যেতে পারে যে প্রোগ্রামটি চলার সাথে সাথে পরিবর্তন হয়। একটি উদাহরণ একটি গ্রাফ সম্পাদক হবে, যেখানে ব্যবহারকারী উইন্ডোতে শীর্ষবিন্দুগুলির অবস্থান নির্দেশ করতে এবং তাদের মধ্যে প্রান্তগুলি আঁকতে মাউস ব্যবহার করে। একটি শীর্ষ বা প্রান্ত অপসারণ করতে, ব্যবহারকারীকে অবশ্যই এটি নির্দেশ করতে হবে। কিন্তু যদি বৃত্ত দ্বারা চিহ্নিত একটি শীর্ষবিন্দুকে নির্দেশ করা বেশ সহজ হয়, তাহলে একটি পাতলা রেখা দিয়ে আঁকা একটি প্রান্ত নির্দেশ করা আরও কঠিন হবে। একটি নিয়ন্ত্রণ মানচিত্র এখানে সাহায্য করবে, যেখানে শীর্ষবিন্দু এবং প্রান্তগুলি দৃশ্যমান চিত্রের চেয়ে প্রশস্ত এলাকাগুলি দখল করে৷

একটি আকর্ষণীয় পার্শ্ব প্রশ্ন উল্লিখিত জটিল শেখার পদ্ধতির সাথে সম্পর্কিত: এই পদ্ধতিটি কি এআই শেখানোর ক্ষেত্রে কার্যকর হতে পারে?

উত্স: www.habr.com