ການຕິດຕາມແບບງ່າຍໆຂອງ DFS Replication ໃນ Zabbix

ການນໍາສະເຫນີ

ດ້ວຍໂຄງສ້າງພື້ນຖານທີ່ຂ້ອນຂ້າງໃຫຍ່ແລະແຈກຢາຍທີ່ໃຊ້ DFS ເປັນຈຸດດຽວຂອງການເຂົ້າເຖິງຂໍ້ມູນແລະ DFSR ສໍາລັບການຈໍາລອງຂໍ້ມູນລະຫວ່າງສູນຂໍ້ມູນແລະເຄື່ອງແມ່ຂ່າຍສາຂາ, ຄໍາຖາມທີ່ເກີດຂື້ນໃນການຕິດຕາມສະຖານະການຂອງການຈໍາລອງນີ້.
ບັງເອີນ, ເກືອບທັນທີຫຼັງຈາກທີ່ພວກເຮົາເລີ່ມໃຊ້ DFSR, ພວກເຮົາເລີ່ມປະຕິບັດ Zabbix ໂດຍມີເປົ້າໝາຍເພື່ອປ່ຽນແທນສວນສັດທີ່ມີຢູ່ຂອງເຄື່ອງມືຕ່າງໆ ແລະນໍາເອົາການຕິດຕາມໂຄງສ້າງພື້ນຖານໄປສູ່ຮູບແບບທີ່ມີຂໍ້ມູນ, ຄົບຖ້ວນ ແລະສົມເຫດສົມຜົນ. ພວກເຮົາຈະເວົ້າກ່ຽວກັບການໃຊ້ Zabbix ເພື່ອຕິດຕາມການຈໍາລອງ DFS.

ກ່ອນອື່ນ ໝົດ, ພວກເຮົາຕ້ອງຕັດສິນໃຈວ່າຂໍ້ມູນໃດແດ່ກ່ຽວກັບການ ຈຳ ລອງ DFS ຕ້ອງການໄດ້ຮັບເພື່ອຕິດຕາມສະຖານະການຂອງມັນ. ຕົວຊີ້ວັດທີ່ກ່ຽວຂ້ອງທີ່ສຸດແມ່ນ backlog. ມັນມີໄຟລ໌ທີ່ຍັງບໍ່ໄດ້ synchronized ກັບສະມາຊິກອື່ນໆຂອງກຸ່ມ replication. ທ່ານສາມາດເບິ່ງຂະຫນາດຂອງມັນໂດຍໃຊ້ປະໂຫຍດ dfsrdiag, ຕິດຕັ້ງດ້ວຍບົດບາດ DFSR. ໃນສະຖານະການຈໍາລອງແບບປົກກະຕິ, ຂະຫນາດຂອງ backlog ຄວນເຂົ້າຫາສູນ. ດັ່ງນັ້ນ, ຈໍານວນໄຟລ໌ຈໍານວນຫລາຍໃນ backlog ຊີ້ໃຫ້ເຫັນບັນຫາກັບການຈໍາລອງ.

ໃນປັດຈຸບັນກ່ຽວກັບພາກປະຕິບັດຂອງບັນຫາ.

ເພື່ອຕິດຕາມຂະຫນາດຂອງ backlog ຜ່ານ Zabbix Agent, ພວກເຮົາຈະຕ້ອງການ:

• ສະຄຣິບທີ່ຈະວິເຄາະຜົນຜະລິດ dfsrdiag ເພື່ອສະຫນອງມູນຄ່າຂະຫນາດ backlog ສຸດທ້າຍໃຫ້ກັບ Zabbix,
• script ທີ່ຈະກໍານົດຈໍານວນກຸ່ມ replication ມີຢູ່ໃນເຄື່ອງແມ່ຂ່າຍ, ໂຟນເດີໃດທີ່ເຂົາເຈົ້າ replicate ແລະສິ່ງທີ່ເຄື່ອງແມ່ຂ່າຍອື່ນໆລວມຢູ່ໃນພວກເຂົາ (ພວກເຮົາບໍ່ຕ້ອງການໃສ່ທັງຫມົດນີ້ເຂົ້າໄປໃນ Zabbix ດ້ວຍມືສໍາລັບແຕ່ລະເຄື່ອງແມ່ຂ່າຍ, ແມ່ນບໍ?),
• ການເພີ່ມສະຄຣິບເຫຼົ່ານີ້ເປັນ UserParameter ກັບການຕັ້ງຄ່າຕົວແທນ Zabbix ສໍາລັບການໂທຫາຕໍ່ໄປຈາກເຄື່ອງແມ່ຂ່າຍຕິດຕາມກວດກາ,
• ການເລີ່ມຕົ້ນການບໍລິການຕົວແທນ Zabbix ເປັນຜູ້ໃຊ້ທີ່ມີສິດອ່ານ backlog,
• ແມ່ແບບສໍາລັບ Zabbix, ເຊິ່ງການກວດສອບກຸ່ມ, ການປະມວນຜົນຂໍ້ມູນທີ່ໄດ້ຮັບແລະການອອກການແຈ້ງເຕືອນກ່ຽວກັບພວກມັນຈະຖືກຕັ້ງຄ່າ.

ຕົວວິເຄາະສະຄຣິບ

ເພື່ອຂຽນຕົວວິເຄາະ, ຂ້ອຍເລືອກ VBS ເປັນພາສາທົ່ວໄປທີ່ສຸດໃນທຸກລຸ້ນຂອງ Windows Server. ເຫດຜົນຂອງສະຄິບແມ່ນງ່າຍດາຍ: ມັນໄດ້ຮັບຊື່ຂອງກຸ່ມ replication, ໂຟນເດີ replicated, ແລະຊື່ຂອງເຄື່ອງແມ່ຂ່າຍການສົ່ງແລະຮັບຜ່ານເສັ້ນຄໍາສັ່ງ. ຕົວກໍານົດການເຫຼົ່ານີ້ຫຼັງຈາກນັ້ນຖືກສົ່ງກັບ dfsrdiag, ແລະຂຶ້ນກັບຜົນຜະລິດຂອງມັນ, ມັນຜະລິດ:
ຈໍານວນໄຟລ໌ - ຖ້າໄດ້ຮັບຂໍ້ຄວາມກ່ຽວກັບການມີໄຟລ໌ໃນ backlog,
0 — ຖ້າ​ຫາກ​ວ່າ​ໄດ້​ຮັບ​ຂໍ້​ຄວາມ​ກ່ຽວ​ກັບ​ການ​ບໍ່​ມີ​ຂອງ​ໄຟລ​໌​ໃນ backlog (“No Backlog”),
-1 - ຖ້າ​ຫາກ​ວ່າ​ຂໍ້​ຄວາມ​ຜິດ​ພາດ​ໄດ້​ຮັບ​ dfsrdiag ເມື່ອປະຕິບັດການຮ້ອງຂໍ ("[ERROR]").

get-Backlog.vbs

strReplicationGroup=WScript.Arguments.Item(0)
strReplicatedFolder=WScript.Arguments.Item(1)
strSending=WScript.Arguments.Item(2)
strReceiving=WScript.Arguments.Item(3)

Set WshShell = CreateObject ("Wscript.shell")
Set objExec = WSHshell.Exec("dfsrdiag.exe Backlog /RGName:""" & strReplicationGroup & """ /RFName:""" & strReplicatedFolder & """ /SendingMember:" & strSending & " /ReceivingMember:" & strReceiving)
strResult = ""
Do While Not objExec.StdOut.AtEndOfStream
	strResult = strResult & objExec.StdOut.ReadLine() & "\"
Loop

If InStr(strResult, "No Backlog") > 0 then
	intBackLog = 0
ElseIf  InStr(strResult, "[ERROR]") > 0 Then
    intBackLog = -1
Else
	arrLines = Split(strResult, "\")
	arrResult = Split(arrLines(1), ":")
	intBackLog = arrResult(1)
End If

WScript.echo intBackLog

ສະຄຣິບ Discovery

ເພື່ອໃຫ້ Zabbix ກໍານົດກຸ່ມ replication ທັງຫມົດທີ່ມີຢູ່ໃນເຄື່ອງແມ່ຂ່າຍແລະຊອກຫາຕົວກໍານົດການທັງຫມົດທີ່ຕ້ອງການສໍາລັບການຮ້ອງຂໍ (ຊື່ໂຟນເດີ, ຊື່ຂອງເຄື່ອງແມ່ຂ່າຍໃກ້ຄຽງ), ພວກເຮົາຈໍາເປັນຕ້ອງ, ທໍາອິດ, ໄດ້ຮັບຂໍ້ມູນນີ້, ແລະທີສອງ, ນໍາສະເຫນີມັນ. ໃນຮູບແບບທີ່ເຂົ້າໃຈໄດ້ກັບ Zabbix. ຮູບແບບທີ່ເຄື່ອງມືຄົ້ນພົບເຂົ້າໃຈເບິ່ງຄືດັ່ງນີ້:

        "data":[
                {
                        "{#GROUP}":"Share1",
                        "{#FOLDER}":"Folder1",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"Server2"}

...

                        "{#GROUP}":"ShareN",
                        "{#FOLDER}":"FolderN",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"ServerN"}]}

ວິທີທີ່ງ່າຍທີ່ສຸດທີ່ຈະໄດ້ຮັບຂໍ້ມູນທີ່ພວກເຮົາສົນໃຈແມ່ນຜ່ານ WMI, ດຶງມັນອອກຈາກພາກສ່ວນທີ່ສອດຄ້ອງກັນຂອງ DfsrReplicationGroupConfig. ດັ່ງນັ້ນ, script ໄດ້ເກີດມາທີ່ສ້າງຄໍາຮ້ອງຂໍໃຫ້ WMI ແລະອອກບັນຊີລາຍຊື່ຂອງກຸ່ມ, ໂຟນເດີແລະເຄື່ອງແມ່ຂ່າຍຂອງພວກເຂົາໃນຮູບແບບທີ່ກໍານົດໄວ້.

DFSRDiscovery.vbs

dim strComputer, strLine, n, k, i

Set wshNetwork = WScript.CreateObject( "WScript.Network" )
strComputer = wshNetwork.ComputerName

Set oWMIService = GetObject("winmgmts:\" & strComputer & "rootMicrosoftDFS")
Set colRGroups = oWMIService.ExecQuery("SELECT * FROM DfsrReplicationGroupConfig")
wscript.echo "{"
wscript.echo "        ""data"":["
n=0
k=0
i=0
For Each oGroup in colRGroups
  n=n+1
  Set colRGFolders = oWMIService.ExecQuery("SELECT * FROM DfsrReplicatedFolderConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
  For Each oFolder in colRGFolders
    k=k+1
    Set colRGConnections = oWMIService.ExecQuery("SELECT * FROM DfsrConnectionConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
    For Each oConnection in colRGConnections
      i=i+1
      binInbound = oConnection.Inbound
      strPartner = oConnection.PartnerName
      strRGName = oGroup.ReplicationGroupName
      strRFName = oFolder.ReplicatedFolderName
      If oConnection.Enabled = True and binInbound = False Then
        strSendingComputer = strComputer
        strReceivingComputer = strPartner
        strLine1="                {"    
        strLine2="                        ""{#GROUP}"":""" & strRGName & """," 
        strLine3="                        ""{#FOLDER}"":""" & strRFName & """," 
        strLine4="                        ""{#SENDING}"":""" & strSendingComputer & ""","                  
        if (n < colRGroups.Count) or (k < colRGFolders.count) or (i < colRGConnections.Count) then
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """},"
        else
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """}]}"       
        end if		
        wscript.echo strLine1
        wscript.echo strLine2
        wscript.echo strLine3
        wscript.echo strLine4
        wscript.echo strLine5	   
      End If
    Next
  Next
Next

ຂ້າພະເຈົ້າຕົກລົງເຫັນດີ, script ອາດຈະບໍ່ສ່ອງແສງກັບຄວາມສະຫງ່າງາມຂອງລະຫັດແລະບາງສິ່ງທີ່ແນ່ນອນອາດຈະງ່າຍດາຍ, ແຕ່ມັນປະຕິບັດຫນ້າທີ່ຕົ້ນຕໍ - ການສະຫນອງຂໍ້ມູນກ່ຽວກັບຕົວກໍານົດການຂອງກຸ່ມ replication ໃນຮູບແບບທີ່ເຂົ້າໃຈໄດ້ໂດຍ Zabbix.

ການເພີ່ມສະຄຣິບໃສ່ການຕັ້ງຄ່າຕົວແທນ Zabbix

ທຸກສິ່ງທຸກຢ່າງຢູ່ທີ່ນີ້ແມ່ນງ່າຍດາຍທີ່ສຸດ. ເພີ່ມແຖວຕໍ່ໄປນີ້ໃສ່ໃນຕອນທ້າຍຂອງໄຟລ໌ການຕັ້ງຄ່າຕົວແທນ:

UserParameter=check_dfsr[*],cscript /nologo "C:Program FilesZabbix Agentget-Backlog.vbs" $1 $2 $3 $4
UserParameter=discovery_dfsr[*],cscript /nologo "C:Program FilesZabbix AgentDFSRDiscovery.vbs"

ແນ່ນອນ, ພວກເຮົາປັບເສັ້ນທາງໄປຫາບ່ອນທີ່ພວກເຮົາມີສະຄິບ. ຂ້ອຍເອົາພວກມັນໄວ້ໃນໂຟນເດີດຽວກັນທີ່ຕົວແທນຖືກຕິດຕັ້ງ.

ຫຼັງຈາກເຮັດການປ່ຽນແປງ, ເປີດບໍລິການຕົວແທນ Zabbix ຄືນໃໝ່.

ການປ່ຽນແປງຜູ້ໃຊ້ພາຍໃຕ້ການໃຫ້ບໍລິການຕົວແທນ Zabbix ດໍາເນີນການ

ໃນຄໍາສັ່ງທີ່ຈະໄດ້ຮັບຂໍ້ມູນຂ່າວສານໂດຍຜ່ານ dfsrdiag, ຜົນປະໂຫຍດຈະຕ້ອງຖືກດໍາເນີນການພາຍໃຕ້ບັນຊີທີ່ມີສິດບໍລິຫານທັງການສົ່ງແລະຮັບສະມາຊິກຂອງກຸ່ມ replication. ບໍລິການຕົວແທນ Zabbix, ເຮັດວຽກໂດຍຄ່າເລີ່ມຕົ້ນພາຍໃຕ້ບັນຊີລະບົບ, ຈະບໍ່ສາມາດດໍາເນີນການຮ້ອງຂໍດັ່ງກ່າວໄດ້. ຂ້ອຍສ້າງບັນຊີແຍກຕ່າງຫາກໃນໂດເມນ, ໃຫ້ສິດບໍລິຫານໃນເຊີບເວີທີ່ຈໍາເປັນ, ແລະກໍາຫນົດຄ່າບໍລິການໃຫ້ດໍາເນີນການພາຍໃຕ້ມັນຢູ່ໃນເຄື່ອງແມ່ຂ່າຍເຫຼົ່ານີ້.

ທ່ານສາມາດໄປທາງອື່ນ: ເພາະວ່າ dfsrdiag, ໃນຄວາມເປັນຈິງ, ເຮັດວຽກໂດຍຜ່ານ WMI ດຽວກັນ, ຫຼັງຈາກນັ້ນທ່ານສາມາດນໍາໃຊ້ ລາຍລະອຽດ, ເຮັດແນວໃດເພື່ອໃຫ້ບັນຊີໂດເມນມີສິດທິໃນການນໍາໃຊ້ມັນໂດຍບໍ່ມີການອອກສິດທິບໍລິຫານ, ແຕ່ຖ້າພວກເຮົາມີຫຼາຍກຸ່ມ replication, ການອອກສິດທິຂອງແຕ່ລະກຸ່ມຈະມີຄວາມຫຍຸ້ງຍາກ. ຢ່າງໃດກໍ່ຕາມ, ໃນກໍລະນີທີ່ພວກເຮົາຕ້ອງການຕິດຕາມກວດກາການຈໍາລອງປະລິມານຂອງລະບົບໂດເມນໃນຕົວຄວບຄຸມໂດເມນ, ນີ້ອາດຈະເປັນທາງເລືອກດຽວທີ່ຍອມຮັບໄດ້, ນັບຕັ້ງແຕ່ການໃຫ້ສິດຂອງຜູ້ເບິ່ງແຍງໂດເມນກັບບັນຊີການບໍລິການຕິດຕາມກວດກາບໍ່ແມ່ນຄວາມຄິດທີ່ດີ.

ແມ່ແບບການຕິດຕາມ

ອີງໃສ່ຂໍ້ມູນທີ່ຂ້ອຍໄດ້ຮັບ, ຂ້ອຍສ້າງແມ່ແບບວ່າ:

• ດໍາເນີນການຄົ້ນພົບອັດຕະໂນມັດຂອງກຸ່ມ replication ຫນຶ່ງຄັ້ງຕໍ່ຊົ່ວໂມງ,
• ກວດ​ສອບ​ຂະ​ຫນາດ backlog ສໍາ​ລັບ​ແຕ່​ລະ​ກຸ່ມ​ຫນຶ່ງ​ຄັ້ງ​ໃນ​ທຸກໆ 5 ນາ​ທີ​,
• ປະກອບມີຕົວກະຕຸ້ນທີ່ອອກການແຈ້ງເຕືອນເມື່ອຂະໜາດ backlog ສໍາລັບກຸ່ມໃດນຶ່ງຫຼາຍກວ່າ 100 ເປັນເວລາ 30 ນາທີ. Trigger ໄດ້ຖືກອະທິບາຍວ່າເປັນຕົວແບບທີ່ຈະຖືກເພີ່ມໃສ່ກຸ່ມທີ່ກວດພົບໂດຍອັດຕະໂນມັດ,
• ສ້າງກາຟຂະຫນາດ backlog ສໍາລັບແຕ່ລະກຸ່ມ replication.

ທ່ານສາມາດດາວໂຫລດແມ່ແບບສໍາລັບ Zabbix 2.2 ທີ່ນີ້.

ຜົນໄດ້ຮັບ

ຫຼັງຈາກການນໍາເຂົ້າແມ່ແບບເຂົ້າໄປໃນ Zabbix ແລະສ້າງບັນຊີທີ່ມີສິດທິທີ່ຈໍາເປັນ, ພວກເຮົາພຽງແຕ່ຕ້ອງການຄັດລອກສະຄິບໃສ່ເຄື່ອງແມ່ຂ່າຍຂອງໄຟລ໌ທີ່ພວກເຮົາຕ້ອງການຕິດຕາມກວດກາສໍາລັບ DFSR, ເພີ່ມສອງແຖວໃຫ້ກັບການຕັ້ງຄ່າຕົວແທນກ່ຽວກັບພວກມັນແລະເລີ່ມຕົ້ນການບໍລິການຕົວແທນ Zabbix ຄືນໃໝ່. , ຕັ້ງໃຫ້ມັນແລ່ນເປັນບັນຊີທີ່ຕ້ອງການ. ບໍ່ຈໍາເປັນຕ້ອງມີການຕັ້ງຄ່າຄູ່ມືອື່ນສໍາລັບການກວດສອບ DFSR.

ແຫຼ່ງຂໍ້ມູນ: www.habr.com