इंडस्ट्रियल निंजा के नक्शेकदम पर: पॉजिटिव हैक डेज़ 9 में एक पीएलसी को कैसे हैक किया गया था

पिछले PHDays 9 में हमने गैस पंपिंग प्लांट को हैक करने के लिए एक प्रतियोगिता आयोजित की - प्रतियोगिता औद्योगिक निंजा. साइट पर अलग-अलग सुरक्षा मापदंडों (कोई सुरक्षा नहीं, कम सुरक्षा, उच्च सुरक्षा) के साथ तीन स्टैंड थे, जो एक ही औद्योगिक प्रक्रिया का अनुकरण करते थे: दबाव में हवा को एक गुब्बारे में पंप किया गया था (और फिर छोड़ दिया गया था)।

विभिन्न सुरक्षा मापदंडों के बावजूद, स्टैंड की हार्डवेयर संरचना समान थी: सीमेंस सिमेटिक पीएलसी एस7-300 श्रृंखला; आपातकालीन अपस्फीति बटन और दबाव मापने वाला उपकरण (पीएलसी डिजिटल इनपुट (डीआई) से जुड़ा); हवा की मुद्रास्फीति और अपस्फीति के लिए काम करने वाले वाल्व (पीएलसी (डीओ) के डिजिटल आउटपुट से जुड़े) - नीचे दिया गया चित्र देखें।

पीएलसी ने, दबाव रीडिंग के आधार पर और अपने कार्यक्रम के अनुसार, गेंद को डिफ्लेट या फुलाने का निर्णय लिया (संबंधित वाल्व खोले और बंद किए)। हालाँकि, सभी स्टैंडों में मैन्युअल नियंत्रण मोड था, जिससे वाल्वों की स्थिति को बिना किसी प्रतिबंध के नियंत्रित करना संभव हो गया।

इस मोड को सक्षम करने की जटिलता में स्टैंड भिन्न थे: असुरक्षित स्टैंड पर ऐसा करना सबसे आसान था, और उच्च सुरक्षा स्टैंड पर यह तदनुसार अधिक कठिन था।

छह में से पांच समस्याएं दो दिनों में हल हो गईं; पहले स्थान पर रहने वाले प्रतिभागी ने 233 अंक अर्जित किए (उसने प्रतियोगिता की तैयारी में एक सप्ताह बिताया)। तीन विजेता: I स्थान - a1exdandy, II - Rubikoid, III - Ze।

हालाँकि, PHDays के दौरान, कोई भी प्रतिभागी सभी तीन स्टैंडों को पार करने में सक्षम नहीं था, इसलिए हमने एक ऑनलाइन प्रतियोगिता करने का निर्णय लिया और जून की शुरुआत में सबसे कठिन कार्य प्रकाशित किया। प्रतिभागियों को एक महीने के भीतर कार्य पूरा करना था, ध्वज ढूंढना था और समाधान का विस्तार से और दिलचस्प तरीके से वर्णन करना था।

कट के नीचे हम महीने भर में भेजे गए कार्यों में से कार्य के सर्वोत्तम समाधान का विश्लेषण प्रकाशित करते हैं, यह डिजिटल सुरक्षा कंपनी के एलेक्सी कोवरिज़्निख (a1exdandy) द्वारा पाया गया, जिन्होंने PHDays के दौरान प्रतियोगिता में प्रथम स्थान प्राप्त किया। नीचे हम इसका पाठ अपनी टिप्पणियों के साथ प्रस्तुत कर रहे हैं।

प्रारंभिक विश्लेषण

तो, कार्य में निम्नलिखित फ़ाइलों वाला एक संग्रह शामिल था:

• ब्लॉक_अपलोड_ट्रैफ़िक.pcapng
• DB100.bin
• संकेत.txt

संकेत.txt फ़ाइल में कार्य को हल करने के लिए आवश्यक जानकारी और संकेत शामिल हैं। यहाँ इसकी सामग्री है:

1. पेत्रोविच ने कल मुझे बताया कि आप PlcSim से स्टेप7 में ब्लॉक लोड कर सकते हैं।
2. स्टैंड पर सीमेंस सिमेटिक एस7-300 श्रृंखला पीएलसी का उपयोग किया गया था।
3. PlcSim एक PLC एमुलेटर है जो आपको सीमेंस S7 PLC के लिए प्रोग्राम चलाने और डिबग करने की अनुमति देता है।

ऐसा प्रतीत होता है कि DB100.bin फ़ाइल में DB100 PLC डेटा ब्लॉक शामिल है: 00000000: 0100 0102 6e02 0401 0206 0100 0101 0102 ....n......... 00000010: 1002 0501 0202 2002 0501 0206 0100 0102 00000020 0102 . ............ 7702: 0401 0206 0100 0103 0102 0 02 00000030a0501 ..w........... 0202: 1602 0501 0206 0100 0104 0102 00000040 7502 ................ 0401: 0206 0100 0105 0102 0 02 0501a00000050 0202 यू........... 1602: 0501 0206 0100 0106 0102 3402 4 00000060............0401. 0206: 0100 0107 0102 2602 0501 0202 00000070 4 ........... & ..... 02: 0501C0206 0100 0108 0102 3302 0401 3 00000080 0206 L ......... 0100। .. 0109 : 0102 0 02 0501 0202a1602 00000090 0501 0206 ................ 0100: 010 0102 3702 0401a 0206 7 000000 0 .......0100. .... 010a0102: 2202 0501b 0202 4602 0501 000000 0 0206 ......"...F... 0100b010: 0102 3302 0401c 0206 0100 3 000000 0 ........010. .... .. 0102c0: 02d 0501 0202a1602 0501 0206 000000 0 0100 ................ 010d0102: 6 02e 0401 0206d0100 010 000000 0 0102f ......m.... .... 1102e0501: 0202 2302 0501 0206 0100 000000 0 0110 ........#...... 0102f3502: 0401 0206 0100 0111 0102 5 00000100 1202 ....0501. ..... ..... 0202: 2502 0501 0206 0100 0112 00000110 0102 3302 ......%... 0401: 0206 0100 0113 0102 2602 3 00000120 0501 ..0202. ..... ....&. 4: 02 0501 0206c0100 XNUMX XNUMX XNUMX ....L......

जैसा कि नाम से पता चलता है, ब्लॉक_अपलोड_ट्रैफ़िक.पीकैपएनजी फ़ाइल में पीएलसी पर ब्लॉक अपलोड ट्रैफ़िक का डंप होता है।

यह ध्यान देने योग्य है कि सम्मेलन के दौरान प्रतियोगिता स्थल पर इस ट्रैफ़िक डंप को प्राप्त करना थोड़ा अधिक कठिन था। ऐसा करने के लिए, TeslaSCADA2 के लिए प्रोजेक्ट फ़ाइल से स्क्रिप्ट को समझना आवश्यक था। इससे यह समझना संभव था कि RC4 का उपयोग करके एन्क्रिप्ट किया गया डंप कहाँ स्थित था और इसे डिक्रिप्ट करने के लिए किस कुंजी का उपयोग करने की आवश्यकता थी। S7 प्रोटोकॉल क्लाइंट का उपयोग करके साइट पर डेटा ब्लॉक के डंप प्राप्त किए जा सकते हैं। इसके लिए मैंने Snap7 पैकेज से डेमो क्लाइंट का उपयोग किया।

ट्रैफ़िक डंप से सिग्नल प्रोसेसिंग ब्लॉक निकालना

डंप की सामग्री को देखकर, आप समझ सकते हैं कि इसमें सिग्नल प्रोसेसिंग ब्लॉक OB1, FC1, FC2 और FC3 शामिल हैं:

इन ब्लॉकों को हटाया जाना चाहिए. यह किया जा सकता है, उदाहरण के लिए, निम्नलिखित स्क्रिप्ट के साथ, पहले ट्रैफ़िक को pcapng प्रारूप से pcap में परिवर्तित किया गया है:

#!/usr/bin/env python2

import struct
from scapy.all import *

packets = rdpcap('block_upload_traffic.pcap')
s7_hdr_struct = '>BBHHHHBB'
s7_hdr_sz = struct.calcsize(s7_hdr_struct)
tpkt_cotp_sz = 7
names = iter(['OB1.bin', 'FC1.bin', 'FC2.bin', 'FC3.bin'])
buf = ''

for packet in packets:
    if packet.getlayer(IP).src == '10.0.102.11':
        tpkt_cotp_s7 = str(packet.getlayer(TCP).payload)
        if len(tpkt_cotp_s7) < tpkt_cotp_sz + s7_hdr_sz:
            continue
        s7 = tpkt_cotp_s7[tpkt_cotp_sz:]
        s7_hdr = s7[:s7_hdr_sz]
        param_sz = struct.unpack(s7_hdr_struct, s7_hdr)[4]
        s7_param = s7[12:12+param_sz]
        s7_data = s7[12+param_sz:]
        if s7_param in ('x1ex00', 'x1ex01'):  # upload
            buf += s7_data[4:]
        elif s7_param == 'x1f':
            with open(next(names), 'wb') as f:
                f.write(buf)
            buf = ''

परिणामी ब्लॉकों की जांच करने पर, आप देखेंगे कि वे हमेशा बाइट्स 70 70 (पीपी) से शुरू होते हैं। अब आपको यह सीखना होगा कि उनका विश्लेषण कैसे किया जाए। असाइनमेंट संकेत बताता है कि आपको इसके लिए PlcSim का उपयोग करने की आवश्यकता है।

ब्लॉकों से मानव-पठनीय निर्देश प्राप्त करना

सबसे पहले, आइए सिमैटिक मैनेजर सॉफ़्टवेयर का उपयोग करके इसमें दोहराए गए निर्देशों (= क्यू 7) के साथ कई ब्लॉक लोड करके और एमुलेटर में प्राप्त पीएलसी को example.plc फ़ाइल में सहेजकर S0.0-PlcSim को प्रोग्राम करने का प्रयास करें। फ़ाइल की सामग्री को देखकर, आप हस्ताक्षर 70 70 द्वारा डाउनलोड किए गए ब्लॉक की शुरुआत आसानी से निर्धारित कर सकते हैं, जिसे हमने पहले खोजा था। ब्लॉक से पहले, जाहिरा तौर पर, ब्लॉक का आकार 4-बाइट छोटे-एंडियन मान के रूप में लिखा जाता है।

पीएलसी फ़ाइलों की संरचना के बारे में जानकारी प्राप्त करने के बाद, पीएलसी एस7 प्रोग्राम पढ़ने के लिए निम्नलिखित कार्य योजना सामने आई:

1. सिमैटिक मैनेजर का उपयोग करके, हम S7-PlcSim में एक ब्लॉक संरचना बनाते हैं जो हमें डंप से प्राप्त हुई थी। ब्लॉक का आकार मेल खाना चाहिए (यह आवश्यक संख्या में निर्देशों के साथ ब्लॉक को भरकर प्राप्त किया जाता है) और उनके पहचानकर्ता (OB1, FC1, FC2, FC3)।
2. पीएलसी को एक फ़ाइल में सहेजें।
3. हम परिणामी फ़ाइल में ब्लॉक की सामग्री को ट्रैफ़िक डंप के ब्लॉक से बदल देते हैं। ब्लॉक की शुरुआत हस्ताक्षर द्वारा निर्धारित की जाती है।
4. हम परिणामी फ़ाइल को S7-PlcSim में लोड करते हैं और सिमेटिक मैनेजर में ब्लॉक की सामग्री को देखते हैं।

उदाहरण के लिए, ब्लॉक को निम्नलिखित कोड से बदला जा सकता है:

with open('original.plc', 'rb') as f:
    plc = f.read()
blocks = []
for fname in ['OB1.bin', 'FC1.bin', 'FC2.bin', 'FC3.bin']:
    with open(fname, 'rb') as f:
        blocks.append(f.read())

i = plc.find(b'pp')
for block in blocks:
    plc = plc[:i] + block + plc[i+len(block):]
    i = plc.find(b'pp', i + 1)

with open('target.plc', 'wb') as f:
    f.write(plc)

एलेक्सी ने शायद अधिक कठिन, लेकिन फिर भी सही रास्ता अपनाया। हमने मान लिया कि प्रतिभागी NetToPlcSim प्रोग्राम का उपयोग करेंगे ताकि PlcSim नेटवर्क पर संचार कर सके, Snap7 के माध्यम से PlcSim पर ब्लॉक अपलोड कर सके, और फिर विकास परिवेश का उपयोग करके इन ब्लॉकों को PlcSim से एक प्रोजेक्ट के रूप में डाउनलोड कर सके।

परिणामी फ़ाइल को S7-PlcSim में खोलकर, आप सिमेटिक मैनेजर का उपयोग करके ओवरराइट किए गए ब्लॉक को पढ़ सकते हैं। मुख्य उपकरण नियंत्रण कार्य ब्लॉक FC1 में दर्ज किए गए हैं। विशेष ध्यान देने योग्य बात #TEMP0 वैरिएबल है, जो चालू होने पर M2.2 और M2.3 बिट मेमोरी मानों के आधार पर PLC नियंत्रण को मैन्युअल मोड पर सेट करता प्रतीत होता है। #TEMP0 मान फ़ंक्शन FC3 द्वारा निर्धारित किया गया है।

समस्या को हल करने के लिए, आपको FC3 फ़ंक्शन का विश्लेषण करने और यह समझने की आवश्यकता है कि क्या करने की आवश्यकता है ताकि यह एक तार्किक परिणाम दे सके।

प्रतियोगिता स्थल पर कम सुरक्षा स्टैंड पर पीएलसी सिग्नल प्रोसेसिंग ब्लॉक को एक समान तरीके से व्यवस्थित किया गया था, लेकिन #TEMP0 वैरिएबल का मान सेट करने के लिए, डीबी1 ब्लॉक में मेरी निंजा लाइन को लिखने के लिए पर्याप्त था। किसी ब्लॉक में मान की जाँच करना सीधा था और इसके लिए ब्लॉक प्रोग्रामिंग भाषा के गहन ज्ञान की आवश्यकता नहीं थी। जाहिर है, उच्च सुरक्षा स्तर पर, मैन्युअल नियंत्रण प्राप्त करना अधिक कठिन होगा और एसटीएल भाषा (एस7 पीएलसी को प्रोग्राम करने के तरीकों में से एक) की जटिलताओं को समझना आवश्यक है।

रिवर्स ब्लॉक FC3

एसटीएल प्रतिनिधित्व में एफसी3 ब्लॉक की सामग्री:

      L     B#16#0
      T     #TEMP13
      T     #TEMP15
      L     P#DBX 0.0
      T     #TEMP4
      CLR   
      =     #TEMP14
M015: L     #TEMP4
      LAR1  
      OPN   DB   100
      L     DBLG
      TAR1  
      <=D   
      JC    M016
      L     DW#16#0
      T     #TEMP0
      L     #TEMP6
      L     W#16#0
      <>I   
      JC    M00d
      L     P#DBX 0.0
      LAR1  
M00d: L     B [AR1,P#0.0]
      T     #TEMP5
      L     W#16#1
      ==I   
      JC    M007
      L     #TEMP5
      L     W#16#2
      ==I   
      JC    M008
      L     #TEMP5
      L     W#16#3
      ==I   
      JC    M00f
      L     #TEMP5
      L     W#16#4
      ==I   
      JC    M00e
      L     #TEMP5
      L     W#16#5
      ==I   
      JC    M011
      L     #TEMP5
      L     W#16#6
      ==I   
      JC    M012
      JU    M010
M007: +AR1  P#1.0
      L     P#DBX 0.0
      LAR2  
      L     B [AR1,P#0.0]
      L     C#8
      *I    
      +AR2  
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M003
      JU    M001
      JU    M002
      JU    M004
M003: JU    M005
M001: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP0
      JU    M006
M002: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP1
      JU    M006
M004: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP2
      JU    M006
M00f: +AR1  P#1.0
      L     B [AR1,P#0.0]
      L     C#8
      *I    
      T     #TEMP11
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      TAR1  #TEMP4
      OPN   DB   101
      L     P#DBX 0.0
      LAR1  
      L     #TEMP11
      +AR1  
      LAR2  #TEMP9
      L     B [AR2,P#0.0]
      T     B [AR1,P#0.0]
      L     #TEMP4
      LAR1  
      JU    M006
M008: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP3
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M009
      JU    M00b
      JU    M00a
      JU    M00c
M009: JU    M005
M00b: L     #TEMP3
      T     #TEMP0
      JU    M006
M00a: L     #TEMP3
      T     #TEMP1
      JU    M006
M00c: L     #TEMP3
      T     #TEMP2
      JU    M006
M00e: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      AW    
      INVI  
      T     #TEMP12
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      OW    
      L     #TEMP12
      AW    
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #TEMP0
      L     MB   101
      T     #TEMP1
      L     MB   102
      T     #TEMP2
      L     #TEMP4
      LAR1  
      JU    M006
M011: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      -I    
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #TEMP0
      L     MB   101
      T     #TEMP1
      L     MB   102
      T     #TEMP2
      L     #TEMP4
      LAR1  
      JU    M006
M012: L     #TEMP15
      INC   1
      T     #TEMP15
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      ==I   
      JCN   M013
      JU    M014
M013: L     P#DBX 0.0
      LAR1  
      T     #TEMP4
      L     B#16#0
      T     #TEMP6
      JU    M006
M014: L     #TEMP4
      LAR1  
      L     #TEMP13
      L     L#1
      +I    
      T     #TEMP13
      JU    M006
M006: L     #TEMP0
      T     MB   100
      L     #TEMP1
      T     MB   101
      L     #TEMP2
      T     MB   102
      +AR1  P#1.0
      L     #TEMP6
      +     1
      T     #TEMP6
      JU    M005
M010: L     P#DBX 0.0
      LAR1  
      L     0
      T     #TEMP6
      TAR1  #TEMP4
M005: TAR1  #TEMP4
      CLR   
      =     #TEMP16
      L     #TEMP13
      L     L#20
      ==I   
      S     #TEMP16
      L     #TEMP15
      ==I   
      A     #TEMP16
      JC    M017
      L     #TEMP13
      L     L#20
      <I    
      S     #TEMP16
      L     #TEMP15
      ==I   
      A     #TEMP16
      JC    M018
      JU    M019
M017: SET   
      =     #TEMP14
      JU    M016
M018: CLR   
      =     #TEMP14
      JU    M016
M019: CLR   
      O     #TEMP14
      =     #RET_VAL
      JU    M015
M016: CLR   
      O     #TEMP14
      =     #RET_VAL

कोड काफी लंबा है और एसटीएल से अपरिचित किसी व्यक्ति को जटिल लग सकता है। इस आलेख के ढांचे के भीतर प्रत्येक निर्देश का विश्लेषण करने का कोई मतलब नहीं है; एसटीएल भाषा के विस्तृत निर्देश और क्षमताएं संबंधित मैनुअल में पाई जा सकती हैं: S7-300 और S7-400 प्रोग्रामिंग के लिए स्टेटमेंट लिस्ट (STL)।. यहां मैं प्रसंस्करण के बाद वही कोड प्रस्तुत करूंगा - लेबल और वेरिएबल्स का नाम बदलना और ऑपरेशन एल्गोरिदम और कुछ एसटीएल भाषा निर्माणों का वर्णन करने वाली टिप्पणियां जोड़ना। मुझे तुरंत ध्यान दें कि विचाराधीन ब्लॉक में एक वर्चुअल मशीन है जो DB100 ब्लॉक में स्थित कुछ बाइटकोड को निष्पादित करती है, जिसकी सामग्री हम जानते हैं। वर्चुअल मशीन निर्देशों में ऑपरेटिंग कोड का 1 बाइट और तर्कों के बाइट्स होते हैं, प्रत्येक तर्क के लिए एक बाइट। सभी विचारित निर्देशों में दो तर्क हैं; मैंने टिप्पणियों में उनके मूल्यों को एक्स और वाई के रूप में निर्दिष्ट किया है।

प्रसंस्करण के बाद कोड]

# Инициализация различных переменных
      L     B#16#0
      T     #CHECK_N        # Счетчик успешно пройденных проверок
      T     #COUNTER_N      # Счетчик общего количества проверок
      L     P#DBX 0.0
      T     #POINTER        # Указатель на текущую инструкцию
      CLR   
      =     #PRE_RET_VAL

# Основной цикл работы интерпретатора байт-кода
LOOP: L     #POINTER
      LAR1  
      OPN   DB   100
      L     DBLG
      TAR1  
      <=D                   # Проверка выхода указателя за пределы программы
      JC    FINISH
      L     DW#16#0
      T     #REG0
      L     #TEMP6
      L     W#16#0
      <>I   
      JC    M00d
      L     P#DBX 0.0
      LAR1  

# Конструкция switch - case для обработки различных опкодов
M00d: L     B [AR1,P#0.0]
      T     #OPCODE
      L     W#16#1
      ==I   
      JC    OPCODE_1
      L     #OPCODE
      L     W#16#2
      ==I   
      JC    OPCODE_2
      L     #OPCODE
      L     W#16#3
      ==I   
      JC    OPCODE_3
      L     #OPCODE
      L     W#16#4
      ==I   
      JC    OPCODE_4
      L     #OPCODE
      L     W#16#5
      ==I   
      JC    OPCODE_5
      L     #OPCODE
      L     W#16#6
      ==I   
      JC    OPCODE_6
      JU    OPCODE_OTHER

# Обработчик опкода 01: загрузка значения из DB101[X] в регистр Y
# OP01(X, Y): REG[Y] = DB101[X]
OPCODE_1: +AR1  P#1.0
      L     P#DBX 0.0
      LAR2  
      L     B [AR1,P#0.0]   # Загрузка аргумента X (индекс в DB101)
      L     C#8
      *I    
      +AR2  
      +AR1  P#1.0
      L     B [AR1,P#0.0]   # Загрузка аргумента Y (индекс регистра)
      JL    M003            # Аналог switch - case на основе значения Y
      JU    M001            # для выбора необходимого регистра для записи.
      JU    M002            # Подобные конструкции используются и в других
      JU    M004            # операциях ниже для аналогичных целей
M003: JU    LOOPEND
M001: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG0           # Запись значения DB101[X] в REG[0]
      JU    PRE_LOOPEND
M002: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG1           # Запись значения DB101[X] в REG[1]
      JU    PRE_LOOPEND
M004: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG2           # Запись значения DB101[X] в REG[2]
      JU    PRE_LOOPEND

# Обработчик опкода 02: загрузка значения X в регистр Y
# OP02(X, Y): REG[Y] = X
OPCODE_2: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP3
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M009
      JU    M00b
      JU    M00a
      JU    M00c
M009: JU    LOOPEND
M00b: L     #TEMP3
      T     #REG0
      JU    PRE_LOOPEND
M00a: L     #TEMP3
      T     #REG1
      JU    PRE_LOOPEND
M00c: L     #TEMP3
      T     #REG2
      JU    PRE_LOOPEND

# Опкод 03 не используется в программе, поэтому пропустим его
...

# Обработчик опкода 04: сравнение регистров X и Y
# OP04(X, Y): REG[0] = 0; REG[X] = (REG[X] == REG[Y])
OPCODE_4: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7          # первый аргумент - X
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          # REG[X]
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9          # REG[X]
      LAR2  #TEMP10         # REG[Y]
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      AW    
      INVI  
      T     #TEMP12         # ~(REG[Y] & REG[X])
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      OW    
      L     #TEMP12
      AW                    # (~(REG[Y] & REG[X])) & (REG[Y] | REG[X]) - аналог проверки на равенство
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #REG0
      L     MB   101
      T     #REG1
      L     MB   102
      T     #REG2
      L     #POINTER
      LAR1  
      JU    PRE_LOOPEND

# Обработчик опкода 05: вычитание регистра Y из X
# OP05(X, Y): REG[0] = 0; REG[X] = REG[X] - REG[Y]
OPCODE_5: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          # REG[X]
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      -I                    # ACCU1 = ACCU2 - ACCU1, REG[X] - REG[Y]
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #REG0
      L     MB   101
      T     #REG1
      L     MB   102
      T     #REG2
      L     #POINTER
      LAR1  
      JU    PRE_LOOPEND

# Обработчик опкода 06: инкремент #CHECK_N при равенстве регистров X и Y
# OP06(X, Y): #CHECK_N += (1 if REG[X] == REG[Y] else 0)
OPCODE_6: L     #COUNTER_N
      INC   1
      T     #COUNTER_N
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7          #  REG[X]     
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          #  REG[X]  
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9          # REG[Y]
      LAR2  #TEMP10         # REG[X]
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      ==I   
      JCN   M013
      JU    M014
M013: L     P#DBX 0.0
      LAR1  
      T     #POINTER
      L     B#16#0
      T     #TEMP6
      JU    PRE_LOOPEND
M014: L     #POINTER
      LAR1  
# Инкремент значения #CHECK_N
      L     #CHECK_N
      L     L#1
      +I    
      T     #CHECK_N
      JU    PRE_LOOPEND

PRE_LOOPEND: L     #REG0
      T     MB   100
      L     #REG1
      T     MB   101
      L     #REG2
      T     MB   102
      +AR1  P#1.0
      L     #TEMP6
      +     1
      T     #TEMP6
      JU    LOOPEND

OPCODE_OTHER: L     P#DBX 0.0
      LAR1  
      L     0
      T     #TEMP6
      TAR1  #POINTER

LOOPEND: TAR1  #POINTER
      CLR   
      =     #TEMP16
      L     #CHECK_N
      L     L#20
      ==I   
      S     #TEMP16
      L     #COUNTER_N
      ==I   
      A     #TEMP16
# Все проверки пройдены, если #CHECK_N == #COUNTER_N == 20
      JC    GOOD
      L     #CHECK_N
      L     L#20
      <I    
      S     #TEMP16
      L     #COUNTER_N
      ==I   
      A     #TEMP16
      JC    FAIL
      JU    M019
GOOD: SET   
      =     #PRE_RET_VAL
      JU    FINISH
FAIL: CLR   
      =     #PRE_RET_VAL
      JU    FINISH
M019: CLR   
      O     #PRE_RET_VAL
      =     #RET_VAL
      JU    LOOP
FINISH: CLR   
      O     #PRE_RET_VAL
      =     #RET_VAL

वर्चुअल मशीन के निर्देशों का अंदाजा लगाने के बाद, आइए DB100 ब्लॉक में बाइटकोड को पार्स करने के लिए एक छोटा डिस्सेबलर लिखें:

import string
alph = string.ascii_letters + string.digits

with open('DB100.bin', 'rb') as f:
    m = f.read()

pc = 0

while pc < len(m):
    op = m[pc]
    if op == 1:
        print('R{} = DB101[{}]'.format(m[pc + 2], m[pc + 1]))
        pc += 3
    elif op == 2:
        c = chr(m[pc + 1])
        c = c if c in alph else '?'
        print('R{} = {:02x} ({})'.format(m[pc + 2], m[pc + 1], c))
        pc += 3
    elif op == 4:
        print('R0 = 0; R{} = (R{} == R{})'.format(
            m[pc + 1], m[pc + 1], m[pc + 2]))
        pc += 3
    elif op == 5:
        print('R0 = 0; R{} = R{} - R{}'.format(
            m[pc + 1], m[pc + 1], m[pc + 2]))
        pc += 3
    elif op == 6:
        print('CHECK (R{} == R{})n'.format(
            m[pc + 1], m[pc + 2]))
        pc += 3
    else:
        print('unk opcode {}'.format(op))
        break

परिणामस्वरूप, हमें निम्नलिखित वर्चुअल मशीन कोड मिलता है:

वर्चुअल मशीन कोड

R1 = DB101[0]
R2 = 6e (n)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[1]
R2 = 10 (?)
R0 = 0; R1 = R1 - R2
R2 = 20 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[2]
R2 = 77 (w)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[3]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[4]
R2 = 75 (u)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[5]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[6]
R2 = 34 (4)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[7]
R2 = 26 (?)
R0 = 0; R1 = R1 - R2
R2 = 4c (L)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[8]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[9]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[10]
R2 = 37 (7)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[11]
R2 = 22 (?)
R0 = 0; R1 = R1 - R2
R2 = 46 (F)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[12]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[13]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[14]
R2 = 6d (m)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[15]
R2 = 11 (?)
R0 = 0; R1 = R1 - R2
R2 = 23 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[16]
R2 = 35 (5)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[17]
R2 = 12 (?)
R0 = 0; R1 = R1 - R2
R2 = 25 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[18]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[19]
R2 = 26 (?)
R0 = 0; R1 = R1 - R2
R2 = 4c (L)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

जैसा कि आप देख सकते हैं, यह प्रोग्राम बस एक निश्चित मान की समानता के लिए DB101 से प्रत्येक वर्ण की जाँच करता है। सभी चेक पास करने की अंतिम पंक्ति है: n0w u 4r3 7h3 m4573r। यदि इस लाइन को ब्लॉक DB101 में रखा जाता है, तो मैन्युअल पीएलसी नियंत्रण सक्रिय हो जाता है और गुब्बारे को विस्फोट करना या पिचकाना संभव होगा।


बस इतना ही! एलेक्सी ने एक औद्योगिक निंजा के योग्य उच्च स्तर के ज्ञान का प्रदर्शन किया :) हमने विजेता को यादगार पुरस्कार भेजे। सभी प्रतिभागियों को बहुत धन्यवाद!

स्रोत: www.habr.com