🥇 জিওফিজিক্সে উলফ্রাম ম্যাথমেটিকা

ব্লগের লেখককে ধন্যবাদ আন্তন একিমেনকো তার রিপোর্টের জন্য

ভূমিকা

সম্মেলনের পরিপ্রেক্ষিতে এই নোটটি লেখা হয়েছে ওলফ্রাম রাশিয়ান প্রযুক্তি সম্মেলন এবং আমার দেওয়া প্রতিবেদনের সারাংশ রয়েছে। ঘটনাটি জুন মাসে সেন্ট পিটার্সবার্গে হয়েছিল। আমি কনফারেন্স সাইট থেকে একটি ব্লক কাজ করার কথা বিবেচনা করে, আমি এই ইভেন্টে যোগ দিতে সাহায্য করতে পারিনি। 2016 এবং 2017 সালে, আমি সম্মেলনের প্রতিবেদনগুলি শুনেছিলাম এবং এই বছর আমি একটি উপস্থাপনা দিয়েছিলাম। প্রথমত, একটি আকর্ষণীয় (এটি আমার কাছে মনে হয়) বিষয় উপস্থিত হয়েছে, যা আমরা বিকাশ করছি কিরিল বেলভ, এবং দ্বিতীয়ত, নিষেধাজ্ঞা নীতি সংক্রান্ত রাশিয়ান ফেডারেশনের আইনের দীর্ঘ অধ্যয়নের পরে, আমি যে এন্টারপ্রাইজে কাজ করি, সেখানে দুটি লাইসেন্স উপস্থিত হয়েছিল Wolfram গণিত.

আমার বক্তৃতার বিষয়ে যাওয়ার আগে, আমি ইভেন্টের ভাল আয়োজনটি লক্ষ্য করতে চাই। সম্মেলনের পরিদর্শন পৃষ্ঠায় কাজান ক্যাথিড্রালের একটি চিত্র ব্যবহার করা হয়েছে। ক্যাথেড্রালটি সেন্ট পিটার্সবার্গের অন্যতম প্রধান আকর্ষণ এবং যে হলটিতে সম্মেলনটি হয়েছিল সেখান থেকে খুব স্পষ্টভাবে দৃশ্যমান।

সেন্ট পিটার্সবার্গ স্টেট ইকোনমিক ইউনিভার্সিটির প্রবেশদ্বারে, অংশগ্রহণকারীদের ছাত্রদের মধ্যে সহকারীরা দেখা করেছিলেন - তারা তাদের হারিয়ে যেতে দেয়নি। রেজিস্ট্রেশনের সময়, ছোট স্যুভেনির দেওয়া হয়েছিল (একটি খেলনা - একটি ফ্ল্যাশিং স্পাইক, একটি কলম, ওলফ্রাম প্রতীক সহ স্টিকার)। মধ্যাহ্নভোজ এবং কফি বিরতিও সম্মেলনের সময়সূচীতে অন্তর্ভুক্ত ছিল। আমি ইতিমধ্যে গ্রুপের দেয়ালে সুস্বাদু কফি এবং পাই সম্পর্কে উল্লেখ করেছি - শেফরা দুর্দান্ত। এই পরিচায়ক অংশের সাথে, আমি জোর দিয়ে বলতে চাই যে ইভেন্ট নিজেই, এর বিন্যাস এবং অবস্থান ইতিমধ্যে ইতিবাচক আবেগ নিয়ে আসছে।

আমার এবং কিরিল বেলভ যে প্রতিবেদনটি তৈরি করেছিলেন তাকে বলা হয় “প্রয়োগিত ভূ-পদার্থবিদ্যার সমস্যা সমাধানের জন্য উলফ্রাম ম্যাথমেটিকা ব্যবহার করে। সিসমিক ডেটার বর্ণালী বিশ্লেষণ বা "যেখানে প্রাচীন নদীগুলি চলত।" প্রতিবেদনের বিষয়বস্তু দুটি অংশ কভার করে: প্রথমত, অ্যালগরিদমের ব্যবহার উপলব্ধ Wolfram গণিত জিওফিজিক্যাল ডাটা বিশ্লেষণের জন্য, এবং দ্বিতীয়ত, ওলফ্রাম ম্যাথমেটিকায় জিওফিজিক্যাল ডাটা কিভাবে রাখা যায়।

সিসমিক অন্বেষণ

প্রথমে আপনাকে জিওফিজিক্সে একটি ছোট ভ্রমণ করতে হবে। ভূপদার্থবিদ্যা হল সেই বিজ্ঞান যা পাথরের ভৌত বৈশিষ্ট্য অধ্যয়ন করে। ঠিক আছে, যেহেতু শিলাগুলির বিভিন্ন বৈশিষ্ট্য রয়েছে: বৈদ্যুতিক, চৌম্বকীয়, স্থিতিস্থাপক, তাই ভূপদার্থবিদ্যার সংশ্লিষ্ট পদ্ধতি রয়েছে: বৈদ্যুতিক সম্ভাবনা, চৌম্বক সম্ভাবনা, সিসমিক প্রসপেক্টিং... এই নিবন্ধের প্রেক্ষাপটে, আমরা কেবল আরও বিশদে সিসমিক প্রসপেক্টিং নিয়ে আলোচনা করব। সিসমিক এক্সপ্লোরেশন হল তেল এবং গ্যাস অনুসন্ধানের প্রধান পদ্ধতি। পদ্ধতিটি স্থিতিস্থাপক কম্পনের উত্তেজনা এবং অধ্যয়ন এলাকা রচনাকারী শিলা থেকে প্রতিক্রিয়ার পরবর্তী রেকর্ডিংয়ের উপর ভিত্তি করে। কম্পনগুলি স্থলে (ডিনামাইট বা স্থিতিস্থাপক কম্পনের অ-বিস্ফোরক কম্পনের উত্স সহ) বা সমুদ্রে (এয়ার বন্দুক সহ) উত্তেজিত হয়। ইলাস্টিক কম্পন শিলা ভরের মাধ্যমে প্রচার করে, বিভিন্ন বৈশিষ্ট্য সহ স্তরগুলির সীমানায় প্রতিসৃত এবং প্রতিফলিত হয়। প্রতিফলিত তরঙ্গগুলি পৃষ্ঠে ফিরে আসে এবং জমিতে জিওফোন (সাধারণত কুণ্ডলীতে ঝুলে থাকা চুম্বকের গতিবিধির উপর ভিত্তি করে ইলেক্ট্রোডাইনামিক ডিভাইস) বা সমুদ্রে হাইড্রোফোন (পিজোইলেক্ট্রিক প্রভাবের উপর ভিত্তি করে) দ্বারা রেকর্ড করা হয়। তরঙ্গের আগমনের সময়, কেউ ভূতাত্ত্বিক স্তরগুলির গভীরতা বিচার করতে পারে।

সিসমিক ভেসেল টোয়িং যন্ত্রপাতি

এয়ার বন্দুক ইলাস্টিক কম্পনকে উত্তেজিত করে

তরঙ্গগুলি শিলা ভরের মধ্য দিয়ে যায় এবং হাইড্রোফোন দ্বারা রেকর্ড করা হয়

সেন্ট পিটার্সবার্গের ব্লাগোভেশচেনস্কি ব্রিজের কাছে পিয়ারে জিওফিজিক্যাল সার্ভে গবেষণা জাহাজ "ইভান গুবকিন"

সিসমিক সিগন্যাল মডেল

পাথরের বিভিন্ন শারীরিক বৈশিষ্ট্য রয়েছে। সিসমিক অন্বেষণের জন্য, স্থিতিস্থাপক বৈশিষ্ট্যগুলি প্রাথমিকভাবে গুরুত্বপূর্ণ - ইলাস্টিক কম্পন এবং ঘনত্বের প্রচারের গতি। যদি দুটি স্তরের একই বা অনুরূপ বৈশিষ্ট্য থাকে, তবে তরঙ্গ তাদের মধ্যে সীমানা "লক্ষ্য করবে না"। যদি স্তরগুলিতে তরঙ্গের গতি ভিন্ন হয়, তবে স্তরগুলির সীমানায় প্রতিফলন ঘটবে। বৈশিষ্ট্যের পার্থক্য যত বেশি, প্রতিফলন তত তীব্র। এর তীব্রতা প্রতিফলিত সহগ (আরসি) দ্বারা নির্ধারিত হবে:

যেখানে ρ হল শিলার ঘনত্ব, ν হল তরঙ্গের গতি, 1 এবং 2 হল উপরের এবং নীচের স্তরগুলি নির্দেশ করে৷

সবচেয়ে সহজ এবং সর্বাধিক ব্যবহৃত সিসমিক সিগন্যাল মডেলগুলির মধ্যে একটি হল কনভোলিউশন মডেল, যখন নথিভুক্ত সিসমিক ট্রেসটিকে একটি প্রোবিং পালসের সাথে প্রতিফলন সহগগুলির একটি অনুক্রমের আবর্তনের ফলাফল হিসাবে উপস্থাপন করা হয়:

যেখানে s(t) — সিসমিক ট্রেস, যেমন একটি নির্দিষ্ট রেকর্ডিং সময়ের মধ্যে একটি হাইড্রোফোন বা জিওফোন দ্বারা রেকর্ড করা সমস্ত কিছু, w(t) - এয়ার বন্দুক দ্বারা উত্পন্ন সংকেত, n(t) - এলোমেলো শব্দ।

আসুন উদাহরণ হিসাবে একটি সিন্থেটিক সিসমিক ট্রেস গণনা করি। আমরা প্রাথমিক সংকেত হিসেবে রিকারের পালস ব্যবহার করব, যা সিসমিক অন্বেষণে ব্যাপকভাবে ব্যবহৃত হয়।

length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]

প্রাথমিক সিসমিক ইমপালস

আমরা 300 ms এবং 600 ms এর গভীরতায় দুটি সীমানা সেট করব এবং প্রতিফলন সহগ হবে র্যান্ডম সংখ্যা

rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]

প্রতিফলন সহগগুলির ক্রম

আসুন সিসমিক ট্রেস গণনা এবং প্রদর্শন করা যাক। যেহেতু প্রতিফলন সহগগুলির বিভিন্ন চিহ্ন রয়েছে, তাই আমরা সিসমিক ট্রেসে দুটি পর্যায়ক্রমে প্রতিফলন পাই।

traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]

সিমুলেটেড ট্র্যাক

এই উদাহরণের জন্য, এটি একটি রিজার্ভেশন করা প্রয়োজন - বাস্তবে, স্তরগুলির গভীরতা নির্ধারিত হয়, অবশ্যই, মিটারে, এবং সিসমিক ট্রেসের গণনা সময় ডোমেনের জন্য ঘটে। মিটারে গভীরতা সেট করা এবং স্তরগুলির বেগ জেনে আগমনের সময় গণনা করা আরও সঠিক হবে। এই ক্ষেত্রে, আমি অবিলম্বে সময় অক্ষের উপর স্তর সেট.

যদি আমরা ক্ষেত্র গবেষণা সম্পর্কে কথা বলি, তাহলে এই ধরনের পর্যবেক্ষণের ফলস্বরূপ বিপুল সংখ্যক অনুরূপ টাইম সিরিজ (সিসমিক ট্রেস) রেকর্ড করা হয়। উদাহরণস্বরূপ, 25 কিমি দীর্ঘ এবং 15 কিমি চওড়া একটি সাইট অধ্যয়ন করার সময়, যেখানে কাজের ফলস্বরূপ, প্রতিটি ট্রেস 25x25 মিটার পরিমাপের একটি কোষকে চিহ্নিত করে (যেমন একটি সেলকে একটি বিন বলা হয়), চূড়ান্ত ডেটা অ্যারেটিতে 600000 ট্রেস থাকবে। 1 এমএস এর একটি নমুনা সময় এবং 5 সেকেন্ডের একটি রেকর্ডিং সময় সহ, চূড়ান্ত ডেটা ফাইলটি 11 গিগাবাইটের বেশি হবে এবং আসল "কাঁচা" উপাদানের আয়তন শত শত গিগাবাইট হতে পারে।

তাদের সাথে কিভাবে কাজ করবেন Wolfram গণিত?

প্যাকেজ ভূতত্ত্ব আইও

প্যাকেজের উন্নয়ন শুরু হয় প্রশ্ন রাশিয়ান-ভাষী সমর্থন গোষ্ঠীর ভিকে দেয়ালে। সম্প্রদায়ের প্রতিক্রিয়ার জন্য ধন্যবাদ, খুব দ্রুত একটি সমাধান পাওয়া গেছে। এবং ফলস্বরূপ, এটি একটি গুরুতর বিকাশে পরিণত হয়েছিল। অনুরূপ ওলফ্রাম কমিউনিটি ওয়াল পোস্ট এমনকি এটি মডারেটরদের দ্বারা চিহ্নিত করা হয়েছিল। বর্তমানে, প্যাকেজটি নিম্নলিখিত ডেটা প্রকারগুলির সাথে কাজ করতে সমর্থন করে যা সক্রিয়ভাবে ভূতাত্ত্বিক শিল্পে ব্যবহৃত হয়:

ZMAP এবং IRAP ফর্ম্যাটে মানচিত্রের ডেটা আমদানি
LAS বিন্যাস কূপ পরিমাপ আমদানি
সিসমিক ফাইল ফরম্যাটের ইনপুট এবং আউটপুট সেজি

প্যাকেজটি ইনস্টল করতে, আপনাকে অবশ্যই একত্রিত প্যাকেজের ডাউনলোড পৃষ্ঠায় নির্দেশাবলী অনুসরণ করতে হবে, যেমন যে কোন একটিতে নিম্নলিখিত কোডটি চালান গণিতের নোটবুক:

If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
    "https://wolfr.am/FiQ5oFih", 
    FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]

এর পরে প্যাকেজটি ডিফল্ট ফোল্ডারে ইনস্টল করা হবে, যার পথটি নিম্নরূপ প্রাপ্ত করা যেতে পারে:

FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]

উদাহরণ হিসেবে, আমরা প্যাকেজের প্রধান ক্ষমতা প্রদর্শন করব। ওলফ্রাম ভাষার প্যাকেজের জন্য কলটি ঐতিহ্যগতভাবে করা হয়:

Get["GeologyIO`"]

প্যাকেজ ব্যবহার করে বিকশিত হয় উলফ্রাম ওয়ার্কবেঞ্চ. এটি আপনাকে ডকুমেন্টেশন সহ প্যাকেজের প্রধান কার্যকারিতা সহ যেতে দেয়, যা উপস্থাপনার বিন্যাসের ক্ষেত্রে উলফ্রাম ম্যাথমেটিকার ডকুমেন্টেশন থেকে আলাদা নয় এবং প্রথম পরিচিতির জন্য পরীক্ষা ফাইল সহ প্যাকেজটি সরবরাহ করতে।

এই ধরনের একটি ফাইল, বিশেষত, ফাইল "Marmousi.segy" - এটি একটি ভূতাত্ত্বিক বিভাগের একটি সিন্থেটিক মডেল, যা ফরাসি পেট্রোলিয়াম ইনস্টিটিউট দ্বারা তৈরি করা হয়েছিল। এই মডেলটি ব্যবহার করে, বিকাশকারীরা ওয়েভ ফিল্ড মডেলিং, ডেটা প্রসেসিং, সিসমিক ট্রেস ইনভার্সন ইত্যাদির জন্য তাদের নিজস্ব অ্যালগরিদম পরীক্ষা করে। মারমাউসি মডেলটি নিজেই সংগ্রহস্থলে সংরক্ষণ করা হয় যেখান থেকে প্যাকেজটি নিজেই ডাউনলোড করা হয়েছিল। ফাইলটি পেতে, নিম্নলিখিত কোডটি চালান:

If[Not[FileExistsQ["Marmousi.segy"]], 
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]

ফলাফল আমদানি করুন - SEGYData অবজেক্ট

SEGY বিন্যাসে পর্যবেক্ষণ সম্পর্কে বিভিন্ন তথ্য সংরক্ষণ করা জড়িত। প্রথমত, এগুলি পাঠ্য মন্তব্য। এতে কাজের অবস্থান, পরিমাপ করা কোম্পানির নাম ইত্যাদির তথ্য অন্তর্ভুক্ত রয়েছে। আমাদের ক্ষেত্রে, এই শিরোনামটি টেক্সটহেডার কী সহ একটি অনুরোধ দ্বারা বলা হয়। এখানে একটি সংক্ষিপ্ত পাঠ্য শিরোনাম:

Short[marmousi["TextHeader"]]

"মারমাউসি ডেটা সেটটি ইনস্টিটিউটে তৈরি করা হয়েছিল ...সর্বনিম্ন বেগ 1500 m/s এবং সর্বোচ্চ 5500 m/s)"

আপনি "ট্রেস" কী ব্যবহার করে সিসমিক ট্রেসগুলি অ্যাক্সেস করে প্রকৃত ভূতাত্ত্বিক মডেলটি প্রদর্শন করতে পারেন (প্যাকেজের অন্যতম বৈশিষ্ট্য হল কীগুলি কেস-সংবেদনশীল):

ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]

মডেল মারমুসি

বর্তমানে, প্যাকেজটি আপনাকে বড় ফাইল থেকে অংশগুলিতে ডেটা লোড করার অনুমতি দেয়, যার ফলে ফাইলগুলি প্রক্রিয়া করা সম্ভব হয় যার আকার দশ গিগাবাইটে পৌঁছাতে পারে। প্যাকেজের ফাংশনগুলির মধ্যে রয়েছে .segy-তে ডেটা রপ্তানি করা এবং ফাইলের শেষে আংশিকভাবে যুক্ত করা।

পৃথকভাবে, .segy ফাইলগুলির জটিল কাঠামোর সাথে কাজ করার সময় প্যাকেজের কার্যকারিতা লক্ষ্য করা মূল্যবান। যেহেতু এটি আপনাকে কী এবং সূচী ব্যবহার করে শুধুমাত্র পৃথক ট্রেস এবং শিরোনামগুলি অ্যাক্সেস করতে দেয় না, তবে সেগুলি পরিবর্তন করতে এবং তারপরে একটি ফাইলে লিখতে দেয়। জিওলজিআইও-এর বাস্তবায়নের অনেক প্রযুক্তিগত বিবরণ এই নিবন্ধের সুযোগের বাইরে এবং সম্ভবত একটি পৃথক বর্ণনার যোগ্য।

সিসমিক অন্বেষণে বর্ণালী বিশ্লেষণের প্রাসঙ্গিকতা

Wolfram Mathematica-এ সিসমিক ডেটা আমদানি করার ক্ষমতা আপনাকে পরীক্ষামূলক ডেটার জন্য বিল্ট-ইন সিগন্যাল প্রসেসিং কার্যকারিতা ব্যবহার করতে দেয়। যেহেতু প্রতিটি সিসমিক ট্রেস একটি টাইম সিরিজের প্রতিনিধিত্ব করে, তাই সেগুলি অধ্যয়নের জন্য প্রধান সরঞ্জামগুলির মধ্যে একটি হল বর্ণালী বিশ্লেষণ। সিসমিক ডেটার ফ্রিকোয়েন্সি গঠন বিশ্লেষণের পূর্বশর্তগুলির মধ্যে, আমরা উদাহরণ স্বরূপ, নিম্নলিখিতগুলির নাম দিতে পারি:

বিভিন্ন ধরনের তরঙ্গ বিভিন্ন ফ্রিকোয়েন্সি রচনা দ্বারা চিহ্নিত করা হয়। এটি আপনাকে দরকারী তরঙ্গগুলি হাইলাইট করতে এবং হস্তক্ষেপ তরঙ্গকে দমন করতে দেয়।
শিলার বৈশিষ্ট্য যেমন পোরোসিটি এবং স্যাচুরেশন ফ্রিকোয়েন্সি কম্পোজিশনকে প্রভাবিত করতে পারে। এটি সেরা বৈশিষ্ট্য সহ শিলা সনাক্ত করা সম্ভব করে তোলে।
বিভিন্ন পুরুত্বের স্তরগুলি বিভিন্ন ফ্রিকোয়েন্সি রেঞ্জে অসামঞ্জস্য সৃষ্টি করে।

এই নিবন্ধের প্রেক্ষাপটে তৃতীয় পয়েন্টটি প্রধান। নীচে বিভিন্ন পুরুত্বের স্তরের ক্ষেত্রে সিসমিক ট্রেস গণনা করার জন্য একটি কোড খণ্ড রয়েছে - একটি কীলক মডেল। অনেক স্তর থেকে প্রতিফলিত তরঙ্গ একে অপরের উপর চাপিয়ে দিলে হস্তক্ষেপের প্রভাব বিশ্লেষণ করার জন্য এই মডেলটি ঐতিহ্যগতভাবে সিসমিক অন্বেষণে অধ্যয়ন করা হয়।

nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]

একটি চিমটি-আউট গঠনের মডেল

কীলকের ভিতরে তরঙ্গের গতি 4500 m/s, কীলকের বাইরে 4000 m/s, এবং ঘনত্ব 2200 g/cm³ ধ্রুবক বলে ধরে নেওয়া হয়। এই ধরনের মডেলের জন্য, আমরা প্রতিফলন সহগ এবং সিসমিক ট্রেস গণনা করি।

rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
	ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
		{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]

কীলক মডেলের জন্য সিসমিক ট্রেস

এই চিত্রে দেখানো সিসমিক ট্রেসগুলির ক্রমকে সিসমিক বিভাগ বলা হয়। আপনি দেখতে পাচ্ছেন, এর ব্যাখ্যাটি একটি স্বজ্ঞাত স্তরেও করা যেতে পারে, যেহেতু প্রতিফলিত তরঙ্গগুলির জ্যামিতিটি আগে নির্দিষ্ট করা মডেলের সাথে স্পষ্টভাবে মিলে যায়। আপনি যদি আরও বিশদে ট্রেসগুলি বিশ্লেষণ করেন তবে আপনি লক্ষ্য করবেন যে 1 থেকে আনুমানিক 30 টি ট্রেস আলাদা নয় - গঠনের ছাদ থেকে এবং নীচে থেকে প্রতিফলন একে অপরকে ওভারল্যাপ করে না। 31 তম ট্রেস থেকে শুরু করে, প্রতিফলনগুলি হস্তক্ষেপ করতে শুরু করে। এবং, যদিও মডেলে, প্রতিফলন সহগগুলি অনুভূমিকভাবে পরিবর্তিত হয় না - ভূমিকম্পের চিহ্নগুলি গঠনের বেধ পরিবর্তনের সাথে সাথে তাদের তীব্রতা পরিবর্তন করে।

আসুন গঠনের উপরের সীমানা থেকে প্রতিফলনের প্রশস্ততা বিবেচনা করা যাক। 60 তম রুট থেকে শুরু করে, প্রতিফলনের তীব্রতা বাড়তে শুরু করে এবং 70 তম রুটে এটি সর্বাধিক হয়ে ওঠে। এভাবেই ছাদ এবং স্তরের নীচ থেকে তরঙ্গের হস্তক্ষেপ নিজেকে প্রকাশ করে, যা কিছু ক্ষেত্রে সিসমিক রেকর্ডে উল্লেখযোগ্য অসঙ্গতির দিকে নিয়ে যায়।

ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]

কীলকের উপরের প্রান্ত থেকে প্রতিফলিত তরঙ্গের প্রশস্ততার গ্রাফ

এটা যৌক্তিক যে যখন সংকেত কম-ফ্রিকোয়েন্সি হয়, তখন হস্তক্ষেপ বড় আকারের ঘনত্বে দেখা দিতে শুরু করে এবং একটি উচ্চ-ফ্রিকোয়েন্সি সংকেতের ক্ষেত্রে, ছোট বেধে হস্তক্ষেপ ঘটে। নিম্নলিখিত কোড স্নিপেট 35 Hz, 55 Hz এবং 85 Hz এর ফ্রিকোয়েন্সি সহ একটি সংকেত তৈরি করে।

waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]

35 Hz, 55Hz, 85Hz ফ্রিকোয়েন্সি সহ উৎস সংকেতের একটি সেট

সিসমিক ট্রেস গণনা করে এবং প্রতিফলিত তরঙ্গ প্রশস্ততার গ্রাফ প্লটিং করে, আমরা দেখতে পারি যে বিভিন্ন কম্পাঙ্কের জন্য বিভিন্ন গঠনের পুরুত্বে একটি অসঙ্গতি পরিলক্ষিত হয়।

tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];

lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];

Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]

বিভিন্ন ফ্রিকোয়েন্সির জন্য কীলকের উপরের প্রান্ত থেকে প্রতিফলিত তরঙ্গের প্রশস্ততার গ্রাফ

সিসমিক পর্যবেক্ষণের ফলাফল থেকে গঠনের পুরুত্ব সম্পর্কে সিদ্ধান্ত নেওয়ার ক্ষমতা অত্যন্ত কার্যকর, কারণ তেল অনুসন্ধানের প্রধান কাজগুলির মধ্যে একটি হল একটি কূপ স্থাপনের জন্য সবচেয়ে প্রতিশ্রুতিশীল পয়েন্টগুলি মূল্যায়ন করা (অর্থাৎ, সেই অঞ্চলগুলি যেখানে গঠন হয় মোটা)। এছাড়াও, ভূতাত্ত্বিক বিভাগে এমন কিছু বস্তু থাকতে পারে যার উৎপত্তি গঠনের বেধে তীব্র পরিবর্তন ঘটায়। এটি তাদের অধ্যয়নের জন্য বর্ণালী বিশ্লেষণকে একটি কার্যকর হাতিয়ার করে তোলে। নিবন্ধের পরবর্তী অংশে আমরা এই ধরনের ভূতাত্ত্বিক বস্তুগুলিকে আরও বিশদে বিবেচনা করব।

পরীক্ষামূলক তথ্য. আপনি তাদের কোথায় পেয়েছেন এবং তাদের মধ্যে কী সন্ধান করবেন?

নিবন্ধে বিশ্লেষণ করা উপকরণগুলি পশ্চিম সাইবেরিয়ায় প্রাপ্ত হয়েছিল। অঞ্চলটি, ব্যতিক্রম ছাড়া সবাই সম্ভবত জানেন, আমাদের দেশের প্রধান তেল উৎপাদনকারী অঞ্চল। গত শতাব্দীর 60 এর দশকে এই অঞ্চলে আমানতের সক্রিয় বিকাশ শুরু হয়েছিল। তেলের আমানত অনুসন্ধানের প্রধান পদ্ধতি হল সিসমিক অন্বেষণ। এই ভূখণ্ডের স্যাটেলাইট চিত্রগুলি দেখতে আকর্ষণীয়। একটি ছোট স্কেলে, আপনি প্রচুর সংখ্যক জলাভূমি এবং হ্রদ নোট করতে পারেন; মানচিত্রটি বড় করে, আপনি গুচ্ছ কূপ ড্রিলিং সাইটগুলি দেখতে পারেন এবং মানচিত্রটিকে সীমা পর্যন্ত বড় করে, আপনি প্রোফাইলগুলির ক্লিয়ারিংগুলিকেও আলাদা করতে পারেন যার সাথে সিসমিক পর্যবেক্ষণ করা হয়েছিল।

Yandex মানচিত্রের স্যাটেলাইট চিত্র - Noyabrsk শহর এলাকা

মাঠের একটিতে ওয়েল প্যাডের নেটওয়ার্ক

পশ্চিম সাইবেরিয়ার তেল বহনকারী শিলাগুলি বিস্তৃত গভীরতায় দেখা যায় - 1 কিমি থেকে 5 কিমি পর্যন্ত। জুরাসিক এবং ক্রিটেসিয়াস সময়ে তেলযুক্ত শিলাগুলির প্রধান আয়তন গঠিত হয়েছিল। জুরাসিক সময়কাল সম্ভবত একই নামের চলচ্চিত্র থেকে অনেকের কাছে পরিচিত। জুরাসিক জলবায়ু আধুনিক এক থেকে উল্লেখযোগ্যভাবে ভিন্ন ছিল. এনসাইক্লোপিডিয়া ব্রিটানিকার প্যালিওম্যাপগুলির একটি সিরিজ রয়েছে যা প্রতিটি হেলজিকাল যুগকে চিহ্নিত করে।

বর্তমান কাল

জুরাসিক পিরিয়ড

দয়া করে মনে রাখবেন যে জুরাসিক সময়ে, পশ্চিম সাইবেরিয়ার অঞ্চলটি একটি সমুদ্র উপকূল ছিল (নদী এবং একটি অগভীর সমুদ্র দ্বারা অতিক্রম করা জমি)। যেহেতু জলবায়ু আরামদায়ক ছিল, আমরা অনুমান করতে পারি যে সেই সময়ের একটি সাধারণ ল্যান্ডস্কেপ এইরকম ছিল:

জুরাসিক সাইবেরিয়া

এই ছবিতে, যা আমাদের কাছে গুরুত্বপূর্ণ তা পশু-পাখি নয়, পটভূমিতে নদীর চিত্র। নদী একই ভূতাত্ত্বিক বস্তু যা আমরা আগে থামিয়েছিলাম। আসল বিষয়টি হ'ল নদীর ক্রিয়াকলাপ ভালভাবে সাজানো বেলেপাথর জমা হতে দেয়, যা পরে তেলের জলাধারে পরিণত হবে। এই জলাধারগুলির একটি উদ্ভট, জটিল আকার থাকতে পারে (নদীর তলদেশের মতো) এবং তাদের পরিবর্তনশীল পুরুত্ব রয়েছে - তীরের কাছে বেধটি ছোট, তবে চ্যানেলের কেন্দ্রের কাছাকাছি বা মধ্যবর্তী অঞ্চলে এটি বৃদ্ধি পায়। সুতরাং, জুরাসিক অঞ্চলে গঠিত নদীগুলি এখন প্রায় তিন কিলোমিটার গভীরে রয়েছে এবং তেলের আধার অনুসন্ধানের বস্তু।

পরীক্ষামূলক তথ্য. প্রক্রিয়াকরণ এবং ভিজ্যুয়ালাইজেশন

আসুন আমরা অবিলম্বে নিবন্ধে দেখানো ভূমিকম্পের উপাদানগুলির বিষয়ে একটি সংরক্ষণ করি - বিশ্লেষণের জন্য ব্যবহৃত ডেটার পরিমাণ তাৎপর্যপূর্ণ হওয়ার কারণে - নিবন্ধটির পাঠ্যে সিসমিক ট্রেসের মূল সেটের শুধুমাত্র একটি অংশ অন্তর্ভুক্ত করা হয়েছে। এটি যে কেউ উপরের গণনাগুলি পুনরুত্পাদন করার অনুমতি দেবে।

সিসমিক ডেটা নিয়ে কাজ করার সময়, একজন জিওফিজিসিস্ট সাধারণত বিশেষায়িত সফ্টওয়্যার ব্যবহার করেন (অনেক শিল্প নেতা আছেন যাদের বিকাশ সক্রিয়ভাবে ব্যবহার করা হয়, উদাহরণস্বরূপ পেট্রেল বা প্যারাডাইম), যা আপনাকে বিভিন্ন ধরণের ডেটা বিশ্লেষণ করতে দেয় এবং একটি সুবিধাজনক গ্রাফিকাল ইন্টারফেস রয়েছে। সমস্ত সুবিধা থাকা সত্ত্বেও, এই ধরণের সফ্টওয়্যারগুলিরও তাদের ত্রুটি রয়েছে - উদাহরণস্বরূপ, স্থিতিশীল সংস্করণগুলিতে আধুনিক অ্যালগরিদমগুলি প্রয়োগ করতে অনেক সময় লাগে এবং স্বয়ংক্রিয় গণনার সম্ভাবনাগুলি সাধারণত সীমিত থাকে। এই ধরনের পরিস্থিতিতে, কম্পিউটার গণিত সিস্টেম এবং উচ্চ-স্তরের প্রোগ্রামিং ভাষাগুলি ব্যবহার করা খুব সুবিধাজনক হয়ে ওঠে, যা একটি বিস্তৃত অ্যালগরিদমিক বেস ব্যবহার করার অনুমতি দেয় এবং একই সময়ে, অনেক রুটিন গ্রহণ করে। ওলফ্রাম ম্যাথেমেটিকায় সিসমিক ডেটা নিয়ে কাজ করার জন্য এই নীতিটি ব্যবহার করা হয়। ডেটা সহ ইন্টারেক্টিভ কাজের জন্য সমৃদ্ধ কার্যকারিতা লেখা অনুপযুক্ত - একটি সাধারণভাবে গৃহীত বিন্যাস থেকে লোড করা নিশ্চিত করা, তাদের জন্য পছন্দসই অ্যালগরিদমগুলি প্রয়োগ করা এবং একটি বহিরাগত বিন্যাসে সেগুলিকে আবার আপলোড করা আরও গুরুত্বপূর্ণ৷

প্রস্তাবিত স্কিম অনুসরণ করে, আমরা মূল সিসমিক ডেটা লোড করব এবং সেগুলি প্রদর্শন করব Wolfram গণিত:

Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]

এইভাবে ডাউনলোড করা এবং আমদানি করা ডেটা হল 10 বাই 5 কিলোমিটার পরিমাপের একটি এলাকায় রেকর্ড করা রুট। যদি একটি ত্রিমাত্রিক সিসমিক জরিপ পদ্ধতি ব্যবহার করে ডেটা প্রাপ্ত করা হয় (তরঙ্গগুলি পৃথক ভূ-ভৌতিক প্রোফাইলের সাথে রেকর্ড করা হয় না, তবে একই সাথে সমগ্র এলাকা জুড়ে), এটি সিসমিক ডেটা কিউবগুলি প্রাপ্ত করা সম্ভব হয়। এগুলি হল ত্রিমাত্রিক বস্তু, উল্লম্ব এবং অনুভূমিক বিভাগ যা ভূতাত্ত্বিক পরিবেশের বিশদ অধ্যয়নের অনুমতি দেয়। বিবেচিত উদাহরণে, আমরা ত্রিমাত্রিক ডেটা নিয়ে কাজ করছি। আমরা টেক্সট হেডার থেকে কিছু তথ্য পেতে পারি, যেমন

StringPartition[seismic3DSEGY["textheader"], 80] // TableForm

সি 1 এটি জিওলজিও প্যাকেজ পরীক্ষার জন্য ডেমো ফাইল
সি 2
সি 3
সি 4
C 5 তারিখ ব্যবহারকারীর নাম: WOLFRAM ব্যবহারকারী
C 6 সার্ভে নাম: সাইবেরিয়ায় কোথাও
C 7 ফাইল টাইপ 3D সিসমিক ভলিউম
সি 8
সি 9
C10 Z রেঞ্জ: প্রথম 2200M শেষ 2400M

এই ডেটা সেটটি ডেটা বিশ্লেষণের প্রধান ধাপগুলি প্রদর্শন করার জন্য আমাদের জন্য যথেষ্ট হবে। ফাইলের ট্রেসগুলি ক্রমানুসারে রেকর্ড করা হয় এবং তাদের প্রত্যেকটি নীচের চিত্রের মতো কিছু দেখায় - এটি উল্লম্ব অক্ষ (গভীর অক্ষ) বরাবর প্রতিফলিত তরঙ্গগুলির প্রশস্ততার বিতরণ।

ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2, 
 PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
 LabelStyle -> Directive[Black, Italic], PlotRange -> All, 
 Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]

সিসমিক সেকশন ট্রেস এক

অধ্যয়ন করা এলাকার প্রতিটি দিকে কতগুলি ট্রেস অবস্থিত তা জেনে, আপনি একটি ত্রিমাত্রিক ডেটা অ্যারে তৈরি করতে পারেন এবং Image3D[] ফাংশন ব্যবহার করে এটি প্রদর্শন করতে পারেন

traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1;   (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1;   (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]

একটি সিসমিক ডেটা কিউবের XNUMXD চিত্র। (উল্লম্ব অক্ষ - গভীরতা)

যদি আগ্রহের ভূতাত্ত্বিক বৈশিষ্ট্যগুলি তীব্র সিসমিক অসঙ্গতি তৈরি করে, তাহলে স্বচ্ছতার সাথে ভিজ্যুয়ালাইজেশন টুল ব্যবহার করা যেতে পারে। রেকর্ডিংয়ের "অগুরুত্বপূর্ণ" ক্ষেত্রগুলিকে অদৃশ্য করা যেতে পারে, শুধুমাত্র অসঙ্গতিগুলি দৃশ্যমান রেখে৷ Wolfram Mathematica এ এটি ব্যবহার করে করা যেতে পারে অস্বচ্ছতা[] и Raster3D[].

data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]}, 
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]

অপাসিটি[] এবং রাস্টার3ডি[] ফাংশন ব্যবহার করে সিসমিক ডেটা কিউব ইমেজ

সিন্থেটিক উদাহরণের মতো, মূল ঘনকের অংশে কেউ পরিবর্তনশীল ত্রাণ সহ কিছু ভূতাত্ত্বিক সীমানা (স্তর) সনাক্ত করতে পারে।

বর্ণালী বিশ্লেষণের প্রধান হাতিয়ার হল ফুরিয়ার রূপান্তর। এর সাহায্যে, আপনি প্রতিটি ট্রেস বা ট্রেসের গ্রুপের প্রশস্ততা-ফ্রিকোয়েন্সি বর্ণালী মূল্যায়ন করতে পারেন। যাইহোক, ফ্রিকোয়েন্সি ডোমেনে ডেটা স্থানান্তর করার পরে, কোন সময়ে (কোন গভীরতায় পড়ুন) ফ্রিকোয়েন্সি পরিবর্তিত হয় সে সম্পর্কে তথ্য হারিয়ে যায়। সময় (গভীরতা) অক্ষে সংকেত পরিবর্তনগুলি স্থানীয়করণ করতে সক্ষম হওয়ার জন্য, উইন্ডোযুক্ত ফুরিয়ার রূপান্তর এবং তরঙ্গের পচন ব্যবহার করা হয়। এই নিবন্ধটি তরঙ্গের পচন ব্যবহার করে। ওয়েভলেট বিশ্লেষণ প্রযুক্তি 90 এর দশকে সিসমিক অন্বেষণে সক্রিয়ভাবে ব্যবহার করা শুরু হয়েছিল। উইন্ডোড ফুরিয়ার ট্রান্সফর্মের উপর সুবিধাটি ভাল সময় রেজোলিউশন হিসাবে বিবেচিত হয়।

নিম্নলিখিত কোড খণ্ডটি ব্যবহার করে, আপনি সিসমিক ট্রেসগুলির একটিকে পৃথক উপাদানগুলিতে পচিয়ে দিতে পারেন:

cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]

উপাদান মধ্যে একটি ট্রেস পচন

বিভিন্ন তরঙ্গের আগমনের সময়ে প্রতিফলন শক্তি কীভাবে বিতরণ করা হয় তা মূল্যায়ন করতে, স্কেলোগ্রাম (একটি বর্ণালীগ্রামের অনুরূপ) ব্যবহার করা হয়। একটি নিয়ম হিসাবে, অনুশীলনে সমস্ত উপাদান বিশ্লেষণ করার প্রয়োজন নেই। সাধারণত, নিম্ন, মধ্য এবং উচ্চ ফ্রিকোয়েন্সি উপাদান নির্বাচন করা হয়।

freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]

স্কেলোগ্রাম। ফাংশন ফলাফল ওয়েভলেটস্ক্যালোগ্রাম[]

ওলফ্রাম ভাষা তরঙ্গ রূপান্তরের জন্য ফাংশন ব্যবহার করে কন্টিনিউয়াস ওয়েভলেট ট্রান্সফর্ম[]. এবং এই ফাংশনটির প্রয়োগ সম্পূর্ণ ট্রেস সেটে ফাংশন ব্যবহার করে করা হবে টেবিল[]. এখানে উলফ্রাম ম্যাথমেটিকার অন্যতম শক্তি লক্ষ্য করা উচিত - সমান্তরালকরণ ব্যবহার করার ক্ষমতা সমান্তরাল সারণী[]. উপরের উদাহরণে, সমান্তরালকরণের কোন প্রয়োজন নেই - ডেটার ভলিউম বড় নয়, তবে কয়েক হাজার ট্রেস ধারণকারী পরীক্ষামূলক ডেটা সেটগুলির সাথে কাজ করার সময়, এটি একটি প্রয়োজনীয়তা।

tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}];

ফাংশন প্রয়োগ করার পরে কন্টিনিউয়াস ওয়েভলেট ট্রান্সফর্ম[] নতুন ডেটা সেটগুলি নির্বাচিত ফ্রিকোয়েন্সিগুলির সাথে মিলে যায়৷ উপরের উদাহরণে, এই ফ্রিকোয়েন্সিগুলি হল: 38Hz, 33Hz, 27Hz। ফ্রিকোয়েন্সিগুলির পছন্দটি প্রায়শই পরীক্ষার ভিত্তিতে করা হয় - তারা বিভিন্ন ফ্রিকোয়েন্সি সংমিশ্রণের জন্য কার্যকর মানচিত্র প্রাপ্ত করে এবং ভূতাত্ত্বিকের দৃষ্টিকোণ থেকে সর্বাধিক তথ্যপূর্ণ একটি নির্বাচন করে।

আপনি যদি সহকর্মীদের সাথে ফলাফলগুলি ভাগ করতে চান বা গ্রাহককে সরবরাহ করতে চান তবে আপনি GeologyIO প্যাকেজের SEGYExport[] ফাংশনটি ব্যবহার করতে পারেন

outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];

এই তিনটি কিউব (লো-ফ্রিকোয়েন্সি, মিড-ফ্রিকোয়েন্সি এবং হাই-ফ্রিকোয়েন্সি উপাদান) সহ, আরজিবি মিশ্রন সাধারণত ডেটাকে একসাথে কল্পনা করতে ব্যবহৃত হয়। প্রতিটি উপাদানের নিজস্ব রঙ বরাদ্দ করা হয় - লাল, সবুজ, নীল। Wolfram Mathematica এ এটি ফাংশন ব্যবহার করে করা যেতে পারে কালার কম্বিন[].

ফলাফল হল ছবি যা থেকে ভূতাত্ত্বিক ব্যাখ্যা করা যেতে পারে। বিভাগে লিপিবদ্ধ করা মেন্ডারগুলি প্যালিওচ্যানেলগুলিকে চিত্রিত করা সম্ভব করে, যা জলাধার হওয়ার সম্ভাবনা বেশি এবং এতে তেলের মজুদ রয়েছে। এই জাতীয় নদী ব্যবস্থার আধুনিক অ্যানালগগুলির অনুসন্ধান এবং বিশ্লেষণ আমাদের মধ্যবর্তী অংশগুলির সবচেয়ে প্রতিশ্রুতিবদ্ধ অংশগুলি নির্ধারণ করতে দেয়। চ্যানেলগুলি নিজেরাই ভালভাবে সাজানো বেলেপাথরের পুরু স্তর দ্বারা চিহ্নিত করা হয় এবং এটি তেলের জন্য একটি ভাল আধার। "লেস" অসঙ্গতির বাইরের অঞ্চলগুলি আধুনিক প্লাবনভূমি আমানতের অনুরূপ। প্লাবনভূমির আমানত প্রধানত কাদামাটি শিলা দ্বারা প্রতিনিধিত্ব করা হয় এবং এই অঞ্চলগুলিতে খনন করা অকার্যকর হবে।

ডাটা কিউবের RGB স্লাইস। কেন্দ্রে (কেন্দ্রের সামান্য বাম দিকে) আপনি ঘোরা নদীটি ট্রেস করতে পারেন।

ডাটা কিউবের RGB স্লাইস। বাম দিকে আপনি ঘোরা নদী ট্রেস করতে পারেন.

কিছু ক্ষেত্রে, সিসমিক ডেটার গুণমান উল্লেখযোগ্যভাবে পরিষ্কার চিত্রের জন্য অনুমতি দেয়। এটি মাঠের কাজের পদ্ধতির উপর নির্ভর করে, শব্দ কমানোর অ্যালগরিদম দ্বারা ব্যবহৃত সরঞ্জাম। এই ধরনের ক্ষেত্রে, শুধুমাত্র নদী ব্যবস্থার টুকরোগুলিই দৃশ্যমান নয়, পুরো বর্ধিত প্যালিও-নদীগুলিও দৃশ্যমান।

একটি সিসমিক ডেটা কিউবের তিনটি উপাদানের RGB মিশ্রণ (অনুভূমিক স্লাইস)। গভীরতা প্রায় 2 কিমি।

সারাতোভের কাছে ভলগা নদীর স্যাটেলাইট ছবি

উপসংহার

Wolfram Mathematica আপনাকে সিসমিক ডেটা বিশ্লেষণ করতে এবং খনিজ অনুসন্ধানের সাথে সম্পর্কিত প্রয়োগিত সমস্যার সমাধান করতে দেয় এবং GeologyIO প্যাকেজ এই প্রক্রিয়াটিকে আরও সুবিধাজনক করে তোলে। সিসমিক ডেটার গঠন এমন যে বিল্ট-ইন পদ্ধতি ব্যবহার করে গণনার গতি বাড়ানো (সমান্তরাল সারণী[], ParallelDo[],…) অত্যন্ত দক্ষ এবং আপনাকে প্রচুর পরিমাণে ডেটা প্রক্রিয়া করার অনুমতি দেয়। অনেকাংশে, জিওলজিআইও প্যাকেজের ডেটা স্টোরেজ বৈশিষ্ট্যগুলি দ্বারা এটি সহজতর হয়েছে। যাইহোক, প্যাকেজটি শুধুমাত্র সিসমিক এক্সপ্লোরেশনের ক্ষেত্রেই ব্যবহার করা যাবে না। প্রায় একই ধরনের ডেটা গ্রাউন্ড পেনিট্রেটিং রাডার এবং সিসমোলজিতে ব্যবহার করা হয়৷ ফলাফলটি কীভাবে উন্নত করা যায় সে সম্পর্কে আপনার যদি পরামর্শ থাকে, উলফ্রাম ম্যাথমেটিকা অস্ত্রাগার থেকে কোন সিগন্যাল বিশ্লেষণ অ্যালগরিদমগুলি এই জাতীয় ডেটার ক্ষেত্রে প্রযোজ্য, বা যদি আপনার কোনও সমালোচনামূলক মন্তব্য থাকে, দয়া করে মতামত দিন.

উত্স: www.habr.com

জিওফিজিক্সে উলফ্রাম ম্যাথমেটিকা