Едноставно следење на репликацијата на DFS во Zabbix

Вовед

Со прилично голема и дистрибуирана инфраструктура која користи DFS како единствена точка за пристап до податоците и DFSR за репликација на податоци помеѓу центрите за податоци и серверите на гранките, се поставува прашањето за следење на статусот на оваа репликација.
Случајно, речиси веднаш откако почнавме да го користиме DFSR, почнавме да го имплементираме Zabbix со цел да ја замениме постоечката зоолошка градина со различни алатки и да го доведеме следењето на инфраструктурата во поинформативна, целосна и логична форма. Ќе зборуваме за користење на Zabbix за следење на репликацијата на DFS.

Пред сè, треба да одлучиме кои податоци за репликацијата на DFS треба да се добијат за да се следи нејзиниот статус. Најрелевантен индикатор е заостанатото. Содржи датотеки што не се синхронизирани со другите членови на групата за репликација. Можете да ја видите нејзината големина користејќи ја алатката dfsrdiag, инсталиран со улогата DFSR. Во нормална состојба на репликација, заостанатата големина треба да се приближи до нула. Соодветно на тоа, голем број датотеки во заостанатиот список укажуваат на проблеми со репликацијата.

Сега за практичната страна на прашањето.

За да ја следиме големината на заостанатиот материјал преку Zabbix Agent, ќе ни требаат:

• Скрипта што ќе го анализира излезот dfsrdiag да се обезбедат конечни вредности за големината на заостанатиот број на Zabbix,
• Скрипта што ќе определи колку групи за репликација има на серверот, кои папки ги реплицираат и кои други сервери се вклучени во нив (не сакаме сето ова да го внесуваме рачно во Zabbix за секој сервер, нели?),
• Додавање на овие скрипти како UserParameter во конфигурацијата на агентот Zabbix за последователно повикување од серверот за следење,
• Започнување на услугата за агенти Zabbix како корисник кој има права да ги чита заостанатите,
• Шаблон за Zabbix, во кој ќе се конфигурира откривање на групи, обработка на примени податоци и издавање предупредувања за нив.

Парсер на скрипти

За да го напишам парсерот, го избрав VBS како најуниверзален јазик присутен во сите верзии на Windows Server. Логиката на скриптата е едноставна: го прима името на групата за репликација, реплицираната папка и имињата на серверите за испраќање и примање преку командната линија. Овие параметри потоа се пренесуваат на dfsrdiag, и во зависност од неговиот аутпут произведува:
Број на датотеки - ако е примена порака за присуство на датотеки во заостанатиот список,
0 — ако се прими порака за отсуство на датотеки во заостанатиот список („Нема заостанати“),
-1 - ако се прими порака за грешка dfsrdiag при извршување на барање („[ГРЕШКА]“).

get-Backlog.vbs

strReplicationGroup=WScript.Arguments.Item(0)
strReplicatedFolder=WScript.Arguments.Item(1)
strSending=WScript.Arguments.Item(2)
strReceiving=WScript.Arguments.Item(3)

Set WshShell = CreateObject ("Wscript.shell")
Set objExec = WSHshell.Exec("dfsrdiag.exe Backlog /RGName:""" & strReplicationGroup & """ /RFName:""" & strReplicatedFolder & """ /SendingMember:" & strSending & " /ReceivingMember:" & strReceiving)
strResult = ""
Do While Not objExec.StdOut.AtEndOfStream
	strResult = strResult & objExec.StdOut.ReadLine() & "\"
Loop

If InStr(strResult, "No Backlog") > 0 then
	intBackLog = 0
ElseIf  InStr(strResult, "[ERROR]") > 0 Then
    intBackLog = -1
Else
	arrLines = Split(strResult, "\")
	arrResult = Split(arrLines(1), ":")
	intBackLog = arrResult(1)
End If

WScript.echo intBackLog

Скрипта за откривање

За да може Zabbix да ги одреди сите групи за репликација присутни на серверот и да ги дознае сите параметри потребни за барањето (име на папката, имиња на соседните сервери), треба, прво, да ги добиеме овие информации и второ, да ги презентираме во формат разбирлив за Zabbix. Форматот што го разбира алатката за откривање изгледа вака:

        "data":[
                {
                        "{#GROUP}":"Share1",
                        "{#FOLDER}":"Folder1",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"Server2"}

...

                        "{#GROUP}":"ShareN",
                        "{#FOLDER}":"FolderN",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"ServerN"}]}

Најлесен начин да ги добиеме информациите за кои сме заинтересирани е преку WMI, извлекувајќи ги од соодветните делови на DfsrReplicationGroupConfig. Како резултат на тоа, се роди скрипта која генерира барање до WMI и излегува листа на групи, нивните папки и сервери во потребниот формат.

DFSRDiscovery.vbs

dim strComputer, strLine, n, k, i

Set wshNetwork = WScript.CreateObject( "WScript.Network" )
strComputer = wshNetwork.ComputerName

Set oWMIService = GetObject("winmgmts:\" & strComputer & "rootMicrosoftDFS")
Set colRGroups = oWMIService.ExecQuery("SELECT * FROM DfsrReplicationGroupConfig")
wscript.echo "{"
wscript.echo "        ""data"":["
n=0
k=0
i=0
For Each oGroup in colRGroups
  n=n+1
  Set colRGFolders = oWMIService.ExecQuery("SELECT * FROM DfsrReplicatedFolderConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
  For Each oFolder in colRGFolders
    k=k+1
    Set colRGConnections = oWMIService.ExecQuery("SELECT * FROM DfsrConnectionConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
    For Each oConnection in colRGConnections
      i=i+1
      binInbound = oConnection.Inbound
      strPartner = oConnection.PartnerName
      strRGName = oGroup.ReplicationGroupName
      strRFName = oFolder.ReplicatedFolderName
      If oConnection.Enabled = True and binInbound = False Then
        strSendingComputer = strComputer
        strReceivingComputer = strPartner
        strLine1="                {"    
        strLine2="                        ""{#GROUP}"":""" & strRGName & """," 
        strLine3="                        ""{#FOLDER}"":""" & strRFName & """," 
        strLine4="                        ""{#SENDING}"":""" & strSendingComputer & ""","                  
        if (n < colRGroups.Count) or (k < colRGFolders.count) or (i < colRGConnections.Count) then
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """},"
        else
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """}]}"       
        end if		
        wscript.echo strLine1
        wscript.echo strLine2
        wscript.echo strLine3
        wscript.echo strLine4
        wscript.echo strLine5	   
      End If
    Next
  Next
Next

Се согласувам, сценариото можеби нема да свети со елеганција на кодот и некои работи во него секако би можеле да се поедностават, но ја извршува својата главна функција - обезбедува информации за параметрите на групите за репликација во формат разбирлив за Zabbix.

Додавање скрипти во конфигурацијата на агентот Zabbix

Сè овде е исклучително едноставно. Додадете ги следните редови на крајот од датотеката за конфигурација на агентот:

UserParameter=check_dfsr[*],cscript /nologo "C:Program FilesZabbix Agentget-Backlog.vbs" $1 $2 $3 $4
UserParameter=discovery_dfsr[*],cscript /nologo "C:Program FilesZabbix AgentDFSRDiscovery.vbs"

Се разбира, ние ги прилагодуваме патеките на оние каде што имаме скрипти. Ги ставам во истата папка каде што е инсталиран агентот.

Откако ќе направите промени, рестартирајте ја услугата за агенти Zabbix.

Промена на корисникот под кој работи услугата Zabbix Agent

Со цел да се добијат информации преку dfsrdiag, алатката мора да се извршува под сметка која има административни права и за испраќање и примање членови на групата за репликација. Услугата за агенти Zabbix, која стандардно работи под системската сметка, нема да може да изврши такво барање. Создадов посебна сметка во доменот, му дадов административни права на потребните сервери и ја конфигурирав услугата да работи под неа на овие сервери.

Можете да одите на друг начин: затоа што dfsrdiag, всушност, работи преку истиот WMI, тогаш можете да го користите опис, како да се даде на сметката на домен правата да ја користи без издавање административни права, но ако имаме многу групи за репликација, тогаш издавањето права за секоја група ќе биде тешко. Меѓутоа, во случај да сакаме да ја следиме репликацијата на волуменот на системот на доменот на контролорите на доменот, ова може да биде единствената прифатлива опција, бидејќи давањето администраторски права на доменот на сметката на услугата за следење не е добра идеја.

Шаблон за следење

Врз основа на податоците што ги добив, создадов образец кој:

• Работи автоматско откривање на групи за репликација еднаш на час,
• Ја проверува големината на заостанатиот запис за секоја група еднаш на секои 5 минути,
• Содржи активирач што издава предупредување кога големината на заостанатиот број за која било група е повеќе од 100 за 30 минути. Активирањето е опишано како прототип што автоматски се додава во откриените групи,
• Гради графикони за големината на заостанатите за секоја репликациска група.

Можете да го преземете шаблонот за Zabbix 2.2 тука.

Вкупно

Откако ќе го увеземе шаблонот во Zabbix и ќе создадеме сметка со потребните права, ќе треба само да ги копираме скриптите на серверите за датотеки што сакаме да ги следиме за DFSR, да додадеме две линии во конфигурацијата на агентот на нив и да ја рестартираме услугата за агенти Zabbix , поставувајќи ја да работи како саканата сметка. Не се потребни други рачни поставки за следење на DFSR.

Извор: www.habr.com