🥇Mendelejevi tabel kooli informaatikas

(Juhtkaartide kohta)
(Pühendatud Rahvusvahelisele Elementide Perioodilise Tabeli Aastale)
(Viimased täiendused tehtud 8. aprillil 2019. Täienduste loetelu kohe allpool)

(Mendelejevi lill, Allikas)

Mäletan, kuidas me through hani õppisime. See olid kohe kolm tundi: geograafia, loodusteadus ja vene keel. Loodusteaduse tunnis uuriti hani kui hani: millised on selle tiivad, millised on jalad, kuidas ta ujub ja nii edasi. Geograafia tunnis uuriti sama hani kui maakeral elavat olendit: tuli kaardil näidata, kus ta elab ja kus teda pole. Vene keeles õpetas Serafima Petrovna meid kirjutama "u-t-k-a" ja luges midagi hani kohta Brema raamatust. Juhtumisi ütles ta meile, et saksa keeles on hani nii ja prantsuse keeles teistsugune. Tundub, et seda nimetati siis "kompleksseks meetodiks". Ühesõnaga, kõik tuli "juhtumisi".

Venjamin Kaverin, Kaks kaptenit

Viidatud tsitaadis on Veniamin Kaverin meisterlikult välja toonud kompleksse õpimeetodi puudused, kuigi mõnel (võib-olla üsna harval) juhul võivad selle meetodi elemendid olla õigustatud. Üks selline juhtum on D.I. Mendelejevi perioodiline tabel kooli informaatika tundides. Ülesanne programmipõhise automaatika rakendamiseks Mendelejevi tabeli tüüpiliste tegevuste jaoks on õpilastele, kes hakkavad keemiat õppima, üpris arusaadav ja jaguneb paljudeks tüüpilisteks keemilisteks ülesanneteks. Samas võimaldab see informaatika valdkonnas lihtsal viisil demonstreerida juhendkaartide kasutamise meetodit, mida võib laiemas mõttes pidada graafiliseks programmeerimiseks — programmeerimiseks graafiliste elementide abil.

(8. aprill 2019 lisatud täiendused:
Täiendamine 1: kuidas keemiline kalkulaator töötab
Täiendamine 2: filterülesannete näidised)

Alustame põhiküsimusest. Kõige lihtsama variandi korral peaks ekraanil vormiaken näitama Perioodilist tabelit, kus iga ruudus on keemiline sümbol: H — vesinik, He — heelium jne. Kui hiirekursor osutab ruudule, kuvatakse meie vormis erikastis elemendi sümbol ja selle number. Kui kasutaja sel juhul paremklõpsab, kuvatakse teises vormi väljas selle valitud elemendi sümbol ja number.

Ülesannet saab lahendada igas universaalses programmeerimiskeeles. Me kasutame lihtsat ja vana Delphi-7, mis on peaaegu kõigile arusaadav. Kuid enne programmeerimist joonistame kaks pilti, näiteks Photoshopis. Esiteks joonistame Perioodilise tabeli sellisena, nagu me tahame seda programmis näha. Salvestame tulemuse graafikafailina. table01.bmp.

Teise joonise jaoks kasutame esimest. Täidame järk-järgult igast graafikast puhastatud ruudud tabelis ainulaadsete värvidega RGB värvimudelis. R ja G on alati 0 ning B=1 vesiniku jaoks, 2 heeliumi jaoks jne. See joonis on meie juhtkardi, mille salvestame faili nimega. table2.bmp.

Esimene samm graafilise programmeerimise saavutas PhotoShopis oma lõpu. Liigume edasi GUI graafilise programmeerimise poole IDE Delpi-7-s. Selleks avame uue projekti, kuhu peame peamisele vormile paigutama dialooge avava nupu (tableDlg), kus toimub tabeliga töötamine. Seejärel töötame vormiga tableDlg.

Asetame vormile komponendi klassist TImage. Saame Image1. Tuleb märkida, et suurte projektide puhul võivad automaatselt genereeritud nimed, nagu ImageN, kus N , ulatuda mitmekümne või rohkemani — see ei ole parim programmeerimisstiil, ning tuleks anda arusaadavamaid nimesid. Kuid meie väikeses projektis, kus N ei ületa 2, võib jätta ka genereeritud nimed.

Asetame omadusse Image1.Picture faili table01.bmp. Loome Image2 ja laadime sinna meie juhtfunktsiooni kaardi table2.bmp. Samal ajal teeme faili väikseks ja kasutajale nähtamatuks, nagu on näidatud vormi vasakus alumises nurgas. Lisame täiendavaid juhtimiselemente, mille eesmärgid on ilmsed. Teine samm GUI graafilises programmeerimises IDE Delpi-7-s on lõpetatud.

Jätkame kolmandasse etappi — koodi kirjutamisse IDE Delpi-7. Moodul koosneb vaid viiest sündmuste käitlejast: vormi loomine (FormCreate), kursori liikumine ( Image1 (Image1MouseMove), hiire vasaku nupu klikkimine lahtrile (Image1Click) ja dialoogist väljumine nuppude OK (OKBtnClick) või Cancel (CancelBtnClick). Nende käitlejate pealkirjad genereeritakse standardmeetodil IDE kaudu.

Mooduli allikas:

unit tableUnit;
// Aperiodiline tabel keemiliste elementide D.I. Mendelejevi
//
// third112
// https://habr.com/ru/users/third112/
//
// Sisukord
// 1) vormi loomine
// 2) tabeliga töötamine: tähistamine ja valik
// 3) dialoogist väljumine

interface

uses Windows, SysUtils, Classes, Graphics, Forms, Controls, StdCtrls,
  Buttons, ExtCtrls;

const
 size = 104; // elementide arv
 
type
 TtableDlg = class(TForm)
    OKBtn: TButton;
    CancelBtn: TButton;
    Bevel1: TBevel;
    Image1: TImage;  // keemiliste elementide tabel
    Label1: TLabel;
    Image2: TImage;  // juhtimiskaart
    Label2: TLabel;
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject); // vormi loomine
    procedure Image1MouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);                        // ruudu tähistamine
    procedure Image1Click(Sender: TObject); // ruudu valik
    procedure OKBtnClick(Sender: TObject);  // OK
    procedure CancelBtnClick(Sender: TObject); // Tühista
  private
    { Privaatsed deklareerimised }
    TableSymbols : array [1..size] of string [2]; // elementide tähiste massiiv
  public
    { Avalikud deklareerimised }
    selectedElement : string; // valitud element
    currNo : integer;         // praegune elemendi number
  end;

var
  tableDlg: TtableDlg;

implementation

{$R *.dfm}

const
PeriodicTableStr1=
'HHeLiBeBCNOFNeNaMgAlSiPSClArKCaScTiVCrMnFeCoNiCuZnGaGeAsSeBrKrRbSrYZrNbMoTcRuRhPdAgCdInSnSbTeIXeCsBaLa';
PeriodicTableStr2='CePrNdPmSmEuGdTbDyHoErTmYbLu';
PeriodicTableStr3='HfTaWReOsIrPtAuHgTlPbBiPoAtRnFrRaAc';
PeriodicTableStr4='ThPaUNpPuAmCmBkCfEsFmMdNoLrKu ';

// vormi loomine  ==================================================

procedure TtableDlg.FormCreate(Sender: TObject);
// vormi loomine
var
  s : string;
  i,j : integer;
begin
  currNo := 0;
// elementide tähiste massiivi initsialiseerimine:
  s := PeriodicTableStr1+ PeriodicTableStr2+PeriodicTableStr3+PeriodicTableStr4;
  j := 1;
  for i :=1 to size do
   begin
     TableSymbols [i] := s[j];
     inc (j);
     if s [j] in ['a'..'z'] then
      begin
        TableSymbols [i] := TableSymbols [i]+ s [j];
        inc (j);
      end; // if s [j] in
   end; // for i :=1
end; // FormCreate ____________________________________________________

// tabeliga töötamine: tähistamine ja valik =========================================

procedure TtableDlg.Image1MouseMove(Sender: TObject; Shift: TShiftState;
  X, Y: Integer);
// ruudu tähistamine
var
  sl : integer;
begin
  sl := GetBValue(Image2.Canvas.Pixels [x,y]);
  if sl in [1..size] then
   begin
    Label1.Caption := intToStr (sl)+ ' '+TableSymbols [sl];
    currNo := sl;
   end
  else
    Label1.Caption := 'Vali element:';
end; // Image1MouseMove   ____________________________________________________

procedure TtableDlg.Image1Click(Sender: TObject);
begin
  if currNo <> 0 then
   begin
    selectedElement := TableSymbols [currNo];
    Label2.Caption := intToStr (currNo)+ ' '+selectedElement+ ' valitud';
    Edit1.Text := selectedElement;
   end;
end; // Image1Click  ____________________________________________________

// dialoogist väljumine  ==================================================

procedure TtableDlg.OKBtnClick(Sender: TObject);
begin
    selectedElement := Edit1.Text;
    hide;
end;  // OKBtnClick ____________________________________________________

procedure TtableDlg.CancelBtnClick(Sender: TObject);
begin
  hide;
end;  // CancelBtnClick ____________________________________________________

end.

Meie versioonis kasutasime 104 elemendiga tabelit (konstant. size). Ilmselgelt võib see suurus suureneda. Elementide tähised (keemilised sümbolid) kirjutatakse massiivi TableSymbols. Kuid lähtudes koodi kompaktsusest tundub mõistlikud esitada nende tähiste järjestus stringi konstantidena PeriodicTableStr1,…, PeriodicTableStr4, et programmi loomise sündmuse korral jaotaks see tähised ise massiivi elementide vahel. Iga elemendi tähis koosneb ühest või kahest ladina tähest, kusjuures esimene täht on suur ja teine (kui see on olemas) väike. See lihtne reegel rakendatakse massiivi laadimise ajal. Seega õnnestub tähiste järjestus salvestada kokkutõmmatud kujul ilma tühikuta. Järjestuse jagamine neljaks osaks (konstantideks PeriodicTableStr1,…, PeriodicTableStr4) on tingitud lähtest koodi lugemise mugavuse pärast, kuna liiga pikk rida ei pruugi ekraanile täielikult mahtuda.

Hiirekursoriga navigeerimise sündmuse korral Image1 selle sündmuse Image1MouseMove käsitleja määrab juhtkaartide pikseli sinise komponendi väärtuse. Image2 kursorikoordinaatide jaoks. Ehitatud Image2 see väärtus on elemendi number, kui kursor asub rakus; null, kui see on piiril, ja 255 muudel juhtudel. Ülejäänud programmis teostatavad toimingud on triviaalset laadi ja ei vaja lisaselgitusi.

Lisaks eespool mainitud programmeerimisstiilidele tasub mainida ka kommentaaride stiili. Rangelt öeldes on arutatud kood nii väike ja lihtne, et kommentaarid ei tundu eriti vajalikud. Kuid need on lisatud osaliselt ka metoodiliste kaalutluste tõttu — lühikood võimaldab mõningaid üldisi järeldusi visuaalselt selgemini esitada. Esitatud koodis on deklareeritud üks klass (TtableDlg). Selle klassi meetodeid saab vahetada ning see ei mõjuta programmi toimimist, kuid võib mõjutada selle loetavust. Näiteks kujutame ette järjestust:

OKBtnClick, Image1MouseMove, FormCreate, Image1Click, CancelBtnClick.

Võib-olla pole see väga märgatav, kuid lugemine ja mõistmine muutub veidi keerukamaks. Kui meetodeid ei ole viis, vaid kümneid kordi rohkem ja sektsioonis rakendamine Neil on täiesti erinev järjestus, kui klasside kirjeldustes, siis kaos suureneb vaid. Seetõttu, kuigi rangelt tõestada on keeruline ja isegi võib-olla võimatu, saab siiski loota, et täiendava korra loomine parandab koodi loetavust. Seda täiendavat korda soodustab loogiline rühmitamine mitmest meetodist, mis teevad sarnaseid ülesandeid. Iga rühmale tasub anda pealkiri, näiteks:

// работа с таблицей: указание и выбор

Need pealkirjad tasuks kopeerida mooduli algusesse ja vormistada sisukorrana. Teatud piisavalt pikkade moodulite puhul pakuvad sellised sisukorrad täiendavaid navigeerimisvõimalusi. Samuti pika meetodi, protseduuri või funktsiooni kehas tasub esiteks märkida selle keha lõpp:

end; // FormCreate

ja teiseks, harunemiste operaatorites programmiklambritega begin – end, märkida operaator, millele sulgev klamber kuulub:

      end; // if s [j] in
   end; // for i :=1
end; // FormCreate

Gruppide pealkirjade ja meetodite kehade lõppude eristamiseks saab lisada ridu, mis ületavad enamikku operaatorite pikkusest ja koosnevad näiteks sümbolitest «=» ja «_» vastavalt.
Siiski tuleb märkida: meil on siin liiga lihtne näide. Kui meetodi kood ei mahu ühele ekraanile, võib kuue järjestikku lõpu mõistmine ja koodi muutmine osutuda keeruliseks. Mõnedes vanades kompilaatorites, näiteks Pascal 8000 IBM 360/370 jaoks, trükiti vasakule lehekohta teenindava kolonni kujul

B5
…
E5

See tähendas, et sulgev programmiline sulg real E5 vastab avavale sulule real B5.

Muidugi on programmeerimise stiil väga subjektiivne teema, seetõttu tuleks siin välja toodud ideid võtta pigem mõtteainena. Kahele piisavalt kogenud programmeerijale, kellel on aastatepikkuse töö jooksul välja kujunenud erinevad harjumused, võib olla väga keeruline omavahel leppida. Teine asi on noor programmeerija, kellel pole veel olnud võimalust oma stiili kujundada. Arvan, et sellisel juhul peaks õpetaja vähemalt edastama oma õpilastele lihtsa, kuid neile mitte ilmse mõtte, et programmi edu sõltub suuresti selle lähtekoodi kirjutamise stiilist. Õpilane võib mitte järgida soovitatud stiili, kuid olgu vähemalt teema, kas „ülejäänud” tegevusi oleks vaja, et lähtekoodi vormistamist parandada.

Tagasi meie peamise ülesande juurde Perioodilisest tabelist: edasine areng võib toimuda erinevates suundades. Üks suund on viidatud: hiirekursori liikudes tabeli lahtrile avaneb infokast, mis sisaldab täiendavaid andmeid antud elemendi kohta. Edasine areng — filtrid. Näiteks, sõltuvalt infokasti seadetest on saadaval ainult: kõige olulisemad füüsikalis-keemilised andmed, teave avastamise ajaloost, teave levikust looduses, loetelu olulisematest ühenditest (kuhu antud element kuulub), füsioloogilised omadused, nimed võõrkeeles jne. Kavatsemiseks Kaverini 'kube' meeles pidades, millega see artikkel algab, võib öelda, et selle programmi sellise arengu korral saame täieliku õpikute kompleksi loodusteadustes: lisaks infotehnoloogiale, füüsikale ja keemiale — bioloogia, majandusgeograafia, teadushistory ja isegi võõrkeeled.

Kuid kohalik andmebaas pole piiriks. Programm ühendub loomulikult Internetiga. Kui element valitakse, avaneb link ja brauseris kuvatakse selle elemendi kohta Wikipedia artikkel. Wikipedia, nagu teada, ei ole autoriteetne allikas. Võib viidata autoriteetsetele allikatele, nagu keemiaraamatud, BSE, refereerivad ajakirjad, teha otsingupäringud selle elemendi kohta jne. Seega saavad õpilased teostada lihtsaid, kuid sisukaid ülesandeid andmebaasi ja Interneti teemadel.

Lisaks eraldi elemendi päringutele saab luua funktsiooni, mis tähistab näiteks erinevate värvidega tabeli lahtrid, mis vastavad teatud kriteeriumidele. Näiteks metallid ja mitte metallid. Või lahtrid, mida kohalik keemiatehas veehoidlatesse suunab.

Samuti saab rakendada märkmiku- ja korraldaja funktsioone. Näiteks esile tõsta tabelis elemendid, mis kuuluvad eksamisse. Seejärel tähistada elemendid, mida õpilane on eksamiks valmistudes õppinud/kordnud.

Näiteks üks tüüpiline kooli keemia ülesanne:

Antud on 10 g kriiti. Kui palju soolhappe lahust tuleks võtta, et see kriit täielikult lahustada?

Selle ülesande lahendamiseks tuleb kirja panna keemiline reaktsioon ja paika panna koefitsiendid, siis arvutada kaltsiumkarbonaadi ja vesinikkloriidi molekulmassid, ning seejärel koostada ja lahendada proportsioon. Selle võib arvutada meie põhiprogrammi alusel. Tõsi, tuleb arvestada ka, et hape peaks olema piisavas koguses ja mõistlikus kontsentratsioonis, kuid see puudutab juba keemiat, mitte informaatikat.
Täiendamine 1: kuidas keemiline kalkulaator töötabAnalüüsime kalkulaatori tööd antud ülesande näitel kriidi ja „soolhappe” puhul. Alustame reaktsioonist:

CaCO3 + 2HCl = CaCl2 + H2O

Seega näeme, et meil on vaja järgmiste elementide aatomimasse: kaltsiumi (Ca), süsiniku (C), hapniku (O), vesiniku (H) ja kloori (Cl). Lihtsamas vormis saame need massid kirja panna ühes mõõtmemassiivi, mis on määratletud kui

AtomicMass : array [1..size] of real;

kus massiivi indeks vastab elemendi numbrile. Veel vaba kohta vormis tableDlg paigutame kaks välja. Esimeses väljas on algselt kirjas: “Esimene reaktiiv antud”, teises — “Teine reaktiiv leida x”. Märgime välja reagent1, reagent2 vastavalt. Programmi teised täiendused selguvad järgmise kalkulaatori töö näitest.

Sisestame arvuti klaviatuuril: 10 g. Kirje väljale reagent1 muutub: „Esimene reaktiiv on 10 g”. Nüüd sisestame selle reaktiivi valemi ja kalkulaator hakkab arvestama ning näitama selle molekulaarset kaalu sisestamise käigus.

Vasakklahvhiirega klõpsame tabeli lahtril, kus on sümbol Ca. Kirje väljale reagent1 muutub: „Esimene reaktiiv Ca 40,078, antud 10 g.”

Vasakklahvhiirega klõpsame tabeli lahtril, kus on sümbol C. Kirje väljale reagent1 muutub: „Esimene reaktiiv CaC 52,089, antud 10 g.” See tähendab, et kalkulaator liitis kaltsiumi ja süsiniku aatomimassid.

Vasakklahvhiirega klõpsame tabeli lahtril, kus on sümbol O. Kirje väljale reagent1 muutub: „Esimene reaktiiv CaCO 68,088, antud 10 g.” Kalkulaator lisas summeeritud aatomimassi hapniku.

Vasakklahvhiirega klõpsame tabeli lahtril, kus on sümbol O. Kirje väljale reagent1 muutub: „Esimene reaktiiv CaCO2 84,087, antud 10 g.” Kalkulaator lisas veel kord summeeritud aatomimassi hapniku.

Vasakklahvhiirega klõpsame tabeli lahtril, kus on sümbol O. Kirje väljale reagent1 muutub: „Esimene reaktiiv CaCO3 100,086, antud 10 g.” Kalkulaator lisas taas summeeritud aatomimassi hapniku.

Vajutame Enter klaviatuuril. Esimese reaktiivi sisestamine on lõpetatud ja liikume väljale. reagent2. Tõstame esile, et antud näites toome välja minimaalversiooni. Soovi korral on lihtne korraldada sama tüüpi aatomite multiplikatoreid, et näiteks mitte vajutada seitse korda järjest hapniku lahtri peale, kui sisestada krompik (K2Cr2O7) valemit.

Klõpsake hiire vasakut nuppu tabeli lahtril, mille sümbol on H. Tekst väljal reagent2 muutub: "Teine reagens H 1.008 leidke x".

Klõpsake hiire vasakut nuppu tabeli lahtril, mille sümbol on Cl. Tekst väljal reagent2 muutub: "Teine reagens HCl 36.458 leidke x". Kalkulaator lisab vesiniku ja kloori aatomimassid. Ülaltoodud reaktsiooni võrrandis on hüdrokloriidhappe ees koefitsient 2. Seetõttu klõpsake hiire vasakut nuppu väljal reagent2. Molekulmass kahekordistub (kahekordse kliki korral kolmekordistub jne). Tekst väljal reagent2 muutub: "Teine reagens 2HCl 72.916 leidke x".

Pärast Enter'i vajutamist arvuti klaviatuuril. Teise reagensi sisestamine on lõpetatud ja kalkulaator leiab x proportsioonist

Nagu oli vaja leida.

Märkus 1. Saadud proportsiooni tähendus: 100.086 Da kriiti on vaja 72.916 Da hapet, ja 10 g kriidi lahustamiseks on vajalik x hapet.

Märkus 2. Sarnaste ülesannete kogumikud:

Homčenko I. G., Keemiaülesannete ja harjutuste kogumik 2009 (8-11 klass).
Homšenko G. P., Homšenko I. G., Keemiaülesannete kogu sisseastujatele ülikoolidesse, 2019.

Märkus 3. Ülesande lihtsustamiseks võib algversioonis formulari sisestamise lihtsamaks teha ning lihtsalt elementi sümboli lõppu lisada. Siis on kaltsiumkarbonaadi valem järgmine:
CaCOOO
Kuid selline kirjutamine ei meeldi tõenäoliselt keemiaõpetajale. Õige kirjutamine pole keeruline — selleks tuleb lisada massiiv:

formula : array [1..size] of integer;

kus indeks on keemilise elemendi number ja selle indeksi väärtus on aatomite arv (alguses kõik massiivi elemendid nullitakse). Tuleb arvestada aatomite järjekorda valemis, mis on keemias vastu võetud. Näiteks O3CaC ei meeldi samuti enamikule. Võtame vastutuse kasutaja peale. Teeme massiivi:

 formulaOrder : array [1..size] of integer; // võib võtta lühemalt

kuhu salvestame keemilise elemendi numbri selle valemis esinemise indeksina. Aatomite lisamine currNo valemisse:

if formula [currNo]=0 then //see aatom on esmakordselt
 begin
 orderIndex := orderIndex+1; // valemi sisestamise alguses orderIndex=0
 formulaOrder [orderIndex] :=  currNo;
 end;
formula [currNo]:=formula [currNo]+1;

Valemi kirjutamine reale:

s := ''; // tühi string valemiks
for i:=1 to orderIndex do // kõik keemilised sümbolid valemis
begin
 s:=s+TableSymbols [ formulaOrder[i]];// lisame keemilise sümboli
 if formula [formulaOrder[i]]<>1 then //lisame aatomite arvu
 s:=s+ intToStr(formula [formulaOrder[i]]);
end;

Märkus 4. On mõistlik tagada võimalus reagendi valemi alternatiivseks sisestamiseks klaviatuurilt. Sel juhul tuleb rakendada lihtne süntaksianalüsaator.

Tasub märkida, et:

Täna on olemas mitu sada erinevat tabelit, samas kui teadlased pakuvad pidevalt uusi variante. (Vikipeedia)

Õpilased saavad ka selles suunas leidlikkust näidata, rakendades mõnda juba pakutud varianti või proovides luua enda originaali. Näiliselt võiks tunduda, et see on kõige vähem kasulik suund infotehnoloogia tundides. Kuid selle artikli vormis esitatud Perioodiline tabel võib mõnedele õpilastele mitte tuvastada juhtkaartide eeliseid alternatiivse lahenduse osas standardsete nuppudega. TButton. Spiraalsete tabelivormide puhul (kus ruudud on erineva kujuga) näidatakse pakutud lahenduse eeliseid selgemalt.

(Teodor Benfey alternatiivne elementide süsteem, Allikas)

Lisame veel, et mitmetest hetkel olemasolevatest arvutiprogrammidest, mis on seotud Mendelejevi tabeliga, on juttu hiljuti Harbes avaldatud artiklis. artiklis.

Lisand 2: filtrite ülesannete näitedFiltreid saab kasutada näiteks järgmiste ülesannete lahendamiseks:

1) Tõsta tabelis esile kõik elemendid, mis olid tuntud keskaegsel ajal.

2) Tõsta esile kõik elemendid, mis olid tuntud perioodil, mil Perioodilise seaduse avastus toimus.

3) Tõsta esile seitse elementi, mida alkeemikud pidasid metallideks.

4) Tõsta esile kõik elemendid, mis on normaalsetes tingimustes (n.t.) gaasilises olekus.

5) Tõsta esile kõik elemendid, mis on normaalsetes tingimustes vedelal kujul.

6) Tõsta esile kõik elemendid, mis on normaalsetes tingimustes tahkel kujul.

7) Tõsta esile kõik elemendid, mis suudavad pikka aega õhus püsida ilma tähelepanuväärsete muutusteta normaalsetes tingimustes.

8) Tõsta esile kõik metallid, mis lahustuvad soolhappes.

9) Tõsta esile kõik metallid, mis lahustuvad väävelhappes normaalsetes tingimustes.

10) Tõsta esile kõik metallid, mis lahustuvad väävelhappes kuumutamisel.

11) Erakorda kõik metallid, mis lahustuvad lämmastikhappes.

12) Erakorda kõik metallid, mis reageerivad veega aktiivselt normaalses olekus.

13) Erakorda kõik metallid.

14) Erakorda elemendid, mis esinevad looduses laialdaselt.

15) Erakorda elemendid, mis esinevad looduses vabas olekus.

16) Erakorda elemendid, mis mängivad olulist rolli inimese ja loomade organismis.

17) Erakorda elemendid, mida kasutatakse laialdaselt igapäevaelus (kas vabalt või ühendites).

18) Erakorda elemendid, millega töötamine on kõige ohtlikum ja nõuab erilisi ettevaatusmeetmeid ja kaitsevahendeid.

19) Erakorda elemendid, mis vabalt või ühendites kujutavad suurimat ohtu ökoloogiale.

20) Erakorda väärismetallid.

21) Erakorda elemendid, mille hind ületab väärismetallide omi.

Märkused

1) On mõistlik tagada mitme filtri töö. Näiteks, kui aktiveerida filter ülesande lahendamiseks 1 (kõik elemendid, mis olid tuntud keskaegadel) ja 20 (väärismetallid), siis tuvastatakse (näiteks värviga) lahtrid väärismetallidega, mis olid tuntud keskaegadel (näiteks palladium, mis avastati 1803. aastal, ei pruugi olla tuvastatud).

2) On oleks mõistlik tagada, et mitu filtrit töötaksid sel viisil, et iga filter tähistaks lahtrid oma värviga, kuid ei eemaldaks täielikult teise filtri märkust (osa lahtrist ühe värviga, osa teisega). Siis oleks eelneva näite puhul nähtav nende elementide ühisosa, mis kuuluvad keskaega ja väärismetallide alla, samuti elemendid, mis kuuluvad ainult esimesse ja ainult teise hulka. St. väärismetallid, mis olid keskaegadele tundmatud, ja elemendid, mis on tuntud keskaegades, kuid ei ole väärismetallid.

3) On mõistlik pärast filtri rakendamist tagada võimalus tegeleda saadud tulemustega. Näiteks, kui kasutaja on valinud keskaegadele tuntud elemendid, võib ta hiire vasaku nupuga klõpsata valitud elemendil ja avada selle kohta artikli Vikipeedias.

4) On mõistlik tagada, et kasutaja saaks eemaldada valimise, klõpsates hiire vasaku nupuga valitud tabeli lahtril. Näiteks, et eemaldada juba vaadatud elemendid.

5) On mõistlik tagada valitud lahtrite salvestamine failis ning selle faili laadimine automaatse lahtri esiletoomisega. See annab kasutajale võimaluse töö katkestamiseks.

KASUTASIME staatilist eelnevalt määratud juhtimiskaart, kuid on palju olulisi ülesandeid, kus võivad kasutada dünaamilised juhtimiskaardid, mis muutuvad programmi käigus. Näiteks graafide redigeerija, kus kasutaja näitab hiirega aknas tippude asukohti ja joonistab nende vahel servi. Tippu või servi eemaldamiseks peab kasutaja sellele osutama. Kuid kui tipp, mis on tähistatud ringiga, on lihtsalt märgatav, siis on serva, mis on joonistatud õhukese joonega, märkamisega keerulisem. Siin aitab juhtimiskaart, kus tipud ja servad hõivavad suuremaid piirkondi kui nähtavas joonises.

Kompleksse õppimise meetodiga on seotud huvitav kõrvalküsimus: kas see meetod võiks olla kasulik tehisintellekti koolitamisel?

Allikas: habr.com

Perioodiline tabel kooli informaatikas