Doako SQLIndexManager tresnaren berrikuspena

Dakizuenez, indizeek zeregin garrantzitsua dute DBMS batean, beharrezkoak diren erregistroei bilaketa azkarra eskainiz. Horregatik da hain garrantzitsua haiei zerbitzua garaiz ematea. Azterketari eta optimizazioari buruzko material dezente idatzi da, baita Interneten ere. Adibidez, gai hau berriki berrikusi da argitalpen hau.

Ordaindutako eta doako irtenbide asko daude horretarako. Adibidez, prest dago erabakia, indize egokitzaileen optimizazio metodo batean oinarrituta.

Jarraian, ikus dezagun doako erabilgarritasuna SQLIndexManager, egileak AlanDenton.

SQLIndexManager eta beste analogo batzuen arteko desberdintasun tekniko nagusia egileak berak ematen du Hemen и Hemen.

Artikulu honetan, proiektuaren eta software irtenbide honen gaitasun operatiboen kanpoko begirada bat emango dugu.

Erabilgarritasun honi buruz eztabaidatzen Hemen.
Denborarekin, iruzkin eta akats gehienak zuzendu ziren.

Beraz, goazen orain SQLIndexManager erabilgarritasunera bera.

Aplikazioa C# .NET Framework 4.5-n idatzita dago Visual Studio 2017-n eta DevExpress erabiltzen du inprimakietarako:

eta itxura hau du:

Eskaera guztiak fitxategi hauetan sortzen dira:

1. Index
2. Kontsulta
3. QueryEngine
4. Zerbitzariaren informazioa

Datu-base batera konektatzean eta DBMSra kontsultak bidaltzean, aplikazioa honela sinatzen da:

ApplicationName=”SQLIndexManager”

Aplikazioa abiarazten duzunean, leiho modal bat irekiko da konexio bat gehitzeko:

Hemen, sare lokaletan eskuragarri dauden MS SQL Server instantzia guztien zerrenda osoa kargatzeak ez du funtzionatzen oraindik.

Konexio bat ere gehi dezakezu menu nagusiko ezkerreko botoia erabiliz:

Jarraian, DBMSrako kontsulta hauek abiaraziko dira:

1. DBMSari buruzko informazioa lortzea

   SELECT ProductLevel  = SERVERPROPERTY('ProductLevel')
        , Edition       = SERVERPROPERTY('Edition')
        , ServerVersion = SERVERPROPERTY('ProductVersion')
        , IsSysAdmin    = CAST(IS_SRVROLEMEMBER('sysadmin') AS BIT)
   

2. Eskuragarri dauden datu-baseen zerrenda eskuratzea haien propietate laburrekin

   SELECT DatabaseName = t.[name]
        , d.DataSize
        , DataUsedSize  = CAST(NULL AS BIGINT)
        , d.LogSize
        , LogUsedSize   = CAST(NULL AS BIGINT)
        , RecoveryModel = t.recovery_model_desc
        , LogReuseWait  = t.log_reuse_wait_desc
   FROM sys.databases t WITH(NOLOCK)
   LEFT JOIN (
       SELECT [database_id]
            , DataSize = SUM(CASE WHEN [type] = 0 THEN CAST(size AS BIGINT) END)
            , LogSize  = SUM(CASE WHEN [type] = 1 THEN CAST(size AS BIGINT) END)
       FROM sys.master_files WITH(NOLOCK)
       GROUP BY [database_id]
   ) d ON d.[database_id] = t.[database_id]
   WHERE t.[state] = 0
       AND t.[database_id] != 2
       AND ISNULL(HAS_DBACCESS(t.[name]), 1) = 1
   

Goiko scriptak exekutatu ondoren, leiho bat agertuko da MS SQL Server-en aukeratutako instantziaren datu-baseei buruzko informazio laburra duena:

Aipatzekoa da informazio hedatua eskubideetan oinarrituta erakusten dela. Bada administratzailea, ondoren bistatik datuak hauta ditzakezu sys.master_files. Horrelako eskubiderik ez badago, datu gutxiago itzultzen dira, eskaera ez moteltzeko.

Hemen interesgarri diren datu-baseak hautatu eta "Ados" botoian klik egin behar duzu.

Ondoren, honako script hau exekutatuko da hautatutako datu-base bakoitzeko indizeen egoera aztertzeko:

Indizearen egoeraren azterketa

declare @Fragmentation float=15;
declare @MinIndexSize bigint=768;
declare @MaxIndexSize bigint=1048576;
declare @PreDescribeSize bigint=32768;
SET NOCOUNT ON
SET ARITHABORT ON
SET NUMERIC_ROUNDABORT OFF
IF OBJECT_ID('tempdb.dbo.#AllocationUnits') IS NOT NULL
DROP TABLE #AllocationUnits
CREATE TABLE #AllocationUnits (
ContainerID   BIGINT PRIMARY KEY
, ReservedPages BIGINT NOT NULL
, UsedPages     BIGINT NOT NULL
)
INSERT INTO #AllocationUnits (ContainerID, ReservedPages, UsedPages)
SELECT [container_id]
, SUM([total_pages])
, SUM([used_pages])
FROM sys.allocation_units WITH(NOLOCK)
GROUP BY [container_id]
HAVING SUM([total_pages]) BETWEEN @MinIndexSize AND @MaxIndexSize
IF OBJECT_ID('tempdb.dbo.#ExcludeList') IS NOT NULL
DROP TABLE #ExcludeList
CREATE TABLE #ExcludeList (ID INT PRIMARY KEY)
INSERT INTO #ExcludeList
SELECT [object_id]
FROM sys.objects WITH(NOLOCK)
WHERE [type] IN ('V', 'U')
AND ( [is_ms_shipped] = 1 )
IF OBJECT_ID('tempdb.dbo.#Partitions') IS NOT NULL
DROP TABLE #Partitions
SELECT [object_id]
, [index_id]
, [partition_id]
, [partition_number]
, [rows]
, [data_compression]
INTO #Partitions
FROM sys.partitions WITH(NOLOCK)
WHERE [object_id] > 255
AND [rows] > 0
AND [object_id] NOT IN (SELECT * FROM #ExcludeList)
IF OBJECT_ID('tempdb.dbo.#Indexes') IS NOT NULL
DROP TABLE #Indexes
CREATE TABLE #Indexes (
ObjectID         INT NOT NULL
, IndexID          INT NOT NULL
, IndexName        SYSNAME NULL
, PagesCount       BIGINT NOT NULL
, UnusedPagesCount BIGINT NOT NULL
, PartitionNumber  INT NOT NULL
, RowsCount        BIGINT NOT NULL
, IndexType        TINYINT NOT NULL
, IsAllowPageLocks BIT NOT NULL
, DataSpaceID      INT NOT NULL
, DataCompression  TINYINT NOT NULL
, IsUnique         BIT NOT NULL
, IsPK             BIT NOT NULL
, FillFactorValue  INT NOT NULL
, IsFiltered       BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Indexes
SELECT ObjectID         = i.[object_id]
, IndexID          = i.index_id
, IndexName        = i.[name]
, PagesCount       = a.ReservedPages
, UnusedPagesCount = CASE WHEN ABS(a.ReservedPages - a.UsedPages) > 32 THEN a.ReservedPages - a.UsedPages ELSE 0 END
, PartitionNumber  = p.[partition_number]
, RowsCount        = ISNULL(p.[rows], 0)
, IndexType        = i.[type]
, IsAllowPageLocks = i.[allow_page_locks]
, DataSpaceID      = i.[data_space_id]
, DataCompression  = p.[data_compression]
, IsUnique         = i.[is_unique]
, IsPK             = i.[is_primary_key]
, FillFactorValue  = i.[fill_factor]
, IsFiltered       = i.[has_filter]
FROM #AllocationUnits a
JOIN #Partitions p ON a.ContainerID = p.[partition_id]
JOIN sys.indexes i WITH(NOLOCK) ON i.[object_id] = p.[object_id] AND p.[index_id] = i.[index_id] 
WHERE i.[type] IN (0, 1, 2, 5, 6)
AND i.[object_id] > 255
DECLARE @files TABLE (ID INT PRIMARY KEY)
INSERT INTO @files
SELECT DISTINCT [data_space_id]
FROM sys.database_files WITH(NOLOCK)
WHERE [state] != 0
AND [type] = 0
IF @@ROWCOUNT > 0 BEGIN
DELETE FROM i
FROM #Indexes i
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
WHERE ISNULL(dds.[data_space_id], i.DataSpaceID) IN (SELECT * FROM @files)
END
DECLARE @DBID   INT
, @DBNAME SYSNAME
SET @DBNAME = DB_NAME()
SELECT @DBID = [database_id]
FROM sys.databases WITH(NOLOCK)
WHERE [name] = @DBNAME
IF OBJECT_ID('tempdb.dbo.#Fragmentation') IS NOT NULL
DROP TABLE #Fragmentation
CREATE TABLE #Fragmentation (
ObjectID         INT NOT NULL
, IndexID          INT NOT NULL
, PartitionNumber  INT NOT NULL
, Fragmentation    FLOAT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Fragmentation (ObjectID, IndexID, PartitionNumber, Fragmentation)
SELECT i.ObjectID
, i.IndexID
, i.PartitionNumber
, r.[avg_fragmentation_in_percent]
FROM #Indexes i
CROSS APPLY sys.dm_db_index_physical_stats(@DBID, i.ObjectID, i.IndexID, i.PartitionNumber, 'LIMITED') r
WHERE i.PagesCount <= @PreDescribeSize
AND r.[index_level] = 0
AND r.[alloc_unit_type_desc] = 'IN_ROW_DATA'
AND i.IndexType IN (0, 1, 2)
IF OBJECT_ID('tempdb.dbo.#Columns') IS NOT NULL
DROP TABLE #Columns
CREATE TABLE #Columns (
ObjectID     INT NOT NULL
, ColumnID     INT NOT NULL
, ColumnName   SYSNAME NULL
, SystemTypeID TINYINT NULL
, IsSparse     BIT
, IsColumnSet  BIT
, MaxLen       INT
, PRIMARY KEY (ObjectID, ColumnID)
)
INSERT INTO #Columns
SELECT ObjectID     = [object_id]
, ColumnID     = [column_id]
, ColumnName   = [name]
, SystemTypeID = [system_type_id]
, IsSparse     = [is_sparse]
, IsColumnSet  = [is_column_set]
, MaxLen       = [max_length]
FROM sys.columns WITH(NOLOCK)
WHERE [object_id] IN (SELECT DISTINCT i.ObjectID FROM #Indexes i)
IF OBJECT_ID('tempdb.dbo.#IndexColumns') IS NOT NULL
DROP TABLE #IndexColumns
CREATE TABLE #IndexColumns (
ObjectID   INT NOT NULL
, IndexID    INT NOT NULL
, OrderID    INT NOT NULL
, ColumnID   INT NOT NULL
, IsIncluded BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, ColumnID)
)
INSERT INTO #IndexColumns
SELECT ObjectID   = [object_id]
, IndexID    = [index_id]
, OrderID    = CASE WHEN [is_included_column] = 0 THEN [key_ordinal] ELSE [index_column_id] END
, ColumnID   = [column_id]
, IsIncluded = ISNULL([is_included_column], 0)
FROM sys.index_columns ic WITH(NOLOCK)
WHERE EXISTS(
SELECT *
FROM #Indexes i
WHERE i.ObjectID = ic.[object_id]
AND i.IndexID = ic.[index_id]
AND i.IndexType IN (1, 2)
)
IF OBJECT_ID('tempdb.dbo.#Lob') IS NOT NULL
DROP TABLE #Lob
CREATE TABLE #Lob (
ObjectID    INT NOT NULL
, IndexID     INT NOT NULL
, IsLobLegacy BIT
, IsLob       BIT
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #Lob (ObjectID, IndexID, IsLobLegacy, IsLob)
SELECT c.ObjectID
, IndexID     = ISNULL(i.IndexID, 1)
, IsLobLegacy = MAX(CASE WHEN c.SystemTypeID IN (34, 35, 99) THEN 1 END)
, IsLob       = 0
FROM #Columns c
LEFT JOIN #IndexColumns i ON c.ObjectID = i.ObjectID AND c.ColumnID = i.ColumnID
WHERE c.SystemTypeID IN (34, 35, 99)
GROUP BY c.ObjectID
, i.IndexID
IF OBJECT_ID('tempdb.dbo.#Sparse') IS NOT NULL
DROP TABLE #Sparse
CREATE TABLE #Sparse (ObjectID INT PRIMARY KEY)
INSERT INTO #Sparse
SELECT DISTINCT ObjectID
FROM #Columns
WHERE IsSparse = 1
OR IsColumnSet = 1
IF OBJECT_ID('tempdb.dbo.#AggColumns') IS NOT NULL
DROP TABLE #AggColumns
CREATE TABLE #AggColumns (
ObjectID        INT NOT NULL
, IndexID         INT NOT NULL
, IndexColumns    NVARCHAR(MAX)
, IncludedColumns NVARCHAR(MAX)
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #AggColumns
SELECT t.ObjectID
, t.IndexID
, IndexColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 0
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
, IncludedColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 1
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
FROM (
SELECT DISTINCT ObjectID, IndexID
FROM #Indexes
WHERE IndexType IN (1, 2)
) t
SELECT i.ObjectID
, i.IndexID
, i.IndexName
, ObjectName       = o.[name]
, SchemaName       = s.[name]
, i.PagesCount
, i.UnusedPagesCount
, i.PartitionNumber
, i.RowsCount
, i.IndexType
, i.IsAllowPageLocks
, u.TotalWrites
, u.TotalReads
, u.TotalSeeks
, u.TotalScans
, u.TotalLookups
, u.LastUsage
, i.DataCompression
, f.Fragmentation
, IndexStats       = STATS_DATE(i.ObjectID, i.IndexID)
, IsLobLegacy      = ISNULL(lob.IsLobLegacy, 0)
, IsLob            = ISNULL(lob.IsLob, 0)
, IsSparse         = CAST(CASE WHEN p.ObjectID IS NULL THEN 0 ELSE 1 END AS BIT)
, IsPartitioned    = CAST(CASE WHEN dds.[data_space_id] IS NOT NULL THEN 1 ELSE 0 END AS BIT)
, FileGroupName    = fg.[name]
, i.IsUnique
, i.IsPK
, i.FillFactorValue
, i.IsFiltered
, a.IndexColumns
, a.IncludedColumns
FROM #Indexes i
JOIN sys.objects o WITH(NOLOCK) ON o.[object_id] = i.ObjectID
JOIN sys.schemas s WITH(NOLOCK) ON s.[schema_id] = o.[schema_id]
LEFT JOIN #AggColumns a ON a.ObjectID = i.ObjectID AND a.IndexID = i.IndexID
LEFT JOIN #Sparse p ON p.ObjectID = i.ObjectID
LEFT JOIN #Fragmentation f ON f.ObjectID = i.ObjectID AND f.IndexID = i.IndexID AND f.PartitionNumber = i.PartitionNumber
LEFT JOIN (
SELECT ObjectID      = [object_id]
, IndexID       = [index_id]
, TotalWrites   = NULLIF([user_updates], 0)
, TotalReads    = NULLIF([user_seeks] + [user_scans] + [user_lookups], 0)
, TotalSeeks    = NULLIF([user_seeks], 0)
, TotalScans    = NULLIF([user_scans], 0)
, TotalLookups  = NULLIF([user_lookups], 0)
, LastUsage     = (
SELECT MAX(dt)
FROM (
VALUES ([last_user_seek])
, ([last_user_scan])
, ([last_user_lookup])
, ([last_user_update])
) t(dt)
)
FROM sys.dm_db_index_usage_stats WITH(NOLOCK)
WHERE [database_id] = @DBID
) u ON i.ObjectID = u.ObjectID AND i.IndexID = u.IndexID
LEFT JOIN #Lob lob ON lob.ObjectID = i.ObjectID AND lob.IndexID = i.IndexID
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
JOIN sys.filegroups fg WITH(NOLOCK) ON ISNULL(dds.[data_space_id], i.DataSpaceID) = fg.[data_space_id] 
WHERE o.[type] IN ('V', 'U')
AND (
f.Fragmentation >= @Fragmentation
OR
i.PagesCount > @PreDescribeSize
OR
i.IndexType IN (5, 6)
)

Kontsultetan bertan ikus daitekeenez, behin-behineko taulak sarri erabiltzen dira. Hau birkonpilaziorik egon ez dadin egiten da, eta eskema handi baten kasuan, planoa paraleloan sor daiteke datuak txertatzean, taulako aldagaiak hari batean bakarrik txertatzea posible baita.

Goiko script-a exekutatu ondoren, indize-taula duen leiho bat agertuko da:

Beste informazio zehatza ere bistaratu dezakezu hemen, hala nola:

1. datu-basea
2. atal kopurua
3. azken deialdiaren data eta ordua
4. konpresioa
5. fitxategi-taldea

eta abar.
Bozgorailuak berak pertsonaliza daitezke:

Konpondu zutabeko gelaxketan, optimizazioan zer ekintza egingo den hauta dezakezu. Gainera, eskaneatzea amaitzen denean, ekintza lehenetsi bat hautatzen da hautatutako ezarpenetan oinarrituta:

Prozesatzeko nahi diren indizeak hautatu behar dituzu.

Menu nagusia erabiliz, script-a gorde dezakezu (botoi berak indizea optimizatzeko prozesua bera hasten du):

eta gorde taula formatu ezberdinetan (botoi berak indizeak aztertzeko eta optimizatzeko ezarpen zehatzak irekitzeko aukera ematen du):

Informazioa eguneratu dezakezu, lupa ondoan dagoen menu nagusiko ezkerreko hirugarren botoian klik eginez.

Lupa duen botoiak kontuan hartu nahi dituzun datu-baseak hautatzeko aukera ematen du.

Gaur egun ez dago laguntza sistema integralik. Hori dela eta, “?” botoia sakatuz besterik gabe, software-produktuari buruzko oinarrizko informazioa duen leiho modal bat agertuko da:

Goian azaldutako guztiaz gain, menu nagusiak bilaketa-barra du:

Indizea optimizatzeko prozesua abiaraztean:

Egindako ekintzen erregistroa ere ikus dezakezu leihoaren behealdean:

Indizea aztertzeko eta optimizatzeko ezarpen zehatzen leihoan, aukera sotilagoak konfigura ditzakezu:

Eskaera eskaerak:

1. indizeetarako ez ezik, modu desberdinetan ere (oso eguneratu edo partzialki) estatistikak modu selektiboan eguneratzea ahalbidetzen du.
2. datu-base bat hautatzeaz gain, zerbitzari desberdinak ere posible egin dezakezu (oso erosoa da MS SQL Server-en instantzia asko daudenean)
3. Erabileran malgutasun handiagoa lortzeko, komandoak liburutegietan biltzea eta PowerShell komandoetara ateratzea gomendatzen da, adibidez, hemen:
4. dbatools.io/commands
5. ezarpen pertsonalak gordetzeko eta aldatzeko aukera ematen du, bai aplikazio osorako bai, beharrezkoa bada, MS SQL Server-en instantzia bakoitzerako eta datu-base bakoitzeko.
6. 2. eta 4. puntuetatik, datu-baseen eta MS SQL Server instantzien araberako taldeak sortu nahi dituzula ondorioztatzen da, ezarpenak berdinak baitira.
7. bilatu indize bikoiztuak (osoak eta osatugabeak, apur bat desberdinak edo sartutako zutabeetan soilik desberdinak direnak)
8. SQLIndexManager MS SQL Server DBMSrako soilik erabiltzen denez, beharrezkoa da hau izenean islatzea, adibidez, honela: SQLIndexManager MS SQL Serverrako
9. Mugitu GUI ez diren aplikazioaren zati guztiak modulu bereizietara eta berridatzi .NET Core 2.1-n

Idazteko unean, nahien 6. elementua aktiboki garatzen ari da eta dagoeneko laguntza dago bikoiztu osoak eta antzekoak bilatzeko moduan:

iturri

• egokitzapen indizea optimizatzeko metodoa
• SQLIndexManager utilitatea
• SQLIndexManager utilitatearen ikuspegi tekniko laburra
• SQLIndexManager utilitateari buruzko eztabaida
• SQL Index Manager - Doako GUI tresna indizea mantentzeko SQL Server eta Azure-n
• SQL Server Indizeen Azterketa eta Optimizazioa

Iturria: www.habr.com