DPI 인터페이스 및 FPGA 보드를 통해 Raspberry Pi3에 대한 두 번째 HDMI 모니터

이 비디오는 GPIO 커넥터를 통해 FPGA Mars Rover3rpi(Cyclone IV) 보드가 연결되고 HDMI 모니터가 연결된 Raspberry Pi2 보드를 보여줍니다. 두 번째 모니터는 표준 Raspberry Pi3 HDMI 커넥터를 통해 연결됩니다. 모두 함께 듀얼 모니터 시스템처럼 작동합니다.

다음으로 구현 방법을 알려 드리겠습니다.

널리 사용되는 Raspberry Pi3 보드에는 센서, LED, 스테퍼 모터 드라이버 등 다양한 확장 보드를 연결할 수 있는 GPIO 커넥터가 있습니다. 커넥터에 있는 각 핀의 특정 기능은 포트 구성에 따라 다릅니다. GPIO ALT2 구성을 사용하면 커넥터를 DPI 인터페이스 모드인 디스플레이 병렬 인터페이스로 전환할 수 있습니다. DPI를 통해 VGA 모니터를 연결하기 위한 확장 보드가 있습니다. 그러나 첫째, VGA 모니터는 더 이상 HDMI만큼 일반적이지 않으며 둘째, 디지털 인터페이스가 아날로그보다 좋아지고 있습니다. 또한 이러한 VGA 확장 카드의 DAC는 일반적으로 R-2-R 체인 형태로 만들어지며 종종 색상당 6비트를 넘지 않습니다.

ALT2 모드에서 GPIO 커넥터의 핀은 다음과 같은 의미를 갖습니다.

여기에서는 커넥터의 RGB 핀을 각각 빨간색, 녹색 및 파란색으로 채색했습니다. 다른 중요한 신호는 V-SYNC 및 H-SYNC 스윕 동기 신호와 CLK입니다. CLK 클록 주파수는 픽셀 값이 커넥터로 출력되는 주파수이며 선택한 비디오 모드에 따라 다릅니다.

디지털 HDMI 모니터를 연결하려면 DPI 인터페이스 신호를 캡처하여 HDMI 신호로 변환해야 합니다. 예를 들어 FPGA 보드를 사용하여 이 작업을 수행할 수 있습니다. 결과적으로 Mars Rover2rpi 보드가 이러한 목적에 적합합니다. 실제로 특수 어댑터를 통해 이 보드를 연결하는 주요 옵션은 다음과 같습니다.

이 보드는 GPIO 포트 수를 늘리고 라즈베리에 더 많은 주변 장치를 연결하는 데 사용됩니다. 동시에 이 연결이 있는 4개의 GPIO 신호가 JTAG 신호에 사용되므로 배포판의 프로그램이 FPGA 펌웨어를 FPGA에 로드할 수 있습니다. 이 때문에 이러한 일반 연결이 나에게 적합하지 않고 4 DPI 신호가 떨어집니다. 운 좋게도 보드의 추가 빗에는 Raspberry 호환 핀아웃이 있습니다. 보드를 90도 회전하고 여전히 내 라즈베리에 연결할 수 있도록:

물론 외부 JTAG 프로그래머를 이용해야 하겠지만 이것은 문제가 되지 않는다.

여전히 작은 문제가 있습니다. 모든 FPGA 핀을 클록 입력으로 사용할 수 있는 것은 아닙니다. 이 용도로 사용할 수 있는 전용 핀은 몇 개뿐입니다. 그래서 여기에서 GPIO_0 CLK 신호가 FPGA 클럭 입력으로 사용할 수 있는 FPGA 입력에 도달하지 않는다는 것이 밝혀졌습니다. 그래서 똑같이 스카프에 하나의 게시물을 던져야했습니다. 보드의 GPIO_0과 KEY[1] 신호를 연결합니다.

이제 FPGA의 프로젝트에 대해 조금 말씀드리겠습니다. HDMI 신호 형성의 주요 어려움은 매우 높은 주파수입니다. HDMI 커넥터의 핀아웃을 보면 RGB 신호가 이제 직렬 차동 신호임을 ​​알 수 있습니다.

차동 신호를 사용하면 전송 라인의 공통 모드 노이즈를 처리할 수 있습니다. 이 경우 각 색상 신호의 원래 10비트 코드는 10비트 TMDS(Transition-minimized Differential Signaling)로 변환됩니다. 이것은 신호에서 DC 성분을 제거하고 차동 라인에서 신호 전환을 최소화하기 위한 특수 인코딩 방법입니다. 이제 직렬 회선을 통해 색상 바이트당 10비트를 전송할 수 있으므로 직렬 변환기의 클록 주파수는 픽셀의 클록 주파수보다 1280배 높아야 합니다. 예를 들어 비디오 모드가 720x60 74,25Hz인 경우 이 모드의 픽셀 주파수는 742,5MHz입니다. 직렬 변환기는 XNUMXMHz여야 합니다.

불행하게도 기존의 FPGA는 일반적으로 이를 수행할 수 없습니다. 그러나 다행스럽게도 FPGA에는 DDIO 핀이 내장되어 있습니다. 이것은 이미 2-to-1 serializer인 결론입니다. 즉, 상승 및 하강 클럭 주파수를 따라 740비트를 순차적으로 출력할 수 있습니다. 이것은 FPGA 프로젝트에서 370MHz가 아닌 370MHz를 사용할 수 있지만 FPGA에서 DDIO 출력 요소를 사용해야 함을 의미합니다. 여기서 1280MHz는 이미 달성 가능한 주파수입니다. 안타깝게도 720×2 모드가 한계입니다. RoverXNUMXrpi 보드에 설치된 FPGA Cyclone IV에서는 더 높은 해상도를 얻을 수 없습니다.

따라서 프로젝트에서 입력 픽셀 주파수 CLK는 PLL에 공급되며 여기에 5가 곱해집니다. 이 주파수에서 R, G, B 바이트는 비트 쌍으로 변환됩니다. 이것이 TMDS 인코더가 하는 일입니다. Verilog HDL의 소스 코드는 다음과 같습니다.

module hdmi(
	input wire pixclk,		// 74MHz
	input wire clk_TMDS2,	// 370MHz
	input wire hsync,
	input wire vsync,
	input wire active,
	input wire [7:0]red,
	input wire [7:0]green,
	input wire [7:0]blue,
	output wire TMDS_bh,
	output wire TMDS_bl,
	output wire TMDS_gh,
	output wire TMDS_gl,
	output wire TMDS_rh,
	output wire TMDS_rl
);

wire [9:0] TMDS_red, TMDS_green, TMDS_blue;
TMDS_encoder encode_R(.clk(pixclk), .VD(red  ), .CD({vsync,hsync}), .VDE(active), .TMDS(TMDS_red));
TMDS_encoder encode_G(.clk(pixclk), .VD(green), .CD({vsync,hsync}), .VDE(active), .TMDS(TMDS_green));
TMDS_encoder encode_B(.clk(pixclk), .VD(blue ), .CD({vsync,hsync}), .VDE(active), .TMDS(TMDS_blue));

reg [2:0] TMDS_mod5=0;  // modulus 5 counter
reg [4:0] TMDS_shift_bh=0, TMDS_shift_bl=0;
reg [4:0] TMDS_shift_gh=0, TMDS_shift_gl=0;
reg [4:0] TMDS_shift_rh=0, TMDS_shift_rl=0;

wire [4:0] TMDS_blue_l  = {TMDS_blue[9],TMDS_blue[7],TMDS_blue[5],TMDS_blue[3],TMDS_blue[1]};
wire [4:0] TMDS_blue_h  = {TMDS_blue[8],TMDS_blue[6],TMDS_blue[4],TMDS_blue[2],TMDS_blue[0]};
wire [4:0] TMDS_green_l = {TMDS_green[9],TMDS_green[7],TMDS_green[5],TMDS_green[3],TMDS_green[1]};
wire [4:0] TMDS_green_h = {TMDS_green[8],TMDS_green[6],TMDS_green[4],TMDS_green[2],TMDS_green[0]};
wire [4:0] TMDS_red_l   = {TMDS_red[9],TMDS_red[7],TMDS_red[5],TMDS_red[3],TMDS_red[1]};
wire [4:0] TMDS_red_h   = {TMDS_red[8],TMDS_red[6],TMDS_red[4],TMDS_red[2],TMDS_red[0]};

always @(posedge clk_TMDS2)
begin
	TMDS_shift_bh <= TMDS_mod5[2] ? TMDS_blue_h  : TMDS_shift_bh  [4:1];
	TMDS_shift_bl <= TMDS_mod5[2] ? TMDS_blue_l  : TMDS_shift_bl  [4:1];
	TMDS_shift_gh <= TMDS_mod5[2] ? TMDS_green_h : TMDS_shift_gh  [4:1];
	TMDS_shift_gl <= TMDS_mod5[2] ? TMDS_green_l : TMDS_shift_gl  [4:1];
	TMDS_shift_rh <= TMDS_mod5[2] ? TMDS_red_h   : TMDS_shift_rh  [4:1];
	TMDS_shift_rl <= TMDS_mod5[2] ? TMDS_red_l   : TMDS_shift_rl  [4:1];
	TMDS_mod5 <= (TMDS_mod5[2]) ? 3'd0 : TMDS_mod5+3'd1;
end

assign TMDS_bh = TMDS_shift_bh[0];
assign TMDS_bl = TMDS_shift_bl[0];
assign TMDS_gh = TMDS_shift_gh[0];
assign TMDS_gl = TMDS_shift_gl[0];
assign TMDS_rh = TMDS_shift_rh[0];
assign TMDS_rl = TMDS_shift_rl[0];

endmodule

module TMDS_encoder(
	input clk,
	input [7:0] VD,	// video data (red, green or blue)
	input [1:0] CD,	// control data
	input VDE,  	// video data enable, to choose between CD (when VDE=0) and VD (when VDE=1)
	output reg [9:0] TMDS = 0
);

wire [3:0] Nb1s = VD[0] + VD[1] + VD[2] + VD[3] + VD[4] + VD[5] + VD[6] + VD[7];
wire XNOR = (Nb1s>4'd4) || (Nb1s==4'd4 && VD[0]==1'b0);
wire [8:0] q_m = {~XNOR, q_m[6:0] ^ VD[7:1] ^ {7{XNOR}}, VD[0]};

reg [3:0] balance_acc = 0;
wire [3:0] balance = q_m[0] + q_m[1] + q_m[2] + q_m[3] + q_m[4] + q_m[5] + q_m[6] + q_m[7] - 4'd4;
wire balance_sign_eq = (balance[3] == balance_acc[3]);
wire invert_q_m = (balance==0 || balance_acc==0) ? ~q_m[8] : balance_sign_eq;
wire [3:0] balance_acc_inc = balance - ({q_m[8] ^ ~balance_sign_eq} & ~(balance==0 || balance_acc==0));
wire [3:0] balance_acc_new = invert_q_m ? balance_acc-balance_acc_inc : balance_acc+balance_acc_inc;
wire [9:0] TMDS_data = {invert_q_m, q_m[8], q_m[7:0] ^ {8{invert_q_m}}};
wire [9:0] TMDS_code = CD[1] ? (CD[0] ? 10'b1010101011 : 10'b0101010100) : (CD[0] ? 10'b0010101011 : 10'b1101010100);

always @(posedge clk) TMDS <= VDE ? TMDS_data : TMDS_code;
always @(posedge clk) balance_acc <= VDE ? balance_acc_new : 4'h0;

endmodule

그런 다음 출력 쌍이 DDIO 출력으로 공급되어 상승 ​​및 하강 시 XNUMX비트 신호를 순차적으로 생성합니다.

DDIO 자체는 다음과 같이 Verilog 코드로 설명할 수 있습니다.

module ddio(
	input wire d0,
	input wire d1,
	input wire clk,
	output wire out
	);

reg r_d0;
reg r_d1;
always @(posedge clk)
begin
	r_d0 <= d0;
	r_d1 <= d1;
end
assign out = clk ? r_d0 : r_d1;
endmodule

하지만 아마 그런 식으로 작동하지 않을 것입니다. 실제로 DDIO 출력 요소를 사용하려면 Altera의 ALTDDIO_OUT 메가 함수를 사용해야 합니다. 내 프로젝트에서 라이브러리 구성 요소 ALTDDIO_OUT이 사용됩니다.

조금 까다로워 보일 수 있지만 작동합니다.

Verilog HDL로 작성된 전체 소스 코드를 볼 수 있습니다. 바로 여기 github에서.

FPGA용으로 컴파일된 펌웨어는 Mars Rover2rpi 보드에 설치된 EPCS 칩에 내장되어 있습니다. 따라서 FPGA 보드에 전원이 공급되면 FPGA가 플래시 메모리에서 초기화되고 시작됩니다.

이제 Raspberry 자체의 구성에 대해 조금 이야기해야 합니다.

Debian Buster, 버전: 32년 2020월,
출시일:2020-08-20, 커널 버전:5.4.

다음 두 가지를 수행해야합니다.

• config.txt 파일을 편집합니다.
• 두 대의 모니터에서 작동하도록 X 서버 구성을 만듭니다.

/boot/config.txt 파일을 편집할 때 다음을 수행해야 합니다.

1. i2c, i2s, spi의 사용을 비활성화합니다.
2. 오버레이로 DPI 모드 활성화 dtoverlay=dpi24;
3. 비디오 모드 설정 1280×720 60Hz, DPI당 포인트당 24비트;
4. 필요한 프레임 버퍼 수 2 지정(max_framebuffers=2, 두 번째 장치 /dev/fb1이 표시됨)

config.txt 파일의 전체 텍스트는 다음과 같습니다.

# For more options and information see
# http://rpf.io/configtxt
# Some settings may impact device functionality. See link above for details

# uncomment if you get no picture on HDMI for a default "safe" mode
#hdmi_safe=1

# uncomment this if your display has a black border of unused pixels visible
# and your display can output without overscan
disable_overscan=1

# uncomment the following to adjust overscan. Use positive numbers if console
# goes off screen, and negative if there is too much border
#overscan_left=16
#overscan_right=16
#overscan_top=16
#overscan_bottom=16

# uncomment to force a console size. By default it will be display's size minus
# overscan.
#framebuffer_width=1280
#framebuffer_height=720

# uncomment if hdmi display is not detected and composite is being output
hdmi_force_hotplug=1

# uncomment to force a specific HDMI mode (this will force VGA)
#hdmi_group=1
#hdmi_mode=1

# uncomment to force a HDMI mode rather than DVI. This can make audio work in
# DMT (computer monitor) modes
#hdmi_drive=2

# uncomment to increase signal to HDMI, if you have interference, blanking, or
# no display
#config_hdmi_boost=4

# uncomment for composite PAL
#sdtv_mode=2

#uncomment to overclock the arm. 700 MHz is the default.
#arm_freq=800

# Uncomment some or all of these to enable the optional hardware interfaces
#dtparam=i2c_arm=on
#dtparam=i2s=on
#dtparam=spi=on

dtparam=i2c_arm=off
dtparam=spi=off
dtparam=i2s=off

dtoverlay=dpi24
overscan_left=0
overscan_right=0
overscan_top=0
overscan_bottom=0
framebuffer_width=1280
framebuffer_height=720
display_default_lcd=0
enable_dpi_lcd=1
dpi_group=2
dpi_mode=87
#dpi_group=1
#dpi_mode=4
dpi_output_format=0x6f027
dpi_timings=1280 1 110 40 220 720 1 5 5 20 0 0 0 60 0 74000000 3

# Uncomment this to enable infrared communication.
#dtoverlay=gpio-ir,gpio_pin=17
#dtoverlay=gpio-ir-tx,gpio_pin=18

# Additional overlays and parameters are documented /boot/overlays/README

# Enable audio (loads snd_bcm2835)
dtparam=audio=on

[pi4]
# Enable DRM VC4 V3D driver on top of the dispmanx display stack
#dtoverlay=vc4-fkms-v3d
max_framebuffers=2

[all]
#dtoverlay=vc4-fkms-v3d
max_framebuffers=2

그런 다음 두 개의 프레임 버퍼 /dev/fb0 및 /dev/fb1에서 두 개의 모니터를 사용하려면 X 서버에 대한 구성 파일을 만들어야 합니다.

내 구성 파일은 다음과 같이 /usr/share/x11/xorg.conf.d/60-dualscreen.conf입니다.

Section "Device"
        Identifier      "LCD"
        Driver          "fbturbo"
        Option          "fbdev" "/dev/fb0"
        Option          "ShadowFB" "off"
        Option          "SwapbuffersWait" "true"
EndSection

Section "Device"
        Identifier      "HDMI"
        Driver          "fbturbo"
        Option          "fbdev" "/dev/fb1"
        Option          "ShadowFB" "off"
        Option          "SwapbuffersWait" "true"
EndSection

Section "Monitor"
        Identifier      "LCD-monitor"
        Option          "Primary" "true"
EndSection

Section "Monitor"
        Identifier      "HDMI-monitor"
        Option          "RightOf" "LCD-monitor"
EndSection

Section "Screen"
        Identifier      "screen0"
        Device          "LCD"
        Monitor         "LCD-monitor"
EndSection

Section "Screen"
        Identifier      "screen1"
        Device          "HDMI" 
	Monitor         "HDMI-monitor"
EndSection

Section "ServerLayout"
        Identifier      "default"
        Option          "Xinerama" "on"
        Option          "Clone" "off"
        Screen 0        "screen0"
        Screen 1        "screen1" RightOf "screen0"
EndSection

음, 아직 설치하지 않았다면 Xinerama를 설치해야 합니다. 그러면 위의 데모 비디오에서 볼 수 있듯이 데스크톱 공간이 두 개의 모니터로 완전히 확장됩니다.

그게 다일 것입니다. 이제 Raspberry Pi3 소유자는 두 개의 모니터를 사용할 수 있습니다.

Mars Rover2rpi 보드의 설명 및 다이어그램은 다음과 같습니다. 여기를 보아라.

출처 : habr.com