ટેલિગ્રામ v 2.0 માંથી Mikrotik સ્ક્રિપ્ટ્સનું દૂરસ્થ સક્રિયકરણ

બધા પાછલી રજા સાથે. આ થીમ વધુ સારી છે મેં 2016 માં જે લખ્યું હતું તેનું સંસ્કરણ અહીં.

સામાન્ય રીતે, ઓપરેશનનો સિદ્ધાંત બદલાયો નથી, માત્ર એટલો જ તફાવત છે કે હવે તે વિલંબ કર્યા વિના તરત જ કાર્ય કરે છે.

અમે સ્ક્રિપ્ટને Mikrotik પર અપલોડ કરીએ છીએ, BotID અને ChatID અમારા પોતાનામાં બદલીએ છીએ અને તેના માટે શેડ્યૂલ બનાવીએ છીએ. સ્ટાર્ટઅપ માટે "સ્ટાર્ટ ટાઇમ" પેરામીટર સેટ કરો (સ્ટાર્ટઅપ વખતે સ્ક્રિપ્ટ ચલાવો.)
અંતરાલ: 00:00:00
બાકીનું બધું જેમ હતું તેમ છે.

ટેલિગ્રામ-v2

:delay 10
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;
:local chatId 0;
:local messageId 0;


:local parse do={
  :local startLoc ([:find $content $variable -1] + [:len $variable] + 2);
  :local commaLoc ([:find $content "," $startLoc] - 1 + 1);
  :local braceLoc ([:find $content "}" $startLoc] - 1 + 1);
  :local endLoc $commaLoc;
  :local startSymbol [:pick $content $startLoc]
  :if ($braceLoc != 0 and ($commaLoc = 0 or $braceLoc < $commaLoc)) do={
    :set endLoc $braceLoc;
  };
  :if ($startSymbol = "{") do={
    :set endLoc ($braceLoc + 1);
  };
  :if ($quotas = true) do={
    :set startLoc ($startLoc + 1);
    :set endLoc ($endLoc - 1);
  }
  :if ($endLoc < $startLoc) do={
    :set endLoc ($startLoc + 1);
  };
  :local message [:pick $content $startLoc $endLoc]
  #:log info $message;
  :return $message;
}


:while ( true ) do={
  :do {
    #:log info "https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60";
    :tool fetch url=("https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60") dst-path="getUpdates";
    :local content [/file get [/file find name=getUpdates] contents] ;
    #:log info $content;
    :if ([:len $content] > 30) do={
      :set messageId ([$parse content=$content variable="update_id"] + 1)
      :local message [$parse content=$content variable="text" quotas=true]
      :local chat [$parse content=$content variable="chat"]
      :local chatId [$parse content=$chat variable="id"]      
      
      :if (($chatId = $myChatID) and ([/system script find name=$message] != "")) do={
        :system script run $message;
      } else={
        :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$chatId&text=$mtIdentity: Unknown command: $message") keep-result=no
      }
    }
  } on-error={}
};

થોડા વર્ષોના ઉપયોગ માટે, એક ભૂલ બહાર આવી હતી, કોઈ અજાણ્યા કારણોસર, નબળા મિક્રોટિક કોઈ કારણોસર સ્ક્રિપ્ટને બંધ કરે છે, વધુ શક્તિશાળી લોકો પર તે બિન-સ્ટોપ કાર્ય કરે છે.

આ હેતુઓ માટે, મેં વોચડોગ ક્રચ ફેંક્યું. અહીં આપણે સ્ક્રિપ્ટનું નામ ઉપર દર્શાવેલ નામમાં બદલીએ છીએ. અને પુનઃપ્રારંભ અંતરાલને 5 મિનિટ પર સેટ કરો. દર 5 મિનિટે, અમારો "વોચ ડોગ" સ્ક્રિપ્ટ તપાસશે, અને જો તે કામ કરતું નથી, તો તે તેને ચલાવશે.

WatchDogT.me

:global scriptname "t.me"
:if ([:len [/system script job find script=$"scriptname"]] > 0) do={
:log info "$scriptname Already Running - killing old script before continuing"
:foreach counter in=[/system script job find script=$"scriptname"] do={
/system script job remove $counter
}
}
/system script run $scriptname

અને ડેઝર્ટ માટે, સ્ક્રિપ્ટ મિક્રોટિક ફોરમમાંથી લેવામાં આવી છે.
લોગમાંથી અમારા કાર્ટમાં મહત્વપૂર્ણ વિષયો મોકલે છે.

સ્ક્રિપ્ટને શેડ્યૂલમાં નાખો અને દર 5 મિનિટે પુનઃપ્રારંભ અંતરાલનો ઉલ્લેખ કરો, BotID અને ChatID ને તમારા પોતાનામાં બદલો.

notify-log

:global lastTime
:global output
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;

:local LogGet [ :toarray [ /log find topics~"critical" || message~"login failure" || message~"[Ff]ailure" ] ] ;
:local LogtLineCount [ :len $LogGet ] ;
if ($LogtLineCount > 0) do={
   :local currentTime "$[ /log get [ :pick $LogGet ($LogtLineCount -1) ] time ]";
   :if ([:len $currentTime] = 10 ) do={
      :set currentTime [ :pick $currentTime 0 10 ];
   }
   :set output "$currentTime - $[/log get [ :pick $LogGet ($LogtLineCount-1) ] message ]";
   :if (([:len $lastTime] < 1) || (([:len $lastTime] > 0) && ($lastTime != $currentTime))) do={
      :set lastTime $currentTime ;
         :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$myChatID&text="$mtIdentity" :  $output") keep-result=no
   }
}

અમને પરિણામ મળે છે:

સોર્સ: www.habr.com