इस लेख में, मैं ग्रैडल बिल्डर का उपयोग करके जीथब क्रियाओं के माध्यम से सोनाटाइप मावेन सेंट्रल रिपॉजिटरी के माध्यम से स्क्रैच से जावा कलाकृतियों को प्रकाशित करने की प्रक्रिया पर करीब से नज़र डालना चाहता हूं।

एक जगह सामान्य ट्यूटोरियल की कमी के कारण मैंने इस लेख को लिखने का फैसला किया। सभी सूचनाओं को विभिन्न स्रोतों से टुकड़े-टुकड़े करके एकत्र किया जाना था, इसके अलावा, पूरी तरह से ताज़ा नहीं। कौन परवाह करता है, बिल्ली के नीचे स्वागत है।

सोनाटाइप में रिपॉजिटरी बनाना

पहला कदम सोनाटाइप मावेन सेंट्रल में एक रिपॉजिटरी बनाना है। इसके लिए हम जाते हैं यहां, रजिस्टर करें और एक नया कार्य बनाएं, हमें एक रिपॉजिटरी बनाने के लिए कहें। हम अपने में चलाते हैं ग्रुप परियोजना, प्रोजेक्ट यूआरएल प्रोजेक्ट लिंक और एससीएम यूआरएल संस्करण नियंत्रण प्रणाली का एक लिंक जिसमें परियोजना स्थित है। ग्रुप यहाँ com.example, com.example.domain, com.example.testsupport के रूप में होना चाहिए, और यह आपके github के लिंक के रूप में भी हो सकता है: github.com/yourusername -> io.github.yourusername। किसी भी स्थिति में, आपको इस डोमेन या प्रोफ़ाइल के स्वामित्व को सत्यापित करने की आवश्यकता होगी। यदि आपने एक जीथब प्रोफ़ाइल निर्दिष्ट की है, तो आपको वांछित नाम के साथ एक सार्वजनिक रिपॉजिटरी बनाने के लिए कहा जाएगा।

पुष्टि के कुछ समय बाद, आपकी GroupId बन जाएगी और हम अगले चरण, Gradle कॉन्फ़िगरेशन पर जा सकते हैं।

ग्रेडल को कॉन्फ़िगर करना

लेखन के समय, मुझे ग्रैडल प्लगइन्स नहीं मिले जो कलाकृतियों को प्रकाशित करने में मदद कर सके। यह एकमात्र प्लगइन जो मुझे मिला, हालांकि, लेखक ने इसे और समर्थन देने से इनकार कर दिया। इसलिए, मैंने सब कुछ खुद करने का फैसला किया, क्योंकि ऐसा करना बहुत मुश्किल नहीं है।

पता लगाने वाली पहली बात सोनाटाइप की प्रकाशन के लिए आवश्यकताएं हैं। वे निम्नलिखित हैं:

• सोर्स कोड और JavaDoc की उपलब्धता, यानी। हाजिर होना चाहिए -sources.jar и-javadoc.jar फ़ाइलें। जैसा कि प्रलेखन में कहा गया है, यदि स्रोत कोड या दस्तावेज़ प्रदान करना संभव नहीं है, तो आप एक डमी बना सकते हैं -sources.jar या -javadoc.jar परीक्षा पास करने के लिए अंदर एक साधारण रीडमे के साथ।
• सभी फाइलों पर हस्ताक्षर होने चाहिए GPG/PGPऔर .asc हस्ताक्षर वाली फ़ाइल को प्रत्येक फ़ाइल के लिए शामिल किया जाना चाहिए।
• उपलब्धता pom फ़ाइल
• सही मान groupId, artifactId и version. संस्करण एक मनमाना स्ट्रिंग हो सकता है और इसके साथ समाप्त नहीं हो सकता -SNAPSHOT
• उपस्थिति आवश्यक है name, description и url
• लाइसेंस, डेवलपर्स और संस्करण नियंत्रण प्रणाली के बारे में जानकारी की उपस्थिति

ये बुनियादी नियम हैं जिनका प्रकाशन करते समय पालन किया जाना चाहिए। पूरी जानकारी उपलब्ध है यहां.

हम इन आवश्यकताओं को लागू करते हैं build.gradle फ़ाइल। सबसे पहले, डेवलपर्स, लाइसेंस, संस्करण नियंत्रण प्रणाली के बारे में सभी आवश्यक जानकारी जोड़ें, और परियोजना का url, नाम और विवरण भी सेट करें। आइए इसके लिए एक सरल विधि लिखते हैं:

def customizePom(pom) {
    pom.withXml {
        def root = asNode()

        root.dependencies.removeAll { dep ->
            dep.scope == "test"
        }

        root.children().last() + {
            resolveStrategy = DELEGATE_FIRST

            description 'Some description of artifact'
            name 'Artifct name'
            url 'https://github.com/login/projectname'
            organization {
                name 'com.github.login'
                url 'https://github.com/login'
            }
            issueManagement {
                system 'GitHub'
                url 'https://github.com/login/projectname/issues'
            }
            licenses {
                license {
                    name 'The Apache License, Version 2.0'
                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                }
            }
            scm {
                url 'https://github.com/login/projectname'
                connection 'scm:https://github.com/login/projectname.git'
                developerConnection 'scm:git://github.com/login/projectname.git'
            }
            developers {
                developer {
                    id 'dev'
                    name 'DevName'
                    email '[email protected]'
                }
            }
        }
    }
}

अगला, आपको यह निर्दिष्ट करने की आवश्यकता है कि विधानसभा उत्पन्न होने के दौरान -sources.jar и-javadoc.jar फ़ाइलें। इस खंड के लिए java आपको निम्नलिखित जोड़ने की आवश्यकता है:

java {
    withJavadocJar()
    withSourcesJar()
}

GPG/PGP सिग्नेचर सेट करते हुए, अंतिम आवश्यकता पर चलते हैं। ऐसा करने के लिए, प्लगइन कनेक्ट करें signing:

plugins {
    id 'signing'
}

और एक खंड जोड़ें:

signing {
    sign publishing.publications
}

अंत में, आइए एक खंड जोड़ें publishing:

publishing {
    publications {
        mavenJava(MavenPublication) {
            customizePom(pom)
            groupId group
            artifactId archivesBaseName
            version version

            from components.java
        }
    }
    repositories {
        maven {
            url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            credentials {
                username sonatypeUsername
                password sonatypePassword
            }
        }
    }
}

यहां सोनाटाइपउपयोगकर्तानाम и सोनाटाइप पासवर्ड पंजीकरण के दौरान बनाए गए लॉगिन और पासवर्ड वाले चर sonatype.org.

इस प्रकार फाइनल build.gradle इस तरह दिखेगा:

पूर्ण बिल्ड.ग्रेडल कोड

plugins {
    id 'java'
    id 'maven-publish'
    id 'signing'
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
    withJavadocJar()
    withSourcesJar()
}

group 'io.github.githublogin'
archivesBaseName = 'projectname'
version = System.getenv('RELEASE_VERSION') ?: "0.0.1"

repositories {
    mavenCentral()
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.5.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.5.2'
}

test {
    useJUnitPlatform()
}

jar {
    from sourceSets.main.output
    from sourceSets.main.allJava
}

signing {
    sign publishing.publications
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            customizePom(pom)
            groupId group
            artifactId archivesBaseName
            version version

            from components.java
        }
    }
    repositories {
        maven {
            url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            credentials {
                username sonatypeUsername
                password sonatypePassword
            }
        }
    }
}

def customizePom(pom) {
    pom.withXml {
        def root = asNode()

        root.dependencies.removeAll { dep ->
            dep.scope == "test"
        }

        root.children().last() + {
            resolveStrategy = DELEGATE_FIRST

            description 'Some description of artifact'
            name 'Artifct name'
            url 'https://github.com/login/projectname'
            organization {
                name 'com.github.login'
                url 'https://github.com/githublogin'
            }
            issueManagement {
                system 'GitHub'
                url 'https://github.com/githublogin/projectname/issues'
            }
            licenses {
                license {
                    name 'The Apache License, Version 2.0'
                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                }
            }
            scm {
                url 'https://github.com/githublogin/projectname'
                connection 'scm:https://github.com/githublogin/projectname.git'
                developerConnection 'scm:git://github.com/githublogin/projectname.git'
            }
            developers {
                developer {
                    id 'dev'
                    name 'DevName'
                    email '[email protected]'
                }
            }
        }
    }
}

मैं यह नोट करना चाहता हूं कि हमें पर्यावरण चर से संस्करण मिलता है: System.getenv('RELEASE_VERSION'). हम इसे असेंबली के दौरान एक्सपोज़ करेंगे और इसे टैग नाम से लेंगे।

पीजीपी कुंजी पीढ़ी

सोनाटाइप की आवश्यकताओं में से एक यह है कि सभी फाइलों पर जीपीजी/पीजीपी कुंजी के साथ हस्ताक्षर किए जाएं। इसके लिए हम जाते हैं यहां और अपने ऑपरेटिंग सिस्टम के लिए GnuPG यूटिलिटी डाउनलोड करें।

• हम एक प्रमुख जोड़ी उत्पन्न करते हैं: gpg --gen-key, एक उपयोगकर्ता नाम, ई-मेल दर्ज करें, और एक पासवर्ड भी सेट करें।
• पता लगाना id आदेश के साथ हमारी कुंजी: gpg --list-secret-keys --keyid-format short. स्लैश के बाद आईडी निर्दिष्ट की जाएगी, उदाहरण के लिए: rsa2048/9B695056
• सर्वर के लिए सार्वजनिक कुंजी प्रकाशित करना https://keys.openpgp.org आदेश द्वारा: gpg --keyserver [https://keys.openpgp.org](https://keys.openpgp.org/) --send-keys 9B695056
• हम गुप्त कुंजी को एक मनमाने स्थान पर निर्यात करते हैं, हमें भविष्य में इसकी आवश्यकता होगी: gpg --export-secret-key 9B695056 > D:\gpg\9B695056.gpg

गीथूब क्रियाओं की स्थापना

चलिए अंतिम चरण पर चलते हैं, जीथब क्रियाओं का उपयोग करके बिल्ड और ऑटो-पब्लिश सेट अप करें।
Github क्रियाएँ एक ऐसी सुविधा है जो आपको पूर्ण CI / CD चक्र लागू करके वर्कफ़्लो को स्वचालित करने की अनुमति देती है। निर्माण, परीक्षण और परिनियोजन को विभिन्न घटनाओं द्वारा ट्रिगर किया जा सकता है: कोड पुश, रिलीज़ निर्माण, या समस्याएँ। यह कार्यक्षमता सार्वजनिक रिपॉजिटरी के लिए बिल्कुल मुफ्त है।

इस खंड में, मैं आपको दिखाऊंगा कि बिल्ड और पुश कोड कैसे सेट अप करें और रिलीज़ होने पर सोनाटाइप रिपॉजिटरी में तैनात करें, साथ ही सीक्रेट्स भी सेट अप करें।

हम राज़ सेट करते हैं

स्वचालित असेंबली और परिनियोजन के लिए, हमें कई गुप्त मानों की आवश्यकता होती है, जैसे कुंजी आईडी, वह पासवर्ड जो हमने कुंजी बनाते समय दर्ज किया था, स्वयं PGP कुंजी, और सोनाटाइप लॉगिन/पासवर्ड। आप उन्हें रिपॉजिटरी सेटिंग्स में एक विशेष खंड में सेट कर सकते हैं:

हम निम्नलिखित चर सेट करते हैं:

• SONATYPE_USERNAME / SONATYPE_PASSWORD - लॉगिन / पासवर्ड जिसे हमने सोनाटाइप के साथ पंजीकरण करते समय दर्ज किया था
• SIGNING_KEYID/SIGNING_PASSWORD — जनरेशन के दौरान PGP कुंजी आईडी और पासवर्ड सेट।

मैं GPG_KEY_CONTENTS चर पर अधिक विस्तार से ध्यान केन्द्रित करना चाहता हूं। तथ्य यह है कि प्रकाशन के लिए हमें एक निजी PGP कुंजी की आवश्यकता होती है। इसे सीक्रेट्स में पोस्ट करने के लिए मैंने इस्तेमाल किया अनुदेश और कई कार्रवाई भी की।

• आइए हमारी कुंजी को GPG के साथ एन्क्रिप्ट करें: gpg --symmetric --cipher-algo AES256 9B695056.gpgएक पासवर्ड दर्ज करके। इसे एक चर में रखा जाना चाहिए: SECRET_PASSPHRASE
• आइए बेस 64 का उपयोग करके प्राप्त एन्क्रिप्टेड कुंजी को टेक्स्ट फॉर्म में अनुवादित करें: base64 9B695056.gpg.gpg > 9B695056.txt. सामग्री को चर में रखा जाएगा: GPG_KEY_CONTENTS।

कोड पुश करते समय और PR बनाते समय सेटअप बनाएँ

सबसे पहले आपको अपने प्रोजेक्ट के रूट में एक फ़ोल्डर बनाना होगा: .github/workflows.

इसमें, फ़ाइल को चिह्नित करें, उदाहरण के लिए, gradle-ci-build.yml निम्नलिखित सामग्री के साथ:

name: build

on:
  push:
    branches:
      - master
      - dev
      - testing
  pull_request:

jobs:
  build:
    runs-on: ubuntu-latest
    steps:
      - uses: actions/checkout@v1
      - name: Set up JDK 8
        uses: actions/setup-java@v1
        with:
          java-version: 8

      - name: Build with Gradle
        uses: eskatos/gradle-command-action@v1
        with:
          gradle-version: current
          arguments: build -PsonatypeUsername=${{secrets.SONATYPE_USERNAME}} -PsonatypePassword=${{secrets.SONATYPE_PASSWORD}}

शाखाओं को धकेलने पर इस कार्यप्रवाह को क्रियान्वित किया जाएगा master, dev и testing, पुल अनुरोध बनाते समय भी।

कार्य अनुभाग में निर्दिष्ट ईवेंट पर निष्पादित किए जाने वाले चरण शामिल हैं। इस मामले में, हम ubuntu के नवीनतम संस्करण पर निर्माण करेंगे, जावा 8 का उपयोग करेंगे, और ग्रैडल के लिए प्लगइन का भी उपयोग करेंगे eskatos/gradle-command-action@v1जो बिल्डर के नवीनतम संस्करण का उपयोग करके निर्दिष्ट कमांड चलाएगा arguments. चर secrets.SONATYPE_USERNAME и secrets.SONATYPE_PASSWORD ये वे रहस्य हैं जो हमने पहले पूछे थे।

बिल्ड परिणाम क्रियाएँ टैब में दिखाई देंगे:

नई रिलीज जारी होने पर ऑटो-तैनाती

चलिए स्वतः परिनियोजन के लिए एक अलग कार्यप्रवाह फ़ाइल बनाते हैं gradle-ci-publish.yml:

name: publish

on:
  push:
    tags:
      - 'v*'

jobs:
  publish:
    runs-on: ubuntu-latest
    steps:
      - uses: actions/checkout@v1
      - name: Set up JDK 8
        uses: actions/setup-java@v1
        with:
          java-version: 8

      - name: Prepare to publish
        run: |
          echo '${{secrets.GPG_KEY_CONTENTS}}' | base64 -d > publish_key.gpg
          gpg --quiet --batch --yes --decrypt --passphrase="${{secrets.SECRET_PASSPHRASE}}" 
          --output secret.gpg publish_key.gpg
          echo "::set-env name=RELEASE_VERSION::${GITHUB_REF:11}"

      - name: Publish with Gradle
        uses: eskatos/gradle-command-action@v1
        with:
          gradle-version: current
          arguments: test publish -Psigning.secretKeyRingFile=secret.gpg -Psigning.keyId=${{secrets.SIGNING_KEYID}} -Psigning.password=${{secrets.SIGNING_PASSWORD}} -PsonatypeUsername=${{secrets.SONATYPE_USERNAME}} -PsonatypePassword=${{secrets.SONATYPE_PASSWORD}}

फ़ाइल लगभग पिछले वाले के समान है, उस घटना को छोड़कर जिसमें इसे ट्रिगर किया जाएगा। इस मामले में, यह v से शुरू होने वाले नाम के साथ एक टैग बनाने की घटना है।

परिनियोजन से पहले, हमें PGP कुंजी को रहस्यों से निकालना होगा और इसे प्रोजेक्ट की जड़ में रखना होगा, साथ ही इसे डिक्रिप्ट करना होगा। अगला, हमें एक विशेष पर्यावरण चर सेट करने की आवश्यकता है RELEASE_VERSION जिसका हम उल्लेख करते हैं gradle.build फ़ाइल। यह सब खंड में किया जाता है Prepare to publish. हम अपनी कुंजी GPG_KEY_CONTENTS चर से प्राप्त करते हैं, इसे एक gpg फ़ाइल में अनुवादित करते हैं, फिर इसे फ़ाइल में डालकर डिक्रिप्ट करते हैं secret.gpg.

अगला, हम एक विशेष चर की ओर मुड़ते हैं GITHUB_REF, जिससे हम वह संस्करण प्राप्त कर सकते हैं जिसे हम टैग बनाते समय सेट करते हैं। यह चर इस मामले में प्रासंगिक है। refs/tags/v0.0.2 जिसमें से हमने विशिष्ट संस्करण प्राप्त करने के लिए पहले 11 वर्णों को काट दिया। अगला, हम प्रकाशन के लिए मानक ग्रेडल कमांड का उपयोग करते हैं: test publish

सोनाटाइप रिपॉजिटरी में परिनियोजन परिणामों की जाँच करना

एक बार रिलीज़ बन जाने के बाद, पिछले अनुभाग में वर्णित कार्यप्रवाह प्रारंभ हो जाना चाहिए। ऐसा करने के लिए, एक रिलीज़ बनाएँ:

टैग का नाम v से शुरू होना चाहिए। यदि, प्रकाशन प्रकाशन पर क्लिक करने के बाद, कार्यप्रवाह सफलतापूर्वक पूर्ण हो जाता है, तो हम जा सकते हैं सोनाटाइप नेक्सस निश्चित करना:

आर्टिफैक्ट स्टेजिंग रिपॉजिटरी में दिखाई दिया। यह तुरंत खुली स्थिति में दिखाई देता है, फिर इसे उचित बटन दबाकर मैन्युअल रूप से बंद स्थिति में स्थानांतरित किया जाना चाहिए। यह जाँचने के बाद कि सभी आवश्यकताएँ पूरी हो गई हैं, विरूपण साक्ष्य बंद स्थिति में चला जाता है और अब संशोधन के लिए उपलब्ध नहीं है। इस रूप में, यह मावेनसेंट्रल में समाप्त हो जाएगा। अगर सब ठीक है, तो आप बटन दबा सकते हैं रिलीज, और आर्टिफैक्ट सोनाटाइप रिपॉजिटरी में समाप्त हो जाएगा।

MavenCentral में विरूपण साक्ष्य प्राप्त करने के लिए, आपको इसे उस कार्य में पूछने की आवश्यकता है जिसे हमने शुरुआत में बनाया था। आपको इसे केवल एक बार करने की आवश्यकता है, इसलिए हम पहली बार प्रकाशित करते हैं। बाद के समय में, इसकी आवश्यकता नहीं है, सब कुछ स्वचालित रूप से सिंक्रनाइज़ हो जाएगा। उन्होंने मेरे लिए जल्दी से सिंक्रोनाइज़ेशन चालू कर दिया, लेकिन कलाकृतियों को मावेनसेंट्रल में उपलब्ध होने में लगभग 5 दिन लग गए।

बस इतना ही, हमने मावेनसेंट्रल में अपनी कलाकृतियों को प्रकाशित किया है।

उपयोगी लिंक्स

• ऐसा ही एक लेख, केवल मेवेन के माध्यम से प्रकाशित करें
• मचान कोष सोनाटाइप
• Jira सोनाटाइप जिसमें कार्य बनाना है
• उदाहरण रिपॉजिटरी जहां यह सब सेट अप है

स्रोत: www.habr.com