🥇Gnuplot 5.0. Spiderplot uz 4 asīm paši

Strādājot pie datu vizualizācijas rakstam, radās nepieciešamība pēc 4 asīm ar pozitīvām atzīmēm visām.

Kā arī citu raksta grafiku gadījumā es nolēmu izmantot gnuplot. Pirmais, ko izdarīju, bija doties uz oficiālo vietni, kur ir daudz piemēru. Ļoti priecājos, kad atradu vajadzīgo piemērs (nedaudz pastrādāšu ar failu un būs skaisti, nodomāju).

Ātri nokopēju kodu un palaidu. Ieguvu kļūdu. Izpētīju. Izrādījās, ka man ir vecs gnuplot (Version 5.0 patchlevel 3 last modified 2016-02-21) un viņš tā neprot.

Zinot par gnuplot elastību, sāku meklēt tīklā un uzdūros vairākiem piemēriem stackoverflow (Double x-axis on a spider plot with Gnuplot un How to Create a Spider Plot in Gnuplot?) un github (gnuplot-radarchart). Tie kļuva par sākumpunktu.

Turpmāk manas darbības ar komandu noveda pie sekojošā:

0) Atspējojam robežas

unset border

1) Izveidojam 4 nulles līnijas — 2 galvenās un 2 papildu:

set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis

Daži vārdi par nulles līnijām dokumentācijā. Šī operācija ļauj samazināt asis uz attēla centru. Papildu nepieciešamas, lai attēlotu pozitīvos tikus.

2) Iestata tiku attēlošanu uz asīm:

max = 1.5 # Elastībai
min = -max
set xtics axis 0,.5,max in scale 0.5,0.25 mirror norotate autojustify offset 0.35
set ytics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify

Ar tikumiem uz asīm iestatījumu ir nedaudz vairāk.
axis — kur būs tiku izkārtojums, uz ass vai (border — uz robežas).
Attiecībā uz asi x, kas iet pa labi 0,.5,max. Pirmais skaitlis — sākuma punkts, otrais — solis, trešais — beigu punkts. Pirmajai no 0, bet pārējām no 0.5, lai nulles netraucētu koordinātu sākumā.

Nulles sajaukšana koordinātu centrā.
Visi intervāli *tics iestatīti kā 0,.5,max
Bez offset 0.35 lai xtics

Iestatījumi scale 0.5,0.25 mirror pievieno atzīmes uz asīm. Ja spēlējas ar skaitļiem, tad mainīsies to izmērs.
Tāpat ievadu mainīgos max, min, ar kuriem kontrolēju grafika asu robežas.
Papildu informāciju par tiku iestatīšanu var atrast dokumentācijā sadaļā Xtics.

3) Iestata asu diapazonus:

set xrange  [ min : max ] 
set yrange  [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]

Šeit jāpiezīmē, ka 2 ass sāk skaitīšanu no min palielināšanās un 2 ass — no max samazināšanās.
Papildu informācija sadaļā Xrange.

4) Piešķiram asīm nosaukumus un skaisti tās novietojam:

set label "H_1" at 0, max center offset char 2, 0
set label "H_2" at max+0.1, 0 center offset char -1, 1
set label "H_3" at 0, min center offset char -2, 0
set label "H_4" at min, 0 center offset char 0, 1

5) Veidojam iegūto datu ievadi
Katram grafam ir piešķirti 2 slāņi. Rindas numurs — ass numurs, piektā rinda, lai aizvērtu kontūru. Nepāra kolonna — koordināta x, pāra — y. Ņemot vērā, ka visi punkti ir izvietoti uz asīm, no pāra (x, y) viena vienmēr ir vienāda ar nulli.
Neskatoties uz to, ka visas 4 ass ir pozitīvas, daži dati mākslīgi tiek pārvietoti uz negatīvo pusi, jo tie atrodas uz galvenajām asinīm x un y.

 0 1 0 1.21
1 0 1.21 0
0 -1 0 -1.06
-1 0 -1.19 0
0 1 0 1.21 #Pirma punkta duplikāts

Rezultāts

Pilns kods

#!/usr/bin/gnuplot -persist
#файл в кодировке cp1251 чтоб русские буквы отображались в eps

set encoding cp1251
set terminal postscript eps enhanced monochrome size 5cm,5cm
set output "./img/eps/fig2.eps"

unset border
set key at -2, 1.5 font 'LiberationSerif, 23' 
set key left top samplen 4.5

set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis

max = 1.5
min = -max

set xtics  axis  0,.5,max in scale 0.5,0.25 mirror norotate  autojustify offset 0.35 font 'LiberationSerif, 20
set ytics  axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20

set xrange  [ min : max ]
set yrange  [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]

set label "H_1" at  0,       max center offset char  2, 0   font 'LiberationSerif, 23'
set label "H_2" at  max+0.1, 0   center offset char -1, 1   font 'LiberationSerif, 23'
set label "H_3" at  0,       min center offset char -2, 0   font 'LiberationSerif, 23'
set label "H_4" at  min,     0   center offset char  0, 1   font 'LiberationSerif, 23'

set style line 1 linetype 1 pointtype 7 linewidth 3 linecolor black
set style line 2 linetype 2 pointtype 7 linewidth 3 linecolor black

plot 'data.csv' using  1:2 title "1" w lp ls 1 ,
     'data.csv' using  3:4 title "2" w lp ls 2

Avots: habr.com

Gnuplot 5.0. Spiderplot uz 4 ass savām rokām