Mar is eol duit, tá ról tábhachtach ag innéacsanna i DBMS, ag soláthar cuardach tapa ar na taifid riachtanacha. Sin an fáth go bhfuil sé chomh tábhachtach iad a sheirbhísiú go tráthúil. Scríobhadh go leor ábhar faoi anailís agus barrfheabhsú, lena n-áirítear ar an Idirlíon. Mar shampla, rinneadh athbhreithniú ar an ábhar seo le déanaí i .
Tá go leor réitigh íoctha agus saor in aisce le haghaidh seo. Mar shampla, tá réidh-déanta , bunaithe ar mhodh leas iomlán a bhaint innéacs oiriúnaitheach.
Ansin, déanaimis féachaint ar an bhfóntas saor in aisce , údar ag .
Is é an t-údar féin a thugann an phríomhdhifríocht theicniúil idir SQLIndexManager agus roinnt analógacha eile и .
San Airteagal seo, déanfaimid breathnú ón taobh amuigh ar an tionscadal agus ar chumais oibriúcháin an réitigh bogearraí seo.
Ag plé an áirgiúlacht seo .
Le himeacht ama, ceartaíodh an chuid is mó de na tuairimí agus na fabhtanna.
Mar sin, déanaimis bogadh ar aghaidh anois chuig fóntais SQLIndexManager féin.
Tá an feidhmchlár scríofa i C# .NET Framework 4.5 in Visual Studio 2017 agus úsáideann DevExpress le haghaidh foirmeacha:
agus tá an chuma air:
Gintear gach iarratas sna comhaid seo a leanas:
- innéacs
- Iarratas
- Inneall Ceist
- ServerInfo
Nuair a nasctar le bunachar sonraí agus nuair a sheoltar ceisteanna chuig an DBMS, sínítear an t-iarratas mar seo a leanas:
ApplicationName=”SQLIndexManager”
Nuair a sheolann tú an feidhmchlár, osclófar fuinneog mhódúil chun nasc a chur leis:
Anseo, ní oibríonn sé fós ag luchtú liosta iomlán de na cásanna MS SQL Server atá inrochtana thar líonraí áitiúla.
Is féidir leat nasc a chur leis leis an gcnaipe is faide ar chlé ar an bpríomhroghchlár:
Ansin, seolfar na fiosruithe seo a leanas chuig an DBMS:
- Eolas a fháil faoin DBMS
SELECT ProductLevel = SERVERPROPERTY('ProductLevel') , Edition = SERVERPROPERTY('Edition') , ServerVersion = SERVERPROPERTY('ProductVersion') , IsSysAdmin = CAST(IS_SRVROLEMEMBER('sysadmin') AS BIT) - Faigh liosta de na bunachair shonraí atá ar fáil lena n-airíonna gairid
SELECT DatabaseName = t.[name] , d.DataSize , DataUsedSize = CAST(NULL AS BIGINT) , d.LogSize , LogUsedSize = CAST(NULL AS BIGINT) , RecoveryModel = t.recovery_model_desc , LogReuseWait = t.log_reuse_wait_desc FROM sys.databases t WITH(NOLOCK) LEFT JOIN ( SELECT [database_id] , DataSize = SUM(CASE WHEN [type] = 0 THEN CAST(size AS BIGINT) END) , LogSize = SUM(CASE WHEN [type] = 1 THEN CAST(size AS BIGINT) END) FROM sys.master_files WITH(NOLOCK) GROUP BY [database_id] ) d ON d.[database_id] = t.[database_id] WHERE t.[state] = 0 AND t.[database_id] != 2 AND ISNULL(HAS_DBACCESS(t.[name]), 1) = 1
Tar éis na scripteanna thuas a chur i gcrích, feicfear fuinneog ina mbeidh faisnéis ghairid faoi bhunachair shonraí an shampla roghnaithe de MS SQL Server:
Is fiú a thabhairt faoi deara go dtaispeántar faisnéis leathnaithe bunaithe ar chearta. Má tá , ansin is féidir leat sonraí a roghnú ón dearcadh . Mura bhfuil cearta den sórt sin ann, seoltar níos lú sonraí ar ais ionas nach gcuirfear moill ar an iarratas.
Anseo ní mór duit na bunachair sonraí spéise a roghnú agus cliceáil ar an gcnaipe “OK”.
Ansin, déanfar an script seo a leanas a fhorghníomhú do gach bunachar sonraí roghnaithe chun staid na n-innéacsanna a anailísiú:
Anailís stádais innéacs
declare @Fragmentation float=15;
declare @MinIndexSize bigint=768;
declare @MaxIndexSize bigint=1048576;
declare @PreDescribeSize bigint=32768;
SET NOCOUNT ON
SET ARITHABORT ON
SET NUMERIC_ROUNDABORT OFF
IF OBJECT_ID('tempdb.dbo.#AllocationUnits') IS NOT NULL
DROP TABLE #AllocationUnits
CREATE TABLE #AllocationUnits (
ContainerID BIGINT PRIMARY KEY
, ReservedPages BIGINT NOT NULL
, UsedPages BIGINT NOT NULL
)
INSERT INTO #AllocationUnits (ContainerID, ReservedPages, UsedPages)
SELECT [container_id]
, SUM([total_pages])
, SUM([used_pages])
FROM sys.allocation_units WITH(NOLOCK)
GROUP BY [container_id]
HAVING SUM([total_pages]) BETWEEN @MinIndexSize AND @MaxIndexSize
IF OBJECT_ID('tempdb.dbo.#ExcludeList') IS NOT NULL
DROP TABLE #ExcludeList
CREATE TABLE #ExcludeList (ID INT PRIMARY KEY)
INSERT INTO #ExcludeList
SELECT [object_id]
FROM sys.objects WITH(NOLOCK)
WHERE [type] IN ('V', 'U')
AND ( [is_ms_shipped] = 1 )
IF OBJECT_ID('tempdb.dbo.#Partitions') IS NOT NULL
DROP TABLE #Partitions
SELECT [object_id]
, [index_id]
, [partition_id]
, [partition_number]
, [rows]
, [data_compression]
INTO #Partitions
FROM sys.partitions WITH(NOLOCK)
WHERE [object_id] > 255
AND [rows] > 0
AND [object_id] NOT IN (SELECT * FROM #ExcludeList)
IF OBJECT_ID('tempdb.dbo.#Indexes') IS NOT NULL
DROP TABLE #Indexes
CREATE TABLE #Indexes (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IndexName SYSNAME NULL
, PagesCount BIGINT NOT NULL
, UnusedPagesCount BIGINT NOT NULL
, PartitionNumber INT NOT NULL
, RowsCount BIGINT NOT NULL
, IndexType TINYINT NOT NULL
, IsAllowPageLocks BIT NOT NULL
, DataSpaceID INT NOT NULL
, DataCompression TINYINT NOT NULL
, IsUnique BIT NOT NULL
, IsPK BIT NOT NULL
, FillFactorValue INT NOT NULL
, IsFiltered BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Indexes
SELECT ObjectID = i.[object_id]
, IndexID = i.index_id
, IndexName = i.[name]
, PagesCount = a.ReservedPages
, UnusedPagesCount = CASE WHEN ABS(a.ReservedPages - a.UsedPages) > 32 THEN a.ReservedPages - a.UsedPages ELSE 0 END
, PartitionNumber = p.[partition_number]
, RowsCount = ISNULL(p.[rows], 0)
, IndexType = i.[type]
, IsAllowPageLocks = i.[allow_page_locks]
, DataSpaceID = i.[data_space_id]
, DataCompression = p.[data_compression]
, IsUnique = i.[is_unique]
, IsPK = i.[is_primary_key]
, FillFactorValue = i.[fill_factor]
, IsFiltered = i.[has_filter]
FROM #AllocationUnits a
JOIN #Partitions p ON a.ContainerID = p.[partition_id]
JOIN sys.indexes i WITH(NOLOCK) ON i.[object_id] = p.[object_id] AND p.[index_id] = i.[index_id]
WHERE i.[type] IN (0, 1, 2, 5, 6)
AND i.[object_id] > 255
DECLARE @files TABLE (ID INT PRIMARY KEY)
INSERT INTO @files
SELECT DISTINCT [data_space_id]
FROM sys.database_files WITH(NOLOCK)
WHERE [state] != 0
AND [type] = 0
IF @@ROWCOUNT > 0 BEGIN
DELETE FROM i
FROM #Indexes i
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
WHERE ISNULL(dds.[data_space_id], i.DataSpaceID) IN (SELECT * FROM @files)
END
DECLARE @DBID INT
, @DBNAME SYSNAME
SET @DBNAME = DB_NAME()
SELECT @DBID = [database_id]
FROM sys.databases WITH(NOLOCK)
WHERE [name] = @DBNAME
IF OBJECT_ID('tempdb.dbo.#Fragmentation') IS NOT NULL
DROP TABLE #Fragmentation
CREATE TABLE #Fragmentation (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, PartitionNumber INT NOT NULL
, Fragmentation FLOAT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Fragmentation (ObjectID, IndexID, PartitionNumber, Fragmentation)
SELECT i.ObjectID
, i.IndexID
, i.PartitionNumber
, r.[avg_fragmentation_in_percent]
FROM #Indexes i
CROSS APPLY sys.dm_db_index_physical_stats(@DBID, i.ObjectID, i.IndexID, i.PartitionNumber, 'LIMITED') r
WHERE i.PagesCount <= @PreDescribeSize
AND r.[index_level] = 0
AND r.[alloc_unit_type_desc] = 'IN_ROW_DATA'
AND i.IndexType IN (0, 1, 2)
IF OBJECT_ID('tempdb.dbo.#Columns') IS NOT NULL
DROP TABLE #Columns
CREATE TABLE #Columns (
ObjectID INT NOT NULL
, ColumnID INT NOT NULL
, ColumnName SYSNAME NULL
, SystemTypeID TINYINT NULL
, IsSparse BIT
, IsColumnSet BIT
, MaxLen INT
, PRIMARY KEY (ObjectID, ColumnID)
)
INSERT INTO #Columns
SELECT ObjectID = [object_id]
, ColumnID = [column_id]
, ColumnName = [name]
, SystemTypeID = [system_type_id]
, IsSparse = [is_sparse]
, IsColumnSet = [is_column_set]
, MaxLen = [max_length]
FROM sys.columns WITH(NOLOCK)
WHERE [object_id] IN (SELECT DISTINCT i.ObjectID FROM #Indexes i)
IF OBJECT_ID('tempdb.dbo.#IndexColumns') IS NOT NULL
DROP TABLE #IndexColumns
CREATE TABLE #IndexColumns (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, OrderID INT NOT NULL
, ColumnID INT NOT NULL
, IsIncluded BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, ColumnID)
)
INSERT INTO #IndexColumns
SELECT ObjectID = [object_id]
, IndexID = [index_id]
, OrderID = CASE WHEN [is_included_column] = 0 THEN [key_ordinal] ELSE [index_column_id] END
, ColumnID = [column_id]
, IsIncluded = ISNULL([is_included_column], 0)
FROM sys.index_columns ic WITH(NOLOCK)
WHERE EXISTS(
SELECT *
FROM #Indexes i
WHERE i.ObjectID = ic.[object_id]
AND i.IndexID = ic.[index_id]
AND i.IndexType IN (1, 2)
)
IF OBJECT_ID('tempdb.dbo.#Lob') IS NOT NULL
DROP TABLE #Lob
CREATE TABLE #Lob (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IsLobLegacy BIT
, IsLob BIT
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #Lob (ObjectID, IndexID, IsLobLegacy, IsLob)
SELECT c.ObjectID
, IndexID = ISNULL(i.IndexID, 1)
, IsLobLegacy = MAX(CASE WHEN c.SystemTypeID IN (34, 35, 99) THEN 1 END)
, IsLob = 0
FROM #Columns c
LEFT JOIN #IndexColumns i ON c.ObjectID = i.ObjectID AND c.ColumnID = i.ColumnID
WHERE c.SystemTypeID IN (34, 35, 99)
GROUP BY c.ObjectID
, i.IndexID
IF OBJECT_ID('tempdb.dbo.#Sparse') IS NOT NULL
DROP TABLE #Sparse
CREATE TABLE #Sparse (ObjectID INT PRIMARY KEY)
INSERT INTO #Sparse
SELECT DISTINCT ObjectID
FROM #Columns
WHERE IsSparse = 1
OR IsColumnSet = 1
IF OBJECT_ID('tempdb.dbo.#AggColumns') IS NOT NULL
DROP TABLE #AggColumns
CREATE TABLE #AggColumns (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IndexColumns NVARCHAR(MAX)
, IncludedColumns NVARCHAR(MAX)
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #AggColumns
SELECT t.ObjectID
, t.IndexID
, IndexColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 0
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
, IncludedColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 1
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
FROM (
SELECT DISTINCT ObjectID, IndexID
FROM #Indexes
WHERE IndexType IN (1, 2)
) t
SELECT i.ObjectID
, i.IndexID
, i.IndexName
, ObjectName = o.[name]
, SchemaName = s.[name]
, i.PagesCount
, i.UnusedPagesCount
, i.PartitionNumber
, i.RowsCount
, i.IndexType
, i.IsAllowPageLocks
, u.TotalWrites
, u.TotalReads
, u.TotalSeeks
, u.TotalScans
, u.TotalLookups
, u.LastUsage
, i.DataCompression
, f.Fragmentation
, IndexStats = STATS_DATE(i.ObjectID, i.IndexID)
, IsLobLegacy = ISNULL(lob.IsLobLegacy, 0)
, IsLob = ISNULL(lob.IsLob, 0)
, IsSparse = CAST(CASE WHEN p.ObjectID IS NULL THEN 0 ELSE 1 END AS BIT)
, IsPartitioned = CAST(CASE WHEN dds.[data_space_id] IS NOT NULL THEN 1 ELSE 0 END AS BIT)
, FileGroupName = fg.[name]
, i.IsUnique
, i.IsPK
, i.FillFactorValue
, i.IsFiltered
, a.IndexColumns
, a.IncludedColumns
FROM #Indexes i
JOIN sys.objects o WITH(NOLOCK) ON o.[object_id] = i.ObjectID
JOIN sys.schemas s WITH(NOLOCK) ON s.[schema_id] = o.[schema_id]
LEFT JOIN #AggColumns a ON a.ObjectID = i.ObjectID AND a.IndexID = i.IndexID
LEFT JOIN #Sparse p ON p.ObjectID = i.ObjectID
LEFT JOIN #Fragmentation f ON f.ObjectID = i.ObjectID AND f.IndexID = i.IndexID AND f.PartitionNumber = i.PartitionNumber
LEFT JOIN (
SELECT ObjectID = [object_id]
, IndexID = [index_id]
, TotalWrites = NULLIF([user_updates], 0)
, TotalReads = NULLIF([user_seeks] + [user_scans] + [user_lookups], 0)
, TotalSeeks = NULLIF([user_seeks], 0)
, TotalScans = NULLIF([user_scans], 0)
, TotalLookups = NULLIF([user_lookups], 0)
, LastUsage = (
SELECT MAX(dt)
FROM (
VALUES ([last_user_seek])
, ([last_user_scan])
, ([last_user_lookup])
, ([last_user_update])
) t(dt)
)
FROM sys.dm_db_index_usage_stats WITH(NOLOCK)
WHERE [database_id] = @DBID
) u ON i.ObjectID = u.ObjectID AND i.IndexID = u.IndexID
LEFT JOIN #Lob lob ON lob.ObjectID = i.ObjectID AND lob.IndexID = i.IndexID
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
JOIN sys.filegroups fg WITH(NOLOCK) ON ISNULL(dds.[data_space_id], i.DataSpaceID) = fg.[data_space_id]
WHERE o.[type] IN ('V', 'U')
AND (
f.Fragmentation >= @Fragmentation
OR
i.PagesCount > @PreDescribeSize
OR
i.IndexType IN (5, 6)
)
Mar is léir ó na ceisteanna iad féin, úsáidtear táblaí sealadacha go minic. Déantar é seo ionas nach mbeidh aon recompilations ann, agus i gcás scéime mór, is féidir an plean a ghiniúint go comhthreomhar nuair a chuirtear sonraí isteach, ós rud é nach féidir athróga tábla a chur isteach ach i snáithe amháin.
Tar éis an script thuas a fheidhmiú, feicfear fuinneog le tábla innéacs:
Is féidir leat faisnéis mhionsonraithe eile a thaispeáint anseo freisin, mar shampla:
- bunachar sonraí
- líon na n-alt
- dáta agus am an ghlao deiridh
- comhbhrú
- grúpa comhaid
agus mar sin de.
Is féidir na cainteoirí féin a shaincheapadh:
I gcealla an cholúin Fix, is féidir leat a roghnú cén gníomh a dhéanfar le linn leas iomlán a bhaint. Chomh maith leis sin, nuair a bheidh an scanadh críochnaithe, roghnaítear gníomh réamhshocraithe bunaithe ar na socruithe roghnaithe:
Ní mór duit na hinnéacsanna atá ag teastáil a roghnú le haghaidh próiseála.
Ag baint úsáide as an príomh-roghchlár, is féidir leat an script a shábháil (tosaíonn an cnaipe céanna an próiseas leas iomlán a bhaint innéacs féin):
agus sábháil an tábla i bhformáidí éagsúla ( ceadaíonn an cnaipe céanna duit socruithe mionsonraithe a oscailt chun innéacsanna a anailísiú agus a bharrfheabhsú):
Is féidir leat an fhaisnéis a nuashonrú freisin trí chliceáil ar an tríú cnaipe ar thaobh na láimhe clé sa phríomh-roghchlár in aice leis an ghloine formhéadúcháin.
Ligeann an cnaipe le gloine formhéadúcháin duit na bunachair shonraí atá uait a roghnú lena mbreithniú.
Níl aon chóras cabhrach cuimsitheach ann faoi láthair. Dá bhrí sin, brúigh an cnaipe “?” go simplí a chuirfidh faoi deara fuinneog mhódúil a thaispeáint ina mbeidh faisnéis bhunúsach faoin táirge bogearraí:
Chomh maith le gach rud a thuairiscítear thuas, tá barra cuardaigh sa phríomh-roghchlár:
Agus an próiseas optamaithe innéacs á thosú:
Is féidir leat logáil de na gníomhartha a rinneadh a fheiceáil freisin ag bun na fuinneoige:
I bhfuinneog na socruithe mionsonraithe le haghaidh anailíse innéacs agus barrfheabhsú, is féidir leat roghanna níos caolchúisí a chumrú:
Iarratais ar an iarratas:
- é a dhéanamh indéanta staitisticí a nuashonrú go roghnach, ní hamháin le haghaidh innéacsanna agus freisin ar bhealaí éagsúla (cothrom le dáta go hiomlán nó i bpáirt)
- é a dhéanamh ní hamháin bunachar sonraí a roghnú, ach freastalaithe éagsúla freisin (tá sé seo an-áisiúil nuair a bhíonn go leor cásanna de MS SQL Server ann)
- Ar mhaithe le níos mó solúbthachta in úsáid, moltar na horduithe a fhilleadh i leabharlanna agus iad a aschur chuig orduithe PowerShell, mar a dhéantar, mar shampla, anseo:
- is féidir socruithe pearsanta a shábháil agus a athrú don fheidhmchlár iomlán agus, más gá, do gach ásc de MS SQL Server agus gach bunachar sonraí
- Ó phointí 2 agus 4, leanann sé gur mian leat grúpaí a chruthú de réir bunachair shonraí agus grúpaí de réir cásanna MS SQL Server, a bhfuil na socruithe mar an gcéanna dóibh
- cuardach a dhéanamh ar innéacsanna dúblacha (iomlán agus neamhiomlán, atá beagán difriúil nó difriúil sna colúin atá san áireamh)
- Ós rud é go n-úsáidtear SQLIndexManager le haghaidh MS SQL Server DBMS amháin, is gá é seo a léiriú san ainm, mar shampla, mar seo a leanas: SQLIndexManager le haghaidh MS SQL Server
- Bog gach cuid neamh-GUI den fheidhmchlár isteach i modúil ar leith agus athscríobh iad i .NET Core 2.1
Agus é seo á scríobh, tá mír 6 de na mianta á forbairt go gníomhach agus tá tacaíocht ann cheana féin i bhfoirm dúblaigh iomlána agus comhchosúla a chuardach:
Foinsí
Foinse: will.com