1C 製品が Linux 環境でどのように動作するかというトピックを掘り下げていくと、1C サーバーのクラスターを管理するための便利なグラフィカル マルチプラットフォーム ツールがないという欠点が XNUMX つ見つかりました。 そして、rac コンソール ユーティリティ用の GUI を作成することでこの欠点を修正することが決定されました。 私の意見では、このタスクに最も適していると考えて、Tcl/tk が開発言語として選択されました。 そこで、この資料では、ソリューションの興味深い側面をいくつか紹介したいと思います。
動作するには、tcl/tk および 1C ディストリビューションが必要です。 そして、サードパーティのパッケージを使用せずに基本的な tcl/tk 配信の機能を最大限に活用することにしたため、ttk が含まれるバージョン 8.6.7 が必要になります。ttk は追加のグラフィック要素を備えたパッケージで、主に ttk が必要です。 ::TreeView を使用すると、データをツリー構造とテーブル (リスト) の両方の形式で表示できます。 また、新しいバージョンでは、例外処理 (プロジェクト内で外部コマンドを実行するときに使用される try コマンド) が再作成されました。
プロジェクトは複数のファイルで構成されています (ただし、すべてを XNUMX つで実行することを妨げるものはありません)。
rac_gui.cfg - デフォルト設定
rac_gui.tcl - メイン起動スクリプト
lib ディレクトリには、起動時に自動的にロードされるファイルが含まれています。
function.tcl - プロシージャを含むファイル
gui.tcl - メインのグラフィカルインターフェイス
image.tcl - Base64 イメージ ライブラリ
実際、rac_gui.tcl ファイルはインタープリタの起動、変数の初期化、モジュールのロード、構成などを行います。 コメントを含むファイルの内容:
rac_gui.tcl
#!/bin/sh
exec wish "$0" -- "$@"
# Устанавливаем текущий каталог
set dir(root) [pwd]
# Устанавливаем рабочий каталог, если его нет то создаём
set dir(work) [file join $env(HOME) .rac_gui]
if {[file exists $dir(work)] == 0 } {
file mkdir $dir(work)
}
# каталог с модулями
set dir(lib) "[file join $dir(root) lib]"
# загружаем пользовательский конфиг, если он отсутствует, то копируем дефолтный
if {[file exists [file join $dir(work) rac_gui.cfg]] ==0} {
file copy [file join [pwd] rac_gui.cfg] [file join $dir(work) rac_gui.cfg]
}
source [file join $dir(work) rac_gui.cfg]
# Код проверки наличия rac и правильности указания пути в конфиге
# если программа не найдена то будет выведен диалог для указания корректного пути
# и этот путь будет записан в пользовательский конфиг
if {[file exists $rac_cmd] == 0} {
set rac_cmd [tk_getOpenFile -initialdir $env(HOME) -parent . -title "Укажите путь до rac" -initialfile rac]
file copy [file join $dir(work) rac_gui.cfg] [file join $dir(work) rac_gui.cfg.bak]
set orig_file [open [file join $dir(work) rac_gui.cfg.bak] "r"]
set file [open [file join $dir(work) rac_gui.cfg] "w"]
while {[gets $orig_file line] >=0 } {
if {[string match "set rac_cmd*" $line]} {
puts $file "set rac_cmd $rac_cmd"
} else {
puts $file $line
}
}
close $file
close $orig_file
#return "$host:$port"
file delete [file join $dir(work) 1c_srv.cfg.bak]
} else {
puts "Found $rac_cmd"
}
set cluster_user ""
set cluster_pwd ""
set agent_user ""
set agent_pwd ""
## LOAD FILE ##
# Загружаем модули кроме gui.tcl так как его надо загрузить последним
foreach modFile [lsort [glob -nocomplain [file join $dir(lib) *.tcl]]] {
if {[file tail $modFile] ne "gui.tcl"} {
source $modFile
puts "Loaded module $modFile"
}
}
source [file join $dir(lib) gui.tcl]
source [file join $dir(work) rac_gui.cfg]
# Читаем файл со списком серверов 1С
# и добавляем в дерево
if [file exists [file join $dir(work) 1c_srv.cfg]] {
set f [open [file join $dir(work) 1c_srv.cfg] "RDONLY"]
while {[gets $f line] >=0} {
.frm_tree.tree insert {} end -id "server::$line" -text "$line" -values "$line"
}
}
必要なものをすべてダウンロードし、rac ユーティリティの存在を確認すると、グラフィカル ウィンドウが起動します。 プログラム インターフェイスは XNUMX つの要素で構成されます。
ツールバー、ツリー、リスト
「ツリー」の内容は、1CのWindows標準装備にできるだけ近づけるようにしました。
このウィンドウを形成するメインコードは、次のファイルに含まれています。
lib/gui.tcl
# установка размера и положения основного окна
# можно установить в переменную topLevelGeometry в конфиг программы
if {[info exists topLevelGeometry]} {
wm geometry . $topLevelGeometry
} else {
wm geometry . 1024x768
}
# Заголовок окна
wm title . "1C Rac GUI"
wm iconname . "1C Rac Gui"
# иконка окна (берется из файла lib/imges.tcl)
wm iconphoto . tcl
wm protocol . WM_DELETE_WINDOW Quit
wm overrideredirect . 0
wm positionfrom . user
ttk::style theme use clam
# Панель инсрументов
set frm_tool [frame .frm_tool]
pack $frm_tool -side left -fill y
ttk::panedwindow .panel -orient horizontal -style TPanedwindow
pack .panel -expand true -fill both
pack propagate .panel false
ttk::button $frm_tool.btn_add -command Add -image add_grey_32
ttk::button $frm_tool.btn_del -command Del -image del_grey_32
ttk::button $frm_tool.btn_edit -command Edit -image edit_grey_32
ttk::button $frm_tool.btn_quit -command Quit -image quit_grey_32
pack $frm_tool.btn_add $frm_tool.btn_del $frm_tool.btn_edit -side top -padx 5 -pady 5
pack $frm_tool.btn_quit -side bottom -padx 5 -pady 5
# Дерево с полосами прокрутки
set frm_tree [frame .frm_tree]
ttk::scrollbar $frm_tree.hsb1 -orient horizontal -command [list $frm_tree.tree xview]
ttk::scrollbar $frm_tree.vsb1 -orient vertical -command [list $frm_tree.tree yview]
set tree [ttk::treeview $frm_tree.tree -show tree
-xscrollcommand [list $frm_tree.hsb1 set] -yscrollcommand [list $frm_tree.vsb1 set]]
grid $tree -row 0 -column 0 -sticky nsew
grid $frm_tree.vsb1 -row 0 -column 1 -sticky nsew
grid $frm_tree.hsb1 -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_tree 0 -weight 1
grid rowconfigure $frm_tree 0 -weight 1
# назначение обработчика нажатия кнопкой мыши
bind $frm_tree.tree <ButtonRelease> "TreePress $frm_tree.tree"
# Список для данных (таблица)
set frm_work [frame .frm_work]
ttk::scrollbar $frm_work.hsb -orient horizontal -command [list $frm_work.tree_work xview]
ttk::scrollbar $frm_work.vsb -orient vertical -command [list $frm_work.tree_work yview]
set tree_work [
ttk::treeview $frm_work.tree_work
-show headings -columns "par val" -displaycolumns "par val"
-xscrollcommand [list $frm_work.hsb set]
-yscrollcommand [list $frm_work.vsb set]
]
# Установка цветов для чередования в таблице
$tree_work tag configure dark -background $color(dark_table_bg)
$tree_work tag configure light -background $color(light_table_bg)
# Размещение элементов на форме
grid $tree_work -row 0 -column 0 -sticky nsew
grid $frm_work.vsb -row 0 -column 1 -sticky nsew
grid $frm_work.hsb -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_work 0 -weight 1
grid rowconfigure $frm_work 0 -weight 1
pack $frm_tree $frm_work -side left -expand true -fill both
#.panel add $frm_tool -weight 1
.panel add $frm_tree -weight 1
.panel add $frm_work -weight 1
プログラムを操作するためのアルゴリズムは次のとおりです。
1. まず、メイン クラスタ サーバー (つまり、クラスタ管理サーバー (Linux では、管理はコマンド「/opt/1C/v8.3/x86_64/ras クラスタ —daemon」で起動されます)) を追加する必要があります。
これを行うには、「+」ボタンをクリックし、開いたウィンドウでサーバーのアドレスとポートを入力します。
その後、サーバーをクリックするとツリーにサーバーが表示され、クラスターのリストが開くか、接続エラーが表示されます。
2. クラスター名をクリックすると、そのクラスターで使用できる機能のリストが表示されます。
3...。
など、つまり新しいクラスターを追加するには、リストで使用可能なクラスターを選択し、ツールバーの「+」ボタンを押すと、新規追加ダイアログが表示されます。
ツールバーのボタンは、コンテキストに応じて機能を実行します。 ツリーまたはリストのどの要素が選択されているかに応じて、XNUMX つまたは別の手順が実行されます。
追加ボタン (「+」) の例を見てみましょう。
ボタン生成コード:
ttk::button $frm_tool.btn_add -command Add -image add_grey_32
ここでは、ボタンが押されると「追加」プロシージャが実行されることがわかります。そのコードは次のとおりです。
proc Add {} {
global active_cluster host
# Определяем идентификатор выделенного элемента
set id [.frm_tree.tree selection]
# Определяем значение этого элемента
set values [.frm_tree.tree item [.frm_tree.tree selection] -values]
set key [lindex [split $id "::"] 0]
# в зависимости от того что выделили будет запущена нужная процедура
if {$key eq "" || $key eq "server"} {
set host [ Add::server ]
return
}
Add::$key .frm_tree.tree $host $values
}
Tickle の利点の XNUMX つは、変数の値をプロシージャ名として渡すことができることです。
Add::$key .frm_tree.tree $host $values
つまり、たとえば、メインサーバーをポイントして「+」を押すと、Add::server プロシージャが起動されます。クラスタの場合は、Add::cluster などです (どこにあるかについては後ほど書きます)。必要な「キー」は後述します)。リストされた手順により、コンテキストに適したグラフィック要素が描画されます。
すでにお気づきかと思いますが、フォームはスタイルが似ています。これらは XNUMX つのプロシージャ、より正確にはフォームのメイン フレーム (ウィンドウ、ボタン、イメージ、ラベル)、プロシージャの名前によって表示されるため、これは驚くべきことではありません。 トップレベルの追加
proc AddToplevel {lbl img {win_name .add}} {
set cmd "destroy $win_name"
if [winfo exists $win_name] {destroy $win_name}
toplevel $win_name
wm title $win_name $lbl
wm iconphoto $win_name tcl
# метка с иконкой
ttk::label $win_name.lbl -image $img
# фрейм с полями ввода
set frm [ttk::labelframe $win_name.frm -text $lbl -labelanchor nw]
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
# фрейм и кнопки
set frm_btn [frame $win_name.frm_btn -border 0]
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }
ttk::button $frm_btn.btn_cancel -command $cmd -image quit_grey_24
grid $win_name.lbl -row 0 -column 0 -sticky nw -padx 5 -pady 10
grid $frm -row 0 -column 1 -sticky nw -padx 5 -pady 5
grid $frm_btn -row 1 -column 1 -sticky se -padx 5 -pady 5
pack $frm_btn.btn_cancel -side right
pack $frm_btn.btn_ok -side right -padx 10
return $frm
}
呼び出しパラメータ: タイトル、ライブラリ (lib/images.tcl) からのアイコンのイメージ名、およびオプションのウィンドウ名パラメータ (デフォルトは .add)。 したがって、上記の例でメイン サーバーとクラスターを追加すると、呼び出しは次のようになります。
AddToplevel "Добавление основного сервера" server_grey_64
または
AddToplevel "Добавление кластера" cluster_grey_64
さて、これらの例を続けて、サーバーまたはクラスターの追加ダイアログを表示する手順を示します。
追加::サーバー
proc Add::server {} {
global default
# выводим основную форму
set frm [AddToplevel "Добавление основного сервера" server_grey_64]
# добавляем етки и поля ввода на эту форму
label $frm.lbl_host -text "Адрес сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
#set frm_btn [frame .add.frm_btn -border 0]
# переопределяем обработчик нажатия кнопки
.add.frm_btn.btn_ok configure -command {
set host [SaveMainServer [.add.frm.ent_host get] [.add.frm.ent_port get]]
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"
destroy .add
return $host
}
return $frm
}
追加::クラスター
proc Add::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes
agent_user agent_pwd cluster_user cluster_pwd auth_agent
if {$agent_user ne "" && $agent_pwd ne ""} {
set auth_agent "--agent-user=$agent_user --agent-pwd=$agent_pwd"
} else {
set auth_agent ""
}
# устанавливаем глобальные переменные ()
set lifetime_limit $default(lifetime_limit)
set expiration_timeout $default(expiration_timeout)
set session_fault_tolerance_level $default(session_fault_tolerance_level)
set max_memory_size $default(max_memory_size)
set max_memory_time_limit $default(max_memory_time_limit)
set errors_count_threshold $default(errors_count_threshold)
set security_level [lindex $default(security_level) 0]
set load_balancing_mode [lindex $default(load_balancing_mode) 0]
set frm [AddToplevel "Добавление кластера" cluster_grey_64]
label $frm.lbl_host -text "Адрес основного сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
label $frm.lbl_name -text "Название кластера"
entry $frm.ent_name
label $frm.lbl_secure_connect -text "Защищённое соединение"
ttk::combobox $frm.cb_security_level -textvariable security_level -values $default(security_level)
label $frm.lbl_expiration_timeout -text "Останавливать выключенные процессы через:"
entry $frm.ent_expiration_timeout -textvariable expiration_timeout
label $frm.lbl_session_fault_tolerance_level -text "Уровень отказоустойчивости"
entry $frm.ent_session_fault_tolerance_level -textvariable session_fault_tolerance_level
label $frm.lbl_load_balancing_mode -text "Режим распределения нагрузки"
ttk::combobox $frm.cb_load_balancing_mode -textvariable load_balancing_mode
-values $default(load_balancing_mode)
label $frm.lbl_errors_count_threshold -text "Допустимое отклонение количества ошибок сервера, %"
entry $frm.ent_errors_count_threshold -textvariable errors_count_threshold
label $frm.lbl_processes -text "Рабочие процессы:"
label $frm.lbl_lifetime_limit -text "Период перезапуска, сек."
entry $frm.ent_lifetime_limit -textvariable lifetime_limit
label $frm.lbl_max_memory_size -text "Допустимый объём памяти, КБ"
entry $frm.ent_max_memory_size -textvariable max_memory_size
label $frm.lbl_max_memory_time_limit -text "Интервал превышения допустимого объёма памяти, сек."
entry $frm.ent_max_memory_time_limit -textvariable max_memory_time_limit
label $frm.lbl_kill_problem_processes -justify left -anchor nw -text "Принудительно завершать проблемные процессы"
checkbutton $frm.check_kill_problem_processes -variable kill_problem_processes -onvalue yes -offvalue no
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_name -row 2 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_name -row 2 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_secure_connect -row 3 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_security_level -row 3 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_expiration_timeout -row 4 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_expiration_timeout -row 4 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_session_fault_tolerance_level -row 5 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_session_fault_tolerance_level -row 5 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_load_balancing_mode -row 6 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_load_balancing_mode -row 6 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_errors_count_threshold -row 7 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_errors_count_threshold -row 7 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_processes -row 8 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.lbl_lifetime_limit -row 9 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_lifetime_limit -row 9 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_size -row 10 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_size -row 10 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_time_limit -row 11 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_time_limit -row 11 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_kill_problem_processes -row 12 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.check_kill_problem_processes -row 12 -column 1 -sticky nw -padx 5 -pady 5
# переопределяем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
return $frm
}
これらのプロシージャのコードを比較すると、その違いは目に見えてわかるため、「OK」ボタン ハンドラに焦点を当てます。 Tk では、グラフィック要素のプロパティは、オプションを使用してプログラム実行中にオーバーライドできます。 configure。 たとえば、ボタンを表示する最初のコマンドは次のとおりです。
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }
ただし、私たちのフォームでは、コマンドは必要な機能に応じて異なります。
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
上の例では、「詰まり」ボタンによりクラスターを追加する手順が開始されます。
ここで、Tk でのグラフィック要素の操作について脱線する価値があります。さまざまなデータ入力要素 (エントリ、コンボボックス、チェックボタンなど) に対して、パラメータがテキスト変数として導入されています。
entry $frm.ent_lifetime_limit -textvariable lifetime_limit
この変数はグローバル名前空間で定義され、現在入力されている値が含まれています。 それらの。 入力されたテキストをフィールドから取得するには、変数に対応する値を読み取るだけです (もちろん、要素の作成時に定義されている場合に限ります)。
入力されたテキスト (エントリ タイプの要素の場合) を取得する XNUMX 番目の方法は、get コマンドを使用することです。
.add.frm.ent_name get
これらのメソッドはどちらも上記のコードで確認できます。
この場合、このボタンをクリックすると、rac に関してクラスターを追加するために生成されたコマンド ラインを使用して RunCommand プロシージャが起動します。
/opt/1C/v8.3/x86_64/rac cluster insert --host=localhost --port=1540 --name=dsdsds --expiration-timeout=0 --lifetime-limit=0 --max-memory-size=0 --max-memory-time-limit=0 --security-level=0 --session-fault-tolerance-level=0 --load-balancing-mode=performance --errors-count-threshold=0 --kill-problem-processes=no localhost:1545
ここで、メイン コマンドに移ります。このコマンドは、必要なパラメータを使用して rac の起動を制御し、必要に応じてコマンドの出力をリストに解析して返します。
実行コマンド
proc RunCommand {root par} {
global dir rac_cmd cluster work_list_row_count agent_user agent_pwd cluster_user cluster_pwd
puts "$rac_cmd $par"
set work_list_row_count 0
# открываем канал в неблокирующем режиме
# $rac - команда с полным путём
# $par - сформированные ключи запуска и опции
set pipe [open "|$rac_cmd $par" "r"]
try {
set lst ""
set l ""
# вывод команды добавляем в список списков
while {[gets $pipe line]>=0} {
#puts $line
if {$line eq ""} {
lappend l $lst
set lst ""
} else {
lappend lst [string trim $line]
}
}
close $pipe
return $l
} on error {result options} {
# Запуск обработчика ошибок
ErrorParcing $result $options
return ""
}
}
メイン サーバー データを入力すると、そのデータがツリーに追加されます。このために、上記の Add:server プロシージャでは、次のコードが役割を果たします。
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"
ここで、ツリー内のサーバー名をクリックすると、そのサーバーによって管理されているクラスターのリストが取得され、クラスターをクリックすると、クラスター要素 (サーバー、情報ベースなど) のリストが取得されます。 これは TreePress プロシージャ (ファイル lib/function.tcl) に実装されています。
proc TreePress {tree} {
global host server active_cluster infobase
# определяем выделенный элемент
set id [$tree selection]
# устанавливаем нужные глобальные переменные
SetGlobalVarFromTreeItems $tree $id
# Определяем ключ и значение, т.е. именно тип выбранного элемента
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
# и в зависимости от того что выбрали будет запущена соответствующая процедура
# в пространстве имён Run
Run::$key $tree $host $values
}
したがって、メイン サーバーに対して Run::server が起動されます (クラスターの場合 - Run::cluster、作業サーバーの場合 - Run::work_server など)。 それらの。 $key 変数の値は、オプションで指定されたツリー要素の名前の一部です。 id.
手続きに注意しましょう
実行::サーバー
proc Run::server {tree host values} {
# получаем список кластеров требуемого сервера
set lst [RunCommand server::$host "cluster list $host"]
if {$lst eq ""} {return}
set l [lindex $lst 0]
#puts $lst
# удаляем лишнее из списка
.frm_work.tree_work delete [ .frm_work.tree_work children {}]
# читаем список
foreach cluster_list $lst {
# Заполняем список полученными значениями
InsertItemsWorkList $cluster_list
# обрабатываем вывод (список) для добавления данных в дерево
foreach i $cluster_list {
#puts $i
set cluster_list [split $i ":"]
if {[string trim [lindex $cluster_list 0]] eq "cluster"} {
set cluster_id [string trim [lindex $cluster_list 1]]
lappend cluster($cluster_id) $cluster_id
}
if {[string trim [lindex $cluster_list 0]] eq "name"} {
lappend cluster($cluster_id) [string trim [lindex $cluster_list 1]]
}
}
}
# добавляем кластеры в дерево
foreach x [array names cluster] {
set id [lindex $cluster($x) 0]
if { [$tree exists "cluster::$id"] == 0 } {
$tree insert "server::$host" end -id "cluster::$id" -text "[lindex $cluster($x) 1]" -values "$id"
# добавляем элементы в кластер
InsertClusterItems $tree $id
}
}
if { [$tree exists "agent_admins::$id"] == 0 } {
$tree insert "server::$host" end -id "agent_admins::$id" -text "Администраторы" -values "$id"
#InsertClusterItems $tree $id
}
}
この手順は、RunCommand コマンドを通じてサーバーから受信したものを処理し、クラスター、さまざまなルート要素 (ベース、作業サーバー、セッションなど) など、あらゆる種類のものをツリーに追加します。 よく見ると、内部に InsertItemsWorkList プロシージャが呼び出されていることがわかります。 これは、事前に $lst 変数にリストとして返されていた rac コンソール ユーティリティの出力を処理することにより、要素をグラフィカル リストに追加するために使用されます。 これは、コロンで区切られた要素のペアを含むリストのリストです。
たとえば、クラスター接続のリストは次のようになります。
svk@svk ~]$ /opt/1C/v8.3/x86_64/rac connection list --cluster=783d2170-56c3-11e8-c586-fc75165efbb2 localhost:1545
connection : dcf5991c-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:49:51
session-number : 0
blocked-by-ls : 0
connection : b993293a-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:48:52
session-number : 0
blocked-by-ls : 0
グラフ形式では次のようになります。
上記の手順では、テーブルに記入するヘッダーとデータの要素の名前を選択します。
挿入アイテムワークリスト
proc InsertItemsWorkList {lst} {
global work_list_row_count
# установка чередования цвета для строки
if [expr $work_list_row_count % 2] {
set tag dark
} else {
set tag light
}
# разбор строк на пары ключ - значение
foreach i $lst {
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
lappend column_list [string trim $param]
lappend value_list [string trim $value]
}
}
# заполнение таблицы
.frm_work.tree_work configure -columns $column_list -displaycolumns $column_list
.frm_work.tree_work insert {} end -values $value_list -tags $tag
.frm_work.tree_work column #0 -stretch
# установка заголовков
foreach j $column_list {
.frm_work.tree_work heading $j -text $j
}
incr work_list_row_count
}
ここでは、文字列を「:」で区切られた要素に分割してリストを返す単純なコマンド [split $str ":"] の代わりに、一部の要素にはコロンも含まれるため、正規表現が使用されます。
InsertClusterItems プロシージャ (類似したプロシージャがいくつかあるうちの XNUMX つ) は、対応する識別子を持つ子要素のリストを必要なクラスタ要素のツリーに追加するだけです。
クラスター項目の挿入
proc InsertClusterItems {tree id} {
set parent "cluster::$id"
$tree insert $parent end -id "infobases::$id" -text "Информационные базы" -values "$id"
$tree insert $parent end -id "servers::$id" -text "Рабочие серверы" -values "$id"
$tree insert $parent end -id "admins::$id" -text "Администраторы" -values "$id"
$tree insert $parent end -id "managers::$id" -text "Менеджеры кластера" -values $id
$tree insert $parent end -id "processes::$id" -text "Рабочие процессы" -values "workprocess-all"
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "sessions-all"
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "blocks-all"
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "connections-all"
$tree insert $parent end -id "profiles::$id" -text "Профили безопасности" -values $id
}
同様の手順を実装するには、さらに XNUMX つのオプションを検討できます。これにより、繰り返しのコマンドを最適化して削除する方法が明確にわかります。
この手順では、追加とチェックが正面から解決されます。
挿入BaseItems
proc InsertBaseItems {tree id} {
set parent "infobase::$id"
if { [$tree exists "sessions::$id"] == 0 } {
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "$id"
}
if { [$tree exists "locks::$id"] == 0 } {
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "$id"
}
if { [$tree exists "connections::$id"] == 0 } {
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "$id"
}
}
より正しいアプローチは次のとおりです。
プロファイル項目の挿入
proc InsertProfileItems {tree id} {
set parent "profile::$id"
set lst {
{dir "Виртуальные каталоги"}
{com "Разрешённые COM-классы"}
{addin "Внешние компоненты"}
{module "Внешние отчёты и обработки"}
{app "Разрешённые приложения"}
{inet "Ресурсы интернет"}
}
foreach i $lst {
append item [lindex $i 0] "::$id"
if { [$tree exists $item] == 0 } {
$tree insert $parent end -id $item -text [lindex $i 1] -values "$id"
}
unset item
}
}
それらの違いは、繰り返されるコマンドが実行されるループの使用です。 どのアプローチを使用するかは開発者の裁量に任されています。
要素の追加とデータの取得については説明しましたが、ここでは編集に焦点を当てます。 基本的に、編集と追加には同じパラメータが使用されます(情報ベースを除く)ので、同じダイアログ形式が使用されます。 追加するプロシージャを呼び出すアルゴリズムは次のようになります。
追加::$key->AddToplevel
そして、次のように編集します。
編集::$key->追加::$key->AddTopLevel
たとえば、クラスターの編集を考えてみましょう。 ツリー内のクラスターの名前をクリックして、ツールバーの編集ボタン (鉛筆) を押すと、対応するフォームが画面に表示されます。
編集::クラスター
proc Edit::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes active_cluster
agent_user agent_pwd cluster_user cluster_pwd auth
if {$cluster_user ne "" && $cluster_pwd ne ""} {
set auth "--cluster-user=$cluster_user --cluster-pwd=$cluster_pwd"
} else {
set auth ""
}
# рисуем форму для кластера
set frm [Add::cluster $tree $host $values]
# меняем текст на метке
$frm configure -text "Редактирование кластера"
set active_cluster $values
# получаем данные по выделенному кластеру
set lst [RunCommand cluster::$values "cluster info --cluster=$active_cluster $host"]
# заполняем поля
FormFieldsDataInsert $frm $lst
# выключаем поля, редактирование которых запрещено
$frm.ent_host configure -state disable
$frm.ent_port configure -state disable
# переназначаем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster update
--cluster=$active_cluster $auth
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth $host"
$tree delete "cluster::$active_cluster"
Run::server $tree $host ""
destroy .add
}
}
コード内のコメントに基づくと、原則として、ボタン ハンドラー コードがオーバーライドされることと、フィールドにデータを入力して変数を初期化する FormFieldsDataInsert プロシージャがあることを除いて、すべてが明らかです。
フォームフィールドデータ挿入
proc FormFieldsDataInsert {frm lst} {
foreach i [lindex $lst 0] {
# получаем список параметров и значений
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
# меняем символы
regsub -all -- "-" [string trim $param] "_" entry_name
# заполняем данными
if [winfo exists $frm.ent_$entry_name] {
$frm.ent_$entry_name delete 0 end
$frm.ent_$entry_name insert end [string trim $value """]
}
if [winfo exists $frm.cb_$entry_name] {
global $entry_name
set $entry_name [string trim $value """]
}
# для чекбоксов меняем значения
if [winfo exists $frm.check_$entry_name] {
global $entry_name
if {$value eq "0"} {
set $entry_name no
} elseif {$value eq "1"} {
set $entry_name yes
} else {
set $entry_name $value
}
}
}
}
}
この手順では、tcl のもう XNUMX つの利点が明らかになりました。それは、他の変数の値が変数名として置き換えられることです。 それらの。 フォームの入力と変数の初期化を自動化するために、フィールドと変数の名前は、rac ユーティリティのコマンド ライン スイッチとコマンド出力パラメータの名前に対応します。ただし、ダッシュはアンダースコアに置き換えられます。 例えば スケジュールされたジョブの拒否 フィールドに一致します ent_scheduled_jobs_deny そして変数 スケジュールされたジョブの拒否.
追加および編集用のフォームは、フィールドの構成が異なる場合があります。たとえば、情報ベースを操作する場合です。
情報セキュリティの追加
情報セキュリティの編集
編集プロシージャ Edit::infobase では、必須フィールドがフォームに追加されますが、コードは膨大であるため、ここでは示しません。
同様に、追加、編集、削除の手順は他の要素にも実装されます。
ユーティリティの操作には無制限の数のサーバー、クラスター、情報ベースなどが含まれるため、どのクラスターがどのサーバーまたは情報セキュリティ システムに属するかを決定するために、いくつかのグローバル変数が導入されており、それぞれの値が設定されています。ツリーの要素をクリックしたとき。 それらの。 このプロシージャはすべての親要素を再帰的に実行し、変数を設定します。
SetGlobalVarFromTreeItems
proc SetGlobalVarFromTreeItems {tree id} {
global host server active_cluster infobase
set parent [$tree parent $id]
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
switch -- $key {
server {set host $values}
work_server {set server $values}
cluster {set active_cluster $values}
infobase {set infobase $values}
}
if {$parent eq ""} {
return
} else {
SetGlobalVarFromTreeItems $tree $parent
}
}
1C クラスターを使用すると、承認の有無にかかわらず作業できます。 管理者には、クラスター エージェント管理者とクラスター管理者の 4 種類があります。 したがって、正しく動作するために、管理者のログインとパスワードを含む XNUMX つのグローバル変数がさらに導入されました。 それらの。 クラスターに管理者アカウントがある場合は、ログインとパスワードを入力するためのダイアログが表示され、データはメモリーに保存され、対応するクラスターの各コマンドに挿入されます。
これはエラー処理手順の責任です。
エラーパーシング
proc ErrorParcing {err opt} {
global cluster_user cluster_pwd agent_user agent_pwd
switch -regexp -- $err {
"Cluster administrator is not authenticated" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Central server administrator is not authenticated" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
"Администратор кластера не аутентифицирован" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Администратор центрального сервера не аутентифицирован" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
(.+) {
tk_messageBox -type ok -icon error -message "$err"
}
}
}
それらの。 コマンドが返す内容に応じて、それに応じた反応が行われます。
現時点では、機能の約 95% が実装されています。残っているのは、セキュリティ プロファイルを使用した作業を実装してテストすることだけです =)。 それだけです。 くしゃくしゃな話で申し訳ありません。
コードは従来から利用可能です
更新: セキュリティ プロファイルの使用を終了しました。 これで、機能が 100% 実装されました。
アップデート 2: 英語とロシア語へのローカライズが追加され、win7 での動作がテストされました
出所: habr.com