Mientras profundizamos en el tema de cómo funcionan los productos 1C en el entorno Linux, se descubrió un inconveniente: la falta de una herramienta gráfica multiplataforma conveniente para administrar un grupo de servidores 1C. Y se decidió corregir este inconveniente escribiendo una GUI para la utilidad de la consola rac. Se eligió Tcl/tk como lenguaje de desarrollo porque, en mi opinión, es el más adecuado para esta tarea. Por eso, me gustaría presentar algunos aspectos interesantes de la solución en este material.
Para trabajar necesitarás las distribuciones tcl/tk y 1C. Y como decidí aprovechar al máximo las capacidades de la entrega básica tcl/tk sin utilizar paquetes de terceros, necesitaré la versión 8.6.7, que incluye ttk, un paquete con elementos gráficos adicionales, del cual necesitamos principalmente ttk. ::TreeView, permite visualizar datos tanto en forma de estructura de árbol como en forma de tabla (lista). Además, en la nueva versión se ha reelaborado el trabajo con excepciones (el comando try, que se utiliza en el proyecto cuando se ejecutan comandos externos).
El proyecto consta de varios archivos (aunque nada te impide hacer todo en uno):
rac_gui.cfg - configuración predeterminada
rac_gui.tcl - script de inicio principal
El directorio lib contiene archivos que se cargan automáticamente al inicio:
function.tcl - archivo con procedimientos
gui.tcl - interfaz gráfica principal
images.tcl - biblioteca de imágenes base64
El archivo rac_gui.tcl, de hecho, inicia el intérprete, inicializa variables, carga módulos, configuraciones, etc. Contenido del archivo con comentarios:
rac_gui.tcl
#!/bin/sh
exec wish "$0" -- "$@"
# Устанавливаем текущий каталог
set dir(root) [pwd]
# Устанавливаем рабочий каталог, если его нет то создаём
set dir(work) [file join $env(HOME) .rac_gui]
if {[file exists $dir(work)] == 0 } {
file mkdir $dir(work)
}
# каталог с модулями
set dir(lib) "[file join $dir(root) lib]"
# загружаем пользовательский конфиг, если он отсутствует, то копируем дефолтный
if {[file exists [file join $dir(work) rac_gui.cfg]] ==0} {
file copy [file join [pwd] rac_gui.cfg] [file join $dir(work) rac_gui.cfg]
}
source [file join $dir(work) rac_gui.cfg]
# Код проверки наличия rac и правильности указания пути в конфиге
# если программа не найдена то будет выведен диалог для указания корректного пути
# и этот путь будет записан в пользовательский конфиг
if {[file exists $rac_cmd] == 0} {
set rac_cmd [tk_getOpenFile -initialdir $env(HOME) -parent . -title "Укажите путь до rac" -initialfile rac]
file copy [file join $dir(work) rac_gui.cfg] [file join $dir(work) rac_gui.cfg.bak]
set orig_file [open [file join $dir(work) rac_gui.cfg.bak] "r"]
set file [open [file join $dir(work) rac_gui.cfg] "w"]
while {[gets $orig_file line] >=0 } {
if {[string match "set rac_cmd*" $line]} {
puts $file "set rac_cmd $rac_cmd"
} else {
puts $file $line
}
}
close $file
close $orig_file
#return "$host:$port"
file delete [file join $dir(work) 1c_srv.cfg.bak]
} else {
puts "Found $rac_cmd"
}
set cluster_user ""
set cluster_pwd ""
set agent_user ""
set agent_pwd ""
## LOAD FILE ##
# Загружаем модули кроме gui.tcl так как его надо загрузить последним
foreach modFile [lsort [glob -nocomplain [file join $dir(lib) *.tcl]]] {
if {[file tail $modFile] ne "gui.tcl"} {
source $modFile
puts "Loaded module $modFile"
}
}
source [file join $dir(lib) gui.tcl]
source [file join $dir(work) rac_gui.cfg]
# Читаем файл со списком серверов 1С
# и добавляем в дерево
if [file exists [file join $dir(work) 1c_srv.cfg]] {
set f [open [file join $dir(work) 1c_srv.cfg] "RDONLY"]
while {[gets $f line] >=0} {
.frm_tree.tree insert {} end -id "server::$line" -text "$line" -values "$line"
}
}Después de descargar todo lo necesario y comprobar la presencia de la utilidad rac, se abrirá una ventana gráfica. La interfaz del programa consta de tres elementos:
Barra de herramientas, árbol y lista
Hice que el contenido del "árbol" fuera lo más parecido posible al equipo estándar de Windows de 1C.
El código principal que forma esta ventana está contenido en el archivo
lib/gui.tcl
# установка размера и положения основного окна
# можно установить в переменную topLevelGeometry в конфиг программы
if {[info exists topLevelGeometry]} {
wm geometry . $topLevelGeometry
} else {
wm geometry . 1024x768
}
# Заголовок окна
wm title . "1C Rac GUI"
wm iconname . "1C Rac Gui"
# иконка окна (берется из файла lib/imges.tcl)
wm iconphoto . tcl
wm protocol . WM_DELETE_WINDOW Quit
wm overrideredirect . 0
wm positionfrom . user
ttk::style theme use clam
# Панель инсрументов
set frm_tool [frame .frm_tool]
pack $frm_tool -side left -fill y
ttk::panedwindow .panel -orient horizontal -style TPanedwindow
pack .panel -expand true -fill both
pack propagate .panel false
ttk::button $frm_tool.btn_add -command Add -image add_grey_32
ttk::button $frm_tool.btn_del -command Del -image del_grey_32
ttk::button $frm_tool.btn_edit -command Edit -image edit_grey_32
ttk::button $frm_tool.btn_quit -command Quit -image quit_grey_32
pack $frm_tool.btn_add $frm_tool.btn_del $frm_tool.btn_edit -side top -padx 5 -pady 5
pack $frm_tool.btn_quit -side bottom -padx 5 -pady 5
# Дерево с полосами прокрутки
set frm_tree [frame .frm_tree]
ttk::scrollbar $frm_tree.hsb1 -orient horizontal -command [list $frm_tree.tree xview]
ttk::scrollbar $frm_tree.vsb1 -orient vertical -command [list $frm_tree.tree yview]
set tree [ttk::treeview $frm_tree.tree -show tree
-xscrollcommand [list $frm_tree.hsb1 set] -yscrollcommand [list $frm_tree.vsb1 set]]
grid $tree -row 0 -column 0 -sticky nsew
grid $frm_tree.vsb1 -row 0 -column 1 -sticky nsew
grid $frm_tree.hsb1 -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_tree 0 -weight 1
grid rowconfigure $frm_tree 0 -weight 1
# назначение обработчика нажатия кнопкой мыши
bind $frm_tree.tree <ButtonRelease> "TreePress $frm_tree.tree"
# Список для данных (таблица)
set frm_work [frame .frm_work]
ttk::scrollbar $frm_work.hsb -orient horizontal -command [list $frm_work.tree_work xview]
ttk::scrollbar $frm_work.vsb -orient vertical -command [list $frm_work.tree_work yview]
set tree_work [
ttk::treeview $frm_work.tree_work
-show headings -columns "par val" -displaycolumns "par val"
-xscrollcommand [list $frm_work.hsb set]
-yscrollcommand [list $frm_work.vsb set]
]
# Установка цветов для чередования в таблице
$tree_work tag configure dark -background $color(dark_table_bg)
$tree_work tag configure light -background $color(light_table_bg)
# Размещение элементов на форме
grid $tree_work -row 0 -column 0 -sticky nsew
grid $frm_work.vsb -row 0 -column 1 -sticky nsew
grid $frm_work.hsb -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_work 0 -weight 1
grid rowconfigure $frm_work 0 -weight 1
pack $frm_tree $frm_work -side left -expand true -fill both
#.panel add $frm_tool -weight 1
.panel add $frm_tree -weight 1
.panel add $frm_work -weight 1
El algoritmo para trabajar con el programa es el siguiente:
1. Primero, debe agregar el servidor del clúster principal (es decir, el servidor de administración del clúster (en Linux, la administración se inicia con el comando “/opt/1C/v8.3/x86_64/ras cluster —daemon”)).
Para hacer esto, haga clic en el botón “+” y en la ventana que se abre ingrese la dirección y el puerto del servidor:
Posteriormente nuestro servidor aparecerá en el árbol al pulsar sobre él, se abrirá una lista de clusters o se mostrará un error de conexión.
2. Al hacer clic en el nombre del clúster se abrirá una lista de funciones disponibles para él.
3. ...
Y así sucesivamente, es decir Para agregar un nuevo clúster, seleccione cualquiera disponible en la lista y presione el botón “+” en la barra de herramientas y se mostrará el cuadro de diálogo Agregar nuevo:
Los botones de la barra de herramientas realizan funciones según el contexto, es decir. Dependiendo de qué elemento del árbol o lista se seleccione se realizará uno u otro procedimiento.
Veamos el ejemplo del botón Agregar (“+”):
Código de generación de botones:
ttk::button $frm_tool.btn_add -command Add -image add_grey_32Aquí vemos que al presionar el botón se ejecutará el procedimiento “Agregar”, su código:
proc Add {} {
global active_cluster host
# Определяем идентификатор выделенного элемента
set id [.frm_tree.tree selection]
# Определяем значение этого элемента
set values [.frm_tree.tree item [.frm_tree.tree selection] -values]
set key [lindex [split $id "::"] 0]
# в зависимости от того что выделили будет запущена нужная процедура
if {$key eq "" || $key eq "server"} {
set host [ Add::server ]
return
}
Add::$key .frm_tree.tree $host $values
}Esta es una de las ventajas de tickle: puedes pasar el valor de una variable como nombre de procedimiento:
Add::$key .frm_tree.tree $host $valuesEs decir, por ejemplo, si apuntamos al servidor principal y presionamos "+", se iniciará el procedimiento Agregar::servidor, si en el clúster - Agregar::clúster y así sucesivamente (escribiré sobre dónde está Las “claves” necesarias se encuentran un poco más abajo), los procedimientos enumerados dibujan elementos gráficos apropiados al contexto.
Como ya habrás notado, los formularios son similares en estilo; esto no es sorprendente, porque se muestran mediante un procedimiento, más precisamente el marco principal del formulario (ventana, botones, imagen, etiqueta), el nombre del procedimiento. Agregar nivel superior
proc AddToplevel {lbl img {win_name .add}} {
set cmd "destroy $win_name"
if [winfo exists $win_name] {destroy $win_name}
toplevel $win_name
wm title $win_name $lbl
wm iconphoto $win_name tcl
# метка с иконкой
ttk::label $win_name.lbl -image $img
# фрейм с полями ввода
set frm [ttk::labelframe $win_name.frm -text $lbl -labelanchor nw]
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
# фрейм и кнопки
set frm_btn [frame $win_name.frm_btn -border 0]
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }
ttk::button $frm_btn.btn_cancel -command $cmd -image quit_grey_24
grid $win_name.lbl -row 0 -column 0 -sticky nw -padx 5 -pady 10
grid $frm -row 0 -column 1 -sticky nw -padx 5 -pady 5
grid $frm_btn -row 1 -column 1 -sticky se -padx 5 -pady 5
pack $frm_btn.btn_cancel -side right
pack $frm_btn.btn_ok -side right -padx 10
return $frm
}
Parámetros de llamada: título, nombre de la imagen del icono de la biblioteca (lib/images.tcl) y un parámetro de nombre de ventana opcional (predeterminado .add). Por lo tanto, si tomamos los ejemplos anteriores para agregar el servidor principal y el clúster, la llamada será en consecuencia:
AddToplevel "Добавление основного сервера" server_grey_64o
AddToplevel "Добавление кластера" cluster_grey_64Bueno, continuando con estos ejemplos, mostraré los procedimientos que muestran cuadros de diálogo para agregar para un servidor o clúster.
Agregar servidor
proc Add::server {} {
global default
# выводим основную форму
set frm [AddToplevel "Добавление основного сервера" server_grey_64]
# добавляем етки и поля ввода на эту форму
label $frm.lbl_host -text "Адрес сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
#set frm_btn [frame .add.frm_btn -border 0]
# переопределяем обработчик нажатия кнопки
.add.frm_btn.btn_ok configure -command {
set host [SaveMainServer [.add.frm.ent_host get] [.add.frm.ent_port get]]
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"
destroy .add
return $host
}
return $frm
}Agregar::clúster
proc Add::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes
agent_user agent_pwd cluster_user cluster_pwd auth_agent
if {$agent_user ne "" && $agent_pwd ne ""} {
set auth_agent "--agent-user=$agent_user --agent-pwd=$agent_pwd"
} else {
set auth_agent ""
}
# устанавливаем глобальные переменные ()
set lifetime_limit $default(lifetime_limit)
set expiration_timeout $default(expiration_timeout)
set session_fault_tolerance_level $default(session_fault_tolerance_level)
set max_memory_size $default(max_memory_size)
set max_memory_time_limit $default(max_memory_time_limit)
set errors_count_threshold $default(errors_count_threshold)
set security_level [lindex $default(security_level) 0]
set load_balancing_mode [lindex $default(load_balancing_mode) 0]
set frm [AddToplevel "Добавление кластера" cluster_grey_64]
label $frm.lbl_host -text "Адрес основного сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
label $frm.lbl_name -text "Название кластера"
entry $frm.ent_name
label $frm.lbl_secure_connect -text "Защищённое соединение"
ttk::combobox $frm.cb_security_level -textvariable security_level -values $default(security_level)
label $frm.lbl_expiration_timeout -text "Останавливать выключенные процессы через:"
entry $frm.ent_expiration_timeout -textvariable expiration_timeout
label $frm.lbl_session_fault_tolerance_level -text "Уровень отказоустойчивости"
entry $frm.ent_session_fault_tolerance_level -textvariable session_fault_tolerance_level
label $frm.lbl_load_balancing_mode -text "Режим распределения нагрузки"
ttk::combobox $frm.cb_load_balancing_mode -textvariable load_balancing_mode
-values $default(load_balancing_mode)
label $frm.lbl_errors_count_threshold -text "Допустимое отклонение количества ошибок сервера, %"
entry $frm.ent_errors_count_threshold -textvariable errors_count_threshold
label $frm.lbl_processes -text "Рабочие процессы:"
label $frm.lbl_lifetime_limit -text "Период перезапуска, сек."
entry $frm.ent_lifetime_limit -textvariable lifetime_limit
label $frm.lbl_max_memory_size -text "Допустимый объём памяти, КБ"
entry $frm.ent_max_memory_size -textvariable max_memory_size
label $frm.lbl_max_memory_time_limit -text "Интервал превышения допустимого объёма памяти, сек."
entry $frm.ent_max_memory_time_limit -textvariable max_memory_time_limit
label $frm.lbl_kill_problem_processes -justify left -anchor nw -text "Принудительно завершать проблемные процессы"
checkbutton $frm.check_kill_problem_processes -variable kill_problem_processes -onvalue yes -offvalue no
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_name -row 2 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_name -row 2 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_secure_connect -row 3 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_security_level -row 3 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_expiration_timeout -row 4 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_expiration_timeout -row 4 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_session_fault_tolerance_level -row 5 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_session_fault_tolerance_level -row 5 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_load_balancing_mode -row 6 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_load_balancing_mode -row 6 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_errors_count_threshold -row 7 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_errors_count_threshold -row 7 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_processes -row 8 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.lbl_lifetime_limit -row 9 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_lifetime_limit -row 9 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_size -row 10 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_size -row 10 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_time_limit -row 11 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_time_limit -row 11 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_kill_problem_processes -row 12 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.check_kill_problem_processes -row 12 -column 1 -sticky nw -padx 5 -pady 5
# переопределяем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
return $frm
}Al comparar el código de estos procedimientos, la diferencia es visible a simple vista; me centraré en el controlador del botón "Aceptar". En Tk, las propiedades de los elementos gráficos se pueden anular durante la ejecución del programa usando la opción configurar. Por ejemplo, el comando inicial para mostrar el botón:
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }Pero en nuestros formularios, el comando depende de la funcionalidad requerida:
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
En el ejemplo anterior, el botón "obstruido" inicia el procedimiento para agregar un clúster.
Aquí vale la pena hacer una digresión hacia el trabajo con elementos gráficos en Tk: para varios elementos de entrada de datos (entrada, cuadro combinado, botón de verificación, etc.) se ha introducido un parámetro como variable de texto:
entry $frm.ent_lifetime_limit -textvariable lifetime_limitEsta variable se define en el espacio de nombres global y contiene el valor ingresado actualmente. Aquellos. para obtener el texto ingresado del campo, basta con leer el valor correspondiente a la variable (por supuesto, siempre que esté definido al crear el elemento).
El segundo método para recuperar el texto ingresado (para elementos de tipo de entrada) es usar el comando get:
.add.frm.ent_name getAmbos métodos se pueden ver en el código anterior.
Al hacer clic en este botón, en este caso, se inicia el procedimiento RunCommand con la línea de comando generada para agregar un clúster en términos de rac:
/opt/1C/v8.3/x86_64/rac cluster insert --host=localhost --port=1540 --name=dsdsds --expiration-timeout=0 --lifetime-limit=0 --max-memory-size=0 --max-memory-time-limit=0 --security-level=0 --session-fault-tolerance-level=0 --load-balancing-mode=performance --errors-count-threshold=0 --kill-problem-processes=no localhost:1545Ahora llegamos al comando principal, que controla el inicio de rac con los parámetros que necesitamos, también analiza la salida de los comandos en listas y devuelve, si es necesario:
EjecutarComando
proc RunCommand {root par} {
global dir rac_cmd cluster work_list_row_count agent_user agent_pwd cluster_user cluster_pwd
puts "$rac_cmd $par"
set work_list_row_count 0
# открываем канал в неблокирующем режиме
# $rac - команда с полным путём
# $par - сформированные ключи запуска и опции
set pipe [open "|$rac_cmd $par" "r"]
try {
set lst ""
set l ""
# вывод команды добавляем в список списков
while {[gets $pipe line]>=0} {
#puts $line
if {$line eq ""} {
lappend l $lst
set lst ""
} else {
lappend lst [string trim $line]
}
}
close $pipe
return $l
} on error {result options} {
# Запуск обработчика ошибок
ErrorParcing $result $options
return ""
}
}Luego de ingresar los datos del servidor principal, se agregarán al árbol, para esto, en el procedimiento Agregar: servidor anterior, el siguiente código es responsable:
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"Ahora, al hacer clic en el nombre del servidor en el árbol, obtenemos una lista de los clústeres administrados por ese servidor, y al hacer clic en un clúster, obtenemos una lista de los elementos del clúster (servidores, bases de datos, etc.). Esto se implementa en el procedimiento TreePress (archivo lib/function.tcl):
proc TreePress {tree} {
global host server active_cluster infobase
# определяем выделенный элемент
set id [$tree selection]
# устанавливаем нужные глобальные переменные
SetGlobalVarFromTreeItems $tree $id
# Определяем ключ и значение, т.е. именно тип выбранного элемента
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
# и в зависимости от того что выбрали будет запущена соответствующая процедура
# в пространстве имён Run
Run::$key $tree $host $values
}En consecuencia, se iniciará Run::server para el servidor principal (para un clúster - Run::cluster, para un servidor en funcionamiento - Run::work_server, etc.). Aquellos. el valor de la variable $key es parte del nombre del elemento del árbol especificado por la opción -carné de identidad.
Prestemos atención al procedimiento.
Ejecutar::servidor
proc Run::server {tree host values} {
# получаем список кластеров требуемого сервера
set lst [RunCommand server::$host "cluster list $host"]
if {$lst eq ""} {return}
set l [lindex $lst 0]
#puts $lst
# удаляем лишнее из списка
.frm_work.tree_work delete [ .frm_work.tree_work children {}]
# читаем список
foreach cluster_list $lst {
# Заполняем список полученными значениями
InsertItemsWorkList $cluster_list
# обрабатываем вывод (список) для добавления данных в дерево
foreach i $cluster_list {
#puts $i
set cluster_list [split $i ":"]
if {[string trim [lindex $cluster_list 0]] eq "cluster"} {
set cluster_id [string trim [lindex $cluster_list 1]]
lappend cluster($cluster_id) $cluster_id
}
if {[string trim [lindex $cluster_list 0]] eq "name"} {
lappend cluster($cluster_id) [string trim [lindex $cluster_list 1]]
}
}
}
# добавляем кластеры в дерево
foreach x [array names cluster] {
set id [lindex $cluster($x) 0]
if { [$tree exists "cluster::$id"] == 0 } {
$tree insert "server::$host" end -id "cluster::$id" -text "[lindex $cluster($x) 1]" -values "$id"
# добавляем элементы в кластер
InsertClusterItems $tree $id
}
}
if { [$tree exists "agent_admins::$id"] == 0 } {
$tree insert "server::$host" end -id "agent_admins::$id" -text "Администраторы" -values "$id"
#InsertClusterItems $tree $id
}
}Este procedimiento procesa lo que se recibió del servidor a través del comando RunCommand y agrega todo tipo de cosas al árbol: clústeres, varios elementos raíz (bases, servidores en funcionamiento, sesiones, etc.). Si observa detenidamente, notará una llamada al procedimiento InsertItemsWorkList en su interior. Se utiliza para agregar elementos a una lista gráfica procesando la salida de la utilidad de la consola rac, que previamente se devolvió como una lista a la variable $lst. Esta es una lista de listas que contienen pares de elementos separados por dos puntos.
Por ejemplo, una lista de conexiones de clúster:
svk@svk ~]$ /opt/1C/v8.3/x86_64/rac connection list --cluster=783d2170-56c3-11e8-c586-fc75165efbb2 localhost:1545
connection : dcf5991c-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:49:51
session-number : 0
blocked-by-ls : 0
connection : b993293a-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:48:52
session-number : 0
blocked-by-ls : 0
En forma gráfica se verá así:
El procedimiento anterior selecciona los nombres de los elementos para el encabezado y los datos para completar la tabla:
Insertar elementos lista de trabajo
proc InsertItemsWorkList {lst} {
global work_list_row_count
# установка чередования цвета для строки
if [expr $work_list_row_count % 2] {
set tag dark
} else {
set tag light
}
# разбор строк на пары ключ - значение
foreach i $lst {
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
lappend column_list [string trim $param]
lappend value_list [string trim $value]
}
}
# заполнение таблицы
.frm_work.tree_work configure -columns $column_list -displaycolumns $column_list
.frm_work.tree_work insert {} end -values $value_list -tags $tag
.frm_work.tree_work column #0 -stretch
# установка заголовков
foreach j $column_list {
.frm_work.tree_work heading $j -text $j
}
incr work_list_row_count
}Aquí, en lugar de un simple comando [split $str ":"], que divide la cadena en elementos separados por ":" y devuelve una lista, se utiliza una expresión regular, ya que algunos elementos también contienen dos puntos.
El procedimiento InsertClusterItems (uno de varios similares) simplemente agrega una lista de elementos secundarios con los identificadores correspondientes al árbol del elemento del clúster requerido.
Insertar elementos de clúster
proc InsertClusterItems {tree id} {
set parent "cluster::$id"
$tree insert $parent end -id "infobases::$id" -text "Информационные базы" -values "$id"
$tree insert $parent end -id "servers::$id" -text "Рабочие серверы" -values "$id"
$tree insert $parent end -id "admins::$id" -text "Администраторы" -values "$id"
$tree insert $parent end -id "managers::$id" -text "Менеджеры кластера" -values $id
$tree insert $parent end -id "processes::$id" -text "Рабочие процессы" -values "workprocess-all"
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "sessions-all"
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "blocks-all"
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "connections-all"
$tree insert $parent end -id "profiles::$id" -text "Профили безопасности" -values $id
}
Puede considerar dos opciones más para implementar un procedimiento similar, donde será claramente visible cómo puede optimizar y deshacerse de comandos repetitivos:
En este procedimiento se resuelven de frente las sumas y comprobaciones:
Insertar elementos base
proc InsertBaseItems {tree id} {
set parent "infobase::$id"
if { [$tree exists "sessions::$id"] == 0 } {
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "$id"
}
if { [$tree exists "locks::$id"] == 0 } {
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "$id"
}
if { [$tree exists "connections::$id"] == 0 } {
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "$id"
}
}
Aquí hay un enfoque más correcto:
Insertar elementos de perfil
proc InsertProfileItems {tree id} {
set parent "profile::$id"
set lst {
{dir "Виртуальные каталоги"}
{com "Разрешённые COM-классы"}
{addin "Внешние компоненты"}
{module "Внешние отчёты и обработки"}
{app "Разрешённые приложения"}
{inet "Ресурсы интернет"}
}
foreach i $lst {
append item [lindex $i 0] "::$id"
if { [$tree exists $item] == 0 } {
$tree insert $parent end -id $item -text [lindex $i 1] -values "$id"
}
unset item
}
}La diferencia entre ellos es el uso de un bucle, en el que se ejecutan los comandos repetidos. El enfoque a utilizar queda a discreción del desarrollador.
Hemos cubierto la adición de elementos y la recuperación de datos, ahora es el momento de centrarse en la edición. Dado que, básicamente, se utilizan los mismos parámetros para editar y agregar (a excepción de la base de información), se utilizan los mismos formularios de diálogo. El algoritmo para llamar a procedimientos de suma tiene este aspecto:
Agregar::$clave->Agregarnivelsuperior
Y para editar así:
Editar::$clave->Agregar::$clave->AgregarNivelSuperior
Por ejemplo, tomemos la edición de un clúster, es decir. Habiendo hecho clic en el nombre del cluster en el árbol, presione el botón editar en la barra de herramientas (lápiz) y se mostrará el formulario correspondiente en la pantalla:
Editar::clúster
proc Edit::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes active_cluster
agent_user agent_pwd cluster_user cluster_pwd auth
if {$cluster_user ne "" && $cluster_pwd ne ""} {
set auth "--cluster-user=$cluster_user --cluster-pwd=$cluster_pwd"
} else {
set auth ""
}
# рисуем форму для кластера
set frm [Add::cluster $tree $host $values]
# меняем текст на метке
$frm configure -text "Редактирование кластера"
set active_cluster $values
# получаем данные по выделенному кластеру
set lst [RunCommand cluster::$values "cluster info --cluster=$active_cluster $host"]
# заполняем поля
FormFieldsDataInsert $frm $lst
# выключаем поля, редактирование которых запрещено
$frm.ent_host configure -state disable
$frm.ent_port configure -state disable
# переназначаем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster update
--cluster=$active_cluster $auth
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth $host"
$tree delete "cluster::$active_cluster"
Run::server $tree $host ""
destroy .add
}
}Según los comentarios en el código, en principio, todo está claro, excepto que el código del controlador del botón se anula y hay un procedimiento FormFieldsDataInsert que llena los campos con datos e inicializa las variables:
Campos de formularioInserción de datos
proc FormFieldsDataInsert {frm lst} {
foreach i [lindex $lst 0] {
# получаем список параметров и значений
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
# меняем символы
regsub -all -- "-" [string trim $param] "_" entry_name
# заполняем данными
if [winfo exists $frm.ent_$entry_name] {
$frm.ent_$entry_name delete 0 end
$frm.ent_$entry_name insert end [string trim $value """]
}
if [winfo exists $frm.cb_$entry_name] {
global $entry_name
set $entry_name [string trim $value """]
}
# для чекбоксов меняем значения
if [winfo exists $frm.check_$entry_name] {
global $entry_name
if {$value eq "0"} {
set $entry_name no
} elseif {$value eq "1"} {
set $entry_name yes
} else {
set $entry_name $value
}
}
}
}
}
En este procedimiento, surgió otra ventaja de tcl: los valores de otras variables se sustituyen como nombres de variables. Aquellos. Para automatizar el llenado de formularios y la inicialización de variables, los nombres de los campos y las variables corresponden a los interruptores de la línea de comando de la utilidad rac y los nombres de los parámetros de salida del comando con alguna excepción: el guión se reemplaza por un guión bajo. P.ej denegar-trabajos-programados coincide con el campo ent_scheduled_jobs_deny y variable trabajos_programados_denegados.
Los formularios para agregar y editar pueden diferir en la composición de los campos, por ejemplo, al trabajar con una base de información:
Agregar seguridad a la información
Edición de seguridad de la información
En el procedimiento de edición Edit::infobase, se agregan los campos requeridos al formulario, el código es voluminoso, por lo tanto no lo presento aquí.
Por analogía, para otros elementos se implementan procedimientos para agregar, editar y eliminar.
Dado que el funcionamiento de la utilidad implica un número ilimitado de servidores, clusters, bases de información, etc., para determinar qué cluster pertenece a qué servidor o sistema de seguridad de la información se han introducido varias variables globales, cuyos valores se establecen cada uno vez que haces clic en los elementos del árbol. Aquellos. el procedimiento recorre recursivamente todos los elementos principales y establece las variables:
SetGlobalVarFromTreeItems
proc SetGlobalVarFromTreeItems {tree id} {
global host server active_cluster infobase
set parent [$tree parent $id]
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
switch -- $key {
server {set host $values}
work_server {set server $values}
cluster {set active_cluster $values}
infobase {set infobase $values}
}
if {$parent eq ""} {
return
} else {
SetGlobalVarFromTreeItems $tree $parent
}
}
El clúster 1C le permite trabajar con o sin autorización. Hay dos tipos de administradores: administrador del agente del clúster y administrador del clúster. En consecuencia, para un correcto funcionamiento, se introdujeron 4 variables globales más que contienen el nombre de usuario y la contraseña del administrador. Aquellos. si hay una cuenta de administrador en el clúster, se mostrará un cuadro de diálogo para ingresar su nombre de usuario y contraseña, los datos se guardarán en la memoria y se insertarán en cada comando para el clúster correspondiente.
Esta es responsabilidad del procedimiento de manejo de errores.
ErrorParcing
proc ErrorParcing {err opt} {
global cluster_user cluster_pwd agent_user agent_pwd
switch -regexp -- $err {
"Cluster administrator is not authenticated" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Central server administrator is not authenticated" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
"Администратор кластера не аутентифицирован" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Администратор центрального сервера не аутентифицирован" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
(.+) {
tk_messageBox -type ok -icon error -message "$err"
}
}
}Aquellos. Dependiendo de lo que devuelva el comando, la reacción será la correspondiente.
Por el momento, se ha implementado alrededor del 95 por ciento de la funcionalidad, solo queda implementar el trabajo con perfiles de seguridad y probarlo =). Eso es todo. Pido disculpas por la historia arrugada.
El código está disponible tradicionalmente. .
Actualización: terminé de trabajar con perfiles de seguridad. Ahora la funcionalidad está 100% implementada.
Actualización 2: se agregó localización al inglés y ruso, se probó el trabajo en win7
Fuente: habr.com