
Prilikom rada na vizualizaciji podataka za članak pojavila se potreba da imam 4 ose sa pozitivnim oznakama na svim.
Kao i za druge grafike u članku, odlučio sam koristiti gnuplot. Prvo sam pogledao na zvaničnu stranicu, gdje ima mnoštvo primjera. Bio sam vrlo srećan kada sam pronašao onaj koji mi treba (malo ću obraditi i biće lepo, pomislih).

Brzo sam kopirao kod, pokrećem. Dobijam grešku. Proučavam. Ispostavilo se da imam stariju verziju gnuplota (Version 5.0 patchlevel 3 last modified 2016-02-21) i on to ne zna.
Znajući za fleksibilnost gnuplota, počeo sam pretraživati internet i naišao na nekoliko odgovarajućih primjera na stackoverflow ( i ) i github (). Oni su postali polazišna tačka.
Zatim, moje manipulacije komandama dovele su do sledećeg:
0) Isključujemo
unset border
1) Kreiramo 4 nulte linije — 2 osnovne i 2 dodatne:
set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis
Par reči o nul-linijama u . Ova operacija omogućava da se ose spoje u centar crteža. A dodatne su potrebne da bi se na njima prikazali pozitivni tikovi.
2) Podešavamo prikaz tikova na osama:
max = 1.5 # Za fleksibilnost
min = -max
set xtics axis 0,.5,max in scale 0.5,0.25 mirror norotate autojustify offset 0.35
set ytics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify
Sa tikovima na osama podešavanja su malo složenija.
axis — gde će se nalaziti tikovi, na osi ili (border — na granici).
Za os x, koja ide udesno 0,.5,max. Prvo broj — početak brojanja, drugi — korak, treći — kraj brojanja. Za prvu od 0, a za ostale od 0.5, da nule ne ometaju na početku koordinata.


Mešanje nula u centru koordinata.
Sve intervale *tics su podešeni kao 0,.5,max
Bez offset 0.35 za xtics
Podešavanje scale 0.5,0.25 mirror dodaje oznake na os. Ako se malo poigrate s brojevima, menjaće se njihova veličina.
Takođe unosim varijable max, min, pomoću kojih upravljam granicama osa grafika.
Dodatne informacije o podešavanju tikova možete pronaći u dokumentaciji u odeljku .
3) Podešavamo opsege osa:
set xrange [ min : max ]
set yrange [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]
Ovde se treba napomenuti da 2 ose počinju brojanje od min na povećanje i 2 ose — sa max na smanjenje.
Dodatne informacije u odeljku .
4) Dajemo osama imena i lijepo ih raspoređujemo:
set label "H_1" at 0, max center offset char 2, 0
set label "H_2" at max+0.1, 0 center offset char -1, 1
set label "H_3" at 0, min center offset char -2, 0
set label "H_4" at min, 0 center offset char 0, 1
5) Formiramo ulazne podatke
Svakoj grafikon je dodijeljeno po 2 kolone. Broj reda — broj osovine, peta linija, kako bismo zatvorili konturu. Neparna kolona — koordinata x, parna — y. S obzirom na to da su sve tačke smještene na osama, jedna od para (x, y) uvijek je jednaka nuli.
Iako su sve 4 osi pozitivne, neki podaci se umjetno pomjeraju na negativnu polovinu, jer se nalaze na glavnim osama x i y.
0 1 0 1.21
1 0 1.21 0
0 -1 0 -1.06
-1 0 -1.19 0
0 1 0 1.21 #Dupliciraj prvu tačku
Rezultat

Kompletan kod
#!/usr/bin/gnuplot -persist
#файл в кодировке cp1251 чтоб русские буквы отображались в eps
set encoding cp1251
set terminal postscript eps enhanced monochrome size 5cm,5cm
set output "./img/eps/fig2.eps"
unset border
set key at -2, 1.5 font 'LiberationSerif, 23'
set key left top samplen 4.5
set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis
max = 1.5
min = -max
set xtics axis 0,.5,max in scale 0.5,0.25 mirror norotate autojustify offset 0.35 font 'LiberationSerif, 20
set ytics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify font 'LiberationSerif, 20
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify font 'LiberationSerif, 20
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify font 'LiberationSerif, 20
set xrange [ min : max ]
set yrange [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]
set label "H_1" at 0, max center offset char 2, 0 font 'LiberationSerif, 23'
set label "H_2" at max+0.1, 0 center offset char -1, 1 font 'LiberationSerif, 23'
set label "H_3" at 0, min center offset char -2, 0 font 'LiberationSerif, 23'
set label "H_4" at min, 0 center offset char 0, 1 font 'LiberationSerif, 23'
set style line 1 linetype 1 pointtype 7 linewidth 3 linecolor black
set style line 2 linetype 2 pointtype 7 linewidth 3 linecolor black
plot 'data.csv' using 1:2 title "1" w lp ls 1 ,
'data.csv' using 3:4 title "2" w lp ls 2
Izvor: habr.com
