🥇 ניטור קל של שכפול DFS ב- Zabbix

מבוא

עם תשתית די גדולה ומבוזרת המשתמשת ב-DFS כנקודת גישה אחת לנתונים ול-DFSR לשכפול נתונים בין מרכזי נתונים ושרתי סניפים, עולה השאלה של ניטור מצב השכפול הזה.
במקרה, כמעט מיד לאחר שהתחלנו להשתמש ב-DFSR, התחלנו ליישם את Zabbix במטרה להחליף את גן החיות הקיים בכלים שונים ולהביא את ניטור התשתיות לצורה אינפורמטיבית, מלאה והגיונית יותר. נדבר על שימוש ב- Zabbix לניטור שכפול DFS.

קודם כל, עלינו להחליט אילו נתונים על שכפול DFS צריכים להתקבל כדי לנטר את המצב שלו. האינדיקטור הרלוונטי ביותר הוא פיגור. הוא מכיל קבצים שלא סונכרנו עם חברים אחרים בקבוצת השכפול. אתה יכול לראות את גודלו באמצעות כלי השירות dfsrdiag, מותקן עם התפקיד DFSR. במצב שכפול רגיל, גודל העומס צריך להתקרב לאפס. בהתאם לכך, מספר רב של קבצים בצבר מצביע על בעיות בשכפול.

עכשיו לגבי הצד המעשי של הנושא.

על מנת לעקוב אחר גודל העומס באמצעות Zabbix Agent, נצטרך:

סקריפט שינתח את הפלט dfsrdiag לספק ערכי גודל פיגור סופיים ל- Zabbix,
סקריפט שיקבע כמה קבוצות רפליקציה יש בשרת, אילו תיקיות הן משכפלות ואילו שרתים נוספים כלולים בהן (אנחנו לא רוצים להכניס את כל זה ל-Zabix ידנית עבור כל שרת, נכון?).
הוספת סקריפטים אלה כ-UserParameter לתצורת הסוכן של Zabbix לצורך קריאה נוספת משרת הניטור,
הפעלת שירות הסוכן של Zabbix כמשתמש שיש לו זכויות לקרוא את צבר ההזמנות,
תבנית ל-Zabix, בה יוגדר איתור קבוצות, עיבוד נתונים שהתקבלו והוצאת התראות עליהן.

מנתח סקריפטים

כדי לכתוב את המנתח, בחרתי ב-VBS כשפה האוניברסלית ביותר הקיימת בכל הגרסאות של Windows Server. ההיגיון של הסקריפט פשוט: הוא מקבל את שם קבוצת השכפול, התיקיה המשוכפלת ושמות השרתים השולחים והמקבלים דרך שורת הפקודה. פרמטרים אלה מועברים לאחר מכן אל dfsrdiag, ובהתאם לתפוקה שלו הוא מייצר:
מספר קבצים - אם מתקבלת הודעה על הימצאות קבצים בצבר,
0 - אם מתקבלת הודעה על היעדר קבצים בצבר ההזמנות ("ללא פיגור"),
-1 - אם מתקבלת הודעת שגיאה dfsrdiag בעת ביצוע בקשה ("[שגיאה]").

get-Backlog.vbs

strReplicationGroup=WScript.Arguments.Item(0)
strReplicatedFolder=WScript.Arguments.Item(1)
strSending=WScript.Arguments.Item(2)
strReceiving=WScript.Arguments.Item(3)

Set WshShell = CreateObject ("Wscript.shell")
Set objExec = WSHshell.Exec("dfsrdiag.exe Backlog /RGName:""" & strReplicationGroup & """ /RFName:""" & strReplicatedFolder & """ /SendingMember:" & strSending & " /ReceivingMember:" & strReceiving)
strResult = ""
Do While Not objExec.StdOut.AtEndOfStream
	strResult = strResult & objExec.StdOut.ReadLine() & "\"
Loop

If InStr(strResult, "No Backlog") > 0 then
	intBackLog = 0
ElseIf  InStr(strResult, "[ERROR]") > 0 Then
    intBackLog = -1
Else
	arrLines = Split(strResult, "\")
	arrResult = Split(arrLines(1), ":")
	intBackLog = arrResult(1)
End If

WScript.echo intBackLog

תסריט גילוי

על מנת ש-Zabix תוכל לקבוע את כל קבוצות השכפול הקיימות בשרת ולברר את כל הפרמטרים הנדרשים לבקשה (שם תיקיה, שמות של שרתים שכנים), עלינו, ראשית, להשיג מידע זה, ושנית, להציג אותו בפורמט המובן לזאביקס. הפורמט שכלי הגילוי מבין נראה כך:

        "data":[
                {
                        "{#GROUP}":"Share1",
                        "{#FOLDER}":"Folder1",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"Server2"}

...

                        "{#GROUP}":"ShareN",
                        "{#FOLDER}":"FolderN",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"ServerN"}]}

הדרך הקלה ביותר להשיג את המידע שאנו מעוניינים בו היא באמצעות WMI, הוצאתו מהסעיפים המתאימים של DfsrReplicationGroupConfig. כתוצאה מכך, נולד סקריפט שיוצר בקשה ל-WMI ומוציא רשימה של קבוצות, התיקיות והשרתים שלהן בפורמט הנדרש.

DFSRDiscovery.vbs


dim strComputer, strLine, n, k, i

Set wshNetwork = WScript.CreateObject( "WScript.Network" )
strComputer = wshNetwork.ComputerName

Set oWMIService = GetObject("winmgmts:\" & strComputer & "rootMicrosoftDFS")
Set colRGroups = oWMIService.ExecQuery("SELECT * FROM DfsrReplicationGroupConfig")
wscript.echo "{"
wscript.echo "        ""data"":["
n=0
k=0
i=0
For Each oGroup in colRGroups
  n=n+1
  Set colRGFolders = oWMIService.ExecQuery("SELECT * FROM DfsrReplicatedFolderConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
  For Each oFolder in colRGFolders
    k=k+1
    Set colRGConnections = oWMIService.ExecQuery("SELECT * FROM DfsrConnectionConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
    For Each oConnection in colRGConnections
      i=i+1
      binInbound = oConnection.Inbound
      strPartner = oConnection.PartnerName
      strRGName = oGroup.ReplicationGroupName
      strRFName = oFolder.ReplicatedFolderName
      If oConnection.Enabled = True and binInbound = False Then
        strSendingComputer = strComputer
        strReceivingComputer = strPartner
        strLine1="                {"    
        strLine2="                        ""{#GROUP}"":""" & strRGName & """," 
        strLine3="                        ""{#FOLDER}"":""" & strRFName & """," 
        strLine4="                        ""{#SENDING}"":""" & strSendingComputer & ""","                  
        if (n < colRGroups.Count) or (k < colRGFolders.count) or (i < colRGConnections.Count) then
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """},"
        else
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """}]}"       
        end if		
        wscript.echo strLine1
        wscript.echo strLine2
        wscript.echo strLine3
        wscript.echo strLine4
        wscript.echo strLine5	   
      End If
    Next
  Next
Next

אני מסכים, אולי התסריט לא זורח באלגנטיות של קוד ובהחלט אפשר לפשט כמה דברים בו, אבל הוא מבצע את תפקידו העיקרי - מתן מידע על הפרמטרים של קבוצות שכפול בפורמט המובן ל-Zabix.

הוספת סקריפטים לתצורת סוכן Zabbix

הכל כאן פשוט ביותר. הוסף את השורות הבאות לסוף קובץ התצורה של הסוכן:

UserParameter=check_dfsr[*],cscript /nologo "C:Program FilesZabbix Agentget-Backlog.vbs" $1 $2 $3 $4
UserParameter=discovery_dfsr[*],cscript /nologo "C:Program FilesZabbix AgentDFSRDiscovery.vbs"

כמובן, אנו מתאימים את הנתיבים לאלה שבהם יש לנו סקריפטים. שמתי אותם באותה תיקיה שבה הסוכן מותקן.

לאחר ביצוע שינויים, הפעל מחדש את שירות הסוכן של Zabbix.

שינוי המשתמש שתחתיו פועל שירות Zabbix Agent

על מנת לקבל מידע דרך dfsrdiag, יש להפעיל את כלי השירות תחת חשבון שיש לו זכויות ניהול הן לחברים השולחים והן המקבלים בקבוצת השכפול. שירות הסוכן Zabbix, הפועל כברירת מחדל תחת חשבון המערכת, לא יוכל לבצע בקשה כזו. יצרתי חשבון נפרד בדומיין, נתתי לו זכויות ניהול בשרתים הדרושים, והגדרתי את השירות כך שיפעל תחתיו בשרתים אלו.

אתה יכול ללכת בדרך אחרת: כי dfsrdiag, למעשה, עובד דרך אותו WMI, אז אתה יכול להשתמש תיאור, כיצד לתת לחשבון דומיין את הזכויות להשתמש בו מבלי להנפיק זכויות ניהול, אבל אם יש לנו קבוצות שכפול רבות, אז הנפקת זכויות לכל קבוצה תהיה קשה. עם זאת, במקרה שנרצה לפקח על שכפול נפח מערכת התחום על בקרי תחום, ייתכן שזו האפשרות המקובלת היחידה, שכן מתן זכויות מנהל תחום לחשבון שירות הניטור אינו רעיון טוב.

תבנית ניטור

על סמך הנתונים שקיבלתי, יצרתי תבנית ש:

מפעיל גילוי אוטומטי של קבוצות שכפול פעם בשעה,
בודק את גודל הפיגור עבור כל קבוצה אחת ל-5 דקות,
מכיל טריגר שמוציא התראה כאשר גודל ה-backlog עבור כל קבוצה הוא יותר מ-100 למשך 30 דקות. הטריגר מתואר כאב טיפוס שמתווסף אוטומטית לקבוצות שזוהו,
בונה גרפים של גודל צבר עבור כל קבוצת שכפול.

אתה יכול להוריד את התבנית עבור Zabbix 2.2 כאן.

סך הכל

לאחר ייבוא התבנית לתוך Zabbix ויצירת חשבון עם הזכויות הדרושות, נצטרך רק להעתיק את הסקריפטים לשרתי הקבצים שנרצה לנטר עבור DFSR, להוסיף שתי שורות לתצורת הסוכן עליהם ולהפעיל מחדש את שירות הסוכן Zabbix. , מגדירים אותו לפעול כחשבון הרצוי. אין צורך בהגדרות ידניות אחרות עבור ניטור DFSR.

מקור: www.habr.com

ניטור פשוט של שכפול DFS ב- Zabbix