Fel y gwyddoch, mae mynegeion yn chwarae rhan bwysig mewn DBMS, gan ddarparu chwiliad cyflym i'r cofnodion gofynnol. Dyna pam ei bod mor bwysig eu gwasanaethu mewn modd amserol. Mae cryn dipyn o ddeunydd wedi'i ysgrifennu am ddadansoddi ac optimeiddio, gan gynnwys ar y Rhyngrwyd. Er enghraifft, adolygwyd y pwnc hwn yn ddiweddar yn .
Mae yna lawer o atebion taledig ac am ddim ar gyfer hyn. Er enghraifft, mae parod , yn seiliedig ar ddull optimeiddio mynegai addasol.
Nesaf, gadewch i ni edrych ar y cyfleustodau rhad ac am ddim , wedi'i awduro gan .
Mae'r prif wahaniaeth technegol rhwng SQLIndexManager a nifer o analogau eraill yn cael ei roi gan yr awdur ei hun и .
Yn yr erthygl hon, byddwn yn edrych o'r tu allan ar y prosiect a galluoedd gweithredol y datrysiad meddalwedd hwn.
Wrth drafod y cyfleustodau hwn .
Dros amser, cywirwyd y rhan fwyaf o'r sylwadau a'r bygiau.
Felly, gadewch i ni nawr symud ymlaen i'r cyfleustodau SQLIndexManager ei hun.
Mae'r cais wedi'i ysgrifennu yn C# .NET Framework 4.5 yn Visual Studio 2017 ac mae'n defnyddio DevExpress ar gyfer ffurflenni:
ac mae'n edrych fel hyn:
Cynhyrchir pob cais yn y ffeiliau canlynol:
- mynegai
- ymholiad
- QueryEngine
- Gwybodaeth Gweinydd
Wrth gysylltu â chronfa ddata ac anfon ymholiadau i'r DBMS, mae'r cais wedi'i lofnodi fel a ganlyn:
ApplicationName=”SQLIndexManager”
Pan fyddwch chi'n lansio'r cais, bydd ffenestr foddol yn agor i ychwanegu cysylltiad:
Yma, nid yw llwytho rhestr gyflawn o'r holl achosion MS SQL Server sy'n hygyrch dros rwydweithiau lleol yn gweithio eto.
Gallwch hefyd ychwanegu cysylltiad gan ddefnyddio'r botwm chwith ar y brif ddewislen:
Nesaf, bydd yr ymholiadau canlynol i'r DBMS yn cael eu lansio:
- Cael gwybodaeth am y DBMS
SELECT ProductLevel = SERVERPROPERTY('ProductLevel') , Edition = SERVERPROPERTY('Edition') , ServerVersion = SERVERPROPERTY('ProductVersion') , IsSysAdmin = CAST(IS_SRVROLEMEMBER('sysadmin') AS BIT) - Cael rhestr o gronfeydd data sydd ar gael gyda'u priodweddau cryno
SELECT DatabaseName = t.[name] , d.DataSize , DataUsedSize = CAST(NULL AS BIGINT) , d.LogSize , LogUsedSize = CAST(NULL AS BIGINT) , RecoveryModel = t.recovery_model_desc , LogReuseWait = t.log_reuse_wait_desc FROM sys.databases t WITH(NOLOCK) LEFT JOIN ( SELECT [database_id] , DataSize = SUM(CASE WHEN [type] = 0 THEN CAST(size AS BIGINT) END) , LogSize = SUM(CASE WHEN [type] = 1 THEN CAST(size AS BIGINT) END) FROM sys.master_files WITH(NOLOCK) GROUP BY [database_id] ) d ON d.[database_id] = t.[database_id] WHERE t.[state] = 0 AND t.[database_id] != 2 AND ISNULL(HAS_DBACCESS(t.[name]), 1) = 1
Ar ôl gweithredu'r sgriptiau uchod, bydd ffenestr yn ymddangos yn cynnwys gwybodaeth gryno am gronfeydd data'r enghraifft a ddewiswyd o MS SQL Server:
Mae'n werth nodi bod gwybodaeth estynedig yn cael ei dangos ar sail hawliau. Os oes , yna gallwch ddewis data o'r golwg . Os nad oes hawliau o'r fath, yna bydd llai o ddata'n cael ei ddychwelyd er mwyn peidio ag arafu'r cais.
Yma mae angen i chi ddewis y cronfeydd data o ddiddordeb a chlicio ar y botwm "OK".
Nesaf, gweithredir y sgript ganlynol ar gyfer pob cronfa ddata a ddewiswyd i ddadansoddi cyflwr y mynegeion:
Dadansoddiad statws mynegai
declare @Fragmentation float=15;
declare @MinIndexSize bigint=768;
declare @MaxIndexSize bigint=1048576;
declare @PreDescribeSize bigint=32768;
SET NOCOUNT ON
SET ARITHABORT ON
SET NUMERIC_ROUNDABORT OFF
IF OBJECT_ID('tempdb.dbo.#AllocationUnits') IS NOT NULL
DROP TABLE #AllocationUnits
CREATE TABLE #AllocationUnits (
ContainerID BIGINT PRIMARY KEY
, ReservedPages BIGINT NOT NULL
, UsedPages BIGINT NOT NULL
)
INSERT INTO #AllocationUnits (ContainerID, ReservedPages, UsedPages)
SELECT [container_id]
, SUM([total_pages])
, SUM([used_pages])
FROM sys.allocation_units WITH(NOLOCK)
GROUP BY [container_id]
HAVING SUM([total_pages]) BETWEEN @MinIndexSize AND @MaxIndexSize
IF OBJECT_ID('tempdb.dbo.#ExcludeList') IS NOT NULL
DROP TABLE #ExcludeList
CREATE TABLE #ExcludeList (ID INT PRIMARY KEY)
INSERT INTO #ExcludeList
SELECT [object_id]
FROM sys.objects WITH(NOLOCK)
WHERE [type] IN ('V', 'U')
AND ( [is_ms_shipped] = 1 )
IF OBJECT_ID('tempdb.dbo.#Partitions') IS NOT NULL
DROP TABLE #Partitions
SELECT [object_id]
, [index_id]
, [partition_id]
, [partition_number]
, [rows]
, [data_compression]
INTO #Partitions
FROM sys.partitions WITH(NOLOCK)
WHERE [object_id] > 255
AND [rows] > 0
AND [object_id] NOT IN (SELECT * FROM #ExcludeList)
IF OBJECT_ID('tempdb.dbo.#Indexes') IS NOT NULL
DROP TABLE #Indexes
CREATE TABLE #Indexes (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IndexName SYSNAME NULL
, PagesCount BIGINT NOT NULL
, UnusedPagesCount BIGINT NOT NULL
, PartitionNumber INT NOT NULL
, RowsCount BIGINT NOT NULL
, IndexType TINYINT NOT NULL
, IsAllowPageLocks BIT NOT NULL
, DataSpaceID INT NOT NULL
, DataCompression TINYINT NOT NULL
, IsUnique BIT NOT NULL
, IsPK BIT NOT NULL
, FillFactorValue INT NOT NULL
, IsFiltered BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Indexes
SELECT ObjectID = i.[object_id]
, IndexID = i.index_id
, IndexName = i.[name]
, PagesCount = a.ReservedPages
, UnusedPagesCount = CASE WHEN ABS(a.ReservedPages - a.UsedPages) > 32 THEN a.ReservedPages - a.UsedPages ELSE 0 END
, PartitionNumber = p.[partition_number]
, RowsCount = ISNULL(p.[rows], 0)
, IndexType = i.[type]
, IsAllowPageLocks = i.[allow_page_locks]
, DataSpaceID = i.[data_space_id]
, DataCompression = p.[data_compression]
, IsUnique = i.[is_unique]
, IsPK = i.[is_primary_key]
, FillFactorValue = i.[fill_factor]
, IsFiltered = i.[has_filter]
FROM #AllocationUnits a
JOIN #Partitions p ON a.ContainerID = p.[partition_id]
JOIN sys.indexes i WITH(NOLOCK) ON i.[object_id] = p.[object_id] AND p.[index_id] = i.[index_id]
WHERE i.[type] IN (0, 1, 2, 5, 6)
AND i.[object_id] > 255
DECLARE @files TABLE (ID INT PRIMARY KEY)
INSERT INTO @files
SELECT DISTINCT [data_space_id]
FROM sys.database_files WITH(NOLOCK)
WHERE [state] != 0
AND [type] = 0
IF @@ROWCOUNT > 0 BEGIN
DELETE FROM i
FROM #Indexes i
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
WHERE ISNULL(dds.[data_space_id], i.DataSpaceID) IN (SELECT * FROM @files)
END
DECLARE @DBID INT
, @DBNAME SYSNAME
SET @DBNAME = DB_NAME()
SELECT @DBID = [database_id]
FROM sys.databases WITH(NOLOCK)
WHERE [name] = @DBNAME
IF OBJECT_ID('tempdb.dbo.#Fragmentation') IS NOT NULL
DROP TABLE #Fragmentation
CREATE TABLE #Fragmentation (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, PartitionNumber INT NOT NULL
, Fragmentation FLOAT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Fragmentation (ObjectID, IndexID, PartitionNumber, Fragmentation)
SELECT i.ObjectID
, i.IndexID
, i.PartitionNumber
, r.[avg_fragmentation_in_percent]
FROM #Indexes i
CROSS APPLY sys.dm_db_index_physical_stats(@DBID, i.ObjectID, i.IndexID, i.PartitionNumber, 'LIMITED') r
WHERE i.PagesCount <= @PreDescribeSize
AND r.[index_level] = 0
AND r.[alloc_unit_type_desc] = 'IN_ROW_DATA'
AND i.IndexType IN (0, 1, 2)
IF OBJECT_ID('tempdb.dbo.#Columns') IS NOT NULL
DROP TABLE #Columns
CREATE TABLE #Columns (
ObjectID INT NOT NULL
, ColumnID INT NOT NULL
, ColumnName SYSNAME NULL
, SystemTypeID TINYINT NULL
, IsSparse BIT
, IsColumnSet BIT
, MaxLen INT
, PRIMARY KEY (ObjectID, ColumnID)
)
INSERT INTO #Columns
SELECT ObjectID = [object_id]
, ColumnID = [column_id]
, ColumnName = [name]
, SystemTypeID = [system_type_id]
, IsSparse = [is_sparse]
, IsColumnSet = [is_column_set]
, MaxLen = [max_length]
FROM sys.columns WITH(NOLOCK)
WHERE [object_id] IN (SELECT DISTINCT i.ObjectID FROM #Indexes i)
IF OBJECT_ID('tempdb.dbo.#IndexColumns') IS NOT NULL
DROP TABLE #IndexColumns
CREATE TABLE #IndexColumns (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, OrderID INT NOT NULL
, ColumnID INT NOT NULL
, IsIncluded BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, ColumnID)
)
INSERT INTO #IndexColumns
SELECT ObjectID = [object_id]
, IndexID = [index_id]
, OrderID = CASE WHEN [is_included_column] = 0 THEN [key_ordinal] ELSE [index_column_id] END
, ColumnID = [column_id]
, IsIncluded = ISNULL([is_included_column], 0)
FROM sys.index_columns ic WITH(NOLOCK)
WHERE EXISTS(
SELECT *
FROM #Indexes i
WHERE i.ObjectID = ic.[object_id]
AND i.IndexID = ic.[index_id]
AND i.IndexType IN (1, 2)
)
IF OBJECT_ID('tempdb.dbo.#Lob') IS NOT NULL
DROP TABLE #Lob
CREATE TABLE #Lob (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IsLobLegacy BIT
, IsLob BIT
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #Lob (ObjectID, IndexID, IsLobLegacy, IsLob)
SELECT c.ObjectID
, IndexID = ISNULL(i.IndexID, 1)
, IsLobLegacy = MAX(CASE WHEN c.SystemTypeID IN (34, 35, 99) THEN 1 END)
, IsLob = 0
FROM #Columns c
LEFT JOIN #IndexColumns i ON c.ObjectID = i.ObjectID AND c.ColumnID = i.ColumnID
WHERE c.SystemTypeID IN (34, 35, 99)
GROUP BY c.ObjectID
, i.IndexID
IF OBJECT_ID('tempdb.dbo.#Sparse') IS NOT NULL
DROP TABLE #Sparse
CREATE TABLE #Sparse (ObjectID INT PRIMARY KEY)
INSERT INTO #Sparse
SELECT DISTINCT ObjectID
FROM #Columns
WHERE IsSparse = 1
OR IsColumnSet = 1
IF OBJECT_ID('tempdb.dbo.#AggColumns') IS NOT NULL
DROP TABLE #AggColumns
CREATE TABLE #AggColumns (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IndexColumns NVARCHAR(MAX)
, IncludedColumns NVARCHAR(MAX)
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #AggColumns
SELECT t.ObjectID
, t.IndexID
, IndexColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 0
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
, IncludedColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 1
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
FROM (
SELECT DISTINCT ObjectID, IndexID
FROM #Indexes
WHERE IndexType IN (1, 2)
) t
SELECT i.ObjectID
, i.IndexID
, i.IndexName
, ObjectName = o.[name]
, SchemaName = s.[name]
, i.PagesCount
, i.UnusedPagesCount
, i.PartitionNumber
, i.RowsCount
, i.IndexType
, i.IsAllowPageLocks
, u.TotalWrites
, u.TotalReads
, u.TotalSeeks
, u.TotalScans
, u.TotalLookups
, u.LastUsage
, i.DataCompression
, f.Fragmentation
, IndexStats = STATS_DATE(i.ObjectID, i.IndexID)
, IsLobLegacy = ISNULL(lob.IsLobLegacy, 0)
, IsLob = ISNULL(lob.IsLob, 0)
, IsSparse = CAST(CASE WHEN p.ObjectID IS NULL THEN 0 ELSE 1 END AS BIT)
, IsPartitioned = CAST(CASE WHEN dds.[data_space_id] IS NOT NULL THEN 1 ELSE 0 END AS BIT)
, FileGroupName = fg.[name]
, i.IsUnique
, i.IsPK
, i.FillFactorValue
, i.IsFiltered
, a.IndexColumns
, a.IncludedColumns
FROM #Indexes i
JOIN sys.objects o WITH(NOLOCK) ON o.[object_id] = i.ObjectID
JOIN sys.schemas s WITH(NOLOCK) ON s.[schema_id] = o.[schema_id]
LEFT JOIN #AggColumns a ON a.ObjectID = i.ObjectID AND a.IndexID = i.IndexID
LEFT JOIN #Sparse p ON p.ObjectID = i.ObjectID
LEFT JOIN #Fragmentation f ON f.ObjectID = i.ObjectID AND f.IndexID = i.IndexID AND f.PartitionNumber = i.PartitionNumber
LEFT JOIN (
SELECT ObjectID = [object_id]
, IndexID = [index_id]
, TotalWrites = NULLIF([user_updates], 0)
, TotalReads = NULLIF([user_seeks] + [user_scans] + [user_lookups], 0)
, TotalSeeks = NULLIF([user_seeks], 0)
, TotalScans = NULLIF([user_scans], 0)
, TotalLookups = NULLIF([user_lookups], 0)
, LastUsage = (
SELECT MAX(dt)
FROM (
VALUES ([last_user_seek])
, ([last_user_scan])
, ([last_user_lookup])
, ([last_user_update])
) t(dt)
)
FROM sys.dm_db_index_usage_stats WITH(NOLOCK)
WHERE [database_id] = @DBID
) u ON i.ObjectID = u.ObjectID AND i.IndexID = u.IndexID
LEFT JOIN #Lob lob ON lob.ObjectID = i.ObjectID AND lob.IndexID = i.IndexID
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
JOIN sys.filegroups fg WITH(NOLOCK) ON ISNULL(dds.[data_space_id], i.DataSpaceID) = fg.[data_space_id]
WHERE o.[type] IN ('V', 'U')
AND (
f.Fragmentation >= @Fragmentation
OR
i.PagesCount > @PreDescribeSize
OR
i.IndexType IN (5, 6)
)
Fel y gwelir o'r ymholiadau eu hunain, defnyddir tablau dros dro yn eithaf aml. Gwneir hyn fel nad oes unrhyw ail-grynhoi, ac yn achos cynllun mawr, gellir cynhyrchu'r cynllun ochr yn ochr wrth fewnosod data, gan mai dim ond mewn un edefyn y gellir mewnosod newidynnau tabl.
Ar ôl gweithredu'r sgript uchod, bydd ffenestr gyda thabl mynegai yn ymddangos:
Gallwch hefyd arddangos gwybodaeth fanwl arall yma, megis:
- cronfa ddata
- nifer o adrannau
- dyddiad ac amser yr alwad ddiwethaf
- gwasgu
- grŵp ffeil
fi t. d.
Gellir addasu'r siaradwyr eu hunain:
Yng nghelloedd y golofn Trwsio, gallwch ddewis pa gamau fydd yn cael eu perfformio yn ystod optimeiddio. Hefyd, pan fydd y sgan wedi'i gwblhau, dewisir gweithred ddiofyn yn seiliedig ar y gosodiadau a ddewiswyd:
Rhaid i chi ddewis y mynegeion dymunol i'w prosesu.
Gan ddefnyddio'r brif ddewislen, gallwch arbed y sgript (mae'r un botwm yn cychwyn y broses optimeiddio mynegai ei hun):
ac arbedwch y tabl mewn gwahanol fformatau (mae'r un botwm yn caniatáu ichi agor gosodiadau manwl ar gyfer dadansoddi ac optimeiddio mynegeion):
Gallwch hefyd ddiweddaru'r wybodaeth trwy glicio ar y trydydd botwm ar y chwith yn y brif ddewislen wrth ymyl y chwyddwydr.
Mae'r botwm gyda chwyddwydr yn caniatáu ichi ddewis y cronfeydd data dymunol i'w hystyried.
Nid oes system gymorth gynhwysfawr ar hyn o bryd. Felly, gwasgwch y botwm “?” yn syml yn achosi ffenestr moddol i ymddangos yn cynnwys gwybodaeth sylfaenol am y cynnyrch meddalwedd:
Yn ogystal â phopeth a ddisgrifir uchod, mae gan y brif ddewislen far chwilio:
Wrth gychwyn y broses optimeiddio mynegai:
Gallwch hefyd weld log o weithredoedd a gyflawnwyd ar waelod y ffenestr:
Yn y ffenestr gosodiadau manwl ar gyfer dadansoddi mynegai ac optimeiddio, gallwch chi ffurfweddu opsiynau mwy cynnil:
Ceisiadau am y cais:
- ei gwneud hi'n bosibl diweddaru ystadegau'n ddetholus nid yn unig ar gyfer mynegeion a hefyd mewn gwahanol ffyrdd (diweddaru'n llawn neu'n rhannol)
- ei gwneud yn bosibl nid yn unig i ddewis cronfa ddata, ond hefyd gweinyddwyr gwahanol (mae hyn yn gyfleus iawn pan mae llawer o achosion o MS SQL Server)
- I gael mwy o hyblygrwydd wrth ddefnyddio, awgrymir lapio'r gorchmynion mewn llyfrgelloedd a'u hallbynnu i orchmynion PowerShell, fel y gwneir, er enghraifft, yma:
- ei gwneud hi'n bosibl cadw a newid gosodiadau personol ar gyfer y rhaglen gyfan ac, os oes angen, ar gyfer pob achos o MS SQL Server a phob cronfa ddata
- O bwyntiau 2 a 4, mae'n dilyn eich bod am greu grwpiau yn ôl cronfeydd data a grwpiau yn ôl achosion MS SQL Server, y mae'r gosodiadau yr un peth ar eu cyfer
- chwilio am fynegeion dyblyg (cyflawn ac anghyflawn, sydd naill ai ychydig yn wahanol neu'n wahanol yn y colofnau sydd wedi'u cynnwys yn unig)
- Gan fod SQLIndexManager yn cael ei ddefnyddio ar gyfer MS SQL Server DBMS yn unig, mae angen adlewyrchu hyn yn yr enw, er enghraifft, fel a ganlyn: SQLIndexManager ar gyfer MS SQL Server
- Symudwch bob rhan o'r rhaglen nad yw'n GUI i fodiwlau ar wahân a'u hailysgrifennu yn .NET Core 2.1
Ar adeg ysgrifennu’r adroddiad hwn, mae eitem 6 o’r dymuniadau yn cael ei datblygu’n weithredol ac mae cefnogaeth eisoes ar ffurf chwilio am ddyblygiadau cyflawn a thebyg:
Ffynonellau
Ffynhonnell: hab.com