gnuplot 5.0. 4 અક્ષો પર સ્પાઈડરપ્લોટ તે જાતે કરો

લેખ માટે ડેટા વિઝ્યુલાઇઝેશન પર કામ કરતી વખતે, બધા પર સકારાત્મક લેબલ્સ સાથે 4 અક્ષો હોવા જરૂરી બન્યું.

લેખમાંના અન્ય ગ્રાફની જેમ, મેં ઉપયોગ કરવાનું નક્કી કર્યું જીનોપ્લોટ. સૌ પ્રથમ, મેં સત્તાવાર વેબસાઇટ પર જોયું, જ્યાં ઘણા ઉદાહરણો છે. જ્યારે મને યોગ્ય મળ્યું ત્યારે હું ખૂબ જ ખુશ હતો ઉદાહરણ (હું ફાઇલ સાથે થોડું કામ કરીશ અને તે સુંદર હશે, મેં વિચાર્યું).

મેં ઝડપથી કોડની નકલ કરી અને તેને ચલાવી. મને એક ભૂલ મળી. હું તેને શોધી રહ્યો છું. તે બહાર આવ્યું છે કે મારી પાસે એક જૂનો ગનપ્લોટ છે (Version 5.0 patchlevel 3 last modified 2016-02-21) અને તે તે કરી શકતો નથી.

gnuplot ની લવચીકતા વિશે જાણીને, મેં વર્લ્ડ વાઇડ વેબને શોધવાનું શરૂ કર્યું અને સ્ટેકઓવરફ્લો પર ઘણા યોગ્ય ઉદાહરણો મળ્યા (Gnuplot સાથે સ્પાઈડર પ્લોટ પર ડબલ એક્સ-અક્ષ и Gnuplot માં સ્પાઈડર પ્લોટ કેવી રીતે બનાવવો?) અને ગીથબ (gnuplot-radarchart). તેઓ પ્રારંભિક બિંદુ બન્યા.

આગળ, આદેશો સાથેના મારા મેનિપ્યુલેશન્સ નીચેના તરફ દોરી ગયા:

0) અક્ષમ કરો સીમાઓ

unset border

1) 4 શૂન્ય રેખાઓ બનાવો - 2 મુખ્ય અને 2 વધારાની:

set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis

માં શૂન્ય રેખાઓ વિશે થોડાક શબ્દો દસ્તાવેજીકરણ. આ ઑપરેશન તમને અક્ષોને ચિત્રની મધ્યમાં લાવવાની મંજૂરી આપે છે. અને તેમના પર સકારાત્મક ટિક પ્રદર્શિત કરવા માટે વધારાના લોકોની જરૂર છે.

2) કુહાડીઓ પર ટિકનું પ્રદર્શન સેટ કરો:

max = 1.5 # Для гибкости
min = -max
set xtics  axis  0,.5,max in scale 0.5,0.25 mirror norotate  autojustify offset 0.35
set ytics  axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            

કુહાડીઓ પર ટિક સાથે થોડી વધુ સેટિંગ્સ છે.
axis - જ્યાં ટિક્સ સ્થિત હશે, ધરી પર અથવા (સરહદ - સરહદ પર).
ધરી માટે x, જે જમણી તરફ જાય છે 0,.5,max. પ્રથમ નંબર કાઉન્ટડાઉનની શરૂઆત છે, બીજો પગલું છે, ત્રીજો કાઉન્ટડાઉનનો અંત છે. થી પ્રથમ માટે 0, અને બાકીના માટે થી 0.5, જેથી શૂન્ય મૂળમાં દખલ ન કરે.

સંકલન કેન્દ્રમાં શૂન્યનું મિશ્રણ.
બધા અંતરાલો *tics તરીકે રૂપરેખાંકિત 0,.5,max
વિના offset 0.35 માટે xtics

ગોઠવણ scale 0.5,0.25 mirror ધરી પર ખાંચો ઉમેરે છે. જો તમે સંખ્યાઓ સાથે રમો છો, તો તેમનું કદ બદલાશે.
હું ચલો પણ દાખલ કરું છું max, min, જેની મદદથી હું ગ્રાફ અક્ષોની સીમાઓને નિયંત્રિત કરું છું.
ટિક સેટ કરવા પર વધારાની માહિતી વિભાગમાંના દસ્તાવેજોમાં મળી શકે છે એક્સટીક્સ.

3) અક્ષ રેન્જ સેટ કરો:

set xrange  [ min : max ] 
set yrange  [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]

અહીં એ નોંધવું જોઈએ કે 2 અક્ષો થી શરૂ થાય છે min વિસ્તૃતીકરણ અને 2 અક્ષો માટે - સાથે max ઘટાડો.
વિભાગમાં વધારાની માહિતી એક્સરેન્જ.

4) અક્ષોના નામ આપો અને તેમને સુંદર રીતે મૂકો:

set label "H_1" at  0,       max center offset char  2, 0
set label "H_2" at  max+0.1, 0   center offset char -1, 1
set label "H_3" at  0,       min center offset char -2, 0
set label "H_4" at  min,     0   center offset char  0, 1

5) ઇનપુટ ડેટાની રચના
દરેક ગ્રાફમાં 2 કૉલમ છે. રેખા નંબર - અક્ષ નંબર, લૂપ બંધ કરવા માટે પાંચમી રેખા. વિચિત્ર કૉલમ - સંકલન x, પણ - y. એ હકીકતને કારણે કે બધા બિંદુઓ અક્ષો પર સ્થિત છે, પછી જોડીમાંથી (x, y) એક હંમેશા શૂન્ય છે.
તમામ 4 અક્ષો સકારાત્મક હોવા છતાં, કેટલાક ડેટાને કૃત્રિમ રીતે નકારાત્મક અર્ધમાં ખસેડવામાં આવે છે કારણ કે તે મુખ્ય અક્ષો પર સ્થિત છે. x и y.

 0  1  0     1.21
 1  0  1.21  0   
 0 -1  0    -1.06
-1  0 -1.19  0   
 0  1  0     1.21 #Дубликат первой точки

પરિણામ

સંપૂર્ણ કોડ

#!/usr/bin/gnuplot -persist
#файл в кодировке cp1251 чтоб русские буквы отображались в eps

set encoding cp1251
set terminal postscript eps enhanced monochrome size 5cm,5cm
set output "./img/eps/fig2.eps"

unset border
set key at -2, 1.5 font 'LiberationSerif, 23' 
set key left top samplen 4.5

set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis

max = 1.5
min = -max

set xtics  axis  0,.5,max in scale 0.5,0.25 mirror norotate  autojustify offset 0.35 font 'LiberationSerif, 20
set ytics  axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20

set xrange  [ min : max ]
set yrange  [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]

set label "H_1" at  0,       max center offset char  2, 0   font 'LiberationSerif, 23'
set label "H_2" at  max+0.1, 0   center offset char -1, 1   font 'LiberationSerif, 23'
set label "H_3" at  0,       min center offset char -2, 0   font 'LiberationSerif, 23'
set label "H_4" at  min,     0   center offset char  0, 1   font 'LiberationSerif, 23'

set style line 1 linetype 1 pointtype 7 linewidth 3 linecolor black
set style line 2 linetype 2 pointtype 7 linewidth 3 linecolor black

plot 'data.csv' using  1:2 title "1" w lp ls 1 ,
     'data.csv' using  3:4 title "2" w lp ls 2

સોર્સ: www.habr.com