gnuplot 5.0. 4 അക്ഷങ്ങളിൽ സ്പൈഡർപ്ലോട്ട് അത് സ്വയം ചെയ്യുക

ഒരു ലേഖനത്തിനായുള്ള ഡാറ്റ ദൃശ്യവൽക്കരണത്തിൽ പ്രവർത്തിക്കുമ്പോൾ, എല്ലാത്തിലും പോസിറ്റീവ് ലേബലുകളുള്ള 4 അക്ഷങ്ങൾ ഉണ്ടായിരിക്കേണ്ടത് ആവശ്യമായി വന്നു.

ലേഖനത്തിലെ മറ്റ് ഗ്രാഫുകൾ പോലെ, ഞാൻ ഉപയോഗിക്കാൻ തീരുമാനിച്ചു ഗ്നുപ്ലോട്ട്. ഒന്നാമതായി, ഞാൻ ഔദ്യോഗിക വെബ്സൈറ്റ് നോക്കി, അവിടെ നിരവധി ഉദാഹരണങ്ങളുണ്ട്. ശരിയായത് കണ്ടെത്തിയപ്പോൾ ഞാൻ വളരെ സന്തോഷിച്ചു ഉദാഹരണം (ഞാൻ ഒരു ഫയലുമായി അൽപ്പം പ്രവർത്തിക്കും, അത് മനോഹരമാകും, ഞാൻ വിചാരിച്ചു).

ഞാൻ വേഗം കോഡ് പകർത്തി റൺ ചെയ്തു. എനിക്ക് ഒരു പിശക് ലഭിക്കുന്നു. ഞാനത് കണ്ടുപിടിക്കുകയാണ്. എനിക്ക് ഒരു പഴയ gnuplot ഉണ്ടെന്ന് മനസ്സിലായി (Version 5.0 patchlevel 3 last modified 2016-02-21) അവന് അത് ചെയ്യാൻ കഴിയില്ല.

ഗ്‌നപ്‌ലോട്ടിന്റെ വഴക്കത്തെക്കുറിച്ച് അറിഞ്ഞുകൊണ്ട്, ഞാൻ വേൾഡ് വൈഡ് വെബിൽ പരതാൻ തുടങ്ങി, സ്റ്റാക്ക്ഓവർഫ്ലോയുടെ അനുയോജ്യമായ നിരവധി ഉദാഹരണങ്ങൾ കണ്ടു (Gnuplot ഉള്ള ഒരു സ്പൈഡർ പ്ലോട്ടിൽ ഇരട്ട x-ആക്സിസ് и ഗ്നുപ്ലോട്ടിൽ ഒരു സ്പൈഡർ പ്ലോട്ട് എങ്ങനെ സൃഷ്ടിക്കാം?) ഒപ്പം ഗിത്തബും (gnuplot-radarchart). അവർ ആരംഭ പോയിന്റായി മാറി.

കൂടാതെ, കമാൻഡുകൾ ഉപയോഗിച്ചുള്ള എന്റെ കൃത്രിമങ്ങൾ ഇനിപ്പറയുന്നതിലേക്ക് നയിച്ചു:

0) പ്രവർത്തനരഹിതമാക്കുക അതിർത്തികൾ

unset border

1) 4 പൂജ്യം ലൈനുകൾ സൃഷ്ടിക്കുക - 2 പ്രധാനവും 2 അധികവും:

set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis

സീറോ ലൈനുകളെ കുറിച്ച് കുറച്ച് വാക്കുകൾ പ്രമാണീകരണം. ചിത്രത്തിന്റെ മധ്യഭാഗത്തേക്ക് അക്ഷങ്ങൾ കൊണ്ടുവരാൻ ഈ പ്രവർത്തനം നിങ്ങളെ അനുവദിക്കുന്നു. അവയിൽ പോസിറ്റീവ് ടിക്കുകൾ പ്രദർശിപ്പിക്കുന്നതിന് അധികമായവ ആവശ്യമാണ്.

2) അക്ഷങ്ങളിൽ ടിക്കുകളുടെ ഡിസ്പ്ലേ സജ്ജീകരിക്കുക:

max = 1.5 # Для гибкости
min = -max
set xtics  axis  0,.5,max in scale 0.5,0.25 mirror norotate  autojustify offset 0.35
set ytics  axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            

അച്ചുതണ്ടിൽ ടിക്കുകൾ ഉപയോഗിച്ച് കുറച്ച് കൂടുതൽ ക്രമീകരണങ്ങളുണ്ട്.
axis - എവിടെയാണ് ടിക്കുകൾ സ്ഥിതി ചെയ്യുന്നത്, അച്ചുതണ്ടിൽ അല്ലെങ്കിൽ (അതിർത്തിയിൽ - അതിർത്തിയിൽ).
അക്ഷത്തിന് x, അത് വലതുവശത്തേക്ക് പോകുന്നു 0,.5,max. ആദ്യ നമ്പർ കൗണ്ട്ഡൗണിന്റെ തുടക്കമാണ്, രണ്ടാമത്തേത് ഘട്ടമാണ്, മൂന്നാമത്തേത് കൗണ്ട്ഡൗണിന്റെ അവസാനമാണ്. ആദ്യത്തേതിന് 0, ബാക്കിയുള്ളവയിൽ നിന്ന് 0.5, അതിനാൽ പൂജ്യങ്ങൾ ഉത്ഭവത്തെ തടസ്സപ്പെടുത്തുന്നില്ല.

കോർഡിനേറ്റ് സെന്ററിൽ പൂജ്യങ്ങൾ കലർത്തുന്നു.
എല്ലാ ഇടവേളകളും *tics ആയി ക്രമീകരിച്ചു 0,.5,max
ഇല്ല offset 0.35 വേണ്ടി xtics

കമപ്പെടുത്തല് scale 0.5,0.25 mirror അച്ചുതണ്ടിലേക്ക് നോട്ടുകൾ ചേർക്കുന്നു. നിങ്ങൾ അക്കങ്ങൾ ഉപയോഗിച്ച് കളിക്കുകയാണെങ്കിൽ, അവയുടെ വലുപ്പം മാറും.
ഞാൻ വേരിയബിളുകളും നൽകുന്നു max, min, അതിന്റെ സഹായത്തോടെ ഞാൻ ഗ്രാഫ് അക്ഷങ്ങളുടെ അതിരുകൾ നിയന്ത്രിക്കുന്നു.
ടിക്കുകൾ സജ്ജീകരിക്കുന്നതിനെക്കുറിച്ചുള്ള കൂടുതൽ വിവരങ്ങൾ വിഭാഗത്തിലെ ഡോക്യുമെന്റേഷനിൽ കാണാം Xtics.

3) അക്ഷ ശ്രേണികൾ സജ്ജീകരിക്കുക:

set xrange  [ min : max ] 
set yrange  [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]

2 അക്ഷങ്ങൾ ആരംഭിക്കുന്നത് ഇവിടെ ശ്രദ്ധിക്കേണ്ടതാണ് min മാഗ്നിഫിക്കേഷനും 2 അക്ഷങ്ങൾക്കും - കൂടെ max കുറയ്ക്കാൻ.
വിഭാഗത്തിലെ അധിക വിവരങ്ങൾ എക്സ്റേഞ്ച്.

4) അക്ഷങ്ങൾക്ക് പേരുകൾ നൽകുകയും മനോഹരമായി സ്ഥാപിക്കുകയും ചെയ്യുക:

set label "H_1" at  0,       max center offset char  2, 0
set label "H_2" at  max+0.1, 0   center offset char -1, 1
set label "H_3" at  0,       min center offset char -2, 0
set label "H_4" at  min,     0   center offset char  0, 1

5) ഇൻപുട്ട് ഡാറ്റ രൂപീകരിക്കുന്നു
ഓരോ ഗ്രാഫിനും 2 നിരകളുണ്ട്. ലൈൻ നമ്പർ - അച്ചുതണ്ട് നമ്പർ, ലൂപ്പ് അടയ്ക്കുന്നതിനുള്ള അഞ്ചാമത്തെ വരി. വിചിത്രമായ നിര - കോർഡിനേറ്റ് x, പോലും - y. എല്ലാ പോയിന്റുകളും അക്ഷങ്ങളിൽ സ്ഥിതി ചെയ്യുന്നതിനാൽ, ജോഡിയിൽ നിന്ന് (x, y) ഒന്ന് എപ്പോഴും പൂജ്യമാണ്.
എല്ലാ 4 അക്ഷങ്ങളും പോസിറ്റീവ് ആണെങ്കിലും, പ്രധാന അക്ഷങ്ങളിൽ സ്ഥിതി ചെയ്യുന്നതിനാൽ ചില ഡാറ്റ കൃത്രിമമായി നെഗറ്റീവ് പകുതിയിലേക്ക് നീക്കുന്നു. x и y.

 0  1  0     1.21
 1  0  1.21  0   
 0 -1  0    -1.06
-1  0 -1.19  0   
 0  1  0     1.21 #Дубликат первой точки

ഫലം

മുഴുവൻ കോഡ്

#!/usr/bin/gnuplot -persist
#файл в кодировке cp1251 чтоб русские буквы отображались в eps

set encoding cp1251
set terminal postscript eps enhanced monochrome size 5cm,5cm
set output "./img/eps/fig2.eps"

unset border
set key at -2, 1.5 font 'LiberationSerif, 23' 
set key left top samplen 4.5

set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis

max = 1.5
min = -max

set xtics  axis  0,.5,max in scale 0.5,0.25 mirror norotate  autojustify offset 0.35 font 'LiberationSerif, 20
set ytics  axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20

set xrange  [ min : max ]
set yrange  [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]

set label "H_1" at  0,       max center offset char  2, 0   font 'LiberationSerif, 23'
set label "H_2" at  max+0.1, 0   center offset char -1, 1   font 'LiberationSerif, 23'
set label "H_3" at  0,       min center offset char -2, 0   font 'LiberationSerif, 23'
set label "H_4" at  min,     0   center offset char  0, 1   font 'LiberationSerif, 23'

set style line 1 linetype 1 pointtype 7 linewidth 3 linecolor black
set style line 2 linetype 2 pointtype 7 linewidth 3 linecolor black

plot 'data.csv' using  1:2 title "1" w lp ls 1 ,
     'data.csv' using  3:4 title "2" w lp ls 2

അവലംബം: www.habr.com