🥇भूभौतिकी में वोल्फ्राम गणितज्ञ

ब्लॉग के लेखक को धन्यवाद एंटोन एकिमेंको उसकी रिपोर्ट के लिए

परिचय

यह नोट सम्मेलन के मद्देनजर लिखा गया था वोल्फ्राम रूसी प्रौद्योगिकी सम्मेलन और इसमें मेरे द्वारा दी गई रिपोर्ट का सारांश शामिल है। यह आयोजन जून में सेंट पीटर्सबर्ग में हुआ था। यह ध्यान में रखते हुए कि मैं सम्मेलन स्थल से एक ब्लॉक दूर काम करता हूं, मैं इस कार्यक्रम में शामिल हुए बिना नहीं रह सका। 2016 और 2017 में, मैंने सम्मेलन रिपोर्टें सुनीं, और इस वर्ष मैंने एक प्रस्तुति दी। सबसे पहले, एक दिलचस्प (मुझे ऐसा लगता है) विषय सामने आया है, जिस पर हम विकास कर रहे हैं किरिल बेलोव, और दूसरी बात, प्रतिबंध नीति के संबंध में रूसी संघ के कानून के लंबे अध्ययन के बाद, जिस उद्यम में मैं काम करता हूं, वहां दो लाइसेंस सामने आए वोल्फ्राम मैथमैटिका.

अपने भाषण के विषय पर आगे बढ़ने से पहले, मैं कार्यक्रम के अच्छे संगठन पर ध्यान देना चाहूंगा। सम्मेलन का विजिटिंग पेज कज़ान कैथेड्रल की एक छवि का उपयोग करता है। कैथेड्रल सेंट पीटर्सबर्ग के मुख्य आकर्षणों में से एक है और उस हॉल से बहुत स्पष्ट रूप से दिखाई देता है जिसमें सम्मेलन हुआ था।

सेंट पीटर्सबर्ग राज्य आर्थिक विश्वविद्यालय के प्रवेश द्वार पर, प्रतिभागियों का स्वागत छात्रों में से सहायकों से हुआ - उन्होंने उन्हें भटकने नहीं दिया। पंजीकरण के दौरान, छोटे स्मृति चिन्ह दिए गए (एक खिलौना - एक चमकती स्पाइक, एक कलम, वोल्फ्राम प्रतीकों वाले स्टिकर)। सम्मेलन कार्यक्रम में दोपहर के भोजन और कॉफी ब्रेक को भी शामिल किया गया था। मैंने पहले ही समूह की दीवार पर स्वादिष्ट कॉफी और पाई के बारे में नोट कर लिया है - शेफ बहुत अच्छे हैं। इस परिचयात्मक भाग के साथ, मैं इस बात पर जोर देना चाहूंगा कि यह आयोजन, इसका प्रारूप और स्थान पहले से ही सकारात्मक भावनाएं ला रहे हैं।

मेरे और किरिल बेलोव द्वारा तैयार की गई रिपोर्ट को "अनुप्रयुक्त भूभौतिकी में समस्याओं को हल करने के लिए वोल्फ्राम मैथमेटिका का उपयोग करना" कहा जाता है। भूकंपीय डेटा का वर्णक्रमीय विश्लेषण या "प्राचीन नदियाँ कहाँ बहती थीं।" रिपोर्ट की सामग्री में दो भाग शामिल हैं: पहला, उपलब्ध एल्गोरिदम का उपयोग वोल्फ्राम मैथमैटिका भूभौतिकीय डेटा का विश्लेषण करने के लिए, और दूसरी बात, यह है कि भूभौतिकीय डेटा को वोल्फ्राम मैथेमेटिका में कैसे डाला जाए।

भूकंपीय अन्वेषण

सबसे पहले आपको भूभौतिकी में एक संक्षिप्त भ्रमण करने की आवश्यकता है। भूभौतिकी वह विज्ञान है जो चट्टानों के भौतिक गुणों का अध्ययन करता है। खैर, चूंकि चट्टानों में अलग-अलग गुण होते हैं: विद्युत, चुंबकीय, लोचदार, भूभौतिकी के संबंधित तरीके हैं: विद्युत पूर्वेक्षण, चुंबकीय पूर्वेक्षण, भूकंपीय पूर्वेक्षण... इस लेख के संदर्भ में, हम केवल भूकंपीय पूर्वेक्षण पर अधिक विस्तार से चर्चा करेंगे। भूकंपीय अन्वेषण तेल और गैस की खोज का मुख्य तरीका है। यह विधि लोचदार कंपन की उत्तेजना और अध्ययन क्षेत्र की रचना करने वाली चट्टानों से प्रतिक्रिया की बाद की रिकॉर्डिंग पर आधारित है। कंपन भूमि पर (डायनामाइट या लोचदार कंपन के गैर-विस्फोटक कंपन स्रोतों के साथ) या समुद्र में (एयर गन के साथ) उत्तेजित होते हैं। लोचदार कंपन चट्टान के द्रव्यमान के माध्यम से फैलते हैं, विभिन्न गुणों के साथ परतों की सीमाओं पर अपवर्तित और प्रतिबिंबित होते हैं। परावर्तित तरंगें सतह पर लौट आती हैं और जमीन पर जियोफोन (आमतौर पर एक कुंडल में निलंबित चुंबक की गति पर आधारित इलेक्ट्रोडायनामिक उपकरण) या समुद्र में हाइड्रोफोन (पीजोइलेक्ट्रिक प्रभाव के आधार पर) द्वारा रिकॉर्ड की जाती हैं। लहरों के आगमन के समय से भूवैज्ञानिक परतों की गहराई का अंदाजा लगाया जा सकता है।

भूकंपीय पोत खींचने के उपकरण

एयर गन लोचदार कंपन को उत्तेजित करती है

लहरें चट्टान के द्रव्यमान से होकर गुजरती हैं और हाइड्रोफोन द्वारा रिकॉर्ड की जाती हैं

सेंट पीटर्सबर्ग में ब्लागोवेशचेंस्की ब्रिज के पास घाट पर भूभौतिकीय सर्वेक्षण अनुसंधान पोत "इवान गुबकिन"

भूकंपीय संकेत मॉडल

चट्टानों के अलग-अलग भौतिक गुण होते हैं। भूकंपीय अन्वेषण के लिए, लोचदार गुण मुख्य रूप से महत्वपूर्ण हैं - लोचदार कंपन और घनत्व के प्रसार की गति। यदि दो परतों में समान या समान गुण हैं, तो तरंग उनके बीच की सीमा को "ध्यान नहीं देगी"। यदि परतों में तरंग की गति भिन्न होती है, तो परतों की सीमा पर परावर्तन होगा। गुणों में अंतर जितना अधिक होगा, प्रतिबिंब उतना ही तीव्र होगा। इसकी तीव्रता परावर्तन गुणांक (आरसी) द्वारा निर्धारित की जाएगी:

जहां ρ चट्टान का घनत्व है, ν तरंग गति है, 1 और 2 ऊपरी और निचली परतों को दर्शाते हैं।

सबसे सरल और सबसे अधिक उपयोग किए जाने वाले भूकंपीय सिग्नल मॉडल में से एक कनवल्शन मॉडल है, जब रिकॉर्ड किए गए भूकंपीय निशान को एक जांच पल्स के साथ प्रतिबिंब गुणांक के अनुक्रम के कनवल्शन के परिणाम के रूप में दर्शाया जाता है:

कहां एस(टी) - भूकंपीय निशान, यानी वह सब कुछ जो एक निश्चित रिकॉर्डिंग समय के दौरान हाइड्रोफोन या जियोफोन द्वारा रिकॉर्ड किया गया था, डब्ल्यू(टी) - एयर गन द्वारा उत्पन्न सिग्नल, एन(टी) - यादृच्छिक शोर.

आइए एक उदाहरण के रूप में सिंथेटिक भूकंपीय निशान की गणना करें। हम प्रारंभिक संकेत के रूप में भूकंपीय अन्वेषण में व्यापक रूप से उपयोग किए जाने वाले रिकर पल्स का उपयोग करेंगे।

length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]

प्रारंभिक भूकंपीय आवेग

हम 300 एमएस और 600 एमएस की गहराई पर दो सीमाएँ निर्धारित करेंगे, और प्रतिबिंब गुणांक यादृच्छिक संख्या होंगे

rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]

परावर्तन गुणांकों का अनुक्रम

आइए भूकंपीय निशान की गणना करें और प्रदर्शित करें। चूंकि परावर्तन गुणांक के अलग-अलग संकेत होते हैं, इसलिए हमें भूकंपीय निशान पर दो वैकल्पिक प्रतिबिंब मिलते हैं।

traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]

नकली ट्रैक

इस उदाहरण के लिए, आरक्षण करना आवश्यक है - वास्तव में, परतों की गहराई, निश्चित रूप से, मीटर में निर्धारित की जाती है, और भूकंपीय निशान की गणना समय डोमेन के लिए होती है। गहराई को मीटर में सेट करना और परतों में वेग को जानकर आगमन के समय की गणना करना अधिक सही होगा। इस मामले में, मैंने तुरंत परतों को समय अक्ष पर सेट कर दिया।

यदि हम क्षेत्र अनुसंधान के बारे में बात करते हैं, तो ऐसे अवलोकनों के परिणामस्वरूप बड़ी संख्या में समान समय श्रृंखला (भूकंपीय निशान) दर्ज की जाती हैं। उदाहरण के लिए, 25 किमी लंबी और 15 किमी चौड़ी साइट का अध्ययन करते समय, जहां, काम के परिणामस्वरूप, प्रत्येक ट्रेस 25x25 मीटर मापने वाले सेल को दर्शाता है (ऐसे सेल को बिन कहा जाता है), अंतिम डेटा सरणी में 600000 ट्रेस होंगे। 1 एमएस के नमूना समय और 5 सेकंड के रिकॉर्डिंग समय के साथ, अंतिम डेटा फ़ाइल 11 जीबी से अधिक होगी, और मूल "कच्ची" सामग्री की मात्रा सैकड़ों गीगाबाइट हो सकती है।

उनके साथ कैसे काम करना है वोल्फ्राम मैथमैटिका?

पैकेज भूविज्ञानआईओ

पैकेज का विकास शुरू हुआ सवाल रूसी भाषी सहायता समूह की वीके दीवार पर। समुदाय की प्रतिक्रियाओं के लिए धन्यवाद, एक समाधान बहुत जल्दी मिल गया। और परिणामस्वरूप, यह एक गंभीर विकास में बदल गया। संगत वोल्फ्राम सामुदायिक दीवार पोस्ट इसे मॉडरेटर द्वारा भी चिह्नित किया गया था। वर्तमान में, पैकेज निम्नलिखित डेटा प्रकारों के साथ काम करने का समर्थन करता है जो भूवैज्ञानिक उद्योग में सक्रिय रूप से उपयोग किए जाते हैं:

ZMAP और IRAP प्रारूपों में मानचित्र डेटा का आयात
एलएएस प्रारूप कुओं में माप का आयात
भूकंपीय फ़ाइल स्वरूप का इनपुट और आउटपुट सेगी

पैकेज को स्थापित करने के लिए, आपको असेंबल किए गए पैकेज के डाउनलोड पृष्ठ पर दिए गए निर्देशों का पालन करना होगा, अर्थात। निम्नलिखित कोड को किसी भी रूप में निष्पादित करें गणितज्ञ नोटबुक:

If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
    "https://wolfr.am/FiQ5oFih", 
    FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]

जिसके बाद पैकेज को डिफ़ॉल्ट फ़ोल्डर में स्थापित किया जाएगा, जिसका पथ निम्नानुसार प्राप्त किया जा सकता है:

FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]

उदाहरण के तौर पर, हम पैकेज की मुख्य क्षमताओं का प्रदर्शन करेंगे। वोल्फ्राम भाषा में पैकेज के लिए कॉल पारंपरिक रूप से की जाती है:

Get["GeologyIO`"]

का उपयोग करके पैकेज विकसित किया गया है वोल्फ्राम कार्यक्षेत्र. यह आपको दस्तावेज़ीकरण के साथ पैकेज की मुख्य कार्यक्षमता प्रदान करने की अनुमति देता है, जो प्रस्तुति प्रारूप के संदर्भ में वोल्फ्राम मैथमैटिका के दस्तावेज़ीकरण से भिन्न नहीं है, और पहले परिचित के लिए परीक्षण फ़ाइलों के साथ पैकेज प्रदान करता है।

ऐसी फ़ाइल, विशेष रूप से, फ़ाइल "Marmousi.segy" है - यह भूवैज्ञानिक अनुभाग का एक सिंथेटिक मॉडल है, जिसे फ्रांसीसी पेट्रोलियम संस्थान द्वारा विकसित किया गया था। इस मॉडल का उपयोग करते हुए, डेवलपर्स तरंग क्षेत्र मॉडलिंग, डेटा प्रोसेसिंग, भूकंपीय ट्रेस व्युत्क्रम आदि के लिए अपने स्वयं के एल्गोरिदम का परीक्षण करते हैं। मार्मौसी मॉडल स्वयं रिपॉजिटरी में संग्रहीत है जहां से पैकेज स्वयं डाउनलोड किया गया था। फ़ाइल प्राप्त करने के लिए, निम्नलिखित कोड चलाएँ:

If[Not[FileExistsQ["Marmousi.segy"]], 
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]

आयात परिणाम - SEGYData ऑब्जेक्ट

SEGY प्रारूप में अवलोकनों के बारे में विभिन्न जानकारी संग्रहीत करना शामिल है। सबसे पहले, ये टेक्स्ट टिप्पणियाँ हैं। इसमें कार्य के स्थान, माप करने वाली कंपनियों के नाम आदि के बारे में जानकारी शामिल है। हमारे मामले में, इस हेडर को टेक्स्टहेडर कुंजी के साथ अनुरोध द्वारा कॉल किया जाता है। यहाँ एक संक्षिप्त पाठ शीर्षलेख है:

Short[marmousi["TextHeader"]]

"मर्मौसी डेटा सेट संस्थान में तैयार किया गया था...न्यूनतम वेग 1500 मीटर/सेकेंड और अधिकतम 5500 मीटर/सेकेंड)"

आप "निशान" कुंजी का उपयोग करके भूकंपीय निशानों तक पहुंच कर वास्तविक भूवैज्ञानिक मॉडल प्रदर्शित कर सकते हैं (पैकेज की विशेषताओं में से एक यह है कि चाबियाँ केस-असंवेदनशील हैं):

ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]

मॉडल मार्मौसी

वर्तमान में, पैकेज आपको बड़ी फ़ाइलों से भागों में डेटा लोड करने की भी अनुमति देता है, जिससे उन फ़ाइलों को संसाधित करना संभव हो जाता है जिनका आकार दसियों गीगाबाइट तक पहुंच सकता है। पैकेज के कार्यों में डेटा को .segy में निर्यात करने और फ़ाइल के अंत में आंशिक रूप से जोड़ने के कार्य भी शामिल हैं।

अलग से, .segy फ़ाइलों की जटिल संरचना के साथ काम करते समय पैकेज की कार्यक्षमता पर ध्यान देना उचित है। चूँकि यह आपको कुंजियों और अनुक्रमणिका का उपयोग करके न केवल व्यक्तिगत ट्रेस और हेडर तक पहुंचने की अनुमति देता है, बल्कि उन्हें बदलने और फिर उन्हें एक फ़ाइल में लिखने की भी अनुमति देता है। जियोलॉजीआईओ के कार्यान्वयन के कई तकनीकी विवरण इस लेख के दायरे से बाहर हैं और संभवतः एक अलग विवरण के योग्य हैं।

भूकंपीय अन्वेषण में वर्णक्रमीय विश्लेषण की प्रासंगिकता

वोल्फ्राम मैथमेटिका में भूकंपीय डेटा आयात करने की क्षमता आपको प्रयोगात्मक डेटा के लिए अंतर्निहित सिग्नल प्रोसेसिंग कार्यक्षमता का उपयोग करने की अनुमति देती है। चूँकि प्रत्येक भूकंपीय निशान एक समय श्रृंखला का प्रतिनिधित्व करता है, उनका अध्ययन करने के लिए मुख्य उपकरणों में से एक वर्णक्रमीय विश्लेषण है। भूकंपीय डेटा की आवृत्ति संरचना का विश्लेषण करने के लिए पूर्वापेक्षाओं में, हम उदाहरण के लिए, निम्नलिखित नाम दे सकते हैं:

विभिन्न प्रकार की तरंगों की विशेषता अलग-अलग आवृत्ति संरचना होती है। यह आपको उपयोगी तरंगों को उजागर करने और हस्तक्षेप तरंगों को दबाने की अनुमति देता है।
चट्टान के गुण जैसे सरंध्रता और संतृप्ति आवृत्ति संरचना को प्रभावित कर सकते हैं। इससे सर्वोत्तम गुणों वाली चट्टानों की पहचान करना संभव हो जाता है।
अलग-अलग मोटाई वाली परतें अलग-अलग आवृत्ति रेंज में विसंगतियों का कारण बनती हैं।

इस लेख के सन्दर्भ में तीसरा बिन्दु मुख्य है। अलग-अलग मोटाई वाली परत के मामले में भूकंपीय निशानों की गणना के लिए नीचे एक कोड टुकड़ा है - एक पच्चर मॉडल। इस मॉडल का पारंपरिक रूप से भूकंपीय अन्वेषण में हस्तक्षेप प्रभावों का विश्लेषण करने के लिए अध्ययन किया जाता है जब कई परतों से परावर्तित तरंगें एक-दूसरे पर आरोपित होती हैं।

nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]

पिंच-आउट फॉर्मेशन का मॉडल

वेज के अंदर लहर की गति 4500 मीटर/सेकेंड है, वेज के बाहर 4000 मीटर/सेकेंड है, और घनत्व स्थिर 2200 ग्राम/सेमी³ माना जाता है। ऐसे मॉडल के लिए, हम प्रतिबिंब गुणांक और भूकंपीय निशान की गणना करते हैं।

rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
	ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
		{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]

वेज मॉडल के लिए भूकंपीय निशान

इस चित्र में दिखाए गए भूकंपीय निशानों के अनुक्रम को भूकंपीय खंड कहा जाता है। जैसा कि आप देख सकते हैं, इसकी व्याख्या सहज स्तर पर भी की जा सकती है, क्योंकि परावर्तित तरंगों की ज्यामिति स्पष्ट रूप से उस मॉडल से मेल खाती है जो पहले निर्दिष्ट किया गया था। यदि आप निशानों का अधिक विस्तार से विश्लेषण करते हैं, तो आप देखेंगे कि 1 से लेकर लगभग 30 तक के निशान अलग-अलग नहीं हैं - संरचना की छत से और नीचे से प्रतिबिंब एक दूसरे को ओवरलैप नहीं करते हैं। 31वें ट्रेस से शुरू होकर, प्रतिबिंब हस्तक्षेप करना शुरू कर देते हैं। और, हालांकि मॉडल में, प्रतिबिंब गुणांक क्षैतिज रूप से नहीं बदलते हैं - भूकंपीय निशान संरचना की मोटाई में परिवर्तन के साथ अपनी तीव्रता बदलते हैं।

आइए गठन की ऊपरी सीमा से प्रतिबिंब के आयाम पर विचार करें। 60वें मार्ग से प्रारंभ करके परावर्तन की तीव्रता बढ़ने लगती है और 70वें मार्ग पर यह अधिकतम हो जाती है। इस प्रकार छत और परतों के नीचे से तरंगों का हस्तक्षेप प्रकट होता है, जिससे कुछ मामलों में भूकंपीय रिकॉर्ड में महत्वपूर्ण विसंगतियाँ होती हैं।

ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]

पच्चर के ऊपरी किनारे से परावर्तित तरंग के आयाम का ग्राफ़

यह तर्कसंगत है कि जब सिग्नल कम-आवृत्ति होता है, तो बड़े गठन की मोटाई पर हस्तक्षेप दिखाई देने लगता है, और उच्च-आवृत्ति सिग्नल के मामले में, छोटी मोटाई पर हस्तक्षेप होता है। निम्नलिखित कोड स्निपेट 35 हर्ट्ज, 55 हर्ट्ज और 85 हर्ट्ज की आवृत्तियों के साथ एक सिग्नल बनाता है।

waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]

35 हर्ट्ज, 55 हर्ट्ज, 85 हर्ट्ज की आवृत्तियों के साथ स्रोत संकेतों का एक सेट

भूकंपीय निशानों की गणना करके और परावर्तित तरंग आयामों के ग्राफ़ बनाकर, हम देख सकते हैं कि विभिन्न आवृत्तियों के लिए अलग-अलग गठन मोटाई पर एक विसंगति देखी जाती है।

tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];

lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];

Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]

विभिन्न आवृत्तियों के लिए पच्चर के ऊपरी किनारे से परावर्तित तरंग के आयाम के ग्राफ़

भूकंपीय अवलोकनों के परिणामों से गठन की मोटाई के बारे में निष्कर्ष निकालने की क्षमता बेहद उपयोगी है, क्योंकि तेल की खोज में मुख्य कार्यों में से एक कुआं बिछाने के लिए सबसे आशाजनक बिंदुओं का आकलन करना है (यानी, वे क्षेत्र जहां गठन है) मोटा)। इसके अलावा, भूवैज्ञानिक खंड में ऐसी वस्तुएं हो सकती हैं जिनकी उत्पत्ति से संरचना की मोटाई में तेज बदलाव होता है। यह वर्णक्रमीय विश्लेषण को उनके अध्ययन के लिए एक प्रभावी उपकरण बनाता है। लेख के अगले भाग में हम ऐसी भूवैज्ञानिक वस्तुओं पर अधिक विस्तार से विचार करेंगे।

प्रयोगात्मक डेटा। आपने उन्हें कहाँ से प्राप्त किया और उनमें क्या देखना है?

लेख में विश्लेषण की गई सामग्री पश्चिमी साइबेरिया में प्राप्त की गई थी। यह क्षेत्र, जैसा कि बिना किसी अपवाद के शायद सभी जानते हैं, हमारे देश का मुख्य तेल उत्पादक क्षेत्र है। पिछली शताब्दी के 60 के दशक में इस क्षेत्र में जमा का सक्रिय विकास शुरू हुआ। तेल भंडारों की खोज का मुख्य तरीका भूकंपीय अन्वेषण है। इस क्षेत्र की उपग्रह छवियों को देखना दिलचस्प है। छोटे पैमाने पर, आप बड़ी संख्या में दलदलों और झीलों को देख सकते हैं; मानचित्र को बड़ा करके, आप क्लस्टर कुओं की ड्रिलिंग साइटों को देख सकते हैं, और मानचित्र को सीमा तक बड़ा करके, आप उन प्रोफाइलों के समाशोधन को भी अलग कर सकते हैं जिनके साथ भूकंपीय हैं अवलोकन किये गये।

यांडेक्स मानचित्रों की उपग्रह छवि - नोयाब्रस्क शहर क्षेत्र

किसी एक खेत में कुएँ पैड का एक नेटवर्क

पश्चिमी साइबेरिया की तेल धारण करने वाली चट्टानें गहराई की एक विस्तृत श्रृंखला में पाई जाती हैं - 1 किमी से 5 किमी तक। तेल युक्त चट्टानों की मुख्य मात्रा का निर्माण जुरासिक और क्रेटेशियस काल में हुआ था। जुरासिक काल को शायद कई लोग इसी नाम की फिल्म से जानते हैं। जुरासिक जलवायु आधुनिक से काफी भिन्न था। एनसाइक्लोपीडिया ब्रिटानिका में पैलियोमैप्स की एक श्रृंखला है जो प्रत्येक हेलॉजिकल युग की विशेषता बताती है।

Настоящее время

जुरासिक काल

कृपया ध्यान दें कि जुरासिक काल में, पश्चिमी साइबेरिया का क्षेत्र एक समुद्री तट (नदियों और उथले समुद्र से पार की गई भूमि) था। चूँकि जलवायु आरामदायक थी, हम मान सकते हैं कि उस समय का एक विशिष्ट परिदृश्य इस तरह दिखता था:

जुरासिक साइबेरिया

इस तस्वीर में हमारे लिए जो चीज़ महत्वपूर्ण है वह पशु-पक्षी नहीं, बल्कि पृष्ठभूमि में नदी की छवि है। नदी वही भूवैज्ञानिक वस्तु है जिस पर हम पहले रुके थे। तथ्य यह है कि नदियों की गतिविधि अच्छी तरह से छांटे गए बलुआ पत्थरों को जमा होने देती है, जो बाद में तेल का भंडार बन जाएगा। इन जलाशयों का आकार विचित्र, जटिल हो सकता है (नदी के तल की तरह) और उनकी मोटाई अलग-अलग होती है - किनारों के पास मोटाई छोटी होती है, लेकिन चैनल के केंद्र के करीब या घुमावदार क्षेत्रों में यह बढ़ जाती है। तो, जुरासिक काल में बनी नदियाँ अब लगभग तीन किलोमीटर की गहराई पर हैं और तेल भंडारों की खोज का उद्देश्य हैं।

प्रयोगात्मक डेटा। प्रसंस्करण और विज़ुअलाइज़ेशन

आइए लेख में दिखाए गए भूकंपीय सामग्रियों के संबंध में तुरंत आरक्षण करें - इस तथ्य के कारण कि विश्लेषण के लिए उपयोग किए गए डेटा की मात्रा महत्वपूर्ण है - लेख के पाठ में भूकंपीय निशान के मूल सेट का केवल एक टुकड़ा शामिल है। यह किसी को भी उपरोक्त गणनाओं को पुन: प्रस्तुत करने की अनुमति देगा।

भूकंपीय डेटा के साथ काम करते समय, एक भूभौतिकीविद् आमतौर पर विशेष सॉफ़्टवेयर का उपयोग करता है (ऐसे कई उद्योग नेता हैं जिनके विकास का सक्रिय रूप से उपयोग किया जाता है, उदाहरण के लिए पेट्रेल या पैराडाइम), जो आपको विभिन्न प्रकार के डेटा का विश्लेषण करने की अनुमति देता है और इसमें एक सुविधाजनक ग्राफिकल इंटरफ़ेस होता है। तमाम सुविधाओं के बावजूद, इस प्रकार के सॉफ़्टवेयर की अपनी कमियाँ भी हैं - उदाहरण के लिए, स्थिर संस्करणों में आधुनिक एल्गोरिदम के कार्यान्वयन में बहुत समय लगता है, और गणनाओं को स्वचालित करने की संभावनाएँ आमतौर पर सीमित होती हैं। ऐसी स्थिति में, कंप्यूटर गणित प्रणालियों और उच्च-स्तरीय प्रोग्रामिंग भाषाओं का उपयोग करना बहुत सुविधाजनक हो जाता है, जो एक विस्तृत एल्गोरिथम आधार के उपयोग की अनुमति देता है और साथ ही, बहुत सारी दिनचर्या अपनाता है। यह वोल्फ्राम मैथमैटिका में भूकंपीय डेटा के साथ काम करने के लिए उपयोग किया जाने वाला सिद्धांत है। डेटा के साथ इंटरैक्टिव कार्य के लिए समृद्ध कार्यक्षमता लिखना अनुचित है - आम तौर पर स्वीकृत प्रारूप से लोडिंग सुनिश्चित करना, उनमें वांछित एल्गोरिदम लागू करना और उन्हें बाहरी प्रारूप में वापस अपलोड करना अधिक महत्वपूर्ण है।

प्रस्तावित योजना का पालन करते हुए, हम मूल भूकंपीय डेटा लोड करेंगे और उन्हें प्रदर्शित करेंगे वोल्फ्राम मैथमैटिका:

Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]

इस तरह से डाउनलोड और आयात किया गया डेटा 10 गुणा 5 किलोमीटर के क्षेत्र पर दर्ज किए गए मार्ग हैं। यदि डेटा त्रि-आयामी भूकंपीय सर्वेक्षण विधि का उपयोग करके प्राप्त किया जाता है (लहरें व्यक्तिगत भूभौतिकीय प्रोफाइल के साथ नहीं, बल्कि पूरे क्षेत्र में एक साथ दर्ज की जाती हैं), तो भूकंपीय डेटा क्यूब प्राप्त करना संभव हो जाता है। ये त्रि-आयामी वस्तुएं हैं, ऊर्ध्वाधर और क्षैतिज खंड जो भूवैज्ञानिक पर्यावरण के विस्तृत अध्ययन की अनुमति देते हैं। विचारित उदाहरण में, हम त्रि-आयामी डेटा से निपट रहे हैं। हम टेक्स्ट हेडर से कुछ जानकारी इस तरह प्राप्त कर सकते हैं

StringPartition[seismic3DSEGY["textheader"], 80] // TableForm

सी 1 यह जियोलॉजी पैकेज परीक्षण के लिए डेमो फ़ाइल है
सी 2
सी 3
सी 4
सी 5 दिनांक उपयोगकर्ता नाम: वोल्फ्राम उपयोगकर्ता
सी 6 सर्वेक्षण का नाम: साइबेरिया में कहीं
सी 7 फ़ाइल प्रकार 3डी भूकंपीय आयतन
सी 8
सी 9
C10 Z रेंज: पहले 2200M आखिरी 2400M

यह डेटा सेट हमारे लिए डेटा विश्लेषण के मुख्य चरणों को प्रदर्शित करने के लिए पर्याप्त होगा। फ़ाइल में निशान क्रमिक रूप से दर्ज किए गए हैं और उनमें से प्रत्येक निम्नलिखित चित्र जैसा दिखता है - यह ऊर्ध्वाधर अक्ष (गहराई अक्ष) के साथ परावर्तित तरंगों के आयाम का वितरण है।

ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2, 
 PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
 LabelStyle -> Directive[Black, Italic], PlotRange -> All, 
 Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]

भूकंपीय खंड के निशानों में से एक

यह जानकर कि अध्ययन किए गए क्षेत्र की प्रत्येक दिशा में कितने निशान स्थित हैं, आप एक त्रि-आयामी डेटा सरणी उत्पन्न कर सकते हैं और इसे Image3D[] फ़ंक्शन का उपयोग करके प्रदर्शित कर सकते हैं।

traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1;   (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1;   (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]

भूकंपीय डेटा क्यूब की XNUMXडी छवि। (ऊर्ध्वाधर अक्ष - गहराई)

यदि रुचि की भूवैज्ञानिक विशेषताएं तीव्र भूकंपीय विसंगतियां पैदा करती हैं, तो पारदर्शिता वाले विज़ुअलाइज़ेशन टूल का उपयोग किया जा सकता है। रिकॉर्डिंग के "महत्वहीन" क्षेत्रों को अदृश्य बनाया जा सकता है, जिससे केवल विसंगतियाँ दिखाई देंगी। वोल्फ्राम मैथमेटिका में इसका उपयोग करके किया जा सकता है अपारदर्शिता[] и रैस्टर3डी[].

data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]}, 
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]

Opacity[] और Raster3D[] फ़ंक्शंस का उपयोग करके भूकंपीय डेटा क्यूब छवि

जैसा कि सिंथेटिक उदाहरण में है, मूल घन के खंडों पर परिवर्तनीय राहत के साथ कुछ भूवैज्ञानिक सीमाओं (परतों) की पहचान की जा सकती है।

वर्णक्रमीय विश्लेषण का मुख्य उपकरण फूरियर रूपांतरण है। इसकी सहायता से आप प्रत्येक ट्रेस या ट्रेस के समूह के आयाम-आवृत्ति स्पेक्ट्रम का मूल्यांकन कर सकते हैं। हालाँकि, डेटा को फ़्रीक्वेंसी डोमेन में स्थानांतरित करने के बाद, यह जानकारी खो जाती है कि किस समय (किस गहराई पर पढ़ें) फ़्रीक्वेंसी बदलती है। समय (गहराई) अक्ष पर सिग्नल परिवर्तनों को स्थानीयकृत करने में सक्षम होने के लिए, विंडोड फूरियर ट्रांसफॉर्म और वेवलेट अपघटन का उपयोग किया जाता है। यह आलेख तरंगिका अपघटन का उपयोग करता है। 90 के दशक में भूकंपीय अन्वेषण में वेवलेट विश्लेषण तकनीक का सक्रिय रूप से उपयोग किया जाने लगा। विंडोड फूरियर ट्रांसफॉर्म पर लाभ को बेहतर समय रिज़ॉल्यूशन माना जाता है।

निम्नलिखित कोड खंड का उपयोग करके, आप भूकंपीय निशानों में से एक को अलग-अलग घटकों में विघटित कर सकते हैं:

cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]

घटकों में ट्रेस का अपघटन

यह आकलन करने के लिए कि विभिन्न तरंग आगमन समय पर परावर्तन ऊर्जा कैसे वितरित की जाती है, स्केलोग्राम (एक स्पेक्ट्रोग्राम के अनुरूप) का उपयोग किया जाता है। एक नियम के रूप में, व्यवहार में सभी घटकों का विश्लेषण करने की आवश्यकता नहीं होती है। आमतौर पर, निम्न, मध्य और उच्च आवृत्ति घटकों का चयन किया जाता है।

freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]

स्केलोग्राम। कार्य परिणाम वेवलेट स्केलोग्राम[]

वोल्फ्राम भाषा तरंगिका परिवर्तन के लिए फ़ंक्शन का उपयोग करती है सतत तरंगिकापरिवर्तन[]. और इस फ़ंक्शन का अनुप्रयोग ट्रेस के पूरे सेट पर फ़ंक्शन का उपयोग करके किया जाएगा मेज़[]. यहां वोल्फ्राम मैथमेटिका की एक ताकत पर ध्यान देना उचित है - समानांतरीकरण का उपयोग करने की क्षमता समानांतर तालिका[]. उपरोक्त उदाहरण में, समानांतरीकरण की कोई आवश्यकता नहीं है - डेटा की मात्रा बड़ी नहीं है, लेकिन सैकड़ों हजारों ट्रेस वाले प्रयोगात्मक डेटा सेट के साथ काम करते समय, यह एक आवश्यकता है।

tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}];

फ़ंक्शन लागू करने के बाद सतत तरंगिकापरिवर्तन[] चयनित आवृत्तियों के अनुरूप नए डेटा सेट दिखाई देते हैं। उपरोक्त उदाहरण में, ये आवृत्तियाँ हैं: 38Hz, 33Hz, 27Hz। आवृत्तियों का चयन अक्सर परीक्षण के आधार पर किया जाता है - वे विभिन्न आवृत्ति संयोजनों के लिए प्रभावी मानचित्र प्राप्त करते हैं और भूविज्ञानी के दृष्टिकोण से सबसे अधिक जानकारीपूर्ण मानचित्र का चयन करते हैं।

यदि आपको सहकर्मियों के साथ परिणाम साझा करने या ग्राहक को प्रदान करने की आवश्यकता है, तो आप जियोलॉजीआईओ पैकेज के SEGYExport[] फ़ंक्शन का उपयोग कर सकते हैं

outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];

इनमें से तीन क्यूब्स (कम-आवृत्ति, मध्य-आवृत्ति और उच्च-आवृत्ति घटक) के साथ, आरजीबी सम्मिश्रण का उपयोग आम तौर पर डेटा को एक साथ देखने के लिए किया जाता है। प्रत्येक घटक को अपना रंग सौंपा गया है - लाल, हरा, नीला। वोल्फ्राम मैथमेटिका में यह फ़ंक्शन का उपयोग करके किया जा सकता है कलरकॉम्बाइन[].

परिणाम ऐसी छवियां हैं जिनसे भूवैज्ञानिक व्याख्या की जा सकती है। खंड पर दर्ज किए गए घुमावदार पेलियोचैनल को चित्रित करना संभव बनाते हैं, जिनमें जलाशय होने और तेल भंडार होने की अधिक संभावना होती है। ऐसी नदी प्रणाली के आधुनिक एनालॉग्स की खोज और विश्लेषण हमें मेन्डर्स के सबसे आशाजनक हिस्सों को निर्धारित करने की अनुमति देता है। चैनल स्वयं अच्छी तरह से छांटे गए बलुआ पत्थर की मोटी परतों की विशेषता रखते हैं और तेल के लिए एक अच्छा भंडार हैं। "फीता" विसंगतियों के बाहर के क्षेत्र आधुनिक बाढ़ के मैदानी जमाओं के समान हैं। बाढ़ के मैदानों का जमाव मुख्य रूप से चिकनी मिट्टी की चट्टानों द्वारा दर्शाया जाता है और इन क्षेत्रों में ड्रिलिंग अप्रभावी होगी।

डेटा क्यूब का RGB टुकड़ा. केंद्र में (केंद्र के थोड़ा बाईं ओर) आप घुमावदार नदी का पता लगा सकते हैं।

डेटा क्यूब का RGB टुकड़ा. बायीं ओर आप घुमावदार नदी का पता लगा सकते हैं।

कुछ मामलों में, भूकंपीय डेटा की गुणवत्ता काफी स्पष्ट छवियों की अनुमति देती है। यह क्षेत्र कार्य पद्धति, शोर कम करने वाले एल्गोरिदम द्वारा उपयोग किए जाने वाले उपकरण पर निर्भर करता है। ऐसे मामलों में, न केवल नदी प्रणालियों के टुकड़े दिखाई देते हैं, बल्कि संपूर्ण विस्तारित पेलियो-नदियाँ भी दिखाई देती हैं।

भूकंपीय डेटा क्यूब (क्षैतिज टुकड़ा) के तीन घटकों का आरजीबी मिश्रण। गहराई लगभग 2 किमी.

सेराटोव के निकट वोल्गा नदी की उपग्रह छवि

निष्कर्ष

वोल्फ्राम मैथमेटिका भूकंपीय डेटा का विश्लेषण कर सकता है और खनिजों की खोज से संबंधित व्यावहारिक समस्याओं को हल कर सकता है, और जियोलॉजीआईओ पैकेज इस प्रक्रिया को और अधिक सुविधाजनक बनाता है। भूकंपीय डेटा की संरचना ऐसी है कि गणना को गति देने के लिए अंतर्निहित तरीकों का उपयोग किया जाता है (समानांतर तालिका[], समानांतर करो[],…) बहुत कुशल है और आपको बड़ी मात्रा में डेटा संसाधित करने की अनुमति देता है। काफी हद तक, यह जियोलॉजीआईओ पैकेज की डेटा भंडारण सुविधाओं द्वारा सुविधाजनक है। वैसे, पैकेज का उपयोग न केवल लागू भूकंपीय अन्वेषण के क्षेत्र में किया जा सकता है। जमीन भेदने वाले रडार और भूकंप विज्ञान में लगभग समान प्रकार के डेटा का उपयोग किया जाता है। यदि आपके पास परिणाम को बेहतर बनाने के बारे में सुझाव हैं, वोल्फ्राम मैथमेटिका शस्त्रागार से कौन से सिग्नल विश्लेषण एल्गोरिदम ऐसे डेटा पर लागू होते हैं, या यदि आपके पास कोई महत्वपूर्ण टिप्पणी है, तो कृपया एक टिप्पणी छोड़ें।

स्रोत: www.habr.com

भूभौतिकी में वोल्फ्राम मैथमैटिका