Hoʻohana mamao i nā palapala Mikrotik mai Telegram v 2.0

Hauʻoli lā hoʻomaha belated to everyone. ʻOi aku ka maikaʻi o kēia kumuhana mana o kaʻu i kākau ai i ka makahiki 2016 maanei.

Ma keʻano laulā, ʻaʻole i loli ke kumu o ka hana, ʻo ka ʻokoʻa wale nō ke hana koke ia me ka kali ʻole.

Hoʻouka mākou i ka palapala iā Mikrotik, hoʻololi i ka BotID a me ChatID iā mākou iho a hana i kahi papa manawa no ia. E hoʻonoho i ka "Start Time" parameter i ka hoʻomaka (E holo i ka palapala ma ka hoʻomaka ʻana.)
"Wā manawa": 00:00:00
A i ʻole, ua like nā mea a pau.

Telegram-v2

:delay 10
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;
:local chatId 0;
:local messageId 0;


:local parse do={
  :local startLoc ([:find $content $variable -1] + [:len $variable] + 2);
  :local commaLoc ([:find $content "," $startLoc] - 1 + 1);
  :local braceLoc ([:find $content "}" $startLoc] - 1 + 1);
  :local endLoc $commaLoc;
  :local startSymbol [:pick $content $startLoc]
  :if ($braceLoc != 0 and ($commaLoc = 0 or $braceLoc < $commaLoc)) do={
    :set endLoc $braceLoc;
  };
  :if ($startSymbol = "{") do={
    :set endLoc ($braceLoc + 1);
  };
  :if ($quotas = true) do={
    :set startLoc ($startLoc + 1);
    :set endLoc ($endLoc - 1);
  }
  :if ($endLoc < $startLoc) do={
    :set endLoc ($startLoc + 1);
  };
  :local message [:pick $content $startLoc $endLoc]
  #:log info $message;
  :return $message;
}


:while ( true ) do={
  :do {
    #:log info "https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60";
    :tool fetch url=("https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60") dst-path="getUpdates";
    :local content [/file get [/file find name=getUpdates] contents] ;
    #:log info $content;
    :if ([:len $content] > 30) do={
      :set messageId ([$parse content=$content variable="update_id"] + 1)
      :local message [$parse content=$content variable="text" quotas=true]
      :local chat [$parse content=$content variable="chat"]
      :local chatId [$parse content=$chat variable="id"]      
      
      :if (($chatId = $myChatID) and ([/system script find name=$message] != "")) do={
        :system script run $message;
      } else={
        :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$chatId&text=$mtIdentity: Unknown command: $message") keep-result=no
      }
    }
  } on-error={}
};

Ma hope o ʻelua mau makahiki o ka hoʻohana ʻana, ua ʻike ʻia kahi pōpoki: no kekahi kumu i ʻike ʻole ʻia, hoʻopau ʻo Mikrotik nāwaliwali i ka palapala, akā ma nā mea ikaika loa e hana me ka ʻole o ka pau ʻana.

No kēia mau kumu, ua hoʻolei au i ke koʻokoʻo WatchDog. Maanei mākou e hoʻololi ai i ka inoa o ka palapala i ka mea i hōʻike ʻia ma luna. a hoʻonoho i ka wā hoʻomaka hou i 5 mau minuke. I kēlā me kēia 5 minuke e nānā kā mākou "ʻīlio kiaʻi" i ka palapala a inā ʻaʻole e holo, holo ia.

WatchDogT.me

:global scriptname "t.me"
:if ([:len [/system script job find script=$"scriptname"]] > 0) do={
:log info "$scriptname Already Running - killing old script before continuing"
:foreach counter in=[/system script job find script=$"scriptname"] do={
/system script job remove $counter
}
}
/system script run $scriptname

ʻAe, no ka mea ʻai, ua lawe ʻia ka palapala mai ka forum Mikrotik.
Hoʻouna i nā kumuhana koʻikoʻi mai ka log i kā mākou kaʻa.

Hoʻohui mākou i ka ʻatikala e hoʻonohonoho a kuhikuhi i ka wā hoʻomaka hou i kēlā me kēia 5 mau minuke, hoʻololi iā BotID a me ChatID iā mākou iho.

Notify-log

:global lastTime
:global output
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;

:local LogGet [ :toarray [ /log find topics~"critical" || message~"login failure" || message~"[Ff]ailure" ] ] ;
:local LogtLineCount [ :len $LogGet ] ;
if ($LogtLineCount > 0) do={
   :local currentTime "$[ /log get [ :pick $LogGet ($LogtLineCount -1) ] time ]";
   :if ([:len $currentTime] = 10 ) do={
      :set currentTime [ :pick $currentTime 0 10 ];
   }
   :set output "$currentTime - $[/log get [ :pick $LogGet ($LogtLineCount-1) ] message ]";
   :if (([:len $lastTime] < 1) || (([:len $lastTime] > 0) && ($lastTime != $currentTime))) do={
      :set lastTime $currentTime ;
         :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$myChatID&text="$mtIdentity" :  $output") keep-result=no
   }
}

Loaʻa iā mākou ka hopena:

Source: www.habr.com