טבלה מחזורית על מדעי המחשב בבית הספר

(כרטיסי בקרה)
(מוקדש לשנה הבינלאומית של הטבלה המחזורית של יסודות כימיים)
(ההוספות האחרונות בוצעו ב-8 באפריל 2019. רשימת התוספות נמצאת מיד מתחת לגזרה)

(הפרח של מנדלייב, מקור)

אני זוכר שעברנו את הברווז. אלה היו שלושה שיעורים בבת אחת: גיאוגרפיה, מדעי הטבע ורוסית. בשיעור מדעים למדו ברווז בתור ברווז, אילו כנפיים יש לו, אילו רגליים יש לו, איך הוא שוחה וכו'. בשיעור גיאוגרפיה, אותו ברווז נחקר כתושב כדור הארץ: היה צורך להראות על מפה היכן הוא חי ואיפה לא. ברוסית, סראפימה פטרובנה לימדה אותנו לכתוב "u-t-k-a" ולקרוא משהו על ברווזים מברם. בדרך אגב היא הודיעה לנו שבגרמנית ברווז זה ככה, ובצרפתית ככה. אני חושב שזה נקרא אז "השיטה המורכבת". באופן כללי, הכל יצא "בדרך אגב".

ונימין קאברין, שני קפטנים

בציטוט לעיל, ונימין קוורין הראה בצורה מופתית את החסרונות של שיטת ההוראה המורכבת, אולם במקרים מסוימים (אולי די נדירים) מרכיבים של שיטה זו מוצדקים. מקרה אחד כזה הוא הטבלה המחזורית של D.I. מנדלייב בשיעורי מדעי המחשב בבית הספר. המשימה של אוטומציה תוכנה של פעולות טיפוסיות עם הטבלה המחזורית ברורה לתלמידי בית ספר שהחלו ללמוד כימיה, ומחולקת למשימות כימיות טיפוסיות רבות. יחד עם זאת, במסגרת מדעי המחשב, משימה זו מאפשרת לנו להדגים בצורה פשוטה את שיטת כרטיסי הבקרה, אותה ניתן לייחס לתכנות גרפי, המובן במובן הרחב של המילה כתכנות באמצעות אלמנטים גרפיים.

(8 באפריל 2019 בוצעו תוספות:
תוספת 1: כיצד פועל מחשבון הכימיה
נספח 2: דוגמאות למשימות עבור מסננים)

נתחיל במשימה הבסיסית. במקרה הפשוט ביותר, יש להציג את הטבלה המחזורית על המסך בצורת חלון, כאשר בכל תא יהיה ייעוד כימי של היסוד: H - מימן, He - הליום וכו'. אם סמן העכבר מצביע על תא, ייעוד האלמנט ומספרו מוצגים בשדה מיוחד בטופס שלנו. אם המשתמש לוחץ על LMB, ייעודו ומספרו של רכיב נבחר זה יצוינו בשדה אחר בטופס.

ניתן לפתור את הבעיה באמצעות כל שפה אוניברסלית. ניקח את דלפי-7 הישן והפשוט, המובן כמעט לכולם. אבל לפני התכנות ב-PL, בואו נצייר שתי תמונות, למשל, בפוטושופ. ראשית, בואו נצייר את הטבלה המחזורית בצורה שאנו רוצים לראות אותה בתוכנית. שמור את התוצאה בקובץ גרפי table01.bmp.

עבור הציור השני אנו משתמשים בראשון. נמלא ברצף את תאי הטבלה, נקיים מכל הגרפיקה, בצבעים ייחודיים במודל הצבעים RGB. R ו-G תמיד יהיו 0, ו-B=1 למימן, 2 להליום וכו'. השרטוט הזה יהיה כרטיס הבקרה שלנו, אותו נשמור בקובץ שנקרא table2.bmp.

הושלם השלב הראשון של תכנות גרפי בפוטושופ. בואו נעבור לתכנות GUI גרפי ב-DELpi-7 IDE. כדי לעשות זאת, פתח פרויקט חדש, שבו בטופס הראשי אנו מציבים כפתור דו-שיח (tableDlg), שבה תתקיים העבודה עם השולחן. לאחר מכן אנו עובדים עם הטופס tableDlg.

הצב רכיב מחלקה בטופס זמן. אנחנו מקבלים Image1. שים לב שבאופן כללי, עבור פרויקטים גדולים, נוצרו אוטומטית שמות של הטופס תמונהNאיפה N יכול להגיע לכמה עשרות או יותר - זה לא סגנון התכנות הטוב ביותר, ויש לתת שמות משמעותיים יותר. אבל בפרויקט הקטן שלנו, איפה N לא יעלה על 2, אתה יכול להשאיר אותו כפי שנוצר.

לרכוש תמונה1.תמונה להעלות את הקובץ table01.bmp. אנחנו יוצרים Image2 וטען את כרטיס הבקרה שלנו שם table2.bmp. במקרה זה, אנו הופכים את הקובץ לקטן ובלתי נראה למשתמש, כפי שמוצג בפינה השמאלית התחתונה של הטופס. אנו מוסיפים רכיבי בקרה נוספים, שמטרתם ברורה. השלב השני של תכנות GUI גרפי ב-DELpi-7 IDE הושלם.

נעבור לשלב השלישי - כתיבת קוד ב-DELpi-7 IDE. המודול מורכב מחמישה מטפלי אירועים בלבד: יצירת טופס (FormCreate), תנועת הסמן Image1 (Image1MouseMove), לחיצה על LMB בתא (תמונה 1 קליק) וצא מתיבת הדו-שיח באמצעות לחצני אישור (OKBtnClick) או בטל (CancelBtnClick). הכותרות של המטפלים הללו נוצרות בצורה סטנדרטית באמצעות ה-IDE.

קוד מקור מודול:

unit tableUnit;
// Периодическая таблица химических элементов Д.И.Менделеева
//
// third112
// https://habr.com/ru/users/third112/
//
// Оглавление
// 1) создание формы
// 2) работа с таблицей: указание и выбор
// 3) выход из диалога

interface

uses Windows, SysUtils, Classes, Graphics, Forms, Controls, StdCtrls, 
  Buttons, ExtCtrls;

const
 size = 104; // число элементов
 
type
 TtableDlg = class(TForm)
    OKBtn: TButton;
    CancelBtn: TButton;
    Bevel1: TBevel;
    Image1: TImage;  //таблица химических элементов
    Label1: TLabel;
    Image2: TImage;  //управляющая карта
    Label2: TLabel;
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject); // создание формы
    procedure Image1MouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);                        // указание клетки
    procedure Image1Click(Sender: TObject); // выбор клетки
    procedure OKBtnClick(Sender: TObject);  // OK
    procedure CancelBtnClick(Sender: TObject); // Cancel
  private
    { Private declarations }
    TableSymbols : array [1..size] of string [2]; // массив обозначений элементов
  public
    { Public declarations }
    selectedElement : string; // выбранный элемент
    currNo : integer;         // текущий номер элемента
  end;

var
  tableDlg: TtableDlg;

implementation

{$R *.dfm}

const
PeriodicTableStr1=
'HHeLiBeBCNOFNeNaMgAlSiPSClArKCaScTiVCrMnFeCoNiCuZnGaGeAsSeBrKrRbSrYZrNbMoTcRuRhPdAgCdInSnSbTeIXeCsBaLa';
PeriodicTableStr2='CePrNdPmSmEuGdTbDyHoErTmYbLu';
PeriodicTableStr3='HfTaWReOsIrPtAuHgTlPbBiPoAtRnFrRaAc';
PeriodicTableStr4='ThPaUNpPuAmCmBkCfEsFmMdNoLrKu ';

// создание формы  ==================================================

procedure TtableDlg.FormCreate(Sender: TObject);
// создание формы
var
  s : string;
  i,j : integer;
begin
  currNo := 0;
// инициализация массива обозначений элементов:
  s := PeriodicTableStr1+ PeriodicTableStr2+PeriodicTableStr3+PeriodicTableStr4;
  j := 1;
  for i :=1 to size do
   begin
     TableSymbols [i] := s[j];
     inc (j);
     if s [j] in ['a'..'z'] then
      begin
        TableSymbols [i] := TableSymbols [i]+ s [j];
        inc (j);
      end; // if s [j] in
   end; // for i :=1
end; // FormCreate ____________________________________________________

// работа с таблицей: указание и выбор =========================================

procedure TtableDlg.Image1MouseMove(Sender: TObject; Shift: TShiftState;
  X, Y: Integer);
// указание клетки
var
  sl : integer;
begin
  sl := GetBValue(Image2.Canvas.Pixels [x,y]);
  if sl in [1..size] then
   begin
    Label1.Caption := intToStr (sl)+ ' '+TableSymbols [sl];
    currNo := sl;
   end
  else
    Label1.Caption := 'Select element:';
end; // Image1MouseMove   ____________________________________________________

procedure TtableDlg.Image1Click(Sender: TObject);
begin
  if currNo <> 0 then
   begin
    selectedElement := TableSymbols [currNo];
    Label2.Caption := intToStr (currNo)+ ' '+selectedElement+ ' selected';
    Edit1.Text := selectedElement;
   end;
end; // Image1Click  ____________________________________________________

// выход из диалога  ==================================================

procedure TtableDlg.OKBtnClick(Sender: TObject);
begin
    selectedElement := Edit1.Text;
    hide;
end;  // OKBtnClick ____________________________________________________

procedure TtableDlg.CancelBtnClick(Sender: TObject);
begin
  hide;
end;  // CancelBtnClick ____________________________________________________

end.

בגרסה שלנו, לקחנו טבלה של 104 אלמנטים (קבוע גודל). ברור שאפשר להגדיל את הגודל הזה. ייעודי יסוד (סמלים כימיים) נכתבים למערך סמלי טבלה. עם זאת, מטעמי קומפקטיות של קוד המקור, נראה שמומלץ לכתוב את רצף הסימונים הללו בצורה של קבועי מחרוזת PeriodicTableStr1..., PeriodicTableStr4כך שכאשר הטופס נוצר, התוכנית עצמה מפזרת את הייעודים הללו בין מרכיבי המערך. כל ייעוד אלמנט מורכב מאות לטינית אחת או שתיים, כאשר האות הראשונה היא אות גדולה והשנייה (אם בכלל) קטנה. כלל פשוט זה מיושם בעת טעינת מערך. לפיכך, ניתן לכתוב את רצף הסימונים בצורה תמציתית ללא רווחים. חלוקת רצף לארבעה חלקים (קבועים PeriodicTableStr1..., PeriodicTableStr4) נובע משיקולים של קלות קריאת קוד המקור, מכיוון קו ארוך מדי עשוי שלא להתאים לגמרי על המסך.

כאשר סמן העכבר נע מעל Image1 מטפל Image1MouseMove אירוע זה קובע את הערך של רכיב הצבע הכחול של פיקסל כרטיס הבקרה Image2 עבור קואורדינטות הסמן הנוכחיות. לפי בנייה Image2 ערך זה שווה למספר האלמנט אם הסמן נמצא בתוך התא; אפס אם על הגבול, ו-255 במקרים אחרים. שאר הפעולות שמבצעת התוכנית הן טריוויאליות ואינן דורשות הסבר.

בנוסף לטכניקות התכנות הסגנוניות שצוינו לעיל, כדאי לשים לב לסגנון הפרשנות. באופן קפדני, הקוד שנדון הוא כל כך קטן ופשוט עד שההערות לא נראות נחוצות במיוחד. עם זאת, הם נוספו גם מסיבות מתודולוגיות - הקוד הקצר מאפשר לנו להסיק כמה מסקנות כלליות בצורה ברורה יותר. בקוד המוצג מוצהרת מחלקה אחת (TtableDlg). ניתן להחליף שיטות של מחלקה זו וזה לא ישפיע על תפקוד התוכנית בשום צורה, אך עשוי להשפיע על הקריאה שלה. לדוגמה, דמיינו את הרצף:

OKBtnClick, Image1MouseMove, FormCreate, Image1Click, CancelBtnClick.

זה אולי לא מאוד מורגש, אבל זה יהפוך קצת יותר קשה לקריאה ולהבנה. אם אין חמש, אלא עשרות מונים יותר שיטות בסעיף הפעלה יש להם סדר שונה לחלוטין מאשר בתיאורי הכיתה, ואז הכאוס רק יגבר. לכן, למרות שקשה להוכיח בקפדנות ואולי אפילו בלתי אפשרי, אפשר לקוות שהכנסת סדר נוסף תשפר את קריאות הקוד. הזמנה נוספת זו מתאפשרת על ידי קיבוץ לוגי של מספר שיטות המבצעות משימות קשורות. לכל קבוצה יש לתת כותרת, למשל:

// работа с таблицей: указание и выбор

יש להעתיק את הכותרות הללו לתחילת המודול ולעצב אותן כתוכן עניינים. במקרים מסוימים של מודולים ארוכים למדי, תוכן עניינים כזה מספק אפשרויות ניווט נוספות. באופן דומה, בגוף הארוך של שיטה, נוהל או פונקציה אחת, כדאי, ראשית, לסמן את סופו של גוף זה:

end; // FormCreate

ושנית, בהצהרות מסועפות עם סוגריים של תוכנית מתחיל - סוף, סמן את ההצהרה שאליה מתייחס הסוגריים הסוגרים:

      end; // if s [j] in
   end; // for i :=1
end; // FormCreate

כדי להדגיש את כותרות הקבוצות ואת הקצוות של גופי השיטה, ניתן להוסיף שורות ארוכות מרוב ההצהרות ומורכבות, למשל, מהתווים "=" ו-"_", בהתאמה.
שוב, אנחנו צריכים לעשות הסתייגות: הדוגמה שלנו פשוטה מדי. וכאשר הקוד של שיטה אינו מתאים למסך אחד, זה יכול להיות קשה להבין שישה קצוות רצופים כדי לבצע שינויים בקוד. בכמה מהדרים ישנים, למשל, Pascal 8000 עבור OS IBM 360/370, עמודת שירות כמו זו הודפסה בצד שמאל ברשימה

B5
…
E5

משמעות הדבר היא שסוגרי הסגירה בשורה E5 תואם את סוגרי הפתיחה בשורה B5.

כמובן, סגנון תכנות הוא נושא מאוד שנוי במחלוקת, ולכן יש לקחת את הרעיונות המובעים כאן כלא יותר מאשר חומר למחשבה. זה יכול להיות קשה מאוד לשני מתכנתים מנוסים למדי, שהתפתחו והתרגלו לסגנונות שונים במשך שנים רבות של עבודה, להגיע להסכמה. זה עניין אחר לתלמיד הלומד לתכנת שעדיין לא הספיק למצוא את הסגנון שלו. אני חושב שבמקרה הזה המורה צריך לפחות להעביר לתלמידיו רעיון כה פשוט, אך לא ברור להם, שהצלחתה של תוכנית תלויה במידה רבה בסגנון שבו כתוב קוד המקור שלה. ייתכן שהתלמיד לא יפעל לפי הסגנון המומלץ, אבל תן לו לפחות לחשוב על הצורך בפעולות "נוספות" לשיפור עיצוב קוד המקור.

נחזור לבעיה הבסיסית שלנו בטבלה המחזורית: התפתחות נוספת יכולה ללכת בכיוונים שונים. אחד ההנחיות הוא לעיון: כאשר אתה מרחף עם סמן העכבר מעל תא טבלה, מופיע חלון מידע המכיל מידע נוסף על האלמנט שצוין. פיתוח נוסף הוא פילטרים. לדוגמה, בהתאם להתקנה, חלון המידע יכיל רק: המידע הפיזיקלי והכימי החשוב ביותר, מידע על היסטוריית הגילוי, מידע על תפוצה בטבע, רשימת התרכובות החשובות ביותר (הכוללת יסוד זה), תכונות פיזיולוגיות, שם בשפה זרה וכו'. הזכרנו את ה"ברווז" של קברין שאיתו מתחיל מאמר זה, אנו יכולים לומר שעם פיתוח זה של התוכנית נקבל מכלול הכשרה שלם במדעי הטבע: בנוסף למחשב מדע, פיזיקה וכימיה - ביולוגיה, גיאוגרפיה כלכלית, תולדות המדע ואפילו שפות זרות.

אבל מסד נתונים מקומי הוא לא הגבול. התוכנית מתחברת לאינטרנט באופן טבעי. כאשר אתה בוחר אלמנט, הקישור מופעל, ומאמר ויקיפדיה על אלמנט זה נפתח בחלון דפדפן האינטרנט. ויקיפדיה, כידוע, אינה מקור סמכותי. אתה יכול להגדיר קישורים למקורות מוסמכים, למשל, האנציקלופדיה הכימית, TSB, כתבי עת מופשטים, להזמין שאילתות במנועי חיפוש עבור אלמנט זה וכו'. זֶה. התלמידים יוכלו לבצע מטלות פשוטות אך משמעותיות בנושאי DBMS ואינטרנט.

בנוסף לשאילתות על אלמנט בודד, ניתן ליצור פונקציונליות שתסמן, למשל, תאים בטבלה העומדים בקריטריונים מסוימים בצבעים שונים. למשל, מתכות ולא מתכות. או תאים שמושלכים למקווי מים על ידי מפעל כימי מקומי.

אתה יכול גם ליישם את הפונקציות של מארגן מחברת. לדוגמה, הדגש בטבלה את המרכיבים הכלולים בבחינה. לאחר מכן הדגישו את האלמנטים שנלמדו/חזרו על ידי התלמיד לקראת הבחינה.

והנה, למשל, אחת הבעיות האופייניות לכימיה בבית הספר:

ניתן 10 גרם גיר. כמה חומצת מלח צריך לקחת כדי להמיס את כל הגיר הזה?

כדי לפתור בעיה זו, יש צורך לרשום את הכים. תגובה והצבת המקדמים בתוכה, חשב את המשקלים המולקולריים של סידן פחמתי ומימן כלורי, ואז חבר ופתור את הפרופורציה. מחשבון המבוסס על התוכנית הבסיסית שלנו יכול לחשב ולפתור. נכון, עדיין תצטרכו לקחת בחשבון שחייבים לקחת את החומצה בעודף סביר ובריכוז סביר, אבל זו כימיה, לא מדעי המחשב.
תוספת 1: כיצד פועל מחשבון הכימיההבה ננתח את פעולת המחשבון באמצעות הדוגמה של הבעיה שלעיל של גיר ו"הודג'פודג'". נתחיל בתגובה:

CaCO3 + 2HCl = CaCl2 + H2O

מכאן אנו רואים שנצטרך את המשקלים האטומיים של היסודות הבאים: סידן (Ca), פחמן (C), חמצן (O), מימן (H) וכלור (Cl). במקרה הפשוט ביותר, נוכל לכתוב משקלים אלו למערך חד מימדי המוגדר כ

AtomicMass : array [1..size] of real;

כאשר אינדקס המערך מתאים למספר האלמנט. עוד על המקום הפנוי של הטופס tableDlg לשים שני שדות. בשדה הראשון נכתב בתחילה: "הריאגנט הראשון ניתן", בשנייה - "הריאגנט השני הוא למצוא x". בואו נסמן את השדות מגיב 1, מגיב 2 בהתאמה. תוספות אחרות לתוכנית יתבררו מהדוגמה הבאה של המחשבון.

אנו מקלידים על מקלדת המחשב: 10 גרם כיתוב בשדה מגיב 1 שינויים: "הריאגנט הראשון מקבל 10 גרם." כעת נזין את הנוסחה של מגיב זה, והמחשבון יחשב ויראה את המשקל המולקולרי שלו תוך כדי הזנתו.

לחץ על LMB בתא הטבלה עם סמל Ca. כיתוב בשטח מגיב 1 שינויים: "ריאגנט ראשון Ca 40.078 נתון 10 גרם."

לחץ על LMB בתא הטבלה עם הסמל C. כיתוב בשדה מגיב 1 שינויים: "ריאגנט ראשון CaC 52.089 נתון 10 גרם." הָהֵן. המחשבון חיבר את המשקלים האטומיים של סידן ופחמן.

לחץ על LMB בתא הטבלה עם הסמל O. כיתוב בשדה מגיב 1 שינויים: "ריאגנט ראשון CaCO 68.088 נתון 10 גרם." המחשבון הוסיף את המשקל האטומי של החמצן לסכום.

לחץ על LMB בתא הטבלה עם הסמל O. כיתוב בשדה מגיב 1 שינויים: "ריאגנט ראשון CaCO2 84.087 נתון 10 גרם." המחשבון הוסיף שוב את המשקל האטומי של החמצן לסכום.

לחץ על LMB בתא הטבלה עם הסמל O. כיתוב בשדה מגיב 1 שינויים: "ריאגנט ראשון CaCO3 100.086 נתון 10 גרם." המחשבון הוסיף שוב את המשקל האטומי של החמצן לסכום.

הקש Enter במקלדת המחשב שלך. הכנסת המגיב הראשון הושלמה ועוברת לשטח מגיב 2. שימו לב שבדוגמה זו אנו מספקים גרסה מינימלית. אם תרצו, תוכלו לארגן בקלות מכפילים של אטומים מאותו סוג, כך, למשל, לא תצטרכו ללחוץ שבע פעמים ברציפות על תא החמצן בכניסה לנוסחת הכרום (K2Cr2O7).

לחץ על LMB בתא הטבלה עם הסמל H. כיתוב בשדה מגיב 2 שינויים: "ריאגנט שני H 1.008 מצא x."

לחץ על LMB בתא הטבלה עם סמל Cl. כיתוב בשטח מגיב 2 שינויים: "מגיב שני HCl 36.458 מצא x." המחשבון חיבר את המשקלים האטומיים של מימן וכלור. במשוואת התגובה לעיל, לפני מימן כלורי מקדם 2. לכן, לחץ על LMB בשדה מגיב 2. המשקל המולקולרי מכפיל את עצמו (משולש בלחיצה פעמיים וכו'). כיתוב בשטח מגיב 2 שינויים: "ריאגנט שני 2HCl 72.916 מצא x."

הקש Enter במקלדת המחשב שלך. הזנת המגיב השני הושלמה, והמחשבון מוצא את x מהפרופורציה

זה מה שהיינו צריכים למצוא.

הערה 1. משמעות הפרופורציה המתקבלת: לפירוק 100.086 Da גיר דורש חומצה של 72.916 דא, וכדי להמיס 10 גרם גיר צריך x חומצה.

הערה 2. אוספים של בעיות דומות:

חומצ'נקו I. G., אוסף בעיות ותרגילים בכימיה 2009 (כיתות ח'-י"א).
Khomchenko G. P., Khomchenko I. G., אוסף בעיות בכימיה למועמדים לאוניברסיטאות, 2019.

הערה 3. כדי לפשט את המשימה, ניתן לפשט את הזנת הנוסחה בגרסה הראשונית ופשוט להוסיף את סמל האלמנט לסוף שורת הנוסחה. אז הנוסחה של סידן פחמתי תהיה:
CaCOOO
אבל לא סביר שמורה לכימיה יאהב הקלטה כזו. זה לא קשה להזין את הערך הנכון - כדי לעשות זאת אתה צריך להוסיף מערך:

formula : array [1..size] of integer;

כאשר האינדקס הוא מספר היסוד הכימי, והערך באינדקס זה הוא מספר האטומים (בתחילה כל היסודות של המערך מאופסים לאפס). יש לקחת בחשבון את הסדר שבו נכתבים האטומים בנוסחה, כפי שאומצה בכימיה. לדוגמה, מעט אנשים יאהבו גם O3CaC. בואו נעביר את האחריות למשתמש. יצירת מערך:

 formulaOrder : array [1..size] of integer; // можно взять покороче

שבו אנו רושמים את מספר היסוד הכימי לפי אינדקס הופעתו בנוסחה. הוספת אטום currNo לתוך הנוסחה:

if formula [currNo]=0 then //этот атом встретился первый раз
 begin
 orderIndex := orderIndex+1;//в начале ввода формулы orderIndex=0
 formulaOrder [orderIndex] :=  currNo;
 end;
formula [currNo]:=formula [currNo]+1;

כתיבת הנוסחה לשורה:

s := ''; // пустая строка для формулы
for i:=1 to  orderIndex do // для всех хим.символов в формуле 
 begin
 s:=s+TableSymbols [ formulaOrder[i]];// добавляем хим.символ
 if formula [formulaOrder[i]]<>1 then //добавляем кол-во атомов
  s:=s+ intToStr(formula [formulaOrder[i]]);
 end;

הערה 4. הגיוני לספק את היכולת להזין לחילופין את נוסחת המגיב מהמקלדת. במקרה זה, תצטרך ליישם מנתח פשוט.

ראוי לציין כי:

כיום, יש כמה מאות גרסאות של הטבלה, ומדענים מציעים כל הזמן אפשרויות חדשות. (ויקיפדיה)

תלמידים יכולים להראות את כושר ההמצאה שלהם בכיוון זה על ידי יישום אחת מהאפשרויות שכבר הוצעו או לנסות ליצור אחת מקורית משלהם. אולי נראה שזהו הכיוון הכי פחות שימושי לשיעורי מדעי המחשב. עם זאת, בצורת הטבלה המחזורית המיושמת במאמר זה, ייתכן שחלק מהתלמידים לא יראו את היתרונות המיוחדים של כרטיסי שליטה על פני הפתרון החלופי באמצעות לחצנים סטנדרטיים TBbutton. צורת הספירלה של השולחן (כאשר התאים בעלי צורות שונות) תדגים בצורה ברורה יותר את היתרונות של הפתרון המוצע כאן.

(מערכת אלמנטים חלופית מאת תיאודור בנפיי, מקור)

הבה נוסיף גם כי מספר תוכנות מחשב הקיימות כיום עבור הטבלה המחזורית מתוארות בכתב העת שפורסם לאחרונה על Habré статье.

נספח 2: דוגמאות למשימות למסנניםבאמצעות מסננים תוכל לפתור, למשל, את המשימות הבאות:

1) בחר בטבלה את כל היסודות הידועים בימי הביניים.

2) זהה את כל היסודות הידועים בעת גילוי החוק התקופתי.

3) זהה שבעה יסודות שאלכימאים חשבו למתכות.

4) בחר את כל האלמנטים שנמצאים במצב גזי בתנאים רגילים (נ.ש).

5) בחר את כל האלמנטים שנמצאים במצב נוזלי ב- no.

6) בחר את כל האלמנטים שנמצאים במצב מוצק ב- no.

7) בחר את כל האלמנטים שיכולים להיחשף לאוויר לאורך זמן ללא שינויים ניכרים בתנאים רגילים.

8) בחר את כל המתכות המתמוססות בחומצה הידרוכלורית.

9) בחר את כל המתכות המתמוססות בחומצה גופרתית במקום מס'.

10) בחר את כל המתכות שמתמוססות בחומצה גופרתית בעת חימום.

11) בחר את כל המתכות שמתמוססות בחומצה חנקתית.

12) לבודד את כל המתכות המגיבות באלימות עם מים בתנאי הסביבה.

13) בחר את כל המתכות.

14) זיהוי אלמנטים הנפוצים בטבע.

15) זיהוי יסודות שנמצאים בטבע במצב חופשי.

16) זהה את האלמנטים הממלאים את התפקיד החשוב ביותר בגוף האדם והחי.

17) בחר אלמנטים שנמצאים בשימוש נרחב בחיי היומיום (בצורה חופשית או בשילובים).

18) זיהוי אלמנטים שהכי מסוכנים לעבוד איתם ודורשים אמצעים מיוחדים וציוד מיגון.

19) זהה את היסודות אשר, בצורה חופשית או בצורה של תרכובות, מהווים את האיום הגדול ביותר על הסביבה.

20) בחר מתכות יקרות.

21) זהה אלמנטים יקרים יותר ממתכות יקרות.

הערות

1) הגיוני לספק מסננים מרובים. לדוגמה, אם תפעיל מסנן כדי לפתור בעיה 1 (כל היסודות המוכרים בימי הביניים) ו-20 (מתכות יקרות), אז תאים עם מתכות יקרות הידועות בימי הביניים יודגשו (לדוגמה, לפי צבע) ( לדוגמה, פלדיום לא יודגש, נפתח בשנת 1803).

2) הגיוני לוודא שמספר מסננים יפעלו במצב כזה שכל מסנן בוחר תאים עם צבע משלו, אך לא מסיר לחלוטין את הבחירה של מסנן אחר (חלק מהתא בצבע אחד, חלק בצבע אחר). לאחר מכן, במקרה של הדוגמה הקודמת, ייראו אלמנטים של הצטלבות של קבוצות שהתגלו בימי הביניים ומתכות יקרות, כמו גם יסודות השייכים רק לקבוצה הראשונה ורק לקבוצה השנייה. הָהֵן. מתכות יקרות לא ידועות בימי הביניים, ויסודות ידועים בימי הביניים אך לא מתכות יקרות.

3) הגיוני לאחר החלת המסנן להבטיח את האפשרות לעבודה אחרת עם התוצאות שהושגו. לדוגמה, לאחר שנבחרו אלמנטים ידועים בימי הביניים, המשתמש לוחץ על LMB על האלמנט הנבחר ומועבר למאמר בוויקיפדיה על אלמנט זה.

4) הגיוני לספק למשתמש את היכולת לבטל את הבחירה על ידי לחיצה על LMB בתא הטבלה שנבחר. לדוגמה, כדי להסיר פריטים שכבר נצפו.

5) הגיוני לוודא שרשימת התאים שנבחרו נשמרת בקובץ ושקובץ כזה נטען בבחירה אוטומטית של תאים. זה ייתן למשתמש את ההזדמנות לקחת הפסקה מהעבודה.

השתמשנו במפת בקרה סטטית, שנקבעה מראש, אך ישנן משימות חשובות רבות שבהן ניתן להשתמש במפות בקרה דינמיות המשתנות עם ריצת התוכנית. דוגמה לכך תהיה עורך גרפים, שבו המשתמש משתמש בעכבר כדי לציין את מיקומי הקודקודים בחלון ולצייר קצוות ביניהם. כדי למחוק קודקוד או קצה, על המשתמש להצביע עליהם. אבל אם די קל להצביע על קודקוד המסומן בעיגול, אז יהיה קשה יותר להצביע על קצה מצויר בקו דק. מפת בקרה תעזור כאן, כאשר קודקודים וקצוות תופסים שכונות רחבות יותר מאשר באיור הנראה לעין.

שאלת צד מעניינת הקשורה לשיטה זו של אימון מורכב היא: האם שיטה זו יכולה להיות שימושית באימון AI?

מקור: www.habr.com