या लेखात, मला Gradle बिल्डर वापरून Sonatype Maven सेंट्रल रिपॉझिटरीमध्ये Github Actions द्वारे सुरवातीपासून Java आर्टिफॅक्ट प्रकाशित करण्याच्या प्रक्रियेवर तपशीलवार नजर टाकायची आहे.

एका ठिकाणी सामान्य ट्यूटोरियल नसल्यामुळे मी हा लेख लिहिण्याचा निर्णय घेतला. सर्व माहिती वेगवेगळ्या स्त्रोतांकडून तुकड्याने गोळा करावी लागली, शिवाय, पूर्णपणे ताजी नाही. कोण काळजी घेते, मांजरीच्या खाली आपले स्वागत आहे.

सोनाटाइपमध्ये भांडार तयार करणे

सोनाटाइप मावेन सेंट्रलमध्ये भांडार तयार करणे ही पहिली पायरी आहे. यासाठी आम्ही जातो येथे, नोंदणी करा आणि नवीन कार्य तयार करा, आम्हाला एक रेपॉजिटरी तयार करण्यास सांगा. आम्ही आमच्या मध्ये ड्राइव्ह ग्रुपआयडी प्रकल्प, प्रकल्प URL प्रकल्प दुवा आणि SCM url आवृत्ती नियंत्रण प्रणालीचा दुवा ज्यामध्ये प्रकल्प स्थित आहे. ग्रुपआयडी येथे com.example, com.example.domain, com.example.testsupport या स्वरूपाचे असावे आणि ते तुमच्या गीथबच्या दुव्याच्या स्वरूपात देखील असू शकते: github.com/yourusername -> io.github.yourusername. कोणत्याही परिस्थितीत, तुम्हाला या डोमेन किंवा प्रोफाइलची मालकी सत्यापित करणे आवश्यक आहे. तुम्ही गिथब प्रोफाइल निर्दिष्ट केल्यास, तुम्हाला इच्छित नावासह सार्वजनिक भांडार तयार करण्यास सांगितले जाईल.

पुष्टीकरणानंतर काही वेळाने, तुमचा GroupId तयार केला जाईल आणि आम्ही पुढील चरण, Gradle कॉन्फिगरेशनवर जाऊ शकतो.

Gradle कॉन्फिगर करत आहे

लेखनाच्या वेळी, मला ग्रॅडल प्लगइन सापडले नाहीत जे आर्टिफॅक्ट प्रकाशित करण्यात मदत करू शकतील. या मला सापडलेले एकमेव प्लगइन, तथापि, लेखकाने त्यास आणखी समर्थन देण्यास नकार दिला. म्हणून, मी सर्वकाही स्वतःच करण्याचा निर्णय घेतला, कारण हे करणे फार कठीण नाही.

आकृती काढण्याची पहिली गोष्ट म्हणजे प्रकाशनासाठी सोनाटाइपची आवश्यकता. ते खालीलप्रमाणे आहेत.

• स्त्रोत कोड आणि JavaDoc ची उपलब्धता, म्हणजे. उपस्थित असणे आवश्यक आहे -sources.jar и-javadoc.jar फाइल्स दस्तऐवजीकरणात सांगितल्याप्रमाणे, जर स्त्रोत कोड किंवा दस्तऐवजीकरण प्रदान करणे शक्य नसेल, तर तुम्ही डमी बनवू शकता -sources.jar किंवा -javadoc.jar चाचणी उत्तीर्ण होण्यासाठी आत एक साधा README सह.
• सर्व फायलींवर स्वाक्षरी करणे आवश्यक आहे GPG/PGPआणि .asc स्वाक्षरी असलेली फाइल प्रत्येक फाइलसाठी समाविष्ट करणे आवश्यक आहे.
• उपलब्धता pom फाइल
• योग्य मूल्ये groupId, artifactId и version. आवृत्ती एक अनियंत्रित स्ट्रिंग असू शकते आणि यासह समाप्त होऊ शकत नाही -SNAPSHOT
• उपस्थिती आवश्यक name, description и url
• परवाना, विकसक आणि आवृत्ती नियंत्रण प्रणालीबद्दल माहितीची उपस्थिती

हे मूलभूत नियम आहेत जे प्रकाशित करताना पाळले पाहिजेत. संपूर्ण माहिती उपलब्ध येथे.

आम्ही या आवश्यकतांची अंमलबजावणी करतो build.gradle फाइल प्रथम, विकासक, परवाने, आवृत्ती नियंत्रण प्रणालीबद्दल सर्व आवश्यक माहिती जोडू आणि प्रकल्पाचे URL, नाव आणि वर्णन देखील सेट करूया. यासाठी एक सोपी पद्धत लिहूया:

def customizePom(pom) {
    pom.withXml {
        def root = asNode()

        root.dependencies.removeAll { dep ->
            dep.scope == "test"
        }

        root.children().last() + {
            resolveStrategy = DELEGATE_FIRST

            description 'Some description of artifact'
            name 'Artifct name'
            url 'https://github.com/login/projectname'
            organization {
                name 'com.github.login'
                url 'https://github.com/login'
            }
            issueManagement {
                system 'GitHub'
                url 'https://github.com/login/projectname/issues'
            }
            licenses {
                license {
                    name 'The Apache License, Version 2.0'
                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                }
            }
            scm {
                url 'https://github.com/login/projectname'
                connection 'scm:https://github.com/login/projectname.git'
                developerConnection 'scm:git://github.com/login/projectname.git'
            }
            developers {
                developer {
                    id 'dev'
                    name 'DevName'
                    email '[email protected]'
                }
            }
        }
    }
}

पुढे, आपण व्युत्पन्न विधानसभा दरम्यान ते निर्दिष्ट करणे आवश्यक आहे -sources.jar и-javadoc.jar फाइल्स या विभागासाठी java आपल्याला खालील जोडण्याची आवश्यकता आहे:

java {
    withJavadocJar()
    withSourcesJar()
}

GPG/PGP स्वाक्षरी सेट करून, शेवटच्या गरजेकडे जाऊ या. हे करण्यासाठी, प्लगइन कनेक्ट करा signing:

plugins {
    id 'signing'
}

आणि एक विभाग जोडा:

signing {
    sign publishing.publications
}

शेवटी, एक विभाग जोडूया publishing:

publishing {
    publications {
        mavenJava(MavenPublication) {
            customizePom(pom)
            groupId group
            artifactId archivesBaseName
            version version

            from components.java
        }
    }
    repositories {
        maven {
            url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            credentials {
                username sonatypeUsername
                password sonatypePassword
            }
        }
    }
}

तो आहे sonatype वापरकर्तानाव и sonatype पासवर्ड वर नोंदणी दरम्यान तयार केलेले लॉगिन आणि पासवर्ड असलेले चल sonatype.org.

अशा प्रकारे अंतिम build.gradle असे दिसेल:

पूर्ण बिल्ड.ग्रेडल कोड

plugins {
    id 'java'
    id 'maven-publish'
    id 'signing'
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
    withJavadocJar()
    withSourcesJar()
}

group 'io.github.githublogin'
archivesBaseName = 'projectname'
version = System.getenv('RELEASE_VERSION') ?: "0.0.1"

repositories {
    mavenCentral()
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.5.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.5.2'
}

test {
    useJUnitPlatform()
}

jar {
    from sourceSets.main.output
    from sourceSets.main.allJava
}

signing {
    sign publishing.publications
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            customizePom(pom)
            groupId group
            artifactId archivesBaseName
            version version

            from components.java
        }
    }
    repositories {
        maven {
            url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            credentials {
                username sonatypeUsername
                password sonatypePassword
            }
        }
    }
}

def customizePom(pom) {
    pom.withXml {
        def root = asNode()

        root.dependencies.removeAll { dep ->
            dep.scope == "test"
        }

        root.children().last() + {
            resolveStrategy = DELEGATE_FIRST

            description 'Some description of artifact'
            name 'Artifct name'
            url 'https://github.com/login/projectname'
            organization {
                name 'com.github.login'
                url 'https://github.com/githublogin'
            }
            issueManagement {
                system 'GitHub'
                url 'https://github.com/githublogin/projectname/issues'
            }
            licenses {
                license {
                    name 'The Apache License, Version 2.0'
                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                }
            }
            scm {
                url 'https://github.com/githublogin/projectname'
                connection 'scm:https://github.com/githublogin/projectname.git'
                developerConnection 'scm:git://github.com/githublogin/projectname.git'
            }
            developers {
                developer {
                    id 'dev'
                    name 'DevName'
                    email '[email protected]'
                }
            }
        }
    }
}

मला हे लक्षात घ्यायचे आहे की आम्हाला पर्यावरण व्हेरिएबलमधून आवृत्ती मिळते: System.getenv('RELEASE_VERSION'). आम्ही ते असेंब्ली दरम्यान उघड करू आणि टॅगच्या नावावरून ते घेऊ.

PGP की जनरेशन

Sonatype च्या आवश्यकतांपैकी एक म्हणजे सर्व फाईल्सवर GPG/PGP की सह स्वाक्षरी करावी. यासाठी आम्ही जातो येथे आणि तुमच्या ऑपरेटिंग सिस्टमसाठी GnuPG युटिलिटी डाउनलोड करा.

• आम्ही एक की जोडी व्युत्पन्न करतो: gpg --gen-key, एक वापरकर्तानाव, ई-मेल प्रविष्ट करा आणि पासवर्ड देखील सेट करा.
• आम्ही शोधून काढतो id कमांडसह आमची की: gpg --list-secret-keys --keyid-format short. स्लॅश नंतर आयडी निर्दिष्ट केला जाईल, उदाहरणार्थ: rsa2048/9B695056
• सर्व्हरवर सार्वजनिक की प्रकाशित करणे https://keys.openpgp.org आज्ञा: gpg --keyserver [https://keys.openpgp.org](https://keys.openpgp.org/) --send-keys 9B695056
• आम्ही गुप्त की एका अनियंत्रित ठिकाणी निर्यात करतो, आम्हाला भविष्यात याची आवश्यकता असेल: gpg --export-secret-key 9B695056 > D:\gpg\9B695056.gpg

Github क्रिया सेट करत आहे

चला अंतिम टप्प्यावर जाऊ, बिल्ड सेट अप करू आणि Github क्रिया वापरून स्वयं-प्रकाशित करू.
गिथब अॅक्शन्स हे एक वैशिष्ट्य आहे जे तुम्हाला पूर्ण CI/CD सायकल लागू करून वर्कफ्लो स्वयंचलित करण्याची परवानगी देते. बिल्ड, टेस्ट आणि डिप्लॉय विविध इव्हेंट्सद्वारे ट्रिगर केले जाऊ शकते: कोड पुश, रिलीज तयार करणे किंवा समस्या. ही कार्यक्षमता सार्वजनिक भांडारांसाठी पूर्णपणे विनामूल्य आहे.

या विभागात, मी तुम्हाला बिल्ड आणि पुश कोड कसा सेट करायचा आणि सोनाटाइप रिपॉझिटरीमध्ये रिलीझ करताना कसे तैनात करायचे ते तसेच गुपिते कसे सेट करायचे ते दाखवेन.

आम्ही रहस्ये सेट करतो

स्वयंचलित असेंब्ली आणि डिप्लॉयमेंटसाठी, आम्हाला अनेक गुप्त मूल्यांची आवश्यकता आहे, जसे की की आयडी, की तयार करताना आम्ही प्रविष्ट केलेला पासवर्ड, स्वतः PGP की आणि सोनाटाइप लॉगिन/पासवर्ड. आपण त्यांना रेपॉजिटरी सेटिंग्जमधील एका विशेष विभागात सेट करू शकता:

आम्ही खालील व्हेरिएबल्स सेट करतो:

• SONATYPE_USERNAME / SONATYPE_PASSWORD - लॉगिन / पासवर्ड जो आम्ही Sonatype सह नोंदणी करताना प्रविष्ट केला आहे
• SIGNING_KEYID/SIGNING_PASSWORD — पीजीपी की आयडी आणि पासवर्ड जनरेशन दरम्यान सेट केला जातो.

मला GPG_KEY_CONTENTS व्हेरिएबलवर अधिक तपशीलवार राहायचे आहे. वस्तुस्थिती अशी आहे की प्रकाशनासाठी आम्हाला खाजगी PGP की आवश्यक आहे. गुपिते मध्ये पोस्ट करण्यासाठी, मी वापरले सूचना आणि याव्यतिरिक्त अनेक क्रिया केल्या.

• चला gpg सह आमची की एनक्रिप्ट करू: gpg --symmetric --cipher-algo AES256 9B695056.gpgपासवर्ड टाकून. ते व्हेरिएबलमध्ये ठेवले पाहिजे: SECRET_PASSPHRASE
• बेस64 वापरून प्राप्त झालेल्या एनक्रिप्टेड कीचे मजकूर फॉर्ममध्ये भाषांतर करूया: base64 9B695056.gpg.gpg > 9B695056.txt. सामग्री व्हेरिएबलमध्ये ठेवली जाईल: GPG_KEY_CONTENTS.

कोड पुश करताना आणि PR तयार करताना सेटअप तयार करा

प्रथम तुम्हाला तुमच्या प्रोजेक्टच्या रूटमध्ये एक फोल्डर तयार करणे आवश्यक आहे: .github/workflows.

त्यामध्ये, फाइल चिन्हांकित करा, उदाहरणार्थ, gradle-ci-build.yml खालील सामग्रीसह:

name: build

on:
  push:
    branches:
      - master
      - dev
      - testing
  pull_request:

jobs:
  build:
    runs-on: ubuntu-latest
    steps:
      - uses: actions/checkout@v1
      - name: Set up JDK 8
        uses: actions/setup-java@v1
        with:
          java-version: 8

      - name: Build with Gradle
        uses: eskatos/gradle-command-action@v1
        with:
          gradle-version: current
          arguments: build -PsonatypeUsername=${{secrets.SONATYPE_USERNAME}} -PsonatypePassword=${{secrets.SONATYPE_PASSWORD}}

शाखांमध्ये ढकलताना हा कार्यप्रवाह कार्यान्वित केला जाईल master, dev и testing, पुल विनंत्या तयार करताना देखील.

जॉब विभाग निर्दिष्ट कार्यक्रमांवर अंमलात आणण्यासाठी पायऱ्या निर्दिष्ट करतो. या प्रकरणात, आम्ही उबंटूच्या नवीनतम आवृत्तीवर तयार करू, Java 8 वापरू आणि Gradle साठी प्लगइन देखील वापरू. eskatos/gradle-command-action@v1जे, बिल्डरच्या नवीनतम आवृत्तीचा वापर करून, मध्ये निर्दिष्ट केलेल्या कमांड चालवेल arguments. चल secrets.SONATYPE_USERNAME и secrets.SONATYPE_PASSWORD आम्ही आधी विचारलेली ही रहस्ये आहेत.

बिल्ड परिणाम क्रिया टॅबमध्ये प्रतिबिंबित होतील:

नवीन रिलीझ झाल्यावर ऑटो-डिप्लॉय करा

ऑटोडिप्लॉयसाठी एक वेगळी वर्कफ्लो फाइल तयार करू gradle-ci-publish.yml:

name: publish

on:
  push:
    tags:
      - 'v*'

jobs:
  publish:
    runs-on: ubuntu-latest
    steps:
      - uses: actions/checkout@v1
      - name: Set up JDK 8
        uses: actions/setup-java@v1
        with:
          java-version: 8

      - name: Prepare to publish
        run: |
          echo '${{secrets.GPG_KEY_CONTENTS}}' | base64 -d > publish_key.gpg
          gpg --quiet --batch --yes --decrypt --passphrase="${{secrets.SECRET_PASSPHRASE}}" 
          --output secret.gpg publish_key.gpg
          echo "::set-env name=RELEASE_VERSION::${GITHUB_REF:11}"

      - name: Publish with Gradle
        uses: eskatos/gradle-command-action@v1
        with:
          gradle-version: current
          arguments: test publish -Psigning.secretKeyRingFile=secret.gpg -Psigning.keyId=${{secrets.SIGNING_KEYID}} -Psigning.password=${{secrets.SIGNING_PASSWORD}} -PsonatypeUsername=${{secrets.SONATYPE_USERNAME}} -PsonatypePassword=${{secrets.SONATYPE_PASSWORD}}

फाईल ज्या इव्हेंटमध्ये ट्रिगर केली जाईल त्याशिवाय, मागील फाइल सारखीच आहे. या प्रकरणात, v ने सुरू होणार्‍या नावासह टॅग तयार करण्याची ही घटना आहे.

डिप्लॉयमेंट करण्यापूर्वी, आम्हाला सिक्रेट्समधून PGP की काढायची आहे आणि ती प्रोजेक्टच्या रूटमध्ये ठेवायची आहे, तसेच ती डिक्रिप्ट करायची आहे. पुढे, आपल्याला एक विशेष पर्यावरण व्हेरिएबल सेट करणे आवश्यक आहे RELEASE_VERSION ज्याचा आम्ही संदर्भ देतो gradle.build फाइल हे सर्व विभागात केले जाते Prepare to publish. आम्हाला आमची की GPG_KEY_CONTENTS व्हेरिएबलमधून मिळते, ती gpg फाइलमध्ये भाषांतरित करा, नंतर ती फाइलमध्ये ठेवून ती डिक्रिप्ट करा. secret.gpg.

पुढे, आपण एका विशेष व्हेरिएबलकडे वळतो GITHUB_REF, ज्यातून आम्ही टॅग तयार करताना सेट केलेली आवृत्ती मिळवू शकतो. हे व्हेरिएबल या प्रकरणात संबंधित आहे. refs/tags/v0.0.2 ज्यामधून आम्ही विशिष्ट आवृत्ती मिळविण्यासाठी पहिले 11 वर्ण कापले. पुढे, आम्ही प्रकाशनासाठी मानक ग्रेडल कमांड वापरतो: test publish

सोनाटाइप रेपॉजिटरीमध्ये तैनाती परिणाम तपासत आहे

रिलीझ तयार झाल्यानंतर, मागील विभागात वर्णन केलेला कार्यप्रवाह सुरू झाला पाहिजे. हे करण्यासाठी, एक प्रकाशन तयार करा:

टॅगचे नाव v ने सुरू होणे आवश्यक आहे. प्रकाशन प्रकाशित करा क्लिक केल्यानंतर, कार्यप्रवाह यशस्वीरित्या पूर्ण झाल्यास, आम्ही येथे जाऊ शकतो सोनाटाइप नेक्सस खात्री करणे:

स्टेजिंग रेपॉजिटरीमध्ये कलाकृती दिसली. ते ताबडतोब ओपन स्टेटसमध्ये दिसते, नंतर योग्य बटण दाबून ते मॅन्युअली क्लोज स्टेटसमध्ये हस्तांतरित केले जाणे आवश्यक आहे. सर्व आवश्यकता पूर्ण झाल्याची तपासणी केल्यानंतर, कलाकृती बंद स्थितीत जाते आणि यापुढे बदलासाठी उपलब्ध नाही. या स्वरूपात, ते MavenCentral मध्ये समाप्त होईल. सर्व काही ठीक असल्यास, आपण बटण दाबू शकता प्रकाशन, आणि कलाकृती सोनाटाइप भांडारात समाप्त होईल.

कलाकृती MavenCentral मध्ये येण्यासाठी, आम्ही अगदी सुरुवातीला तयार केलेल्या कार्यामध्ये तुम्हाला ते विचारण्याची आवश्यकता आहे. तुम्हाला हे फक्त एकदाच करण्याची आवश्यकता आहे, म्हणून आम्ही प्रथमच प्रकाशित करतो. त्यानंतरच्या काळात, हे आवश्यक नाही, सर्वकाही आपोआप सिंक्रोनाइझ केले जाईल. त्यांनी माझ्यासाठी पटकन सिंक्रोनाइझेशन चालू केले, परंतु आर्टिफॅक्ट MavenCentral मध्ये उपलब्ध होण्यासाठी सुमारे 5 दिवस लागले.

एवढेच, आम्ही आमची कलाकृती MavenCentral मध्ये प्रकाशित केली आहे.

उपयुक्त दुवे

• तत्सम लेख, फक्त maven द्वारे प्रकाशित
• स्टेजिंग भांडार सोनाटाईप
• Jira सोनाटाइप ज्यामध्ये टास्क तयार करायचा आहे
• उदाहरण: रेपॉजिटरी जेथे हे सर्व सेट केले आहे

स्त्रोत: www.habr.com