🥇CMake आणि C++ हे कायमचे भाऊ आहेत

विकासादरम्यान, मला कंपाइलर बदलणे, मोड तयार करणे, अवलंबित्व आवृत्त्या, स्थिर विश्लेषण करणे, कार्यप्रदर्शन मोजणे, कव्हरेज गोळा करणे, दस्तऐवजीकरण तयार करणे इ. आणि मला CMake खरोखर आवडते कारण ते मला मला हवे ते सर्व करू देते.

बरेच लोक CMake वर टीका करतात, आणि बर्‍याचदा योग्यतेने, परंतु जर तुम्ही पाहिले तर सर्वकाही इतके वाईट नाही आणि अलीकडेच अजिबात वाईट नाही, आणि विकासाची दिशा खूप सकारात्मक आहे.

या नोटमध्ये, मी तुम्हाला खालील कार्यक्षमता मिळविण्यासाठी C++ मध्ये C++ मध्ये शीर्षलेख लायब्ररी कशी व्यवस्थित करावी हे सांगू इच्छितो:

विधानसभा;
ऑटोरन चाचण्या;
कोड कव्हरेज मोजमाप;
स्थापना;
स्वयं-दस्तऐवजीकरण;
ऑनलाइन सँडबॉक्स निर्मिती;
स्थिर विश्लेषण.

ज्याला आधीच फायदे आणि सी-मेक समजले आहे ते सहजपणे करू शकतात प्रकल्प टेम्पलेट डाउनलोड करा आणि त्याचा वापर सुरू करा.

आतून प्रकल्प

प्रकल्प रचना

.
├── CMakeLists.txt
├── README.en.md
├── README.md
├── doc
│   ├── CMakeLists.txt
│   └── Doxyfile.in
├── include
│   └── mylib
│       └── myfeature.hpp
├── online
│   ├── CMakeLists.txt
│   ├── mylib-example.cpp
│   └── wandbox.py
└── test
    ├── CMakeLists.txt
    ├── mylib
    │   └── myfeature.cpp
    └── test_main.cpp

आम्ही मुख्यत्वे CMake स्क्रिप्ट्स कसे व्यवस्थित करावे याबद्दल बोलू, म्हणून त्यांची तपशीलवार चर्चा केली जाईल. बाकीच्या फाइल्स कोणीही थेट पाहू शकतो टेम्पलेट प्रकल्प पृष्ठावर.

मुख्य CMake फाइल (./CMakeLists.txt)

प्रकल्प माहिती

सर्व प्रथम, तुम्हाला CMake सिस्टमच्या आवश्यक आवृत्तीची विनंती करणे आवश्यक आहे. CMake विकसित होत आहे, कमांड स्वाक्षरी आणि वेगवेगळ्या परिस्थितीत वर्तन बदलत आहे. CMake कडून आम्हाला काय हवे आहे हे त्वरित समजण्यासाठी, आम्हाला त्यासाठी आमच्या आवश्यकता त्वरित नोंदवण्याची आवश्यकता आहे.

cmake_minimum_required(VERSION 3.13)

मग आम्ही आमचा प्रकल्प, त्याचे नाव, आवृत्ती, वापरलेल्या भाषा इ. नियुक्त करू (पहा. команду project).

या प्रकरणात आम्ही भाषा सूचित करतो CXX (आणि याचा अर्थ C++) जेणेकरून CMake ताणत नाही आणि C भाषा कंपाइलर शोधत नाही (डिफॉल्टनुसार, CMake मध्ये दोन भाषा समाविष्ट आहेत: C आणि C++).

project(Mylib VERSION 1.0 LANGUAGES CXX)

आमचा प्रकल्प उपप्रकल्प म्हणून दुसर्‍या प्रकल्पात समाविष्ट आहे की नाही हे तुम्ही येथे लगेच तपासू शकता. यामुळे भविष्यात खूप मदत होईल.

get_directory_property(IS_SUBPROJECT PARENT_DIRECTORY)

प्रकल्प पर्याय

आम्ही दोन पर्याय देऊ.

पहिला पर्याय आहे MYLIB_TESTING - युनिट चाचण्या अक्षम करण्यासाठी. हे आवश्यक असू शकते जर आम्हाला खात्री असेल की सर्व काही चाचण्यांनुसार आहे, परंतु आम्हाला फक्त, उदाहरणार्थ, आमचा प्रकल्प स्थापित किंवा पॅकेज करायचा आहे. किंवा आमचा प्रकल्प उपप्रकल्प म्हणून समाविष्ट केला आहे - या प्रकरणात, आमच्या प्रकल्पाच्या वापरकर्त्याला आमच्या चाचण्या चालविण्यात स्वारस्य नाही. तुम्ही वापरत असलेल्या अवलंबित्वांची तुम्ही चाचणी करत नाही, नाही का?

option(MYLIB_TESTING "Включить модульное тестирование" ON)

याव्यतिरिक्त, आम्ही एक स्वतंत्र पर्याय बनवू MYLIB_COVERAGE चाचण्यांद्वारे कोड कव्हरेज मोजण्यासाठी, परंतु त्यासाठी अतिरिक्त साधनांची आवश्यकता असेल, म्हणून ते स्पष्टपणे सक्षम करणे आवश्यक आहे.

option(MYLIB_COVERAGE "Включить измерение покрытия кода тестами" OFF)

संकलन पर्याय

अर्थात, आम्ही कूल प्लस प्रोग्रामर आहोत, त्यामुळे आम्हाला कंपाइलरकडून कंपाइल-टाइम डायग्नोस्टिक्सची कमाल पातळी हवी आहे. त्यातून एकही उंदीर सरकणार नाही.

add_compile_options(
    -Werror

    -Wall
    -Wextra
    -Wpedantic

    -Wcast-align
    -Wcast-qual
    -Wconversion
    -Wctor-dtor-privacy
    -Wenum-compare
    -Wfloat-equal
    -Wnon-virtual-dtor
    -Wold-style-cast
    -Woverloaded-virtual
    -Wredundant-decls
    -Wsign-conversion
    -Wsign-promo
)

C++ भाषा मानकांचे पूर्णपणे पालन करण्यासाठी आम्ही विस्तार अक्षम करू. ते सीमेकमध्ये डीफॉल्टनुसार सक्षम केले जातात.

if(NOT CMAKE_CXX_EXTENSIONS)
    set(CMAKE_CXX_EXTENSIONS OFF)
endif()

प्राथमिक ध्येय

आमच्या लायब्ररीमध्ये फक्त हेडर फाइल्स असतात, याचा अर्थ आमच्याकडे स्टॅटिक किंवा डायनॅमिक लायब्ररीच्या स्वरूपात कोणतेही एक्झॉस्ट नाही. दुसरीकडे, आमची लायब्ररी बाहेरून वापरण्यासाठी, ती स्थापित करणे आवश्यक आहे, ते सिस्टममध्ये शोधण्यायोग्य असणे आवश्यक आहे आणि आपल्या प्रकल्पाशी कनेक्ट केलेले असणे आवश्यक आहे आणि त्याच वेळी हे समान शीर्षलेख तसेच शक्यतो काही अतिरिक्त, त्याच्याशी गुणधर्म जोडलेले आहेत.

या उद्देशासाठी, आम्ही इंटरफेस लायब्ररी तयार करतो.

add_library(mylib INTERFACE)

आम्ही आमच्या इंटरफेस लायब्ररीमध्ये शीर्षलेख बांधतो.

CMake चा आधुनिक, फॅशनेबल, तरुण वापर सुचवतो की हेडर, गुणधर्म इ. एकाच लक्ष्याद्वारे प्रसारित. तर म्हणणे पुरेसे आहे target_link_libraries(target PRIVATE dependency), आणि लक्ष्याशी संबंधित असलेले सर्व शीर्षलेख dependency, लक्ष्याशी संबंधित स्त्रोतांसाठी उपलब्ध असेल target. आणि तुम्हाला कशाचीही गरज नाही [target_]include_directories. हे खाली विश्लेषणात दाखवले जाईल युनिट चाचण्यांसाठी CMake स्क्रिप्ट.

तथाकथितकडे लक्ष देणे देखील योग्य आहे. выражения-генераторы: $<...>.

ही कमांड आम्हाला आवश्यक असलेले हेडर आमच्या इंटरफेस लायब्ररीशी जोडते आणि जर आमची लायब्ररी समान CMake पदानुक्रमातील कोणत्याही लक्ष्याशी जोडलेली असेल, तर निर्देशिकेतील शीर्षलेख त्याच्याशी संबंधित असतील. ${CMAKE_CURRENT_SOURCE_DIR}/include, आणि जर आमची लायब्ररी सिस्टमवर स्थापित केली असेल आणि कमांड वापरून दुसर्या प्रोजेक्टशी कनेक्ट केली असेल find_package, नंतर निर्देशिकेतील शीर्षलेख त्याच्याशी संबंधित असतील include प्रतिष्ठापन निर्देशिकेशी संबंधित.

target_include_directories(mylib INTERFACE
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:include>
)

भाषा मानक ठरवूया. अर्थात, अगदी शेवटचा. त्याच वेळी, आम्ही केवळ मानक समाविष्ट करत नाही, तर ते आमच्या लायब्ररीचा वापर करणार्‍यांपर्यंत देखील वाढवतो. सेट मालमत्तेची श्रेणी आहे या वस्तुस्थितीमुळे हे प्राप्त झाले आहे INTERFACE (पहा target_compile_features कमांड).

target_compile_features(mylib INTERFACE cxx_std_17)

चला आपल्या लायब्ररीसाठी एक उपनाम तयार करूया. शिवाय, सौंदर्यासाठी, ते एका खास "नेमस्पेस" मध्ये असेल. जेव्हा आमच्या लायब्ररीमध्ये भिन्न मॉड्यूल दिसतात तेव्हा हे उपयुक्त ठरेल आणि आम्ही त्यांना एकमेकांपासून स्वतंत्रपणे जोडण्यासाठी जाऊ. उदाहरणार्थ, Busta मध्ये.

add_library(Mylib::mylib ALIAS mylib)

सेटिंग

सिस्टममध्ये आमचे शीर्षलेख स्थापित करत आहे. येथे सर्व काही सोपे आहे. आम्ही म्हणतो की सर्व शीर्षलेखांसह फोल्डर निर्देशिकेत जावे include स्थापना स्थानाशी संबंधित.

install(DIRECTORY include/mylib DESTINATION include)

पुढे, आम्ही बिल्ड सिस्टमला सूचित करतो की आम्हाला थर्ड-पार्टी प्रोजेक्ट्समध्ये कमांड कॉल करण्यास सक्षम व्हायचे आहे find_package(Mylib) आणि एक ध्येय मिळवा Mylib::mylib.

install(TARGETS mylib EXPORT MylibConfig)
install(EXPORT MylibConfig NAMESPACE Mylib:: DESTINATION share/Mylib/cmake)

पुढील शब्दलेखन अशा प्रकारे समजले पाहिजे. तृतीय-पक्षाच्या प्रकल्पात असताना आम्ही कमांडला कॉल करतो find_package(Mylib 1.2.3 REQUIRED), आणि स्थापित केलेल्या लायब्ररीची वास्तविक आवृत्ती आवृत्तीशी विसंगत असेल 1.2.3CMake आपोआप त्रुटी निर्माण करेल. म्हणजेच, तुम्हाला व्यक्तिचलितपणे आवृत्त्यांचा मागोवा घेण्याची आवश्यकता नाही.

include(CMakePackageConfigHelpers)
write_basic_package_version_file("${PROJECT_BINARY_DIR}/MylibConfigVersion.cmake"
    VERSION
        ${PROJECT_VERSION}
    COMPATIBILITY
        AnyNewerVersion
)
install(FILES "${PROJECT_BINARY_DIR}/MylibConfigVersion.cmake" DESTINATION share/Mylib/cmake)

RўРµСЃС‚С ‹

चाचण्या स्पष्टपणे वापरून अक्षम केले असल्यास संबंधित पर्याय किंवा आमचा प्रोजेक्ट हा सबप्रोजेक्ट आहे, म्हणजेच तो कमांड वापरून दुसर्‍या CMake प्रोजेक्टशी जोडलेला आहे add_subdirectory, आम्ही पदानुक्रमासह पुढे जात नाही, आणि स्क्रिप्ट, जे चाचण्या निर्माण आणि चालवण्याच्या आदेशांचे वर्णन करते, फक्त चालत नाही.

if(NOT MYLIB_TESTING)
    message(STATUS "Тестирование проекта Mylib выключено")
elseif(IS_SUBPROJECT)
    message(STATUS "Mylib не тестируется в режиме подмодуля")
else()
    add_subdirectory(test)
endif()

दस्तऐवजीकरण

उपप्रकल्पाच्या बाबतीत दस्तऐवजीकरण देखील तयार केले जाणार नाही.

if(NOT IS_SUBPROJECT)
    add_subdirectory(doc)
endif()

ऑनलाइन सँडबॉक्स

त्याचप्रमाणे, उपप्रकल्पात ऑनलाइन सँडबॉक्सही नसेल.

if(NOT IS_SUBPROJECT)
    add_subdirectory(online)
endif()

चाचणी स्क्रिप्ट (test/CMakeLists.txt)

चाचणी

सर्व प्रथम, आम्हाला आवश्यक चाचणी फ्रेमवर्कसह पॅकेज सापडते (तुमच्या आवडत्यासह बदला).

find_package(doctest 2.3.3 REQUIRED)

चाचण्यांसह आमची एक्झिक्युटेबल फाइल तयार करू. सहसा मी फंक्शन असणारी फाईल थेट एक्झिक्यूटेबल बायनरीमध्ये जोडतो main.

add_executable(mylib-unit-tests test_main.cpp)

आणि मी फायली जोडतो ज्यामध्ये स्वतः चाचण्या नंतर वर्णन केल्या जातात. पण तुम्हाला हे करण्याची गरज नाही.

target_sources(mylib-unit-tests PRIVATE mylib/myfeature.cpp)

आम्ही अवलंबित्व कनेक्ट करतो. कृपया लक्षात घ्या की आम्ही आमच्या बायनरीशी फक्त सीमेक टार्गेट्स लिंक केले आणि कमांडला कॉल केला नाही target_include_directories. चाचणी फ्रेमवर्क आणि आमच्याकडून शीर्षके Mylib::mylib, तसेच बिल्ड पॅरामीटर्स (आमच्या बाबतीत, हे C++ भाषा मानक आहे) या उद्दिष्टांसह आले.

target_link_libraries(mylib-unit-tests
    PRIVATE
        Mylib::mylib
        doctest::doctest
)

शेवटी, आम्ही एक डमी टार्गेट तयार करतो, ज्याचा “बिल्ड” चालू असलेल्या चाचण्यांच्या समतुल्य आहे आणि हे लक्ष्य डीफॉल्ट बिल्डमध्ये जोडतो (विशेषता यासाठी जबाबदार आहे ALL). याचा अर्थ असा की डीफॉल्ट बिल्ड चाचण्या चालवण्यास ट्रिगर करते, याचा अर्थ आम्ही त्या चालवण्यास कधीही विसरणार नाही.

add_custom_target(check ALL COMMAND mylib-unit-tests)

व्याप्ती

पुढे, योग्य पर्याय निर्दिष्ट केल्यास आम्ही कोड कव्हरेज मापन सक्षम करतो. मी तपशिलात जाणार नाही, कारण ते CMake पेक्षा कव्हरेज मोजण्याच्या साधनाशी अधिक संबंधित आहेत. केवळ हे लक्षात घेणे महत्त्वाचे आहे की परिणामांवर आधारित एक ध्येय तयार केले जाईल coverage, ज्यासह कव्हरेज मोजणे सुरू करणे सोयीचे आहे.

find_program(GCOVR_EXECUTABLE gcovr)
if(MYLIB_COVERAGE AND GCOVR_EXECUTABLE)
    message(STATUS "Измерение покрытия кода тестами включено")

    target_compile_options(mylib-unit-tests PRIVATE --coverage)
    target_link_libraries(mylib-unit-tests PRIVATE gcov)

    add_custom_target(coverage
        COMMAND
            ${GCOVR_EXECUTABLE}
                --root=${PROJECT_SOURCE_DIR}/include/
                --object-directory=${CMAKE_CURRENT_BINARY_DIR}
        DEPENDS
            check
    )
elseif(MYLIB_COVERAGE AND NOT GCOVR_EXECUTABLE)
    set(MYLIB_COVERAGE OFF)
    message(WARNING "Для замеров покрытия кода тестами требуется программа gcovr")
endif()

दस्तऐवजीकरणासाठी स्क्रिप्ट (doc/CMakeLists.txt)

डॉक्सिजन सापडला.

find_package(Doxygen)

पुढे, वापरकर्त्याने भाषा व्हेरिएबल सेट केले आहे की नाही ते आम्ही तपासतो. जर होय, तर आम्ही त्याला स्पर्श करत नाही, जर नाही, तर आम्ही रशियन घेतो. मग आम्ही डॉक्सिजन सिस्टम फाइल्स कॉन्फिगर करतो. कॉन्फिगरेशन प्रक्रियेदरम्यान भाषेसह सर्व आवश्यक व्हेरिएबल्स तेथे जातात (पहा. команду configure_file).

मग आपण एक ध्येय तयार करतो doc, जे दस्तऐवजीकरण तयार करण्यास प्रारंभ करेल. विकास प्रक्रियेत दस्तऐवज तयार करणे ही सर्वात मोठी गरज नसल्यामुळे, लक्ष्य डीफॉल्टनुसार सक्षम केले जाणार नाही; ते स्पष्टपणे लाँच करावे लागेल.

if (Doxygen_FOUND)
    if (NOT MYLIB_DOXYGEN_LANGUAGE)
        set(MYLIB_DOXYGEN_LANGUAGE Russian)
    endif()
    message(STATUS "Doxygen documentation will be generated in ${MYLIB_DOXYGEN_LANGUAGE}")
    configure_file(Doxyfile.in Doxyfile)
    add_custom_target(doc COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile)
endif ()

ऑनलाइन सँडबॉक्ससाठी स्क्रिप्ट (ऑनलाइन/CMakeLists.txt)

येथे आपण तिसरा पायथन शोधतो आणि लक्ष्य तयार करतो wandbox, जे सेवा API शी संबंधित विनंती व्युत्पन्न करते वँडबॉक्स, आणि त्याला दूर पाठवते. प्रतिसाद तयार सँडबॉक्सच्या दुव्यासह येतो.

find_program(PYTHON3_EXECUTABLE python3)
if(PYTHON3_EXECUTABLE)
    set(WANDBOX_URL "https://wandbox.org/api/compile.json")

    add_custom_target(wandbox
        COMMAND
            ${PYTHON3_EXECUTABLE} wandbox.py mylib-example.cpp "${PROJECT_SOURCE_DIR}" include |
            curl -H "Content-type: application/json" -d @- ${WANDBOX_URL}
        WORKING_DIRECTORY
            ${CMAKE_CURRENT_SOURCE_DIR}
        DEPENDS
            mylib-unit-tests
    )
else()
    message(WARNING "Для создания онлайн-песочницы требуется интерпретатор ЯП python 3-й версии")
endif()

बाहेर प्रकल्प

आता हे सर्व कसे वापरायचे ते पाहू.

असेंब्ली

सीमेक बिल्ड सिस्टीमवरील इतर कोणत्याही प्रकल्पाप्रमाणेच हा प्रकल्प तयार करताना दोन टप्प्यांचा समावेश आहे:

पिढी

cmake -S путь/к/исходникам -B путь/к/сборочной/директории [опции ...]

CMake च्या जुन्या आवृत्तीमुळे वरील आदेश कार्य करत नसल्यास, वगळण्याचा प्रयत्न करा -S:
cmake путь/к/исходникам -B путь/к/сборочной/директории [опции ...]

पर्यायांबद्दल अधिक.

प्रकल्प बांधणे

cmake --build путь/к/сборочной/директории [--target target]

असेंब्ली उद्दिष्टांबद्दल अधिक.

पर्याय

MYLIB_COVERAGE

cmake -S ... -B ... -DMYLIB_COVERAGE=ON [прочие опции ...]

लक्ष्याचा समावेश आहे coverage, ज्याद्वारे तुम्ही चाचण्यांद्वारे कोड कव्हरेज मोजणे सुरू करू शकता.

MYLIB_TESTING

cmake -S ... -B ... -DMYLIB_TESTING=OFF [прочие опции ...]

युनिट चाचणी बिल्ड आणि लक्ष्य अक्षम करण्याची क्षमता प्रदान करते check. परिणामी, चाचण्यांद्वारे कोड कव्हरेजचे मोजमाप बंद केले आहे (पहा. MYLIB_COVERAGE).

कमांड वापरून सबप्रोजेक्ट म्हणून प्रोजेक्ट दुसर्‍या प्रोजेक्टशी कनेक्ट केलेला असल्यास चाचणी देखील स्वयंचलितपणे अक्षम केली जाते add_subdirectory.

MYLIB_DOXYGEN_LANGUAGE

cmake -S ... -B ... -DMYLIB_DOXYGEN_LANGUAGE=English [прочие опции ...]

लक्ष्य व्युत्पन्न केलेल्या दस्तऐवजीकरणाची भाषा स्विच करते doc दिलेल्या एकाला. उपलब्ध भाषांच्या सूचीसाठी, पहा डॉक्सिजन सिस्टम वेबसाइट.

रशियन मुलभूतरित्या सक्षम आहे.

विधानसभा लक्ष्य

मुलभूतरित्या

cmake --build path/to/build/directory
cmake --build path/to/build/directory --target all

लक्ष्य निर्दिष्ट केलेले नसल्यास (जे लक्ष्याच्या समतुल्य आहे all), ते जे काही करू शकते ते गोळा करते आणि लक्ष्य देखील कॉल करते check.

mylib-युनिट-चाचण्या

cmake --build path/to/build/directory --target mylib-unit-tests

युनिट चाचण्या संकलित करते. डीफॉल्टनुसार सक्षम.

तपासा

cmake --build путь/к/сборочной/директории --target check

संकलित (संकलित, आधीच नसल्यास) युनिट चाचण्या चालवते. डीफॉल्टनुसार सक्षम.

हे देखील पहा mylib-unit-tests.

कव्हरेज

cmake --build путь/к/сборочной/директории --target coverage

प्रोग्राम वापरून चाचण्यांद्वारे कोड कव्हरेजसाठी चालत असलेल्या (धावल्या, आधीच नसल्यास) युनिट चाचण्यांचे विश्लेषण करते gcovr.

कोटिंग एक्झॉस्ट असे काहीतरी दिसेल:

------------------------------------------------------------------------------
                           GCC Code Coverage Report
Directory: /path/to/cmakecpptemplate/include/
------------------------------------------------------------------------------
File                                       Lines    Exec  Cover   Missing
------------------------------------------------------------------------------
mylib/myfeature.hpp                            2       2   100%   
------------------------------------------------------------------------------
TOTAL                                          2       2   100%
------------------------------------------------------------------------------

जेव्हा पर्याय सक्षम असेल तेव्हाच लक्ष्य उपलब्ध होते MYLIB_COVERAGE.

हे देखील पहा check.

दस्तऐवज

cmake --build путь/к/сборочной/директории --target doc

सिस्टम वापरून कोड दस्तऐवजीकरण तयार करणे सुरू करते ऑक्सिजन.

वँडबॉक्स

cmake --build путь/к/сборочной/директории --target wandbox

सेवेचा प्रतिसाद यासारखा दिसतो:

{
    "permlink" :    "QElvxuMzHgL9fqci",
    "status" :  "0",
    "url" : "https://wandbox.org/permlink/QElvxuMzHgL9fqci"
}

यासाठी ही सेवा वापरली जाते वँडबॉक्स. त्यांचे सर्व्हर किती लवचिक आहेत हे मला माहित नाही, परंतु मला वाटते की या संधीचा गैरवापर केला जाऊ नये.

उदाहरणे

कव्हरेज मापनासह डीबग मोडमध्ये प्रकल्प तयार करा

cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DCMAKE_BUILD_TYPE=Debug -DMYLIB_COVERAGE=ON
cmake --build путь/к/сборочной/директории --target coverage --parallel 16

प्राथमिक असेंब्ली आणि चाचणीशिवाय प्रकल्प स्थापित करणे

cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DMYLIB_TESTING=OFF -DCMAKE_INSTALL_PREFIX=путь/к/установойной/директории
cmake --build путь/к/сборочной/директории --target install

दिलेल्या कंपाइलरसह रिलीझ मोडमध्ये तयार करा

cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DCMAKE_BUILD_TYPE=Release -DCMAKE_CXX_COMPILER=g++-8 -DCMAKE_PREFIX_PATH=путь/к/директории/куда/установлены/зависимости
cmake --build путь/к/сборочной/директории --parallel 4

इंग्रजीमध्ये दस्तऐवजीकरण तयार करणे

cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DCMAKE_BUILD_TYPE=Release -DMYLIB_DOXYGEN_LANGUAGE=English
cmake --build путь/к/сборочной/директории --target doc

साधने

सीएमके 3.13

खरं तर, CMake आवृत्ती 3.13 फक्त या मदतीमध्ये वर्णन केलेल्या काही कन्सोल आदेश चालवण्यासाठी आवश्यक आहे. CMake स्क्रिप्ट्सच्या वाक्यरचनेच्या दृष्टिकोनातून, आवृत्ती 3.8 इतर मार्गांनी जनरेशन कॉल केल्यास पुरेसे आहे.
चाचणी लायब्ररी doctest

चाचणी अक्षम केली जाऊ शकते (पहा опцию MYLIB_TESTING).
ऑक्सिजन

दस्तऐवजीकरण ज्या भाषेत तयार केले जाईल ती भाषा बदलण्यासाठी, एक पर्याय प्रदान केला आहे MYLIB_DOXYGEN_LANGUAGE.
भाषा दुभाषी python ला 3

स्वयंचलित निर्मितीसाठी ऑनलाइन सँडबॉक्सेस.

स्थिर विश्लेषण

CMake आणि काही चांगल्या साधनांसह, तुम्ही किमान प्रयत्नात स्थिर विश्लेषण देऊ शकता.

Cppcheck

CMake मध्ये स्थिर विश्लेषण साधनासाठी अंगभूत समर्थन आहे Cppcheck.

हे करण्यासाठी तुम्हाला पर्याय वापरावा लागेल CMAKE_CXX_CPPCHECK:

cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DCMAKE_BUILD_TYPE=Debug -DCMAKE_CXX_CPPCHECK="cppcheck;--enable=all;-Iпуть/к/исходникам/include"

यानंतर, प्रत्येक वेळी स्त्रोत संकलित आणि पुन्हा संकलित केल्यावर स्थिर विश्लेषण स्वयंचलितपणे लॉन्च केले जाईल. अतिरिक्त काहीही करण्याची गरज नाही.

रेंगा

एक अद्भुत साधन मदतीने scan-build तुम्ही काही वेळेत स्थिर विश्लेषण देखील चालवू शकता:

scan-build cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DCMAKE_BUILD_TYPE=Debug
scan-build cmake --build путь/к/сборочной/директории

येथे, Cppcheck च्या बाबतीत विपरीत, तुम्हाला प्रत्येक वेळी बिल्ड चालवणे आवश्यक आहे scan-build.

नंतरचा शब्द

CMake ही एक अतिशय शक्तिशाली आणि लवचिक प्रणाली आहे जी तुम्हाला प्रत्येक चव आणि रंगासाठी कार्यक्षमता लागू करण्यास अनुमती देते. आणि, जरी वाक्यरचना कधीकधी इच्छित होण्यासाठी बरेच काही सोडते, तरीही सैतान अजूनही तितका भयंकर नाही जितका तो रंगवला आहे. समाज आणि आरोग्याच्या फायद्यासाठी CMake बिल्ड सिस्टम वापरा.

→ प्रकल्प टेम्पलेट डाउनलोड करा

स्त्रोत: www.habr.com

CMake आणि C++ हे कायमचे भाऊ आहेत