Surveillance SMS du poids de trois ruches pour 30$

Non, ce n'est pas une offre commerciale, c'est le coût des composants du système que vous pourrez assembler après avoir lu l'article.

Un peu d'historique :

Il y a quelque temps, j'ai décidé d'adopter des abeilles, et elles sont bien arrivées… pour toute une saison, mais elles n'ont pas survécu à l'hiver.
Et cela malgré le fait que je pensais avoir tout fait correctement — alimentation d'automne, isolation avant le froid.
La ruche était en bois classique du système « Dadant » avec 10 cadres en planche de 40 mm.
Mais cet hiver, à cause des « variations » de température, même les apiculteurs expérimentés ont perdu beaucoup plus que d'habitude.

C'est ainsi qu'est venue l'idée d'un système de surveillance de l'état de la ruche.
Après la publication de plusieurs articles sur Habr et des échanges sur le forum des apiculteurs, j'ai décidé de partir du simple vers le complexe.
Le poids est le seul paramètre incontestable, mais en général, les systèmes existants surveillent seulement une ruche « étalon ».
Si quelque chose ne va pas (par exemple, l'envol d'un essaim, maladie des abeilles), les indicateurs deviennent obsolètes.

Il a donc été décidé de suivre l'évolution du poids de trois ruches avec un seul microcontrôleur, et d'ajouter d'autres « fonctionnalités » par la suite.
Au final, j'ai obtenu un système autonome avec environ un mois de fonctionnement sur une seule charge de batterie 18650, envoyant des statistiques une fois par jour.
J'ai essayé de simplifier la construction autant que possible, afin qu'elle puisse être répétée même sans schémas, juste avec des photos.

La logique de fonctionnement est la suivante : lors du premier démarrage/réinitialisation, les valeurs des capteurs installés sous les ruches sont mémorisées dans l'EEPROM.
Ensuite, chaque jour, après le coucher du soleil, le système « s'éveille », lit les données et envoie un SMS avec les variations de poids sur les 24 heures et depuis le moment de l'activation.
De plus, la valeur de la tension de la batterie est transmise, et lorsque cela descend en dessous de 3,5 V, un avertissement est émis concernant la nécessité de recharger, car en dessous de 3,4 V, le module de communication ne s'allume pas, et les indications de poids « s'échappent » déjà.

« Tu te souviens comment tout a commencé. Tout était nouveau et encore une fois. »

Oui, c'est exactement ce jeu d'équipements qui était à l'origine, bien que seuls les capteurs de force et les fils aient survécu jusqu'à la version finale, mais nous y reviendrons.
En réalité, une bobine de câble n'est pas nécessaire, car elle s'est révélée au même prix que 30 m en coupe.

Si le démontage de 3 LED SMD et d'une cinquantaine de points de soudure ordinaires (en sortie) ne vous fait pas peur — alors en avant !

Nous aurons besoin du matériel suivant :

1. Arduino Pro Mini 3V
   Il faut faire attention à la puce du régulateur linéaire — elle doit être de 3.3V — avec les marquages KB 33/LB 33/DE A10 — les Chinois ont commis une erreur, et tout le lot
   de cartes en magasin était équipé de régulateurs de 5 volts et de quartz à 16 MHz.
2. USB-Ttl avec puce CH340 — même un 5 volts peut fonctionner, mais pendant la programmation du microcontrôleur, il faudra déconnecter l'Arduino du module GSM pour ne pas le détruire.
   Les cartes avec puce PL2303 ne fonctionnent pas sous Windows 10.
3. Module de communication GSM Goouu Tech IOT GA-6-B ou AI-THINKER A-6 Mini.
   Pourquoi avoir opté pour lui ? Neoway M590 — un constructeur qui nécessite des manipulations spécifiques, GSM SIM800L — je n'ai pas aimé le niveau logique non standard de 2.8V, qui nécessite un compromis même avec l'Arduino 3 volts.
   De plus, la solution d'AiThinker a une consommation d'énergie minimale (en envoyant des SMS, je n'ai pas vu de courant dépasser 100mA).
4. Antenne GSM GPRS 3DBI (sur la photo ci-dessus — petite plaque rectangulaire avec "queue", à 9 heures)
5. Pack de démarrage d'un opérateur ayant une bonne couverture dans le lieu où se trouve votre ruche.
   Oui, le pack doit d'abord être activé sur un téléphone ordinaire, DÉCONNECTER LA DEMANDE DE PIN lors de l'entrée, et recharger le solde.
   Il existe actuellement de nombreuses options avec des noms comme «Capteur», «IoT» — leur abonnement est légèrement moins cher.
6. Câble dupont 20 cm femelle-femelle — 3 pièces (pour connecter l'Arduino au USB-TTL)
7. 3 pièces HX711 — ADC pour balances
8. 6 capteurs de tension pour un poids maximal de 50 kg
9. 15 mètres de câble téléphonique 4 fils — pour connecter les modules de poids à l'ARDUINO.
10. Photo-résistance GL5528 (il est important qu'elle soit exactement celle-ci, avec une résistance sombre de 1MΩ et une résistance lumineuse de 10-20kΩ) et deux résistances ordinaires de 20kΩ
11. Un morceau de ruban double face "épais" 18x18 mm — pour fixer l'Arduino au module de communication.
12. Support de batterie 18650 et, en fait, la batterie elle-même d'environ 2600mAh.
13. Un peu de cire ou de paraffine (bougie tablette d'aromathérapie) — pour protéger l'HX711 de l'humidité.
14. Un morceau de bois de 25x50x300 mm pour la base des capteurs de tension.
15. Une douzaine de vis avec rondelle de pression 4,2x19 mm pour fixer les capteurs à la base.

La batterie peut être récupérée d'ordinateurs portables — beaucoup moins cher qu'une nouvelle, et sa capacité sera bien plus grande que celle de la chinoise UltraFire — j'ai obtenu 1500 contre 450 (c'est 6800 pour l'UltraFire 😉

En plus, il vous faudra des mains habiles, un fer à souder EPSN-25, de la résine et de l'étain POS-60.

Il y a cinq ans, j'utilisais un fer à souder soviétique avec une pointe en cuivre (je n'ai jamais été convaincu par les stations de soudage — j'ai testé, puis j'ai terminé le circuit avec un EPSN).
Mais après sa défaillance et plusieurs horribles contrefaçons chinoises, la dernière s'appelait Sparta — un objet aussi sévère que son nom, j'ai arrêté
sur un produit avec un thermorégulateur.

Alors, c'est parti !

Pour commencer, retirons deux LED du module GSM (l'endroit où elles se trouvaient est entouré d'un ovale orange).
Insérons la carte SIM avec les contacts vers le circuit imprimé, l'angle biseauté sur la photo est marqué par une flèche.

Nous effectuons ensuite la même procédure pour la LED sur la carte Arduino (ovale à gauche de la puce carrée),
Nous souderons un connecteur à quatre contacts (1),
Prenons deux résistances de 20k, tordons les fils d'un côté, souder la torsion dans le trou du contact A5, les fils restants dans RAW et GND de l'Arduino (2),
Raccourcissons les pattes du photo-résistor à 10mm et le souderons aux bornes GND et D2 de la carte (3).

Il est maintenant temps d'utiliser du ruban adhésif double face — nous le collons sur le support de la carte SIM du module de communication, et par-dessus — l'Arduino — le bouton rouge (argenté) est tourné vers nous et se trouve au-dessus de la SIM.

Nous soudons l'alimentation : le positif du condensateur du module de communication (4) vers le contact RAW de l'Arduino.
En effet, le module de communication nécessite une alimentation de 3,4 à 4,2V, et son contact PWR est relié à un convertisseur abaisseur, donc pour fonctionner avec une batterie Li-ion, la tension doit être fournie en contournant cette partie du circuit.

Dans l'Arduino, en revanche, nous alimentons à travers un régulateur linéaire — pour des courants faibles, la chute de tension est de 0,1V.
En fournissant une tension régulée aux modules HX711, nous évitons d'avoir à les adapter à une tension inférieure (et par la même occasion de générer des bruits supplémentaires en raison de cette opération).

Ensuite, nous soudons des ponts (5) entre les contacts PWR-A1, URX-D4 et UTX-D5, la « terre » GND-G (6) et enfin l'alimentation du support de batterie 18650 (7), nous connectons l'antenne (8).
Prenons maintenant un convertisseur USB-TTL et connectons-le avec des fils Dupont à l'ARDUINO (connecteur 1) aux contacts RXD-TXD, TXD-RXD, GND-GND :

Sur la photo ci-dessus — encore la première version (sur trois) du système, qui a été utilisée pour le débogage.

Et maintenant, nous allons nous éloigner un moment du fer à souder et passer à la partie logicielle.
Je vais décrire la séquence d'actions pour Windows :
Tout d'abord, il est nécessaire de télécharger et d'installer/décompresser le programme Arduino IDE — la version actuelle est 1.8.9, mais j'utilise 1.6.4

Pour plus de simplicité, nous décompressons l'archive dans le dossier C:\arduino-«numéro_de_votre_version», à l'intérieur nous aurons les dossiers /dist, drivers, examples, hardware, java, lib, libraries, reference, tools, ainsi que le fichier exécutable arduino (en plus d'autres).

Nous aurons maintenant besoin d'une bibliothèque pour travailler avec l'ADC HX711 — le bouton vert «clone or download» — télécharger ZIP.
Le contenu (dossier HX711-master) va dans le répertoire C:\arduino-«numéro_de_votre_version»libraries

Et bien sûr, le pilote pour USB-TTL du même github — depuis l'archive décompressée, il suffit de lancer l'installation avec le fichier SETUP.

Ok, lançons et configurons le programme C:\arduino-«numéro_de_votre_version»arduino

Allons dans le menu «Outils» - sélectionnons la carte «Arduino Pro ou Pro Mini», processeur Atmega 328 3.3V 8 MHz, port — numéro autre que le COM1 système (il apparaît après l'installation du pilote CH340 avec l'adaptateur USB-TTL connecté)

Ok, copions le sketch (programme) ci-dessous et collons-le dans la fenêtre de l'Arduino IDE

char phone_no[]="+123456789012"; // Your phone number that receive SMS with counry code 
#include <avr/sleep.h>  // ARDUINO sleep mode library
#include <SoftwareSerial.h> // Sofrware serial library
#include "HX711.h" // HX711 lib. https://github.com/bogde/HX711
#include <EEPROM.h> // EEPROM lib.
HX711 scale0(10, 14);
HX711 scale1(11, 14);
HX711 scale2(12, 14);
#define SENSORCNT 3
HX711 *scale[SENSORCNT];

SoftwareSerial mySerial(5, 4); // Set I/O-port TXD, RXD of GSM-shield  
byte pin2sleep=15; //  Set powerON/OFF pin

float delta00; // delta weight from start
float delta10;
float delta20;
float delta01; // delta weight from yesterday
float delta11;
float delta21;

float raw00; //raw data from sensors on first start
float raw10;
float raw20;
float raw01; //raw data from sensors on yesterday
float raw11;
float raw21;
float raw02; //actual raw data from sensors
float raw12;
float raw22;

word calibrate0=20880; //calibration factor for each sensor
word calibrate1=20880;
word calibrate2=20880;

word daynum=0; //numbers of day after start

int notsunset=0;

boolean setZero=false;

float readVcc() { // Read battery voltage function
  long result1000;
  float rvcc;  
  result1000 = analogRead(A5);
  rvcc=result1000;
  rvcc=6.6*rvcc/1023;
  return rvcc;
}

void setup() { // Setup part run once, at start

  pinMode(13, OUTPUT);  // Led pin init
  pinMode(2, INPUT_PULLUP); // Set pullup voltage
  Serial.begin(9600);
  mySerial.begin(115200); // Open Software Serial port to work with GSM-shield
  pinMode(pin2sleep, OUTPUT);// Itit ON/OFF pin for GSM
  digitalWrite(pin2sleep, LOW); // Turn ON modem
  delay(16000); // Wait for its boot 

scale[0] = &scale0; //init scale
scale[1] = &scale1;
scale[2] = &scale2;

scale0.set_scale();
scale1.set_scale();
scale2.set_scale();

delay(200);

setZero=digitalRead(2);

if (EEPROM.read(500)==EEPROM.read(501) || setZero) // first boot/reset with hiding photoresistor
//if (setZero)
{
raw00=scale0.get_units(16); //read data from scales
raw10=scale1.get_units(16);
raw20=scale2.get_units(16);
EEPROM.put(500, raw00); //write data to eeprom
EEPROM.put(504, raw10);
EEPROM.put(508, raw20);
for (int i = 0; i <= 24; i++) { //blinking LED13 on reset/first boot
    digitalWrite(13, HIGH);
    delay(500);
    digitalWrite(13, LOW);
    delay(500);
  }
}
else {
EEPROM.get(500, raw00); // read data from eeprom after battery change
EEPROM.get(504, raw10);
EEPROM.get(508, raw20);
digitalWrite(13, HIGH); // turn on LED 13 on 12sec. 
    delay(12000);
digitalWrite(13, LOW);
}

delay(200); // Test SMS at initial boot

//
  mySerial.println("AT+CMGF=1");    //  Send SMS part
  delay(2000);
  mySerial.print("AT+CMGS="");
  mySerial.print(phone_no); 
  mySerial.write(0x22);
  mySerial.write(0x0D);  // hex equivalent of Carraige return    
  mySerial.write(0x0A);  // hex equivalent of newline
  delay(2000);
  mySerial.println("INITIAL BOOT OK");
  mySerial.print("V Bat= ");
  mySerial.println(readVcc());
 if (readVcc()<3.5) {mySerial.print("!!! CHARGE BATTERY !!!");}
  delay(500);
  mySerial.println (char(26));//the ASCII code of the ctrl+z is 26
  delay(3000);

//  

raw02=raw00;
raw12=raw10;
raw22=raw20;

//scale0.power_down(); //power down all scales 
//scale1.power_down();
//scale2.power_down();

}

void loop() {

  attachInterrupt(0, NULL , RISING); // Interrupt on high lewel
  set_sleep_mode(SLEEP_MODE_PWR_DOWN); //Set ARDUINO sleep mode
  digitalWrite(pin2sleep, HIGH); // Turn OFF GSM-shield
  delay(2200);
  digitalWrite(pin2sleep, LOW); // Turn OFF GSM-shield
  delay(2200);
  digitalWrite(pin2sleep, HIGH);
  digitalWrite(13, LOW);
  scale0.power_down(); //power down all scales 
  scale1.power_down();
  scale2.power_down();
  delay(90000);
  sleep_mode(); // Go to sleep
  detachInterrupt(digitalPinToInterrupt(0)); // turn off external interrupt

  notsunset=0;
 for (int i=0; i <= 250; i++){
      if ( !digitalRead(2) ){ notsunset++; } //is a really sunset now? you shure?
      delay(360);
   }
  if ( notsunset==0 )
  { 
  digitalWrite(13, HIGH);
  digitalWrite(pin2sleep, LOW); // Turn-ON GSM-shield
  scale0.power_up(); //power up all scales 
  scale1.power_up();
  scale2.power_up();
  raw01=raw02;
  raw11=raw12;
  raw21=raw22;
  raw02=scale0.get_units(16); //read data from scales
  raw12=scale1.get_units(16);
  raw22=scale2.get_units(16);

  daynum++; 
  delta00=(raw02-raw00)/calibrate0; // calculate weight changes 
  delta01=(raw02-raw01)/calibrate0;
  delta10=(raw12-raw10)/calibrate1;
  delta11=(raw12-raw11)/calibrate1; 
  delta20=(raw22-raw20)/calibrate2;
  delta21=(raw22-raw21)/calibrate2;

  delay(16000);
  mySerial.println("AT+CMGF=1");    //  Send SMS part
  delay(2000);
  mySerial.print("AT+CMGS="");
  mySerial.print(phone_no); 
  mySerial.write(0x22);
  mySerial.write(0x0D);  // hex equivalent of Carraige return    
  mySerial.write(0x0A);  // hex equivalent of newline
  delay(2000);
  mySerial.print("Turn ");
  mySerial.println(daynum);
  mySerial.print("Hive1  ");
  mySerial.print(delta01);
  mySerial.print("   ");
  mySerial.println(delta00);
  mySerial.print("Hive2  ");
  mySerial.print(delta11);
  mySerial.print("   ");
  mySerial.println(delta10);
  mySerial.print("Hive3 ");
  mySerial.print(delta21);
  mySerial.print("   ");
  mySerial.println(delta20);

  mySerial.print("V Bat= ");
  mySerial.println(readVcc());
  if (readVcc()<3.5) {mySerial.print("!!! CHARGE BATTERY !!!");}
  delay(500);
  mySerial.println (char(26));//the ASCII code of the ctrl+z is 26
  delay(3000);

  }

}

Dans la première ligne, entre guillemets char phone_no[]="+123456789012"; — au lieu de 123456789012, mettez votre numéro de téléphone avec l'indicatif du pays, sur lequel les SMS arriveront.

Maintenant, appuyons sur le bouton vérifier (au-dessus du chiffre un sur la capture d'écran ci-dessus) — si en bas (sous le trois sur l'écran) il est marqué «Compilation terminée» — alors nous pouvons flasher le microcontrôleur.

Ainsi, l'USB-TTL est connecté à l'ARDUINO et à l'ordinateur, plaçons une batterie chargée dans le support (généralement sur une nouvelle Arduino, la LED clignote avec une fréquence d'une fois par seconde).

Maintenant pour le flashage — entraînons-nous à appuyer sur le bouton rouge (argenté) du microcontrôleur — il faudra le faire strictement à un moment donné !!!
C'est bon ? Appuyons sur le bouton «Téléverser» (au-dessus du deux sur la capture d'écran), et regardons attentivement la ligne en bas de l'interface (sous le trois de l'écran).
Dès que l'inscription «compilation» se transforme en «téléversement» — appuyons sur le bouton rouge (reset) — si tout va bien — des lumières clignoteront joyeusement sur l'adaptateur USB-TTL, et en bas de l'interface, l'inscription «Téléversé»

Maintenant, pendant que nous attendons la réception d'un SMS de test sur le téléphone, je vais vous expliquer comment fonctionne le programme :

Sur la photo — la deuxième version de la plateforme de test.

Au premier démarrage, le système compare les octets numéro 500 et 501 EEPROM s'ils sont égaux, cela signifie que les données de calibration ne sont pas enregistrées, et l'algorithme passe à la section de configuration.
Il en va de même si le photorésistor est ombragé lors de l'allumage (avec un capuchon de stylo) — le mode de réinitialisation des paramètres est activé.

Les capteurs de force doivent déjà être installés sous les ruches, car nous fixons simplement le niveau de référence et mesurons ensuite la variation de poids (pour l'instant, nous obtiendrons juste des zéros, car nous n'avons pas encore connecté quoi que ce soit).
Sur l'Arduino, la LED intégrée de la pin 13 commencera à clignoter.
Si la réinitialisation ne se produit pas, la LED s'allume pendant 12 secondes.
Après cela, un SMS de test est envoyé avec le message «INITIAL BOOT OK» et la tension de la batterie.
Le module de communication est désactivé, et au bout de 3 minutes, la carte Arduino met les cartes ADC HX711 en mode veille et s'endort elle-même.
Ce retard est fait pour éviter de capter des interférences du module GSM en fonctionnement (après désactivation, il émet des perturbations pendant un certain temps).

Ensuite, nous avons une interruption par le photodétecteur sur la deuxième broche (une résistance de tirage positive est activée par la fonction pullup).
Après le déclenchement, l'état du photorésistor est vérifié pendant encore 3 minutes — pour éviter des déclenchements répétés ou faussement positifs.
Il est caractéristique que, sans aucun réglage, le système se déclenche 10 minutes après le coucher astronomique du soleil par temps nuageux et 20 minutes par temps clair.
Oui, pour éviter que le système ne redémarre à chaque activation, le premier module HX711 doit être connecté (broches DT-D10, SCK-A0).

Ensuite, les lectures des capteurs de force sont effectuées, la variation de poids depuis le dernier déclenchement est calculée (le premier nombre sur la ligne après Hive) et depuis la première activation, la tension de la batterie est vérifiée et ces informations sont envoyées sous forme de SMS :

Au fait, avez-vous reçu le SMS ? Félicitations ! Nous sommes à mi-chemin ! Vous pouvez retirer la batterie du support, l'ordinateur ne nous sera plus nécessaire.

À titre de remarque, le centre de contrôle des vols est si compact qu'il peut tenir dans un pot de mayonnaise, dans mon cas, une boîte semi-transparente de taille 30x60x100 mm (pour les cartes de visite) a parfaitement fonctionné.

Oui, le système en veille consomme environ 2,3 mA — à 90 % à cause du module de communication — il ne s'éteint pas complètement, mais passe en mode veille.

Passons à la fabrication des capteurs, pour commencer, nous allons toucher au schéma de disposition des capteurs :

Voici le plan de la ruche - vue de dessus.

Classiquement, 4 capteurs sont installés dans les coins (1, 2, 3, 4)

Nous allons mesurer différemment. Plus précisément même d'une troisième manière. Puisque les gars de BroodMinder font les choses autrement :

Dans cette configuration, les capteurs sont installés aux positions 1 et 2, les points 3 et 4 reposent sur la poutre.
Dans ce cas, les capteurs ne supportent que la moitié du poids.
Oui, cette méthode a une précision inférieure, mais il est difficile d'imaginer que les abeilles construisent tous les cadres avec des « langues » de cire le long d'un seul côté de la ruche.

Donc, je propose de consolider les capteurs au point 5 — cela supprimera le besoin d'écrans pour le système, et en utilisant des ruches légères, un seul capteur suffira.

En somme, deux types de modules sur HX711 ont été testés, deux types de capteurs, et deux variantes de leur connexion — avec un pont de Wheatstone complet (2 capteurs) et avec une partie, où la seconde est complétée par des résistances de 1k avec une tolérance de 0,1%.
Mais cette dernière méthode est indésirable et même déconseillée par les fabricants de capteurs, je vais donc décrire seulement la première.

Ainsi, un seul rucher aura deux capteurs de contrainte et un module HX711, le schéma de câblage est le suivant :

De la carte ADC jusqu'à l'Arduino, il y a 5 mètres de câble téléphonique à 4 fils — nous nous souvenons comment les abeilles détestent les appareils GSM dans la ruche..

En somme, nous laissons des « queues » de 8 cm sur les capteurs, nous dénudons la paire torsadée et tout soudons comme sur la photo ci-dessus.

Avant de commencer la partie menuiserie, mettez la cire / paraffine dans un récipient approprié pour fondre au bain-marie.

Maintenant, prenons notre poutre et la divisons en trois segments de 100 mm.

Ensuite, marquons la rainure longitudinale de 25 mm de large, d'une profondeur de 7 à 8 mm, à l'aide d'une scie et d'un ciseau à bois pour enlever l'excès — cela devrait donner un profil en P.

La cire est-elle chaude ? — plongeons nos cartes ADC dans celle-ci — cela les protégera de l'humidité / de la condensation :

Nous plaçons le tout sur une base en bois (il est nécessaire de le traiter avec un agent antiseptique contre la pourriture) :

Et enfin, fixons les capteurs avec des vis auto-perceuses :

Il y avait aussi une option avec du ruban adhésif bleu, mais pour des raisons d'humanité, je ne la présente pas 😉.

Du côté de l'Arduino, nous faisons ceci :

Nous dénudons nos câbles téléphoniques, torsadons les fils colorés ensemble, puis les étamons.

Après cela, nous soudeons aux contacts de la carte comme sur la photo :

Voilà, maintenant pour la vérification finale, disposons les capteurs par secteurs en cercle, au-dessus — un morceau de contreplaqué, effaçons le contrôleur (mettons la batterie avec un capuchon de stylo posé sur la photodiode).

Le voyant LED sur l'Arduino doit commencer à clignoter et vous devez recevoir un SMS de test.

Ensuite, retirez le capuchon du photoélément et allez remplir une bouteille en plastique de 1,5 litre avec de l'eau.
Placez la bouteille sur du contreplaqué et si quelques minutes se sont écoulées depuis l'allumage, remettez le capuchon sur le photorésistor (en imitant un coucher de soleil).

Dans trois minutes, la LED sur l'Arduino s'allumera, et vous devriez recevoir un SMS avec des valeurs de poids d'environ 1 kg sur toutes les positions.

Félicitations ! Le système est assemblé avec succès !

Si vous faites maintenant fonctionner le système à nouveau, la première colonne de poids affichera des zéros.

Oui, dans des conditions réelles, il est préférable d'orienter le photorésistor verticalement vers le haut.

Voici un petit manuel d'utilisation :

1. Installer les capteurs de pesage sous les parois arrière des ruches (placer une poutre / planche d'environ 30 mm d'épaisseur sous les parois avant)
2. Obscurcir le photorésistor et mettre la batterie — la LED doit clignoter et vous devriez recevoir un SMS de test avec le texte « INITIAL BOOT OK »
3. Placer le bloc central à la distance maximale des ruches, de manière à ce que les fils ne gênent pas lors du travail avec les abeilles.
   Chaque soir, après le coucher du soleil, un SMS sera envoyé avec le changement de poids sur une période de 24 heures et depuis le lancement.
   Lorsque la tension de la batterie atteint 3,5 V, le SMS se terminera par la phrase « !!! CHARGE BATTERY !!! »
   Le temps de fonctionnement avec une batterie de 2600 mAh est d'environ un mois.
   En cas de remplacement de la batterie, les changements de poids journaliers des ruches ne sont pas mémorisés.

UPD AVERTISSEMENT !

DANS DES CONDITIONS DE FAIBLE SIGNAUX, le module GSM augmente sa puissance, ce qui entraîne un REDÉMARRAGE DU SYSTÈME.

Cela a été constaté lors des tests « sur le terrain » (il n'est pas clair pourquoi les utilisateurs des boucliers GSM ne signalent pas de tels problèmes).

Je prépare actuellement un nouveau schéma :

Après vérification réussie, cette publication sera mise à jour.

Electrochauffeur André.

Source : habr.com