🥇$30 के लिए तीन छत्तों के वजन की एसएमएस निगरानी

नहीं, यह कोई व्यावसायिक प्रस्ताव नहीं है, यह सिस्टम घटकों की लागत है जिसे आप लेख पढ़ने के बाद असेंबल कर सकते हैं।

एक छोटी सी पृष्ठभूमि:

कुछ समय पहले मैंने मधुमक्खियाँ लाने का फैसला किया, और वे पूरे सीज़न के लिए दिखाई दीं, लेकिन सर्दियों की झोपड़ी नहीं छोड़ीं।
और यह इस तथ्य के बावजूद कि वह सब कुछ सही ढंग से कर रहा था - शरद ऋतु पूरक आहार, ठंड के मौसम से पहले इन्सुलेशन।
छत्ता एक क्लासिक लकड़ी की "दादान" प्रणाली थी जिसमें 10 मिमी बोर्डों से बने 40 फ्रेम थे।
लेकिन उस सर्दी में, तापमान में उतार-चढ़ाव के कारण, अनुभवी मधुमक्खी पालकों को भी सामान्य से कहीं अधिक नुकसान हुआ।

इस प्रकार छत्ते की स्थिति की निगरानी के लिए एक प्रणाली का विचार आया।
हैबर पर कई लेख प्रकाशित करने और मधुमक्खी पालक मंच पर संचार करने के बाद, मैंने सरल से जटिल की ओर जाने का निर्णय लिया।
वजन ही एकमात्र निर्विवाद पैरामीटर है, लेकिन एक नियम के रूप में, मौजूदा सिस्टम केवल एक "संदर्भ" हाइव की निगरानी करते हैं।
यदि इसमें कुछ गलत होता है (उदाहरण के लिए, झुंड का प्रस्थान, मधुमक्खी रोग), तो संकेतक अप्रासंगिक हो जाते हैं।

इसलिए, एक माइक्रोकंट्रोलर का उपयोग करके एक साथ तीन छत्ते के वजन में परिवर्तन की निगरानी करने और बाद में अन्य "उपहार" जोड़ने का निर्णय लिया गया।
नतीजा यह हुआ कि 18650 बैटरी को एक बार चार्ज करने और दिन में एक बार आंकड़े भेजने पर लगभग एक महीने का संचालन समय वाला एक स्वायत्त सिस्टम बन गया।
मैंने डिज़ाइन को यथासंभव सरल बनाने की कोशिश की ताकि इसे बिना आरेख के भी, केवल तस्वीरों से दोहराया जा सके।

ऑपरेशन का तर्क इस प्रकार है: पहली शुरुआत/रीसेट के दौरान, छत्तों के नीचे स्थापित सेंसर की रीडिंग EEPROM में संग्रहीत की जाती है।
फिर, हर दिन, सूर्यास्त के बाद, सिस्टम "जागता है", रीडिंग पढ़ता है और दिन और उसके चालू होने के क्षण से वजन में परिवर्तन के साथ एक एसएमएस भेजता है।
इसके अलावा, बैटरी वोल्टेज मान प्रसारित होता है, और जब यह 3.5V तक गिर जाता है, तो चार्ज करने की आवश्यकता के बारे में एक चेतावनी जारी की जाती है, क्योंकि 3.4V से नीचे संचार मॉड्यूल चालू नहीं होता है, और वजन रीडिंग पहले से ही "दूर तैरती है"।

"क्या आपको याद है कि यह सब कैसे शुरू हुआ। सब कुछ पहली बार और बार-बार था।

हां, यह बिल्कुल हार्डवेयर का सेट है जो मूल रूप से था, हालांकि अंतिम संस्करण तक केवल स्ट्रेन गेज और तार ही बचे थे, लेकिन सबसे पहले चीज़ें।
वास्तव में, आपको केबल कॉइल की आवश्यकता नहीं है, इसकी कीमत 30 मीटर सीधी कॉइल के समान ही है।

यदि आप 3 एसएमडी एलईडी और पारंपरिक (आउटपुट) सोल्डरिंग के आधा सौ बिंदुओं को नष्ट करने से डरते नहीं हैं, तो जाएं!

तो, हमें उपकरण/सामग्री के निम्नलिखित सेट की आवश्यकता होगी:

Arduino प्रो मिनी 3V
आपको रैखिक कनवर्टर माइक्रोक्रिकिट पर ध्यान देना चाहिए - यह बिल्कुल 3.3V होना चाहिए - चिप मार्किंग KB 33/LB 33/DE A10 पर - मेरे चीनी में कुछ गड़बड़ है, और पूरा बैच
स्टोर के बोर्डों में 5-वोल्ट रेगुलेटर और 16 मेगाहर्ट्ज क्रिस्टल लगे थे।
CH340 चिप पर USB-Ttl - आप 5-वोल्ट का भी उपयोग कर सकते हैं, लेकिन फिर माइक्रोकंट्रोलर को फ्लैश करते समय, Arduino को GSM मॉड्यूल से डिस्कनेक्ट करने की आवश्यकता होगी ताकि बाद वाला जल न जाए।
PL2303 चिप पर आधारित बोर्ड विंडोज 10 के तहत काम नहीं करते हैं।
जीएसएम संचार मॉड्यूल गोउ टेक आईओटी जीए-6-बी या एआई-थिंकर ए-6 मिनी।
आप वहां क्यों रुके? Neoway M590 - एक डिज़ाइनर जिसे टैम्बोरिन, GSM SIM800L के साथ अलग-अलग नृत्यों की आवश्यकता होती है - को तर्क का गैर-मानक 2.8V स्तर पसंद नहीं आया, जिसके लिए तीन-वोल्ट Arduino के साथ भी समन्वय की आवश्यकता होती है।
इसके अलावा, AiThinker के समाधान में न्यूनतम ऊर्जा खपत होती है (एसएमएस भेजते समय मैंने 100mA से अधिक करंट नहीं देखा)।
जीएसएम जीपीआरएस 3डीबीआई एंटीना (ऊपर फोटो में - 9 बजे "पूंछ" वाला एक आयताकार स्कार्फ)
आपके मधुमक्खी पालन गृह के स्थान पर अच्छे कवरेज वाले ऑपरेटर का स्टार्टर पैकेज।
हां, पैकेज को पहले एक नियमित फोन में सक्रिय किया जाना चाहिए, प्रवेश पर पिन अनुरोध को अक्षम करें, और अपने खाते को टॉप अप करें।
अब "सेंसर", "IoT" की शैली में नामों के साथ कई विकल्प हैं - उनकी सदस्यता शुल्क थोड़ी कम है।
ड्यूपॉन्ट तार 20 सेमी महिला-महिला - 3 पीसी। (Arduino को USB-TTL से कनेक्ट करने के लिए)
3 पीसीएस। HX711 - तराजू के लिए एडीसी
6 किलोग्राम तक वजन के लिए 50 लोड सेल
15 मीटर 4-कोर टेलीफोन केबल - वजन मॉड्यूल को ARDUINO से जोड़ने के लिए।
फोटोरेसिस्टर GL5528 (यह महत्वपूर्ण है, 1 MΩ का गहरा प्रतिरोध और 10-20 kΩ का हल्का प्रतिरोध) और दो साधारण 20 kΩ प्रतिरोधक
Arduino को संचार मॉड्यूल से जोड़ने के लिए दो तरफा "मोटी" टेप 18x18 मिमी का एक टुकड़ा।
18650 बैटरी धारक और, वास्तव में, बैटरी स्वयं ~2600mAh है।
थोड़ा मोम या पैराफिन (मोमबत्ती-टैबलेट सुगंध लैंप) - नमी संरक्षण HX711 के लिए
स्ट्रेन गेज के आधार के लिए लकड़ी के बीम का एक टुकड़ा 25x50x300 मिमी।
सेंसर को आधार से जोड़ने के लिए 4,2x19 मिमी प्रेस वॉशर के साथ एक दर्जन सेल्फ-टैपिंग स्क्रू।

बैटरी को लैपटॉप के डिस्सेप्लर से लिया जा सकता है - यह नए की तुलना में कई गुना सस्ता है, और क्षमता चीनी अल्ट्राफ़ायर की तुलना में बहुत अधिक होगी - मुझे 1500 बनाम 450 मिला (यह आग के लिए 6800 है 😉

इसके अलावा, आपको स्थिर हाथों, एक EPSN-25 सोल्डरिंग आयरन, रोसिन और POS-60 सोल्डर की आवश्यकता होगी।

यहां तक कि 5 साल पहले भी मैंने तांबे की टिप के साथ एक सोवियत सोल्डरिंग आयरन का उपयोग किया था (सोल्डरिंग स्टेशन मेरे लिए काम नहीं करते थे - मैंने इसे टेस्ट ड्राइव के लिए लिया और ईपीएसएन के साथ सर्किट समाप्त कर दिया)।
लेकिन इसकी विफलता और कई चीनी राक्षसी नकली चीज़ों के बाद, बाद वाले को स्पार्टा कहा जाता था - जो कि इसके नाम के समान ही गंभीर था, बंद हो गया
थर्मोस्टेट वाले उत्पाद पर।

तो चलते हैं!

आरंभ करने के लिए, हम जीएसएम मॉड्यूल से दो एलईडी को अनसोल्डर करते हैं (वह स्थान जहां वे स्थित थे, एक नारंगी अंडाकार में घिरा हुआ है)
हम संपर्क पैड के साथ सिम कार्ड को मुद्रित सर्किट बोर्ड में डालते हैं, फोटो में बेवेल्ड कोने को एक तीर द्वारा दर्शाया गया है।

फिर हम Arduino बोर्ड (वर्गाकार चिप के बाईं ओर अंडाकार) पर एलईडी के साथ एक समान प्रक्रिया अपनाते हैं,
कंघी को चार संपर्कों से मिलाएं (1),
हम दो 20k रेसिस्टर्स लेते हैं, लीड्स को एक तरफ मोड़ते हैं, ट्विस्ट को पिन A5 के छेद में मिलाते हैं, शेष लीड्स Arduino (2) के RAW और GND में होते हैं,
हम फोटोरेसिस्टर के पैरों को 10 मिमी तक छोटा करते हैं और इसे बोर्ड (2) के जीएनडी और डी3 पिन से मिलाते हैं।

अब यह दो तरफा टेप के नीले विद्युत टेप का समय है - हम इसे संचार मॉड्यूल के सिम कार्ड धारक पर चिपकाते हैं, और शीर्ष पर - Arduino - लाल (चांदी) बटन हमारे सामने होता है और सिम कार्ड के ऊपर स्थित होता है।

हम बिजली की आपूर्ति को मिलाप करते हैं: साथ ही संचार मॉड्यूल कैपेसिटर (4) से रॉ आर्डिनो पिन तक।
तथ्य यह है कि संचार मॉड्यूल को अपनी बिजली आपूर्ति के लिए 3.4-4.2V की आवश्यकता होती है, और इसका PWR संपर्क एक स्टेप-डाउन कनवर्टर से जुड़ा होता है, इसलिए ली-आयन से संचालित करने के लिए, सर्किट के इस हिस्से को बायपास करके वोल्टेज की आपूर्ति की जानी चाहिए।

इसके विपरीत, Arduino में, हम एक रैखिक कनवर्टर के माध्यम से बिजली की आपूर्ति करते हैं - कम वर्तमान खपत पर, ड्रॉप-आउट वोल्टेज ड्रॉप 0.1V है।
लेकिन HX711 मॉड्यूल को एक स्थिर वोल्टेज की आपूर्ति करके, हम उन्हें कम वोल्टेज में संशोधित करने की आवश्यकता से छुटकारा पाते हैं (और साथ ही इस ऑपरेशन के परिणामस्वरूप बढ़ते शोर से भी)।

इसके बाद हम पिन PWR-A5, URX-D1 और UTX-D4 के बीच जंपर्स (5) को मिलाते हैं, GND-G (6) को ग्राउंड करते हैं और अंत में 18650 बैटरी होल्डर (7) से पावर लेते हैं, एंटीना (8) को कनेक्ट करते हैं।
अब हम एक USB-TTL कनवर्टर लेते हैं और RXD-TXD और TXD-RXD, GND-GND संपर्कों को डुपोंट तारों से ARDUINO (कंघी 1) से जोड़ते हैं:

ऊपर दी गई तस्वीर सिस्टम का पहला संस्करण (तीन में से) दिखाती है, जिसका उपयोग डिबगिंग के लिए किया गया था।

लेकिन अब हम सोल्डरिंग आयरन से थोड़ी देर के लिए ब्रेक लेंगे और सॉफ्टवेयर भाग पर आगे बढ़ेंगे।
मैं विंडोज़ के लिए क्रियाओं के क्रम का वर्णन करूँगा:
सबसे पहले, आपको प्रोग्राम को डाउनलोड और इंस्टॉल/अनपैक करना होगा अरुडिनो आईडीई — वर्तमान संस्करण 1.8.9 है, लेकिन मैं 1.6.4 का उपयोग करता हूं

सरलता के लिए, हम संग्रह को फ़ोल्डर C: arduino - "your_version_number" में अनपैक करते हैं, अंदर हमारे पास फ़ोल्डर्स /dist, ड्राइवर, उदाहरण, हार्डवेयर, जावा, lib, लाइब्रेरी, संदर्भ, उपकरण, साथ ही arduino निष्पादन योग्य फ़ाइल होगी (दूसरों के बीच में)।

अब हमें ADC के साथ काम करने के लिए एक लाइब्रेरी की आवश्यकता है HX711 - हरा बटन "क्लोन या डाउनलोड" - ज़िप डाउनलोड करें।
सामग्री (फ़ोल्डर HX711-मास्टर) को निर्देशिका C:arduino-“your_version_number” लाइब्रेरीज़ में रखा गया है

और निश्चित रूप से ड्राइवर के लिए यूएसबी-टीटीएल उसी जीथब से - अनपैक्ड आर्काइव से, इंस्टॉलेशन को केवल SETUP फ़ाइल के साथ लॉन्च किया जाता है।

ठीक है, आइए प्रोग्राम C:arduino-“your_version_number”arduino लॉन्च और कॉन्फ़िगर करें

"टूल्स" आइटम पर जाएं - "Arduino Pro या Pro Mini" बोर्ड, Atmega 328 3.3V 8 MHz प्रोसेसर, पोर्ट - सिस्टम COM1 के अलावा एक नंबर चुनें (यह USB-TTL एडाप्टर के साथ CH340 ड्राइवर स्थापित करने के बाद दिखाई देता है) जुड़े हुए)

ठीक है, निम्नलिखित स्केच (प्रोग्राम) को कॉपी करें और इसे Arduino IDE विंडो में पेस्ट करें

char phone_no[]="+123456789012"; // Your phone number that receive SMS with counry code 
#include <avr/sleep.h>  // ARDUINO sleep mode library
#include <SoftwareSerial.h> // Sofrware serial library
#include "HX711.h" // HX711 lib. https://github.com/bogde/HX711
#include <EEPROM.h> // EEPROM lib.
HX711 scale0(10, 14);
HX711 scale1(11, 14);
HX711 scale2(12, 14);
#define SENSORCNT 3
HX711 *scale[SENSORCNT];

SoftwareSerial mySerial(5, 4); // Set I/O-port TXD, RXD of GSM-shield  
byte pin2sleep=15; //  Set powerON/OFF pin

float delta00; // delta weight from start
float delta10;
float delta20;
float delta01; // delta weight from yesterday
float delta11;
float delta21;

float raw00; //raw data from sensors on first start
float raw10;
float raw20;
float raw01; //raw data from sensors on yesterday
float raw11;
float raw21;
float raw02; //actual raw data from sensors
float raw12;
float raw22;

word calibrate0=20880; //calibration factor for each sensor
word calibrate1=20880;
word calibrate2=20880;

word daynum=0; //numbers of day after start

int notsunset=0;

boolean setZero=false;

float readVcc() { // Read battery voltage function
  long result1000;
  float rvcc;  
  result1000 = analogRead(A5);
  rvcc=result1000;
  rvcc=6.6*rvcc/1023;
  return rvcc;
}

void setup() { // Setup part run once, at start

  pinMode(13, OUTPUT);  // Led pin init
  pinMode(2, INPUT_PULLUP); // Set pullup voltage
  Serial.begin(9600);
  mySerial.begin(115200); // Open Software Serial port to work with GSM-shield
  pinMode(pin2sleep, OUTPUT);// Itit ON/OFF pin for GSM
  digitalWrite(pin2sleep, LOW); // Turn ON modem
  delay(16000); // Wait for its boot 

scale[0] = &scale0; //init scale
scale[1] = &scale1;
scale[2] = &scale2;

scale0.set_scale();
scale1.set_scale();
scale2.set_scale();

delay(200);

setZero=digitalRead(2);

if (EEPROM.read(500)==EEPROM.read(501) || setZero) // first boot/reset with hiding photoresistor
//if (setZero)
{
raw00=scale0.get_units(16); //read data from scales
raw10=scale1.get_units(16);
raw20=scale2.get_units(16);
EEPROM.put(500, raw00); //write data to eeprom
EEPROM.put(504, raw10);
EEPROM.put(508, raw20);
for (int i = 0; i <= 24; i++) { //blinking LED13 on reset/first boot
    digitalWrite(13, HIGH);
    delay(500);
    digitalWrite(13, LOW);
    delay(500);
  }
}
else {
EEPROM.get(500, raw00); // read data from eeprom after battery change
EEPROM.get(504, raw10);
EEPROM.get(508, raw20);
digitalWrite(13, HIGH); // turn on LED 13 on 12sec. 
    delay(12000);
digitalWrite(13, LOW);
}

delay(200); // Test SMS at initial boot

//
  mySerial.println("AT+CMGF=1");    //  Send SMS part
  delay(2000);
  mySerial.print("AT+CMGS="");
  mySerial.print(phone_no); 
  mySerial.write(0x22);
  mySerial.write(0x0D);  // hex equivalent of Carraige return    
  mySerial.write(0x0A);  // hex equivalent of newline
  delay(2000);
  mySerial.println("INITIAL BOOT OK");
  mySerial.print("V Bat= ");
  mySerial.println(readVcc());
 if (readVcc()<3.5) {mySerial.print("!!! CHARGE BATTERY !!!");}
  delay(500);
  mySerial.println (char(26));//the ASCII code of the ctrl+z is 26
  delay(3000);

//  

raw02=raw00;
raw12=raw10;
raw22=raw20;

//scale0.power_down(); //power down all scales 
//scale1.power_down();
//scale2.power_down();

}

void loop() {

  attachInterrupt(0, NULL , RISING); // Interrupt on high lewel
  set_sleep_mode(SLEEP_MODE_PWR_DOWN); //Set ARDUINO sleep mode
  digitalWrite(pin2sleep, HIGH); // Turn OFF GSM-shield
  delay(2200);
  digitalWrite(pin2sleep, LOW); // Turn OFF GSM-shield
  delay(2200);
  digitalWrite(pin2sleep, HIGH);
  digitalWrite(13, LOW);
  scale0.power_down(); //power down all scales 
  scale1.power_down();
  scale2.power_down();
  delay(90000);
  sleep_mode(); // Go to sleep
  detachInterrupt(digitalPinToInterrupt(0)); // turn off external interrupt

  notsunset=0;
 for (int i=0; i <= 250; i++){
      if ( !digitalRead(2) ){ notsunset++; } //is a really sunset now? you shure?
      delay(360);
   }
  if ( notsunset==0 )
  { 
  digitalWrite(13, HIGH);
  digitalWrite(pin2sleep, LOW); // Turn-ON GSM-shield
  scale0.power_up(); //power up all scales 
  scale1.power_up();
  scale2.power_up();
  raw01=raw02;
  raw11=raw12;
  raw21=raw22;
  raw02=scale0.get_units(16); //read data from scales
  raw12=scale1.get_units(16);
  raw22=scale2.get_units(16);

  daynum++; 
  delta00=(raw02-raw00)/calibrate0; // calculate weight changes 
  delta01=(raw02-raw01)/calibrate0;
  delta10=(raw12-raw10)/calibrate1;
  delta11=(raw12-raw11)/calibrate1; 
  delta20=(raw22-raw20)/calibrate2;
  delta21=(raw22-raw21)/calibrate2;

  delay(16000);
  mySerial.println("AT+CMGF=1");    //  Send SMS part
  delay(2000);
  mySerial.print("AT+CMGS="");
  mySerial.print(phone_no); 
  mySerial.write(0x22);
  mySerial.write(0x0D);  // hex equivalent of Carraige return    
  mySerial.write(0x0A);  // hex equivalent of newline
  delay(2000);
  mySerial.print("Turn ");
  mySerial.println(daynum);
  mySerial.print("Hive1  ");
  mySerial.print(delta01);
  mySerial.print("   ");
  mySerial.println(delta00);
  mySerial.print("Hive2  ");
  mySerial.print(delta11);
  mySerial.print("   ");
  mySerial.println(delta10);
  mySerial.print("Hive3 ");
  mySerial.print(delta21);
  mySerial.print("   ");
  mySerial.println(delta20);

  mySerial.print("V Bat= ");
  mySerial.println(readVcc());
  if (readVcc()<3.5) {mySerial.print("!!! CHARGE BATTERY !!!");}
  delay(500);
  mySerial.println (char(26));//the ASCII code of the ctrl+z is 26
  delay(3000);

  }

}

पहली पंक्ति में, उद्धरण चिह्नों में, char फ़ोन_नो[]=”+123456789012″; — 123456789012 के बजाय अपना फ़ोन नंबर उस देश के कोड के साथ डालें जिस पर एसएमएस भेजा जाएगा।

अब हम चेक बटन दबाते हैं (ऊपर स्क्रीनशॉट में नंबर एक के ऊपर) - यदि नीचे (स्क्रीन पर नंबर तीन के नीचे) "संकलन पूरा हो गया है" - तो हम माइक्रोकंट्रोलर को फ्लैश कर सकते हैं।

तो, USB-TTL ARDUINO और कंप्यूटर से जुड़ा है, चार्ज की गई बैटरी को होल्डर में रखें (आमतौर पर नए Arduino पर LED प्रति सेकंड एक बार झपकने लगती है)।

अब फ़र्मवेयर के लिए - हम माइक्रोकंट्रोलर के लाल (सिल्वर) बटन को दबाने का प्रशिक्षण ले रहे हैं - इसे एक निश्चित समय पर सख्ती से करने की आवश्यकता होगी!!!
खाओ? "लोड" बटन (स्क्रीनशॉट में दोनों के ऊपर) पर क्लिक करें, और इंटरफ़ेस के नीचे (स्क्रीनशॉट में तीन के नीचे) लाइन को ध्यान से देखें।
जैसे ही "संकलन" शिलालेख "डाउनलोड" में बदल जाता है, लाल बटन दबाएं (रीसेट करें) - यदि सब कुछ ठीक है, तो यूएसबी-टीटीएल एडाप्टर पर रोशनी खुशी से झपकेगी, और इंटरफ़ेस के नीचे शिलालेख "अपलोड किया गया" होगा ”

अब, जबकि हम फ़ोन पर परीक्षण एसएमएस आने की प्रतीक्षा कर रहे हैं, मैं आपको बताऊंगा कि प्रोग्राम कैसे काम करता है:

फोटो डिबगिंग स्टैंड का दूसरा संस्करण दिखाता है।

पहली बार चालू होने पर, सिस्टम EEPROM के बाइट्स नंबर 500 और 501 की जांच करता है; यदि वे बराबर हैं, तो अंशांकन डेटा रिकॉर्ड नहीं किया जाता है, और एल्गोरिदम सेटअप अनुभाग पर आगे बढ़ता है।
यही बात तब होती है, जब चालू होने पर, फोटोरेसिस्टर को छायांकित किया जाता है (पेन कैप द्वारा) - रीसेट मोड सक्रिय होता है।

लोड कोशिकाओं को पहले से ही छत्ते के नीचे स्थापित किया जाना चाहिए, क्योंकि हम बस प्रारंभिक शून्य स्तर को ठीक करते हैं और फिर वजन में परिवर्तन को मापते हैं (अब शून्य बस आएंगे, क्योंकि हमने अभी तक कुछ भी कनेक्ट नहीं किया है)।
उसी समय, पिन 13 की अंतर्निहित एलईडी Arduino पर ब्लिंक करना शुरू कर देगी।
यदि रीसेट नहीं होता है, तो एलईडी 12 सेकंड के लिए जलती है।
इसके बाद, "इनिशियल बूट ओके" संदेश और बैटरी वोल्टेज के साथ एक परीक्षण एसएमएस भेजा जाता है।
संचार मॉड्यूल बंद हो जाता है, और 3 मिनट के बाद Arduino बोर्ड HX711 ADC बोर्ड को स्लीप मोड में डाल देता है और स्वयं सो जाता है।
यह देरी इसलिए की गई ताकि काम कर रहे जीएसएम मॉड्यूल से हस्तक्षेप न हो (स्विच ऑफ करने के बाद, यह कुछ समय के लिए "बीन्स") हो जाता है।

इसके बाद, हमारे पास दूसरे पिन पर एक फोटो सेंसर इंटरप्ट है (प्लस फ़ंक्शन सक्षम है)।
इस मामले में, ट्रिगरिंग के बाद, फोटोरेसिस्टर की स्थिति को अगले 3 मिनट के लिए जांचा जाता है - बार-बार/गलत ट्रिगरिंग को खत्म करने के लिए।
सामान्य बात यह है कि बिना किसी समायोजन के सिस्टम बादल वाले मौसम में खगोलीय सूर्यास्त के 10 मिनट बाद और साफ मौसम में 20 मिनट बाद सक्रिय हो जाता है।
हां, ताकि सिस्टम हर बार चालू होने पर रीसेट न हो, कम से कम पहला HX711 मॉड्यूल (पिन DT-D10, SCK-A0) कनेक्ट होना चाहिए

फिर स्ट्रेन गेज की रीडिंग ली जाती है, पिछले ऑपरेशन से वजन में परिवर्तन की गणना की जाती है (हाइव के बाद लाइन में पहला नंबर) और पहले सक्रियण से, बैटरी वोल्टेज की जांच की जाती है और यह जानकारी एसएमएस के रूप में भेजी जाती है:

वैसे, क्या आपको एसएमएस प्राप्त हुआ? बधाई हो! हम अधबीच में हैं! बैटरी को अभी होल्डर से हटाया जा सकता है; हमें अब कंप्यूटर की आवश्यकता नहीं होगी।

वैसे, मिशन नियंत्रण केंद्र इतना कॉम्पैक्ट निकला कि इसे मेयोनेज़ जार में रखा जा सकता है; मेरे मामले में, 30x60x100 मिमी (बिजनेस कार्ड से) मापने वाला एक पारभासी बॉक्स पूरी तरह से फिट बैठता है।

हां, संचार मॉड्यूल के कारण स्लीपिंग सिस्टम ~2.3mA - 90% की खपत करता है - यह पूरी तरह से बंद नहीं होता है, लेकिन स्टैंडबाय मोड में चला जाता है।

आइए सेंसर बनाना शुरू करें; सबसे पहले, सेंसर के लेआउट पर ध्यान दें:

यह छत्ता-शीर्ष दृश्य की एक योजना है।

शास्त्रीय रूप से, कोनों में 4 सेंसर स्थापित होते हैं (1,2,3,4)

हम अलग तरीके से मापेंगे. या यूं कहें कि तीसरे तरीके से भी. क्योंकि ब्रूडमाइंडर के लोग इसे अलग तरीके से करते हैं:

इस डिज़ाइन में, सेंसर स्थिति 1 और 2 पर स्थापित किए गए हैं, बिंदु 3,4 और XNUMX बीम पर आराम करते हैं।
तब सेंसर का वजन केवल आधा होता है।
हां, इस विधि में कम सटीकता है, लेकिन यह कल्पना करना अभी भी मुश्किल है कि मधुमक्खियां छत्ते की एक दीवार के साथ छत्ते की "जीभ" के साथ सभी फ़्रेमों का निर्माण करेंगी।

इसलिए, मैं आम तौर पर सेंसर को बिंदु 5 तक कम करने का प्रस्ताव करता हूं - फिर सिस्टम को ढालने की कोई आवश्यकता नहीं है, और प्रकाश छत्ता का उपयोग करते समय, एक सेंसर के साथ काम करना पूरी तरह से आवश्यक है।

सामान्य तौर पर, हमने HX711 पर दो प्रकार के मॉड्यूल, दो प्रकार के सेंसर और उन्हें जोड़ने के लिए दो विकल्पों का परीक्षण किया - एक पूर्ण व्हीटस्टोन ब्रिज (2 सेंसर) के साथ और एक आधे के साथ, जब दूसरे भाग को 1k प्रतिरोधों के साथ पूरक किया जाता है। 0.1% की सहनशीलता.
लेकिन बाद वाली विधि अवांछनीय है और सेंसर निर्माताओं द्वारा भी अनुशंसित नहीं है, इसलिए मैं केवल पहले का वर्णन करूंगा।

तो, एक छत्ते के लिए हम दो स्ट्रेन गेज और एक HX711 मॉड्यूल स्थापित करेंगे, वायरिंग आरेख इस प्रकार है:

ADC बोर्ड से Arduino तक 5 मीटर की 4-तार टेलीफोन केबल है - हमें याद है कि कैसे मधुमक्खियाँ छत्ते में जीएसएम उपकरणों को पसंद नहीं करतीं.

सामान्य तौर पर, हम सेंसर पर 8 सेमी "पूंछ" छोड़ते हैं, मुड़ी हुई जोड़ी को हटाते हैं और ऊपर की तस्वीर में सब कुछ मिलाप करते हैं।

बढ़ईगीरी का काम शुरू करने से पहले, मोम/पैराफिन को पानी के स्नान में पिघलाने के लिए एक उपयुक्त कंटेनर में रखें।

अब हम अपनी लकड़ी लेते हैं और इसे 100 मिमी प्रत्येक के तीन खंडों में विभाजित करते हैं

इसके बाद, हम 25 मिमी चौड़े, 7-8 मिमी गहरे एक अनुदैर्ध्य खांचे को चिह्नित करते हैं, हैकसॉ और छेनी का उपयोग करके अतिरिक्त हटा देते हैं - एक यू-आकार की प्रोफ़ाइल उभरनी चाहिए।

क्या मोम गर्म हो गया है? - हम अपने एडीसी बोर्डों को वहां डुबाते हैं - यह उन्हें नमी/कोहरे से बचाएगा:

हम यह सब एक लकड़ी के आधार पर रखते हैं (सड़न को रोकने के लिए इसे एक एंटीसेप्टिक के साथ इलाज किया जाना चाहिए):

और अंत में, हम सेंसर को सेल्फ-टैपिंग स्क्रू से ठीक करते हैं:

नीले विद्युत टेप वाला एक विकल्प भी था, लेकिन मानवता के कारण मैं इसे प्रस्तुत नहीं कर रहा हूं 😉

Arduino की ओर से हम निम्नलिखित कार्य करते हैं:

हम अपने टेलीफोन केबल उतारते हैं, रंगीन तारों को एक साथ मोड़ते हैं, और उन्हें टिन करते हैं।

उसके बाद, फोटो के अनुसार बोर्ड संपर्कों को मिलाएं:

बस, अब अंतिम जांच के लिए, हम सेंसर को सर्कल के सेक्टरों में रखते हैं, शीर्ष पर प्लाईवुड का एक टुकड़ा, नियंत्रक को रीसेट करते हैं (हम फोटोडायोड पर पेन कैप के साथ एक बैटरी डालते हैं)।

उसी समय, Arduino पर LED झपकनी चाहिए और एक परीक्षण एसएमएस आना चाहिए।

इसके बाद, फोटोसेल से ढक्कन हटा दें और पानी को 1.5 लीटर प्लास्टिक की बोतल में भरें।
हम बोतल को प्लाईवुड पर रखते हैं और यदि इसे चालू हुए कई मिनट पहले ही बीत चुके हैं, तो हम टोपी को वापस फोटोरेसिस्टर पर रख देते हैं (सूर्यास्त का अनुकरण करते हुए)।

तीन मिनट के बाद, Arduino पर LED जल जाएगी, और आपको सभी स्थितियों में लगभग 1 किलो वजन मान वाला एक एसएमएस प्राप्त होना चाहिए।

बधाई हो! सिस्टम को सफलतापूर्वक असेंबल किया गया है!

यदि अब हम सिस्टम को फिर से काम करने के लिए मजबूर करते हैं, तो पहले वजन कॉलम में शून्य होगा।

हां, वास्तविक परिस्थितियों में फोटोरेसिस्टर को लंबवत ऊपर की ओर उन्मुख करने की सलाह दी जाती है।

अब मैं एक संक्षिप्त उपयोगकर्ता पुस्तिका दूंगा:

छत्ते की पिछली दीवारों के नीचे स्ट्रेन गेज स्थापित करें (सामने वाले दीवारों के नीचे ~30 मिमी मोटा एक बीम/बोर्ड रखें)
फोटोरेसिस्टर को शेड करें और बैटरी स्थापित करें - एलईडी झपकनी चाहिए और आपको "प्रारंभिक बूट ठीक है" टेक्स्ट के साथ एक परीक्षण एसएमएस प्राप्त होना चाहिए।
केंद्रीय इकाई को छत्ते से अधिकतम दूरी पर रखें ताकि मधुमक्खियों के साथ काम करते समय तार हस्तक्षेप न करें।
हर शाम, सूर्यास्त के बाद, आपको दिन भर और लॉन्च के क्षण से आपके वजन में बदलाव के बारे में एक एसएमएस प्राप्त होगा।
जब बैटरी वोल्टेज 3.5V तक पहुंच जाएगा, तो एसएमएस "!!!" लाइन के साथ समाप्त हो जाएगा। प्रभारी बैटरी!!!"
एक 2600mAh बैटरी पर परिचालन समय लगभग एक महीने है।
यदि बैटरी बदल दी जाती है, तो छत्तों के वजन में दैनिक परिवर्तन याद नहीं रहता है।

आगे क्या है?

यह पता लगाएं कि यह सब जीथब के लिए एक प्रोजेक्ट में कैसे डाला जाए
पालीवोडा प्रणाली के छत्ते में 3 मधुमक्खी परिवार शुरू करें (या लोगों में सींग वाले)
"बन्स" जोड़ें - आर्द्रता, तापमान मापना, और सबसे महत्वपूर्ण - मधुमक्खियों की भिनभिनाहट का विश्लेषण करना।

अभी के लिए बस इतना ही, ईमानदारी से आपका, इलेक्ट्रिक मधुमक्खी पालक एंड्री

स्रोत: www.habr.com

$30 में तीन छत्तों के वजन की एसएमएस-निगरानी

एक टिप्पणी जोड़ें उत्तर रद्द