Grafana を例として使用した Yandex.Cloud への分散サービスの展開

こんにちは、みんな！授業の一環として、私は国内のクラウドプラットフォームの機能について研究していました。 Yandex.Cloud。このプラットフォームは、実用的な問題を解決するためのさまざまなサービスを提供します。ただし、場合によっては、これらのサービスに基づいて、かなり大規模なインフラストラクチャを備えた独自のクラウド アプリケーションをセットアップする必要があります。この記事では、このようなアプリケーションを展開した私の経験を共有したいと思います。

何が欲しいですか？

グラファナ — あらゆるシステムの分析上の問題を解決したり、問題を監視したりするための強力なツールです。基本的な構成では、これは Grafana Web サーバーと、分析が構築されるデータセットを含むデータベース (ClickHouse、InfluxDB など) を備えた仮想マシンです。

Web サーバーで仮想マシンを起動した後、そのホストにアクセスして便利な UI を取得し、データベースを以降の作業のソースとして指定し、ダッシュボードとグラフを作成できます。

基本バージョンには 10 つの重大な欠点があります。それは、フォールト トレランスがまったくないことです。つまり、アプリケーションの機能全体が XNUMX 台の仮想マシンの実行可能性に依存します。失敗したり、XNUMX 人が同時に UI を開いたりすると、問題が発生します。

解決方法は簡単です。Web サーバーを使用して多数の同一の仮想マシンを展開し、それらを L3 バランサーの下に配置するだけです。しかし、ここではすべてがそれほど明確というわけではありません。 Grafana は、ユーザー設定 (データベース、ダッシュボード、グラフへのパスなど) を仮想マシンのディスクに直接保存します。したがって、UI で設定を変更した場合、これらの変更はバランサーが送信した仮想マシンにのみ表示されます。これにより、アプリケーションの設定に一貫性がなくなり、起動や使用に問題が発生します。

ここで、MySQL やそれと同等のものなど、別のデータベースが役に立ちます。 Grafana に、ユーザー設定をこの「予備」データベースに保存するように指示します。その後は、各マシンでこのデータベースへのパスを 1 回指定し、任意の仮想マシン上の他のすべてのユーザー設定を編集するだけで十分です。他の人にも広がるでしょう。

最終的なアプリケーション インフラストラクチャの図を以下に示します。

手で持ち上げる方法を学びましょう

MySQLとClickHouse

ボタンを押すだけでこのようなアプリケーションを展開する前に、ハンドルを使用して各コンポーネントを持ち上げて相互に統合する方法を習得する必要がありました。

ここでは、L3 バランサー、ClickHouse、MySQL を管理サービスとして提供する Yandex.Cloud が役立ちます。ユーザーはパラメータを指定して、プラットフォームがすべてを正常に動作させるまで待つだけです。

登録し、クラウドと支払いアカウントを作成しました。その後、クラウドにアクセスし、最小限の設定で MySQL と ClickHouse クラスターをセットアップしました。彼らが活動的になるまで待ちました。

また、各クラスターにデータベースを作成し、ログインとパスワードを使用してアクセスを設定することも忘れないようにしてください。ここでは詳細には触れませんが、インターフェースですべてが明らかになります。

あまり知られていない詳細は、これらのデータベースには複数のホストがあり、フォールト トレランスが確保されていることです。ただし、Grafana では、操作するデータベースごとに 1 つのホストが必要です。長文記事 ドキュメンテーション 雲が私を解決策へと導いてくれました。宿主は種であることが分かりました c-<cluster_id>.rw.mdb.yandexcloud.net 対応する ID を持つ現在アクティブなクラスター マスター ホストにマップされます。これがまさに Grafana に提供するものです。

ウェブサーバー

次はウェブサーバーです。通常の仮想マシンをセットアップしましょう。 Linux そして、私たちは手作業でその上にGrafanaをセットアップします。

ssh 経由で接続し、必要なパッケージをインストールしましょう。

sudo apt-get install -y apt-transport-https software-properties-common wget
wget -q -O - https://packages.grafana.com/gpg.key | sudo apt-key add -
sudo add-apt-repository "deb https://packages.grafana.com/enterprise/deb stable main"
sudo apt-get update
sudo apt-get install -y grafana-enterprise 

その後、systemctl で Grafana を起動し、ClickHouse を操作するためのプラグインをインストールします (はい、基本パッケージには含まれていません)。

sudo systemctl start grafana-server
sudo systemctl enable grafana-server
sudo grafana-cli plugins install vertamedia-clickhouse-datasource

この簡単なコマンドを実行するだけで

sudo service grafana-server start

Webサーバーを起動します。これで、ブラウザに仮想マシンの外部 IP アドレスを入力し、ポート 3000 を指定して、美しい Grafana UI を表示できるようになります。

ただし、急がないでください。Grafana を設定する前に、設定を保存するための MySQL へのパスを指定することを忘れないでください。

Grafanaウェブサーバー全体の設定は、ファイルにあります。 /etc/grafana/grafana.ini。必要な行は次のようになります。

;url =

ホストを MySQL クラスターに公開します。同じファイルには、上の図の Grafana にアクセスするためのログインとパスワードが含まれており、デフォルトでは両方とも同じです。 admin.

sed コマンドを使用できます:

sudo sed -i "s#.*;url =.*#url = mysql://${MYSQL_USERNAME}:${MYSQL_PASSWORD}@${MYSQL_CLUSTER_URI}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_user =.*#admin_user = ${GRAFANA_USERNAME}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_password =.*#admin_password = ${GRAFANA_PASSWORD}#" /etc/grafana/grafana.ini

ウェブサーバーを再起動しましょう。

sudo service grafana-server restart

ここで、Grafana UI で ClickHouse を DataSource として指定します。

以下の設定で動作する構成を実現できました。

私が指定したURLとして https://c-<cluster_id>.rw.mdb.yandexcloud.net:8443

全て！ CH と MySQL に接続された Web サーバーを備えた稼働中の VM が 1 つあります。すでにデータセットを ClickHouse にアップロードしてダッシュボードを構築できます。しかし、私たちはまだ目標を達成しておらず、本格的なインフラを展開していません。

パッカー

Yandex.Cloud を使用すると、既存の仮想マシンのディスク イメージを作成し、それに基づいて任意の数の同一マシンを作成できます。まさにこれこそが私たちが活用するものです。画像を便利に組み立てるために、ツールを使いましょう パッカー HashiCorp より。イメージを組み立てるための指示を含む json ファイルを入力として受け取ります。

json ファイルは、builders と provisioners の 2 つのブロックで構成されます。最初のブロックでは、画像自体のパラメータをエンティティとして記述し、2 番目のブロックでは、必要なコンテンツを入力する手順を記述します。

ビルダー

{
"builders": [
    {
      "type": "yandex",
      "endpoint": "{{user `endpoint`}}",
      "folder_id": "<folder_id>",
      "subnet_id": "{{user `subnet_id`}}",
      "zone": "{{user `zone`}}",
      "labels": {},
      "use_ipv4_nat": true,
      "use_internal_ip": false,
      "service_account_key_file": "<service_account_key_file>",
      "image_name": "grafana-{{timestamp}}",
      "image_family": "grafana",
      "image_labels": {},
      "image_description": "GRAFANA",
      "source_image_family": "ubuntu-1804-lts",
      "disk_size_gb": 3,
      "disk_type": "network-hdd",
      "ssh_username": "ubuntu"
    }
  ],
...
}

このテンプレートでは、イメージを作成するクラウド内のセクションの識別子と、このセクションで以前に作成したサービス アカウントのキーを含むファイルへのパスを設定する必要があります。サービスアカウントとキーをファイル形式で作成する方法の詳細については、対応するセクションをご覧ください。 ドキュメンテーション.

この設定では、ディスクイメージはプラットフォームに基づいて構築されることになります ubuntu-1804-lts、画像ファミリーの対応するユーザーセクションに配置 GRAFANA 名前の下で grafana-{{timestamp}}.

プロビジョナー

ここで、構成のより興味深い部分が始まります。仮想マシンの状態をディスク イメージに固定する前に仮想マシン上で実行する必要がある一連のアクションについて説明します。

{
...,
"provisioners": [
    {
            "type": "shell",
            "pause_before": "5s",
            "scripts": [
                "prepare-ctg.sh"
            ]
        },
    {
            "type": "file",
            "source": "setup.sh",
            "destination": "/opt/grafana/setup.sh"
        },
        {
            "type": "shell",
        "execute_command": "sudo {{ .Vars }} bash '{{ .Path }}'",
            "pause_before": "5s",
            "scripts": [
                "install-packages.sh",
                "grafana-setup.sh",
                "run-setup-at-reboot.sh"
        ]
        }
  ]
}

ここではすべてのアクションが 3 つのステージに分かれています。最初のステップは、補助ディレクトリを作成する簡単なスクリプトを実行することです。

準備ctg.sh:

#!/bin/bash
sudo mkdir -p /opt/grafana
sudo chown -R ubuntu:ubuntu /opt/grafana

次の段階では、仮想マシンの起動直後に実行する必要があるスクリプトをこのディレクトリに配置します。このスクリプトは、書き込む必要があるユーザー変数を Grafana 構成に配置し、Web サーバーを再起動します。

セットアップ.sh:

#!/bin/bash
CLUSTER_ID="<cluster_id>"
USERNAME="<username>"
PASSWORD="<password>"
sudo sed -i "s#.*;url =.*#url = mysql://${USERNAME}:${PASSWORD}@c-${CLUSTER_ID}.rw.mdb.yandexcloud.net#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_user =.*#admin_user = ${USERNAME}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_password =.*#admin_password = ${PASSWORD}#" /etc/grafana/grafana.ini
sudo service grafana-server restart

この後、やるべきことが 3 つ残っています。
1) パッケージをインストールする
2) systemctlでGrafanaを実行し、ClickHouseプラグインをインストールする
3) 仮想マシンの電源を入れた直後に、setup.sh スクリプトを実行キューに入れます。

インストールパッケージ.sh:

#!/bin/bash
sudo systemd-run --property='After=apt-daily.service apt-daily-upgrade.service' --wait /bin/true
sudo apt-get install -y apt-transport-https
sudo apt-get install -y software-properties-common wget
wget -q -O - https://packages.grafana.com/gpg.key | sudo apt-key add -
sudo add-apt-repository "deb https://packages.grafana.com/enterprise/deb stable main"
sudo apt-get update
sudo apt-get install -y grafana-enterprise 

grafana-setup.sh:

#!/bin/bash
sudo systemctl start grafana-server
sudo systemctl enable grafana-server
sudo grafana-cli plugins install vertamedia-clickhouse-datasource

実行セットアップ at reboot.sh:

#!/bin/bash
chmod +x /opt/grafana/setup.sh
cat > /etc/cron.d/first-boot <<EOF
PATH=/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin:/usr/games:/usr/local/games
@reboot root /bin/bash /opt/grafana/setup.sh > /var/log/yc-setup.log 2>&1
EOF
chmod +x /etc/cron.d/first-boot;

残っているのは、Packer を実行して、指定されたセクションに配置された画像を出力として取得することだけです。仮想マシンを作成するときに、それをブート ディスクとして選択し、起動すると、すぐに使用できる Grafana Web サーバーが取得されます。

インスタンスグループとバランサ

複数の同一の Grafana Web サーバーを作成できるディスク イメージができたら、インスタンス グループを作成できます。 Yandex.Cloud プラットフォームでは、この用語は同一の特性を持つ仮想マシンの組み合わせを指します。インスタンス グループが作成されると、グループ内のすべてのマシンのプロトタイプが構成され、次にグループ自体の特性 (アクティブなマシンの最小数と最大数など) が構成されます。現在の数がこれらの基準を満たしていない場合、インスタンス グループは不要なマシンを削除するか、同じイメージと類似性を持つ新しいマシンを作成します。

タスクの一環として、以前に作成したディスク イメージから生成される Web サーバーのインスタンス グループを作成します。

最後のインスタンス グループ設定は本当に注目に値します。ロード バランサーと統合されたターゲット グループを使用すると、数回クリックするだけで、このグループの仮想マシン上に L3 バランサーを構成できます。

バランサーを設定する際に、次の 2 つの重要なポイントを実装しました。

1. バランサーがポート 80 でユーザー トラフィックを受信し、それを Grafana が存在する仮想マシンのポート 3000 にリダイレクトするようにしました。
2. ポート 3000 で ping を実行してマシンのヘルス チェックを構成しました。

ミニサマリー

最後に、必要なアプリケーション インフラストラクチャを手動でデプロイできるようになり、非常に安定した Grafana サービスが実現しました。データセットをロードするには、アプリケーションへのエントリ ポイントとしてバランサーの IP アドレスと ClickHouse クラスター ホストを知るだけで十分です。

それは勝利のように思えますか？はい、勝利です。しかし、まだ気になることがあります。上記のプロセス全体には多くの手動アクションが必要であり、まったくスケーラブルではないため、可能であれば自動化したいと考えています。次のセクションではこれについて説明します。

Terraform統合

ここでもHashiCorpのツールを使用します。 テラフォーム。ユーザーが渡したいくつかの変数に基づいて、ボタンをクリックするだけでアプリケーション インフラストラクチャ全体を展開できるようになります。異なるユーザーに対して、異なるセクションで複数回実行できるレシピを作成しましょう。

Terraform でのすべての作業は、設定ファイルの作成に集約されます (*.tf）とそれに基づいたインフラの構築です。

変数

ファイルの先頭に、将来のインフラストラクチャがどこにどのように展開されるかに依存する変数を配置します。

variable "oauth_token" {
    type = string
    default = "<oauth-token>"
}
variable "cloud_id" {
    type = string
    default = "<cloud-id>"
}
variable "folder_id" {
    type = string
    default = "<folder_id>"
}
variable "service_account_id" {
    type = string
    default = "<service_account_id>"
}
variable "image_id" {
    type = string
    default = "<image_id>"
}
variable "username" {
    type = string
    default = "<username>"
}
variable "password" {
    type = string
    default = "<password>"
}
variable "dbname" {
    type = string
    default = "<dbname>"
}
variable "public_key_path" {
    type = string
    default = "<path to ssh public key>"
}

アプリケーションを展開するプロセス全体は、ディスク イメージの組み立てとこれらの変数の設定にまで簡素化されます。彼らが何の責任を負っているのか説明しましょう。

oauth_トークン — クラウドにアクセスするためのトークン。入手するには リンク.
クラウドID — アプリケーションをデプロイするクラウドの識別子
フォルダID — アプリケーションをデプロイするセクションの識別子
サービスアカウントID — クラウドの対応するセクション内のサービス アカウントの識別子。
画像ID — Packerを使用して取得したディスクイメージの識別子
ユーザ名 и password — データベースとGrafanaウェブサーバーの両方にアクセスするためのユーザー名とパスワード
データベース名 — CHおよびMySQLクラスタ内のデータベースの名前
公開鍵パス — 公開SSHキーを含むファイルへのパス。このキーを使用して、次の名前で接続できます。 ubuntu ウェブサーバーを備えた仮想マシンへ

プロバイダーの設定

ここで、Terraform プロバイダー (この場合は Yandex) を構成する必要があります。

provider "yandex" {
  token     = var.oauth_token
  cloud_id  = var.cloud_id
  folder_id = var.folder_id
  zone      = "ru-central1-a"
}

ここでは上記で定義した変数を使用していることがわかります。

ネットワークとクラスター

ここで、インフラストラクチャの要素が通信するネットワーク、3 つのサブネット (各リージョンに 1 つ) を作成し、CH クラスターと MySQL クラスターを構築します。

resource "yandex_vpc_network" "grafana_network" {}

resource "yandex_vpc_subnet" "subnet_a" {
  zone           = "ru-central1-a"
  network_id     = yandex_vpc_network.grafana_network.id
  v4_cidr_blocks = ["10.1.0.0/24"]
}

resource "yandex_vpc_subnet" "subnet_b" {
  zone           = "ru-central1-b"
  network_id     = yandex_vpc_network.grafana_network.id
  v4_cidr_blocks = ["10.2.0.0/24"]
}

resource "yandex_vpc_subnet" "subnet_c" {
  zone           = "ru-central1-c"
  network_id     = yandex_vpc_network.grafana_network.id
  v4_cidr_blocks = ["10.3.0.0/24"]
}

resource "yandex_mdb_clickhouse_cluster" "ch_cluster" {
  name        = "grafana-clickhouse"
  environment = "PRODUCTION"
  network_id  = yandex_vpc_network.grafana_network.id

  clickhouse {
    resources {
      resource_preset_id = "s2.micro"
      disk_type_id       = "network-ssd"
      disk_size          = 16
    }
  }

  zookeeper {
    resources {
      resource_preset_id = "s2.micro"
      disk_type_id       = "network-ssd"
      disk_size          = 10
    }
  }

  database {
    name = var.dbname
  }

  user {
    name     = var.username
    password = var.password
    permission {
      database_name = var.dbname
    }
  }

  host {
    type      = "CLICKHOUSE"
    zone      = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.subnet_a.id
  }

  host {
    type      = "CLICKHOUSE"
    zone      = "ru-central1-b"
    subnet_id = yandex_vpc_subnet.subnet_b.id
  }

  host {
    type      = "CLICKHOUSE"
    zone      = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.subnet_c.id
  }

  host {
    type      = "ZOOKEEPER"
    zone      = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.subnet_a.id
  }

  host {
    type      = "ZOOKEEPER"
    zone      = "ru-central1-b"
    subnet_id = yandex_vpc_subnet.subnet_b.id
  }

  host {
    type      = "ZOOKEEPER"
    zone      = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.subnet_c.id
  }
}

resource "yandex_mdb_mysql_cluster" "mysql_cluster" {
  name        = "grafana_mysql"
  environment = "PRODUCTION"
  network_id  = yandex_vpc_network.grafana_network.id
  version     = "8.0"

  resources {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 16
  }

  database {
    name = var.dbname
  }

  user {
    name     = var.username
    password = var.password
    permission {
      database_name = var.dbname
      roles         = ["ALL"]
    }
  }

  host {
    zone      = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.subnet_a.id
  }
  host {
    zone      = "ru-central1-b"
    subnet_id = yandex_vpc_subnet.subnet_b.id
  }
  host {
    zone      = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.subnet_c.id
  }
}

ご覧のとおり、2 つのクラスターはそれぞれ 3 つのアベイラビリティーゾーンに配置されているため、かなり耐障害性が高まっています。

ウェブサーバー

同じ精神で続けることができるように思えましたが、困難に直面しました。その前に、まず MySQL クラスターをセットアップし、その後、その ID を知って、クラスターのホストを指定する必要な構成でディスク イメージを組み立てました。しかし、現時点では、イメージのアセンブリ時を含め、Terraform が起動される前のクラスター ID はわかりません。そのため、私たちは次のような手段に頼らざるを得ませんでした。 トリック.

Amazon のメタデータ サービスを使用して、仮想マシンにいくつかのパラメータを渡し、仮想マシンがそれを受け入れて処理します。起動後にユーザーが Terraform ファイルで指定したユーザー名とパスワードと、MySQL クラスター ホストのメタデータにアクセスできるマシンが必要です。ファイルの内容を少し変更してみましょう setup.sh仮想マシンの電源がオンになると起動します。

セットアップ.sh:

#!/bin/bash
CLUSTER_URI="$(curl -H 'Metadata-Flavor:Google' http://169.254.169.254/computeMetadata/v1/instance/attributes/mysql_cluster_uri)"
USERNAME="$(curl -H 'Metadata-Flavor:Google' http://169.254.169.254/computeMetadata/v1/instance/attributes/username)"
PASSWORD="$(curl -H 'Metadata-Flavor:Google' http://169.254.169.254/computeMetadata/v1/instance/attributes/password)"
sudo sed -i "s#.*;url =.*#url = mysql://${USERNAME}:${PASSWORD}@${CLUSTER_URI}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_user =.*#admin_user = ${USERNAME}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_password =.*#admin_password = ${PASSWORD}#" /etc/grafana/grafana.ini
sudo service grafana-server restart

イントランスグループとバランサー

新しいディスク イメージを再構築したら、Terraform 用のファイルの書き込みを最終的に完了できます。

既存のディスク イメージを使用することを指定します。

data "yandex_compute_image" "grafana_image" {
  image_id = var.image_id
}

次にインスタンス グループを作成しましょう。

resource "yandex_compute_instance_group" "grafana_group" {
  name               = "grafana-group"
  folder_id          = var.folder_id
  service_account_id = var.service_account_id
  instance_template {
    platform_id = "standard-v1"
    resources {
      memory = 1
      cores  = 1
    }
    boot_disk {
      mode = "READ_WRITE"
      initialize_params {
        image_id = data.yandex_compute_image.grafana_image.id
        size     = 4
      }
    }
    network_interface {
      network_id = yandex_vpc_network.grafana_network.id
      subnet_ids = [yandex_vpc_subnet.subnet_a.id, yandex_vpc_subnet.subnet_b.id, yandex_vpc_subnet.subnet_c.id]
      nat = "true"
    }
    metadata = {
      mysql_cluster_uri = "c-${yandex_mdb_mysql_cluster.mysql_cluster.id}.rw.mdb.yandexcloud.net:3306/${var.dbname}"
      username = var.username
      password = var.password
      ssh-keys = "ubuntu:${file("${var.public_key_path}")}"
    }
    network_settings {
      type = "STANDARD"
    }
  }

  scale_policy {
    fixed_scale {
      size = 6
    }
  }

  allocation_policy {
    zones = ["ru-central1-a", "ru-central1-b", "ru-central1-c"]
  }

  deploy_policy {
    max_unavailable = 2
    max_creating    = 2
    max_expansion   = 2
    max_deleting    = 2
  }

  load_balancer {
    target_group_name = "grafana-target-group"
  }
}

メタデータへの転送方法に注目する価値がある cluster_uri, username и password。これらは、仮想マシンが起動時に抽出し、Grafana 構成に配置するものです。

それはバランサー次第です。

resource "yandex_lb_network_load_balancer" "grafana_balancer" {
  name = "grafana-balancer"

  listener {
    name = "grafana-listener"
    port = 80
    target_port = 3000
    external_address_spec {
      ip_version = "ipv4"
    }
  }

  attached_target_group {
    target_group_id = yandex_compute_instance_group.grafana_group.load_balancer.0.target_group_id

    healthcheck {
      name = "healthcheck"
      tcp_options {
        port = 3000
      }
    }
  }
}

砂糖少々

残りわずかです。インフラストラクチャがデプロイされたら、Grafana UI に移動し、CH クラスター (ID をまだ取得する必要があります) をデータ ソースとして手動で追加する必要があります。しかし、Terraform はクラスター ID を認識しています。彼に仕事を終わらせるよう任せましょう。

新しいプロバイダー Grafana を追加し、バランサーの IP アドレスをホストとして割り当てましょう。バランサーが割り当てたマシン上で Terraform が行ったすべての変更は MySQL に拡張され、他のすべてのマシンにも拡張されます。

provider "grafana" {
  url  = "http://${[for s in yandex_lb_network_load_balancer.grafana_balancer.listener: s.external_address_spec.0.address].0}"
  auth = "${var.username}:${var.password}"
}

resource "grafana_data_source" "ch_data_source" {
  type          = "vertamedia-clickhouse-datasource"
  name          = "grafana"
  url           = "https://c-${yandex_mdb_clickhouse_cluster.ch_cluster.id}.rw.mdb.yandexcloud.net:8443"
  basic_auth_enabled = "true"
  basic_auth_username = var.username
  basic_auth_password = var.password
  is_default = "true"
  access_mode = "proxy"
}

櫛で梳かしましょう

バランサーのIPアドレスとClickHouseクラスターのホストを出力します。

output "grafana_balancer_ip_address" {
  value = [for s in yandex_lb_network_load_balancer.grafana_balancer.listener: s.external_address_spec.0.address].0
}

output "clickhouse_cluster_host" {
  value = "https://c-${yandex_mdb_clickhouse_cluster.ch_cluster.id}.rw.mdb.yandexcloud.net:8443"
}

起動できます

全て！構成ファイルの準備ができたので、変数を設定して、上で説明したすべてのことを実行するように Terraform に指示できます。全体のプロセスには約15分かかりました。
最後に美しいメッセージを見ることができます。

Apply complete! Resources: 9 added, 0 changed, 0 destroyed.
Outputs:

clickhouse_cluster_host = https://c-c9q14ipa2ngadqsbp2iq.rw.mdb.yandexcloud.net:8443
grafana_balancer_ip_address = 130.193.50.25

クラウドでは、構築されたインフラストラクチャの要素が目に見えるようになります。

要約します

現在、Grafana を例にすると、各自が Yandex.Cloud プラットフォーム上に広大なクラウド アーキテクチャを備えたアプリケーションを展開できます。 Packer や Terraform などの HashiCorp の便利なツールが役立ちます。この記事が誰かの役に立つことを願っています🙂

追伸以下に、この記事で提供した Packer と Terraform の既成レシピが見つかるリポジトリへのリンクを添付します。

リポジトリ

出所： habr.com