학교 컴퓨터 과학의 주기율표

(컨트롤 카드)
(세계 화학 원소 주기율표의 해를 기념하여)
(최신 추가는 8년 2019월 XNUMX일에 이루어졌습니다. 추가 목록은 컷 바로 아래에 있습니다)

(멘델레예프의 꽃, 출처)

우리가 오리를 지나쳤던 것을 기억합니다. 지리, 자연 과학, 러시아어의 세 가지 수업이 동시에 이루어졌습니다. 과학 수업에서는 오리가 오리인지, 날개가 무엇인지, 다리가 무엇인지, 어떻게 헤엄치는지 등을 연구했습니다. 지리 수업에서 동일한 오리가 지구의 주민으로 연구되었습니다. 오리가 사는 곳과 그렇지 않은 곳을 지도에 표시해야 했습니다. 러시아어로 Serafima Petrovna는 우리에게 "u-t-k-a"라고 쓰고 Brem의 오리에 관한 내용을 읽는 법을 가르쳤습니다. 지나가면서 그녀는 독일 오리는 이렇고, 프랑스어에서는 이렇다고 알려줬습니다. 당시에는 '복잡한 방법'이라고 불렀던 것 같아요. 일반적으로 모든 것이 "지나면서"나타났습니다.

베니아민 카베린, 선장 XNUMX명

위의 인용문에서 Veniamin Kaverin은 복잡한 교육 방법의 단점을 훌륭하게 보여 주었지만 일부 (아마도 매우 드문 경우) 경우 이 방법의 요소가 정당화됩니다. 그러한 사례 중 하나는 학교 컴퓨터 과학 수업에서 D.I. Mendeleev의 주기율표입니다. 주기율표를 사용한 일반적인 동작의 소프트웨어 자동화 작업은 화학을 공부하기 시작한 학생들에게 분명하며 많은 일반적인 화학 작업으로 나뉩니다. 동시에, 컴퓨터 과학의 틀 내에서 이 작업을 통해 우리는 그래픽 요소를 사용한 프로그래밍이라는 단어의 넓은 의미에서 이해되는 그래픽 프로그래밍에 기인할 수 있는 제어 카드 방법을 간단한 형태로 보여줄 수 있습니다.

(8년 2019월 XNUMX일에 추가된 내용:
부록 1: 화학 계산기 작동 방식
부록 2: 필터 작업의 예)

기본적인 작업부터 시작해 보겠습니다. 가장 간단한 경우 주기율표는 창 형태로 화면에 표시되어야 하며, 각 셀에는 H-수소, He-헬륨 등과 같은 원소의 화학적 지정이 있습니다. 마우스 커서가 셀을 가리키면 요소 지정과 해당 번호가 양식의 특수 필드에 표시됩니다. 사용자가 LMB를 누르면 선택한 요소의 지정과 번호가 양식의 다른 필드에 표시됩니다.

모든 보편적 언어를 사용하여 문제를 해결할 수 있습니다. 거의 모든 사람이 이해할 수 있는 단순하고 오래된 Delpi-7을 사용하겠습니다. 하지만 PL로 프로그래밍하기 전에 예를 들어 Photoshop에서 두 장의 그림을 그려 보겠습니다. 먼저, 프로그램에서 보고 싶은 형태로 주기율표를 그려보자. 결과를 그래픽 파일에 저장 table01.bmp.

두 번째 그림에서는 첫 번째 그림을 사용합니다. 모든 그래픽이 지워진 테이블 셀을 RGB 색상 모델의 고유한 색상으로 순차적으로 채울 것입니다. R과 G는 항상 0이고 B=1은 수소, 2는 헬륨 등입니다. 이 그림은 제어 카드가 되며 이를 다음과 같은 파일에 저장합니다. table2.bmp.

Photoshop에서 그래픽 프로그래밍의 첫 번째 단계가 완료되었습니다. Delpi-7 IDE의 그래픽 GUI 프로그래밍으로 넘어가겠습니다. 이렇게 하려면 새 프로젝트를 열고 기본 양식에 대화 상자 버튼(테이블Dlg), 테이블 작업이 진행됩니다. 다음으로 우리는 양식을 사용하여 작업합니다. 테이블Dlg.

폼에 클래스 컴포넌트 배치 Timage. 우리는 얻는다 Image1. 일반적으로 대규모 프로젝트의 경우 양식 이름이 자동으로 생성됩니다. 이미지N어디에서 N 수십 개 이상에 도달할 수 있습니다. 이는 최고의 프로그래밍 스타일이 아니며 더 의미 있는 이름을 지정해야 합니다. 하지만 우리의 작은 프로젝트에서는 N 2를 초과하지 않으면 생성된 상태로 둘 수 있습니다.

부동산으로 이미지1.사진 파일을 업로드하세요 table01.bmp. 우리는 창조한다 Image2 거기에 제어 카드를 로드합니다. table2.bmp. 이 경우 양식의 왼쪽 하단에 표시된 것처럼 파일을 작게 만들어 사용자에게 보이지 않게 만듭니다. 목적이 분명한 추가 제어 요소를 추가합니다. Delpi-7 IDE의 그래픽 GUI 프로그래밍의 두 번째 단계가 완료되었습니다.

세 번째 단계인 Delpi-7 IDE에서 코드 작성으로 넘어가겠습니다. 모듈은 XNUMX개의 이벤트 핸들러로만 구성됩니다. 양식 생성(양식생성), 커서 이동 Image1 (이미지1마우스이동), 셀에서 LMB를 클릭합니다(이미지1클릭) 확인 버튼(OKBtn클릭) 또는 취소(취소Btn클릭). 이러한 핸들러의 헤더는 IDE를 사용하여 표준 방식으로 생성됩니다.

모듈 소스 코드:

unit tableUnit;
// Периодическая таблица химических элементов Д.И.Менделеева
//
// third112
// https://habr.com/ru/users/third112/
//
// Оглавление
// 1) создание формы
// 2) работа с таблицей: указание и выбор
// 3) выход из диалога

interface

uses Windows, SysUtils, Classes, Graphics, Forms, Controls, StdCtrls, 
  Buttons, ExtCtrls;

const
 size = 104; // число элементов
 
type
 TtableDlg = class(TForm)
    OKBtn: TButton;
    CancelBtn: TButton;
    Bevel1: TBevel;
    Image1: TImage;  //таблица химических элементов
    Label1: TLabel;
    Image2: TImage;  //управляющая карта
    Label2: TLabel;
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject); // создание формы
    procedure Image1MouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);                        // указание клетки
    procedure Image1Click(Sender: TObject); // выбор клетки
    procedure OKBtnClick(Sender: TObject);  // OK
    procedure CancelBtnClick(Sender: TObject); // Cancel
  private
    { Private declarations }
    TableSymbols : array [1..size] of string [2]; // массив обозначений элементов
  public
    { Public declarations }
    selectedElement : string; // выбранный элемент
    currNo : integer;         // текущий номер элемента
  end;

var
  tableDlg: TtableDlg;

implementation

{$R *.dfm}

const
PeriodicTableStr1=
'HHeLiBeBCNOFNeNaMgAlSiPSClArKCaScTiVCrMnFeCoNiCuZnGaGeAsSeBrKrRbSrYZrNbMoTcRuRhPdAgCdInSnSbTeIXeCsBaLa';
PeriodicTableStr2='CePrNdPmSmEuGdTbDyHoErTmYbLu';
PeriodicTableStr3='HfTaWReOsIrPtAuHgTlPbBiPoAtRnFrRaAc';
PeriodicTableStr4='ThPaUNpPuAmCmBkCfEsFmMdNoLrKu ';

// создание формы  ==================================================

procedure TtableDlg.FormCreate(Sender: TObject);
// создание формы
var
  s : string;
  i,j : integer;
begin
  currNo := 0;
// инициализация массива обозначений элементов:
  s := PeriodicTableStr1+ PeriodicTableStr2+PeriodicTableStr3+PeriodicTableStr4;
  j := 1;
  for i :=1 to size do
   begin
     TableSymbols [i] := s[j];
     inc (j);
     if s [j] in ['a'..'z'] then
      begin
        TableSymbols [i] := TableSymbols [i]+ s [j];
        inc (j);
      end; // if s [j] in
   end; // for i :=1
end; // FormCreate ____________________________________________________

// работа с таблицей: указание и выбор =========================================

procedure TtableDlg.Image1MouseMove(Sender: TObject; Shift: TShiftState;
  X, Y: Integer);
// указание клетки
var
  sl : integer;
begin
  sl := GetBValue(Image2.Canvas.Pixels [x,y]);
  if sl in [1..size] then
   begin
    Label1.Caption := intToStr (sl)+ ' '+TableSymbols [sl];
    currNo := sl;
   end
  else
    Label1.Caption := 'Select element:';
end; // Image1MouseMove   ____________________________________________________

procedure TtableDlg.Image1Click(Sender: TObject);
begin
  if currNo <> 0 then
   begin
    selectedElement := TableSymbols [currNo];
    Label2.Caption := intToStr (currNo)+ ' '+selectedElement+ ' selected';
    Edit1.Text := selectedElement;
   end;
end; // Image1Click  ____________________________________________________

// выход из диалога  ==================================================

procedure TtableDlg.OKBtnClick(Sender: TObject);
begin
    selectedElement := Edit1.Text;
    hide;
end;  // OKBtnClick ____________________________________________________

procedure TtableDlg.CancelBtnClick(Sender: TObject);
begin
  hide;
end;  // CancelBtnClick ____________________________________________________

end.

우리 버전에서는 104개 요소로 구성된 테이블을 사용했습니다(상수 크기). 분명히 이 크기는 늘어날 수 있습니다. 요소 지정(화학 기호)이 배열에 기록됩니다. 테이블기호. 그러나 소스 코드가 간결하다는 이유로 이러한 표기법의 순서를 문자열 상수 형식으로 작성하는 것이 좋습니다. 주기적인 테이블Str1..., 주기적인 테이블Str4따라서 양식이 생성될 때 프로그램 자체는 이러한 지정을 배열 요소에 분산시킵니다. 각 요소 지정은 하나 또는 두 개의 라틴 문자로 구성되며, 첫 번째 문자는 대문자이고 두 번째 문자(있는 경우)는 소문자입니다. 이 간단한 규칙은 배열을 로드할 때 구현됩니다. 따라서 일련의 표기법을 공백 없이 간결하게 작성할 수 있습니다. 시퀀스를 네 부분으로 나누기(상수 주기적인 테이블Str1..., 주기적인 테이블Str4)은 소스 코드를 읽기 쉽도록 고려한 것입니다. 너무 긴 줄은 화면에 완전히 들어가지 않을 수 있습니다.

마우스 커서가 해당 항목 위로 이동하면 Image1 매니저 이미지1마우스이동 이 이벤트는 제어 카드 픽셀의 파란색 구성 요소 값을 결정합니다. Image2 현재 커서 좌표에 대해. 건설로 Image2 커서가 셀 내부에 있으면 이 값은 요소 번호와 같습니다. 국경에 있으면 255이고, 다른 경우에는 XNUMX입니다. 프로그램이 수행하는 나머지 작업은 사소하며 설명이 필요하지 않습니다.

위에서 언급한 스타일리시한 프로그래밍 기술 외에도 해설 스타일에 주목할 가치가 있습니다. 엄밀히 말하면, 논의된 코드는 너무 작고 단순해서 주석이 특별히 필요해 보이지 않습니다. 그러나 방법론적인 이유로 추가되었습니다. 짧은 코드를 사용하면 몇 가지 일반적인 결론을 더 명확하게 내릴 수 있습니다. 제시된 코드에서는 하나의 클래스가 선언되었습니다(TtableDlg). 이 클래스의 메서드는 교체될 수 있으며 이로 인해 프로그램의 기능에는 어떤 영향도 미치지 않지만 가독성에는 영향을 미칠 수 있습니다. 예를 들어 다음 순서를 상상해 보세요.

OKBtnClick, Image1MouseMove, FormCreate, Image1Click, CancelBtnClick.

별로 눈에 띄지 않을 수도 있지만 읽고 이해하기가 조금 더 어려워질 것입니다. 해당 섹션에 XNUMX개가 아니라 수십 배 더 많은 메서드가 있는 경우 이행 수업 설명과 완전히 다른 순서를 가지면 혼란이 커질 것입니다. 따라서 엄밀하게 증명하기는 어렵고 불가능할 수도 있지만, 추가 순서를 도입하면 코드의 가독성이 향상될 것으로 기대됩니다. 이 추가 순서는 관련 작업을 수행하는 여러 메서드를 논리적으로 그룹화함으로써 촉진됩니다. 각 그룹에는 제목이 지정되어야 합니다. 예를 들면 다음과 같습니다.

// работа с таблицей: указание и выбор

이러한 제목은 모듈 시작 부분에 복사되어야 하며 목차 형식으로 지정되어야 합니다. 매우 긴 모듈의 경우 이러한 목차는 추가 탐색 옵션을 제공합니다. 마찬가지로, 하나의 메서드, 프로시저 또는 함수의 긴 본문에서는 먼저 이 본문의 끝을 표시하는 것이 좋습니다.

end; // FormCreate

둘째, 프로그램 괄호가 시작 - 끝인 분기된 명령문에서 닫는 괄호가 참조하는 명령문을 표시하십시오.

      end; // if s [j] in
   end; // for i :=1
end; // FormCreate

그룹 헤더와 메소드 본문의 끝을 강조 표시하려면 대부분의 연산자 길이를 초과하고 예를 들어 각각 "=" 및 "_" 문자로 구성된 행을 추가할 수 있습니다.
다시 한 번 유보해야 합니다. 우리의 예는 너무 간단합니다. 그리고 메소드의 코드가 한 화면에 다 들어가지 않을 경우, 코드 변경을 위해 8000개의 연속된 끝이 이해하기 어려울 수 있습니다. 예를 들어 OS IBM 360/370용 Pascal XNUMX과 같은 일부 오래된 컴파일러에서는 이와 같은 서비스 열이 목록 왼쪽에 인쇄되었습니다.

B5
…
E5

이는 E5 행의 닫는 괄호가 B5 행의 여는 괄호에 해당함을 의미합니다.

물론 프로그래밍 스타일은 매우 논란의 여지가 있는 문제이므로 여기에 표현된 아이디어는 단지 생각할 거리로 받아들여야 합니다. 수년간의 작업을 통해 서로 다른 스타일을 개발하고 익숙해진 상당히 경험이 풍부한 두 프로그래머가 합의하는 것은 매우 어려울 수 있습니다. 아직 자신의 스타일을 찾을 시간이 없었지만 프로그램을 배우는 학생에게는 다른 문제입니다. 이 경우 교사는 최소한 프로그램의 성공이 소스 코드 작성 스타일에 크게 좌우된다는 간단하지만 명확하지 않은 아이디어를 학생들에게 전달해야 한다고 생각합니다. 학생이 권장되는 스타일을 따르지 않을 수도 있지만 최소한 소스 코드 디자인을 개선하기 위해 "추가" 작업이 필요한지 생각하게 하십시오.

주기율표의 기본 문제로 돌아가서, 추가 개발은 다른 방향으로 진행될 수 있습니다. 지침 중 하나는 참조용입니다. 표 셀 위에 마우스 커서를 올리면 지정된 요소에 대한 추가 정보가 포함된 정보 창이 나타납니다. 추가 개발은 필터입니다. 예를 들어, 설치에 따라 정보 창에는 가장 중요한 물리적 및 화학적 정보, 발견 이력에 대한 정보, 자연 분포에 대한 정보, 가장 중요한 화합물 목록(이 요소 포함)만 포함됩니다. 생리적 특성, 외국어로 된 이름 등 e. 이 기사가 시작되는 Kaverin의 "오리"를 기억하면 이러한 프로그램 개발을 통해 컴퓨터 외에도 자연 과학에서 완전한 훈련 단지를 얻게 될 것이라고 말할 수 있습니다. 과학, 물리학, 화학 - 생물학, 경제 지리, 과학사, 심지어 외국어까지.

그러나 로컬 데이터베이스에는 한계가 없습니다. 프로그램은 자연스럽게 인터넷에 연결됩니다. 요소를 선택하면 링크가 활성화되고 이 요소에 대한 Wikipedia 문서가 웹 브라우저 창에서 열립니다. 아시다시피 위키피디아는 권위 있는 출처가 아닙니다. 예를 들어 화학 백과사전, TSB, 초록 저널, 이 요소에 대한 검색 엔진의 주문 쿼리 등과 같은 신뢰할 수 있는 소스에 대한 링크를 설정할 수 있습니다. 저것. 학생들은 DBMS 및 인터넷 주제에 대해 간단하지만 의미 있는 과제를 완료할 수 있습니다.

개별 요소에 대한 쿼리 외에도 특정 기준을 충족하는 테이블의 셀을 다른 색상으로 표시하는 기능 등을 만들 수 있습니다. 예를 들어 금속과 비금속이 있습니다. 또는 지역 화학 공장에서 수역에 버려진 세포입니다.

노트북 정리 기능을 구현할 수도 있습니다. 예를 들어, 시험에 포함된 요소를 표에서 강조 표시하십시오. 그런 다음 시험 준비 과정에서 학생이 공부/반복한 요소를 강조 표시합니다.

예를 들어 여기에 전형적인 학교 화학 문제 중 하나가 있습니다.

10g의 분필이 주어졌습니다. 이 분필을 모두 녹이려면 얼마나 많은 염산을 섭취해야 합니까?

이 문제를 해결하려면 화학을 적어야 합니다. 반응식에 계수를 대입하여 탄산칼슘과 염화수소의 분자량을 계산하고 그 비율을 구성하여 푼다. 우리의 기본 프로그램을 기반으로 한 계산기는 계산하고 해결할 수 있습니다. 사실, 산을 합리적으로 과잉으로 그리고 합리적인 농도로 섭취해야 한다는 점을 고려해야 하지만 이것은 컴퓨터 과학이 아니라 화학입니다.
부록 1: 화학 계산기 작동 방식위의 분필과 "호지포지" 문제의 예를 사용하여 계산기의 작동을 분석해 보겠습니다. 반응부터 시작해 보겠습니다.

CaCO3 + 2HCl = CaCl2 + H2O

이를 통해 칼슘(Ca), 탄소(C), 산소(O), 수소(H) 및 염소(Cl) 원소의 원자량이 필요하다는 것을 알 수 있습니다. 가장 간단한 경우, 이러한 가중치를 다음과 같이 정의된 XNUMX차원 배열에 쓸 수 있습니다.

AtomicMass : array [1..size] of real;

여기서 배열 인덱스는 요소 번호에 해당합니다. 양식의 여유 공간에 대해 자세히 알아보기 테이블Dlg 두 개의 필드를 넣으십시오. 첫 번째 필드에는 처음에 "첫 번째 시약이 제공됩니다", 두 번째 필드에는 "두 번째 시약은 x를 찾는 것입니다"라고 기록됩니다. 필드를 나타내자 시약1, 시약2 각기. 프로그램에 추가된 다른 사항은 다음 계산기 예를 통해 명확해집니다.

컴퓨터 키보드에 10g을 입력합니다. 필드에 비문 시약1 변경: "첫 번째 시약은 10g이 주어집니다." 이제 이 시약의 공식을 입력하면 입력한 대로 계산기가 분자량을 계산하여 표시합니다.

Ca 기호가 있는 테이블 셀에서 LMB를 클릭합니다. 현장의 비문 시약1 변경: "40.078g에 첫 번째 시약 Ca 10 제공."

기호 C가 있는 테이블 셀에서 LMB를 클릭합니다. 필드에 비문 시약1 변경: "52.089g에 첫 번째 시약 CaC 10 제공." 저것들. 계산기는 칼슘과 탄소의 원자량을 합산했습니다.

O 기호가 있는 테이블 셀에서 LMB를 클릭합니다. 필드에 비문 시약1 변경 사항: "첫 번째 시약 CaCO 68.088 10g 제공." 계산기는 합계에 산소의 원자량을 더했습니다.

O 기호가 있는 테이블 셀에서 LMB를 클릭합니다. 필드에 비문 시약1 변경: "2g에 첫 번째 시약 CaCO84.087 10 제공." 계산기는 다시 한 번 합계에 산소의 원자량을 더했습니다.

O 기호가 있는 테이블 셀에서 LMB를 클릭합니다. 필드에 비문 시약1 변경: "3g에 첫 번째 시약 CaCO100.086 10 제공." 계산기는 다시 합계에 산소의 원자량을 더했습니다.

컴퓨터 키보드에서 Enter 키를 누릅니다. XNUMX차 시약 투입이 완료되고 현장으로 전환됩니다. 시약2. 이 예에서는 최소 버전을 제공하고 있습니다. 원하는 경우 동일한 유형의 원자 승수를 쉽게 구성할 수 있으므로 예를 들어 크롬 공식(K2Cr2O7)을 입력할 때 산소 셀을 연속으로 XNUMX번 클릭할 필요가 없습니다.

H 기호가 있는 테이블 셀에서 LMB를 클릭합니다. 필드에 비문 시약2 변경 사항: "두 번째 시약 H 1.008 x를 찾으세요."

Cl 기호가 있는 테이블 셀에서 LMB를 클릭합니다. 현장의 비문 시약2 변경 사항: "두 번째 시약 HCl 36.458 x를 찾으세요." 계산기는 수소와 염소의 원자량을 합산했습니다. 위 반응식에서 염화수소 앞에 계수 2가 붙습니다. 따라서 해당 필드에서 LMB를 클릭합니다. 시약2. 분자량은 두 배로 늘어납니다(두 번 누르면 세 배 등). 현장의 비문 시약2 변경 사항: "두 번째 시약 2HCl 72.916 찾기 x."

컴퓨터 키보드에서 Enter 키를 누릅니다. 두 번째 시약 입력이 완료되고, 계산기는 그 비율에서 x를 구합니다.

그것이 우리가 찾아야 했던 것입니다.

1에 유의하십시오. 결과 비율의 의미: 용해 100.086 Da 분필에는 72.916Da의 산이 필요하며, 10g의 분필을 녹이려면 x산이 필요합니다.

2에 유의하십시오. 유사한 문제 모음:

Khomchenko I. G., 화학 문제 및 연습 모음 2009(8-11학년).
Khomchenko G. P., Khomchenko I. G., 대학 지원자를 위한 화학 문제 모음, 2019.

3에 유의하십시오. 작업을 단순화하려면 초기 버전에서 공식 입력을 단순화하고 공식 줄 끝에 요소 기호를 추가하기만 하면 됩니다. 그러면 탄산칼슘의 공식은 다음과 같습니다.
카쿠오
그러나 화학 교사는 그러한 녹음을 좋아하지 않을 것입니다. 올바른 항목을 작성하는 것은 어렵지 않습니다. 이를 위해서는 배열을 추가해야 합니다.

formula : array [1..size] of integer;

여기서 인덱스는 화학 원소의 수이고 이 인덱스의 값은 원자의 수입니다(초기에는 배열의 모든 요소가 3으로 재설정됩니다). 화학에서 채택된 대로 공식에 원자가 기록되는 순서를 고려해야 합니다. 예를 들어 OXNUMXCaC를 좋아하는 사람도 거의 없습니다. 책임을 사용자에게 전가합시다. 배열 만들기:

 formulaOrder : array [1..size] of integer; // можно взять покороче

여기서 우리는 공식에 나타나는 색인에 따라 화학 원소의 수를 기록합니다. 원자 추가 통화아니요 공식에:

if formula [currNo]=0 then //этот атом встретился первый раз
 begin
 orderIndex := orderIndex+1;//в начале ввода формулы orderIndex=0
 formulaOrder [orderIndex] :=  currNo;
 end;
formula [currNo]:=formula [currNo]+1;

한 줄에 수식을 작성합니다.

s := ''; // пустая строка для формулы
for i:=1 to  orderIndex do // для всех хим.символов в формуле 
 begin
 s:=s+TableSymbols [ formulaOrder[i]];// добавляем хим.символ
 if formula [formulaOrder[i]]<>1 then //добавляем кол-во атомов
  s:=s+ intToStr(formula [formulaOrder[i]]);
 end;

4에 유의하십시오. 키보드에서 시약 공식을 입력할 수 있는 기능을 제공하는 것이 합리적입니다. 이 경우 간단한 파서를 구현해야 합니다.

다음 사항에 주목할 가치가 있습니다.

오늘날에는 수백 가지 버전의 테이블이 있으며 과학자들은 끊임없이 새로운 옵션을 제공하고 있습니다. (위키 백과)

학생들은 이미 제안된 옵션 중 하나를 구현하여 이 방향에 대한 독창성을 보여주거나 자신만의 독창적인 옵션을 만들어 볼 수 있습니다. 이것이 컴퓨터 과학 수업에 있어서 가장 유용하지 않은 방향인 것처럼 보일 수도 있습니다. 그러나 이 기사에서 구현된 주기율표의 형태에서 일부 학생들은 표준 버튼을 사용하는 대체 솔루션에 비해 컨트롤 카드의 특별한 이점을 보지 못할 수도 있습니다. T버튼. 테이블의 나선형 모양(셀의 모양이 서로 다름)은 여기에 제안된 솔루션의 장점을 더욱 명확하게 보여줍니다.

(Theodore Benfey의 대체 요소 시스템, 출처)

또한 주기율표에 대해 현재 존재하는 다수의 컴퓨터 프로그램이 최근 Habré에 출판된 논문에 설명되어 있다는 점을 덧붙여 보겠습니다. 기사.

부록 2: 필터 작업의 예필터를 사용하면 예를 들어 다음 작업을 해결할 수 있습니다.

1) 중세 시대에 알려진 모든 요소를 ​​표에서 선택하십시오.

2) 주기율 발견 당시 알려진 모든 원소를 확인하십시오.

3) 연금술사가 금속으로 간주한 일곱 가지 원소를 밝히십시오.

4) 정상적인 조건(n.s.)에서 기체 상태에 있는 요소를 모두 선택합니다.

5) XNUMX번 항목에서 액체 상태인 요소를 모두 선택합니다.

6) XNUMX번에서 고체상태에 있는 요소를 모두 선택합니다.

7) 정상적인 조건에서 오랜 시간 동안 눈에 띄는 변화가 없이 공기에 노출될 수 있는 요소를 모두 선택합니다.

8) 염산에 녹는 금속을 모두 선택한다.

9) 황산에 녹는 금속을 모두 선택하여 No.

10) 가열하면 황산에 녹는 금속을 모두 선택한다.

11) 질산에 녹는 금속을 모두 선택하시오.

12) 주변 조건에서 물과 격렬하게 반응하는 모든 금속을 격리하십시오.

13) 모든 금속을 선택하세요.

14) 자연에 널리 퍼져 있는 요소를 식별합니다.

15) 자유상태의 자연에서 발견되는 원소를 알아본다.

16) 인간과 동물의 신체에서 가장 중요한 역할을 하는 요소를 알아보세요.

17) 일상생활에서 널리 사용되는 요소를 선택하세요(자유형태 또는 조합).

18) 작업하기에 가장 위험하고 특별한 조치와 보호 장비가 필요한 요소를 식별하십시오.

19) 자유 형태 또는 화합물 형태로 환경에 가장 큰 위협을 가하는 요소를 식별하십시오.

20) 귀금속을 선택하세요.

21) 귀금속보다 비싼 원소를 식별합니다.

참고 사항

1) 여러 개의 필터를 제공하는 것이 합리적입니다. 예를 들어, 문제 1(중세 시대에 알려진 모든 원소)과 문제 20(귀금속)을 해결하기 위해 필터를 켜면 중세 시대에 알려진 귀금속이 포함된 셀이 강조 표시됩니다(예: 색상별로)( 예를 들어 팔라듐은 강조 표시되지 않으며 1803년에 개봉되었습니다.)

2) 각 필터가 고유한 색상으로 셀을 선택하지만 다른 필터의 선택을 완전히 제거하지 않는 모드에서 여러 필터가 작동하는지 확인하는 것이 합리적입니다(셀의 일부는 한 색상, 일부는 다른 색상). 그러면 이전 예의 경우 중세 시대에 발견된 집합의 교차점과 귀금속의 원소뿐만 아니라 첫 번째 집합에만 속하는 원소와 두 번째 집합에만 속하는 원소도 표시됩니다. 저것들. 중세 시대에 알려지지 않은 귀금속, 중세 시대에 알려졌으나 귀금속이 아닌 원소.

3) 얻은 결과로 다른 작업의 가능성을 보장하기 위해 필터를 적용한 후에는 의미가 있습니다. 예를 들어, 중세 시대에 알려진 요소를 선택한 경우 사용자는 선택한 요소에서 LMB를 클릭하고 해당 요소에 대한 Wikipedia 문서로 이동합니다.

4) 선택한 테이블 셀에서 LMB를 클릭하여 선택을 취소할 수 있는 기능을 사용자에게 제공하는 것이 합리적입니다. 예를 들어 이미 본 항목을 제거하려는 경우입니다.

5) 선택한 셀 목록이 파일에 저장되고 해당 파일이 자동 셀 선택과 함께 로드되는지 확인하는 것이 합리적입니다. 이를 통해 사용자는 직장에서 휴식을 취할 수 있습니다.

우리는 정적이고 미리 결정된 컨트롤 맵을 사용했지만 프로그램이 실행됨에 따라 변경되는 동적 컨트롤 맵을 사용할 수 있는 중요한 작업이 많이 있습니다. 예를 들어 사용자가 마우스를 사용하여 창의 정점 위치를 나타내고 정점 사이에 가장자리를 그리는 그래프 편집기가 있습니다. 정점이나 가장자리를 삭제하려면 사용자가 이를 가리켜야 합니다. 그러나 원으로 표시된 꼭지점을 가리키는 것이 아주 쉽다면 가는 선으로 그린 ​​모서리를 가리키는 것은 더 어려울 것입니다. 여기서는 정점과 가장자리가 보이는 그림보다 더 넓은 이웃을 차지하는 제어 맵이 도움이 될 것입니다.

이 복잡한 훈련 방법과 관련된 흥미로운 부가 질문은 다음과 같습니다. 이 방법이 AI 훈련에 유용할 수 있습니까?

출처 : habr.com