टेलीग्राम v 2.0 से मिक्रोटिक स्क्रिप्ट का रिमोट सक्षमीकरण

सभी को देर से छुट्टियाँ मुबारक। ये थीम बेहतर है 2016 में मैंने जो लिखा था उसका संस्करण यहाँ.

सामान्य तौर पर, ऑपरेशन का सिद्धांत नहीं बदला है, एकमात्र अंतर यह है कि अब यह बिना किसी देरी के तुरंत काम करता है।

हम स्क्रिप्ट को मिकरोटिक पर अपलोड करते हैं, बॉटआईडी और चैटआईडी को अपने हिसाब से बदलते हैं और इसके लिए एक शेड्यूल बनाते हैं। स्टार्टअप पर "प्रारंभ समय" पैरामीटर सेट करें (स्टार्टअप पर स्क्रिप्ट चलाएँ।)
"अंतराल": 00:00:00
अन्यथा सब कुछ वैसा ही है जैसा था।

टेलीग्राम-v2

:delay 10
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;
:local chatId 0;
:local messageId 0;


:local parse do={
  :local startLoc ([:find $content $variable -1] + [:len $variable] + 2);
  :local commaLoc ([:find $content "," $startLoc] - 1 + 1);
  :local braceLoc ([:find $content "}" $startLoc] - 1 + 1);
  :local endLoc $commaLoc;
  :local startSymbol [:pick $content $startLoc]
  :if ($braceLoc != 0 and ($commaLoc = 0 or $braceLoc < $commaLoc)) do={
    :set endLoc $braceLoc;
  };
  :if ($startSymbol = "{") do={
    :set endLoc ($braceLoc + 1);
  };
  :if ($quotas = true) do={
    :set startLoc ($startLoc + 1);
    :set endLoc ($endLoc - 1);
  }
  :if ($endLoc < $startLoc) do={
    :set endLoc ($startLoc + 1);
  };
  :local message [:pick $content $startLoc $endLoc]
  #:log info $message;
  :return $message;
}


:while ( true ) do={
  :do {
    #:log info "https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60";
    :tool fetch url=("https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60") dst-path="getUpdates";
    :local content [/file get [/file find name=getUpdates] contents] ;
    #:log info $content;
    :if ([:len $content] > 30) do={
      :set messageId ([$parse content=$content variable="update_id"] + 1)
      :local message [$parse content=$content variable="text" quotas=true]
      :local chat [$parse content=$content variable="chat"]
      :local chatId [$parse content=$chat variable="id"]      
      
      :if (($chatId = $myChatID) and ([/system script find name=$message] != "")) do={
        :system script run $message;
      } else={
        :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$chatId&text=$mtIdentity: Unknown command: $message") keep-result=no
      }
    }
  } on-error={}
};

कुछ वर्षों के उपयोग के बाद, एक बग का पता चला: किसी अज्ञात कारण से, कमजोर मिकरोटिक स्क्रिप्ट को रोक देता है, लेकिन अधिक शक्तिशाली लोगों पर यह बिना रुके काम करता है।

इन उद्देश्यों के लिए, मैंने वॉचडॉग बैसाखी का सहारा लिया। यहां हम स्क्रिप्ट का नाम बदलकर ऊपर बताए अनुसार कर देते हैं। और पुनरारंभ अंतराल को 5 मिनट पर सेट करें। हर 5 मिनट में हमारा "वॉचडॉग" स्क्रिप्ट की जांच करेगा और यदि यह काम नहीं करता है, तो यह इसे चलाएगा।

WatchDogT.me

:global scriptname "t.me"
:if ([:len [/system script job find script=$"scriptname"]] > 0) do={
:log info "$scriptname Already Running - killing old script before continuing"
:foreach counter in=[/system script job find script=$"scriptname"] do={
/system script job remove $counter
}
}
/system script run $scriptname

खैर, मिठाई के लिए स्क्रिप्ट मिकरोटिक फोरम से ली गई थी।
लॉग से महत्वपूर्ण विषयों को हमारे कार्ट में भेजता है।

हम स्क्रिप्ट को शेड्यूल में जोड़ते हैं और हर 5 मिनट में पुनरारंभ अंतराल निर्दिष्ट करते हैं, BotID और ChatID को अपने हिसाब से बदलते हैं।

सूचित करें-लॉग

:global lastTime
:global output
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;

:local LogGet [ :toarray [ /log find topics~"critical" || message~"login failure" || message~"[Ff]ailure" ] ] ;
:local LogtLineCount [ :len $LogGet ] ;
if ($LogtLineCount > 0) do={
   :local currentTime "$[ /log get [ :pick $LogGet ($LogtLineCount -1) ] time ]";
   :if ([:len $currentTime] = 10 ) do={
      :set currentTime [ :pick $currentTime 0 10 ];
   }
   :set output "$currentTime - $[/log get [ :pick $LogGet ($LogtLineCount-1) ] message ]";
   :if (([:len $lastTime] < 1) || (([:len $lastTime] > 0) && ($lastTime != $currentTime))) do={
      :set lastTime $currentTime ;
         :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$myChatID&text="$mtIdentity" :  $output") keep-result=no
   }
}

हमें परिणाम मिलता है:

स्रोत: www.habr.com