Zabbix માં DFS પ્રતિકૃતિની સરળ દેખરેખ

પરિચય

એકદમ વિશાળ અને વિતરિત ઈન્ફ્રાસ્ટ્રક્ચર કે જે ડેટા સેન્ટર્સ અને બ્રાન્ચ સર્વર્સ વચ્ચે ડેટા રિપ્લિકેશન માટે ડેટાના એક્સેસના સિંગલ પોઈન્ટ તરીકે DFS અને DFSR નો ઉપયોગ કરે છે, આ પ્રતિકૃતિની સ્થિતિનું નિરીક્ષણ કરવાનો પ્રશ્ન ઊભો થાય છે.
યોગાનુયોગ, અમે DFSR નો ઉપયોગ કરવાનું શરૂ કર્યા પછી લગભગ તરત જ, અમે વિવિધ સાધનોના હાલના પ્રાણી સંગ્રહાલયને બદલવા અને ઇન્ફ્રાસ્ટ્રક્ચર મોનિટરિંગને વધુ માહિતીપ્રદ, સંપૂર્ણ અને તાર્કિક સ્વરૂપમાં લાવવાના ધ્યેય સાથે Zabbix અમલમાં મૂકવાનું શરૂ કર્યું. અમે DFS પ્રતિકૃતિને મોનિટર કરવા માટે Zabbix નો ઉપયોગ કરવા વિશે વાત કરીશું.

સૌ પ્રથમ, આપણે તે નક્કી કરવાની જરૂર છે કે DFS પ્રતિકૃતિ વિશે કયો ડેટા તેની સ્થિતિનું નિરીક્ષણ કરવા માટે મેળવવાની જરૂર છે. સૌથી સુસંગત સૂચક બેકલોગ છે. તેમાં એવી ફાઇલો છે કે જે પ્રતિકૃતિ જૂથના અન્ય સભ્યો સાથે સિંક્રનાઇઝ કરવામાં આવી નથી. તમે ઉપયોગિતાનો ઉપયોગ કરીને તેનું કદ જોઈ શકો છો dfsrdiag, DFSR ભૂમિકા સાથે ઇન્સ્ટોલ કરેલું છે. સામાન્ય પ્રતિકૃતિ સ્થિતિમાં, બેકલોગનું કદ શૂન્ય સુધી પહોંચવું જોઈએ. તદનુસાર, બેકલોગમાં મોટી સંખ્યામાં ફાઇલો પ્રતિકૃતિ સાથે સમસ્યાઓ સૂચવે છે.

હવે મુદ્દાની વ્યવહારિક બાજુ વિશે.

Zabbix એજન્ટ દ્વારા બેકલોગના કદનું નિરીક્ષણ કરવા માટે, અમને જરૂર પડશે:

• સ્ક્રિપ્ટ જે આઉટપુટને પાર્સ કરશે dfsrdiag Zabbix ને અંતિમ બેકલોગ કદ મૂલ્યો પ્રદાન કરવા માટે,
• એક સ્ક્રિપ્ટ જે નિર્ધારિત કરશે કે સર્વર પર કેટલા પ્રતિકૃતિ જૂથો છે, તેઓ કયા ફોલ્ડર્સની નકલ કરે છે અને તેમાં અન્ય કયા સર્વર્સ શામેલ છે (અમે દરેક સર્વર માટે આ બધું ઝબ્બિક્સમાં હાથથી દાખલ કરવા માંગતા નથી, બરાબર?),
• મોનિટરિંગ સર્વરમાંથી અનુગામી કૉલિંગ માટે Zabbix એજન્ટ રૂપરેખાંકનમાં આ સ્ક્રિપ્ટોને UserParameter તરીકે ઉમેરવાનું,
• બેકલોગ વાંચવાના અધિકારો ધરાવતા વપરાશકર્તા તરીકે Zabbix એજન્ટ સેવા શરૂ કરવી,
• Zabbix માટે એક નમૂનો, જેમાં જૂથોની શોધ, પ્રાપ્ત ડેટાની પ્રક્રિયા અને તેના પર ચેતવણીઓ જારી કરવાની ગોઠવણી કરવામાં આવશે.

સ્ક્રિપ્ટ પાર્સર

પાર્સર લખવા માટે, મેં વિન્ડોઝ સર્વરના તમામ સંસ્કરણોમાં હાજર સૌથી સાર્વત્રિક ભાષા તરીકે VBS પસંદ કર્યું છે. સ્ક્રિપ્ટનો તર્ક સરળ છે: તે પ્રતિકૃતિ જૂથનું નામ, નકલ કરેલ ફોલ્ડર, અને આદેશ વાક્ય દ્વારા મોકલવા અને પ્રાપ્ત કરનારા સર્વર્સના નામ મેળવે છે. આ પરિમાણો પછી પસાર કરવામાં આવે છે dfsrdiag, અને તેના આઉટપુટના આધારે તે ઉત્પન્ન કરે છે:
ફાઇલોની સંખ્યા - જો બેકલોગમાં ફાઇલોની હાજરી વિશે સંદેશ પ્રાપ્ત થાય છે,
0 — જો બેકલોગ ("કોઈ બેકલોગ") માં ફાઇલોની ગેરહાજરી વિશે સંદેશ પ્રાપ્ત થાય છે,
-1 - જો કોઈ ભૂલ સંદેશ પ્રાપ્ત થાય છે dfsrdiag વિનંતિ ચલાવતી વખતે ("[ERROR]").

get-Backlog.vbs

strReplicationGroup=WScript.Arguments.Item(0)
strReplicatedFolder=WScript.Arguments.Item(1)
strSending=WScript.Arguments.Item(2)
strReceiving=WScript.Arguments.Item(3)

Set WshShell = CreateObject ("Wscript.shell")
Set objExec = WSHshell.Exec("dfsrdiag.exe Backlog /RGName:""" & strReplicationGroup & """ /RFName:""" & strReplicatedFolder & """ /SendingMember:" & strSending & " /ReceivingMember:" & strReceiving)
strResult = ""
Do While Not objExec.StdOut.AtEndOfStream
	strResult = strResult & objExec.StdOut.ReadLine() & "\"
Loop

If InStr(strResult, "No Backlog") > 0 then
	intBackLog = 0
ElseIf  InStr(strResult, "[ERROR]") > 0 Then
    intBackLog = -1
Else
	arrLines = Split(strResult, "\")
	arrResult = Split(arrLines(1), ":")
	intBackLog = arrResult(1)
End If

WScript.echo intBackLog

ડિસ્કવરી સ્ક્રિપ્ટ

Zabbix સર્વર પર હાજર તમામ પ્રતિકૃતિ જૂથોને નિર્ધારિત કરવા અને વિનંતી માટે જરૂરી તમામ પરિમાણો (ફોલ્ડરનું નામ, પડોશી સર્વર્સના નામ) શોધવા માટે, આપણે સૌ પ્રથમ, આ માહિતી મેળવવાની જરૂર છે, અને બીજું, તેને પ્રસ્તુત કરવું પડશે. Zabbix માટે સમજી શકાય તેવા ફોર્મેટમાં. શોધ સાધન જે ફોર્મેટને સમજે છે તે આના જેવું દેખાય છે:

        "data":[
                {
                        "{#GROUP}":"Share1",
                        "{#FOLDER}":"Folder1",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"Server2"}

...

                        "{#GROUP}":"ShareN",
                        "{#FOLDER}":"FolderN",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"ServerN"}]}

અમને જે માહિતીમાં રુચિ છે તે મેળવવાનો સૌથી સહેલો રસ્તો WMI દ્વારા છે, તેને DfsrReplicationGroupConfig ના અનુરૂપ વિભાગોમાંથી બહાર કાઢવો. પરિણામે, એક સ્ક્રિપ્ટનો જન્મ થયો જે WMI ને વિનંતી જનરેટ કરે છે અને જરૂરી ફોર્મેટમાં જૂથો, તેમના ફોલ્ડર્સ અને સર્વર્સની સૂચિને આઉટપુટ કરે છે.

DFSRDiscovery.vbs

dim strComputer, strLine, n, k, i

Set wshNetwork = WScript.CreateObject( "WScript.Network" )
strComputer = wshNetwork.ComputerName

Set oWMIService = GetObject("winmgmts:\" & strComputer & "rootMicrosoftDFS")
Set colRGroups = oWMIService.ExecQuery("SELECT * FROM DfsrReplicationGroupConfig")
wscript.echo "{"
wscript.echo "        ""data"":["
n=0
k=0
i=0
For Each oGroup in colRGroups
  n=n+1
  Set colRGFolders = oWMIService.ExecQuery("SELECT * FROM DfsrReplicatedFolderConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
  For Each oFolder in colRGFolders
    k=k+1
    Set colRGConnections = oWMIService.ExecQuery("SELECT * FROM DfsrConnectionConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
    For Each oConnection in colRGConnections
      i=i+1
      binInbound = oConnection.Inbound
      strPartner = oConnection.PartnerName
      strRGName = oGroup.ReplicationGroupName
      strRFName = oFolder.ReplicatedFolderName
      If oConnection.Enabled = True and binInbound = False Then
        strSendingComputer = strComputer
        strReceivingComputer = strPartner
        strLine1="                {"    
        strLine2="                        ""{#GROUP}"":""" & strRGName & """," 
        strLine3="                        ""{#FOLDER}"":""" & strRFName & """," 
        strLine4="                        ""{#SENDING}"":""" & strSendingComputer & ""","                  
        if (n < colRGroups.Count) or (k < colRGFolders.count) or (i < colRGConnections.Count) then
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """},"
        else
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """}]}"       
        end if		
        wscript.echo strLine1
        wscript.echo strLine2
        wscript.echo strLine3
        wscript.echo strLine4
        wscript.echo strLine5	   
      End If
    Next
  Next
Next

હું સંમત છું, સ્ક્રિપ્ટ કોડની લાવણ્ય સાથે ચમકતી નથી અને તેમાં કેટલીક વસ્તુઓ ચોક્કસપણે સરળ બનાવી શકાય છે, પરંતુ તે તેનું મુખ્ય કાર્ય કરે છે - Zabbix દ્વારા સમજી શકાય તેવા ફોર્મેટમાં પ્રતિકૃતિ જૂથોના પરિમાણો વિશે માહિતી પ્રદાન કરવી.

Zabbix એજન્ટ રૂપરેખાંકન માટે સ્ક્રિપ્ટો ઉમેરી રહ્યા છે

અહીં બધું અત્યંત સરળ છે. એજન્ટ રૂપરેખાંકન ફાઇલના અંતમાં નીચેની લીટીઓ ઉમેરો:

UserParameter=check_dfsr[*],cscript /nologo "C:Program FilesZabbix Agentget-Backlog.vbs" $1 $2 $3 $4
UserParameter=discovery_dfsr[*],cscript /nologo "C:Program FilesZabbix AgentDFSRDiscovery.vbs"

અલબત્ત, જ્યાં અમારી પાસે સ્ક્રિપ્ટો છે ત્યાં અમે પાથને સમાયોજિત કરીએ છીએ. હું તેમને એ જ ફોલ્ડરમાં મૂકું છું જ્યાં એજન્ટ ઇન્સ્ટોલ કરેલું છે.

ફેરફારો કર્યા પછી, Zabbix એજન્ટ સેવા પુનઃપ્રારંભ કરો.

જે હેઠળ Zabbix એજન્ટ સેવા ચાલે છે તે વપરાશકર્તાને બદલવું

દ્વારા માહિતી મેળવવા માટે dfsrdiag, ઉપયોગિતા એવા ખાતા હેઠળ ચલાવવામાં આવવી જોઈએ જે પ્રતિકૃતિ જૂથના સભ્યોને મોકલવા અને પ્રાપ્ત કરવા બંનેના વહીવટી અધિકારો ધરાવે છે. Zabbix એજન્ટ સેવા, સિસ્ટમ એકાઉન્ટ હેઠળ ડિફૉલ્ટ રૂપે ચાલી રહી છે, આવી વિનંતીને ચલાવવા માટે સમર્થ હશે નહીં. મેં ડોમેનમાં એક અલગ એકાઉન્ટ બનાવ્યું છે, તેને જરૂરી સર્વર્સ પર વહીવટી અધિકારો આપ્યા છે, અને આ સર્વર્સ પર તેની હેઠળ ચલાવવા માટે સેવાને ગોઠવી છે.

તમે બીજી રીતે જઈ શકો છો: કારણ કે dfsrdiag, વાસ્તવમાં, સમાન WMI દ્વારા કામ કરે છે, પછી તમે ઉપયોગ કરી શકો છો વર્ણન, વહીવટી અધિકારો જારી કર્યા વિના ડોમેન એકાઉન્ટને તેનો ઉપયોગ કરવાના અધિકારો કેવી રીતે આપવા, પરંતુ જો અમારી પાસે ઘણા પ્રતિકૃતિ જૂથો છે, તો દરેક જૂથને અધિકારો આપવાનું મુશ્કેલ બનશે. જો કે, જો અમે ડોમેન નિયંત્રકો પર ડોમેન સિસ્ટમ વોલ્યુમ પ્રતિકૃતિને મોનિટર કરવા માંગીએ છીએ, તો આ એકમાત્ર સ્વીકાર્ય વિકલ્પ હોઈ શકે છે, કારણ કે મોનિટરિંગ સેવા એકાઉન્ટને ડોમેન એડમિનિસ્ટ્રેટર અધિકારો આપવા એ સારો વિચાર નથી.

મોનીટરીંગ ટેમ્પલેટ

મને મળેલા ડેટાના આધારે, મેં એક નમૂનો બનાવ્યો જે:

• પ્રતિ કલાકે એકવાર પ્રતિકૃતિ જૂથોની સ્વચાલિત શોધ ચલાવે છે,
• દરેક જૂથ માટે દર 5 મિનિટે એકવાર બેકલોગ કદ તપાસે છે,
• ટ્રિગર સમાવે છે જે 100 મિનિટ માટે કોઈપણ જૂથ માટે બેકલોગનું કદ 30 કરતાં વધુ હોય ત્યારે ચેતવણી જારી કરે છે. ટ્રિગરને પ્રોટોટાઇપ તરીકે વર્ણવવામાં આવે છે જે શોધાયેલ જૂથોમાં આપમેળે ઉમેરવામાં આવે છે,
• દરેક પ્રતિકૃતિ જૂથ માટે બેકલોગ કદના ગ્રાફ બનાવે છે.

તમે Zabbix 2.2 માટે ટેમ્પલેટ ડાઉનલોડ કરી શકો છો અહીં.

પરિણામ

Zabbix માં નમૂનાને આયાત કર્યા પછી અને જરૂરી અધિકારો સાથે ખાતું બનાવ્યા પછી, અમારે ફક્ત તે ફાઇલ સર્વર્સ પર સ્ક્રિપ્ટ્સની નકલ કરવાની જરૂર પડશે કે જેને આપણે DFSR માટે મોનિટર કરવા માંગીએ છીએ, તેના પર એજન્ટ રૂપરેખાંકનમાં બે લીટીઓ ઉમેરો અને Zabbix એજન્ટ સેવાને પુનઃપ્રારંભ કરો. , તેને ઇચ્છિત એકાઉન્ટ તરીકે ચલાવવા માટે સેટ કરો. DFSR મોનિટરિંગ માટે અન્ય કોઈ મેન્યુઅલ સેટિંગ્સની જરૂર નથી.

સોર્સ: www.habr.com