ಟೆಲಿಗ್ರಾಮ್ v 2.0 ನಿಂದ ಮೈಕ್ರೋಟಿಕ್ ಸ್ಕ್ರಿಪ್ಟ್‌ಗಳ ರಿಮೋಟ್ ಸಕ್ರಿಯಗೊಳಿಸುವಿಕೆ

ಎಲ್ಲರಿಗೂ ತಡವಾದ ರಜಾದಿನದ ಶುಭಾಶಯಗಳು. ಈ ಥೀಮ್ ಉತ್ತಮವಾಗಿದೆ ನಾನು 2016 ರಲ್ಲಿ ಬರೆದದ್ದರ ಆವೃತ್ತಿ ಇಲ್ಲಿದೆ.

ಸಾಮಾನ್ಯವಾಗಿ, ಕಾರ್ಯಾಚರಣೆಯ ತತ್ವವು ಬದಲಾಗಿಲ್ಲ, ಒಂದೇ ವ್ಯತ್ಯಾಸವೆಂದರೆ ಈಗ ಅದು ವಿಳಂಬವಿಲ್ಲದೆ ತಕ್ಷಣವೇ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ.

ನಾವು ಸ್ಕ್ರಿಪ್ಟ್ ಅನ್ನು Mikrotik ಗೆ ಅಪ್‌ಲೋಡ್ ಮಾಡುತ್ತೇವೆ, BotID ಮತ್ತು ChatID ಅನ್ನು ನಮ್ಮದೇ ಆಗಿ ಬದಲಾಯಿಸುತ್ತೇವೆ ಮತ್ತು ಅದಕ್ಕಾಗಿ ವೇಳಾಪಟ್ಟಿಯನ್ನು ರಚಿಸುತ್ತೇವೆ. ಪ್ರಾರಂಭಕ್ಕೆ "ಪ್ರಾರಂಭದ ಸಮಯ" ನಿಯತಾಂಕವನ್ನು ಹೊಂದಿಸಿ (ಪ್ರಾರಂಭದಲ್ಲಿ ಸ್ಕ್ರಿಪ್ಟ್ ಅನ್ನು ರನ್ ಮಾಡಿ.)
"ಮಧ್ಯಂತರ": 00:00:00
ಇಲ್ಲದಿದ್ದರೆ ಎಲ್ಲವೂ ಇದ್ದಂತೆಯೇ ಇರುತ್ತದೆ.

ಟೆಲಿಗ್ರಾಮ್-v2

:delay 10
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;
:local chatId 0;
:local messageId 0;


:local parse do={
  :local startLoc ([:find $content $variable -1] + [:len $variable] + 2);
  :local commaLoc ([:find $content "," $startLoc] - 1 + 1);
  :local braceLoc ([:find $content "}" $startLoc] - 1 + 1);
  :local endLoc $commaLoc;
  :local startSymbol [:pick $content $startLoc]
  :if ($braceLoc != 0 and ($commaLoc = 0 or $braceLoc < $commaLoc)) do={
    :set endLoc $braceLoc;
  };
  :if ($startSymbol = "{") do={
    :set endLoc ($braceLoc + 1);
  };
  :if ($quotas = true) do={
    :set startLoc ($startLoc + 1);
    :set endLoc ($endLoc - 1);
  }
  :if ($endLoc < $startLoc) do={
    :set endLoc ($startLoc + 1);
  };
  :local message [:pick $content $startLoc $endLoc]
  #:log info $message;
  :return $message;
}


:while ( true ) do={
  :do {
    #:log info "https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60";
    :tool fetch url=("https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60") dst-path="getUpdates";
    :local content [/file get [/file find name=getUpdates] contents] ;
    #:log info $content;
    :if ([:len $content] > 30) do={
      :set messageId ([$parse content=$content variable="update_id"] + 1)
      :local message [$parse content=$content variable="text" quotas=true]
      :local chat [$parse content=$content variable="chat"]
      :local chatId [$parse content=$chat variable="id"]      
      
      :if (($chatId = $myChatID) and ([/system script find name=$message] != "")) do={
        :system script run $message;
      } else={
        :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$chatId&text=$mtIdentity: Unknown command: $message") keep-result=no
      }
    }
  } on-error={}
};

ಒಂದೆರಡು ವರ್ಷಗಳ ಬಳಕೆಯ ನಂತರ, ದೋಷವನ್ನು ಕಂಡುಹಿಡಿಯಲಾಯಿತು: ಕೆಲವು ಅಪರಿಚಿತ ಕಾರಣಗಳಿಗಾಗಿ, ದುರ್ಬಲ ಮೈಕ್ರೊಟಿಕ್ ಸ್ಕ್ರಿಪ್ಟ್ ಅನ್ನು ನಿಲ್ಲಿಸುತ್ತದೆ, ಆದರೆ ಹೆಚ್ಚು ಶಕ್ತಿಯುತವಾದವುಗಳಲ್ಲಿ ಅದು ನಿಲ್ಲದೆ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ.

ಈ ಉದ್ದೇಶಗಳಿಗಾಗಿ, ನಾನು ವಾಚ್ಡಾಗ್ ಊರುಗೋಲನ್ನು ಎಸೆದಿದ್ದೇನೆ. ಇಲ್ಲಿ ನಾವು ಸ್ಕ್ರಿಪ್ಟ್‌ನ ಹೆಸರನ್ನು ಮೇಲೆ ಸೂಚಿಸಿದ ಹೆಸರಿಗೆ ಬದಲಾಯಿಸುತ್ತೇವೆ. ಮತ್ತು ಮರುಪ್ರಾರಂಭದ ಮಧ್ಯಂತರವನ್ನು 5 ನಿಮಿಷಗಳಿಗೆ ಹೊಂದಿಸಿ. ಪ್ರತಿ 5 ನಿಮಿಷಗಳಿಗೊಮ್ಮೆ ನಮ್ಮ "ಕಾವಲುಗಾರ" ಸ್ಕ್ರಿಪ್ಟ್ ಅನ್ನು ಪರಿಶೀಲಿಸುತ್ತದೆ ಮತ್ತು ಅದು ಕೆಲಸ ಮಾಡದಿದ್ದರೆ, ಅದು ಅದನ್ನು ರನ್ ಮಾಡುತ್ತದೆ.

WatchDogT.me

:global scriptname "t.me"
:if ([:len [/system script job find script=$"scriptname"]] > 0) do={
:log info "$scriptname Already Running - killing old script before continuing"
:foreach counter in=[/system script job find script=$"scriptname"] do={
/system script job remove $counter
}
}
/system script run $scriptname

ಒಳ್ಳೆಯದು, ಸಿಹಿತಿಂಡಿಗಾಗಿ, ಸ್ಕ್ರಿಪ್ಟ್ ಅನ್ನು ಮೈಕ್ರೋಟಿಕ್ ಫೋರಮ್‌ನಿಂದ ತೆಗೆದುಕೊಳ್ಳಲಾಗಿದೆ.
ಲಾಗ್‌ನಿಂದ ಪ್ರಮುಖ ವಿಷಯಗಳನ್ನು ನಮ್ಮ ಕಾರ್ಟ್‌ಗೆ ಕಳುಹಿಸುತ್ತದೆ.

ಪ್ರತಿ 5 ನಿಮಿಷಗಳಿಗೊಮ್ಮೆ ಮರುಪ್ರಾರಂಭಿಸುವ ಮಧ್ಯಂತರವನ್ನು ನಿಗದಿಪಡಿಸಲು ಮತ್ತು ನಿರ್ದಿಷ್ಟಪಡಿಸಲು ನಾವು ಸ್ಕ್ರಿಪ್ಟ್ ಅನ್ನು ಸೇರಿಸುತ್ತೇವೆ, BotID ಮತ್ತು ChatID ಅನ್ನು ನಮ್ಮದೇ ಆಗಿ ಬದಲಾಯಿಸುತ್ತೇವೆ.

ಸೂಚನೆ-ಲಾಗ್

:global lastTime
:global output
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;

:local LogGet [ :toarray [ /log find topics~"critical" || message~"login failure" || message~"[Ff]ailure" ] ] ;
:local LogtLineCount [ :len $LogGet ] ;
if ($LogtLineCount > 0) do={
   :local currentTime "$[ /log get [ :pick $LogGet ($LogtLineCount -1) ] time ]";
   :if ([:len $currentTime] = 10 ) do={
      :set currentTime [ :pick $currentTime 0 10 ];
   }
   :set output "$currentTime - $[/log get [ :pick $LogGet ($LogtLineCount-1) ] message ]";
   :if (([:len $lastTime] < 1) || (([:len $lastTime] > 0) && ($lastTime != $currentTime))) do={
      :set lastTime $currentTime ;
         :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$myChatID&text="$mtIdentity" :  $output") keep-result=no
   }
}

ನಾವು ಫಲಿತಾಂಶವನ್ನು ಪಡೆಯುತ್ತೇವೆ:

ಮೂಲ: www.habr.com