लिनक्स वातावरणात 1C उत्पादने कशी कार्य करतात या विषयावर आम्ही शोध घेत असताना, एक त्रुटी आढळली - 1C सर्व्हरचे क्लस्टर व्यवस्थापित करण्यासाठी सोयीस्कर ग्राफिकल मल्टी-प्लॅटफॉर्म साधनाचा अभाव. आणि rac कन्सोल युटिलिटीसाठी GUI लिहून ही कमतरता दूर करण्याचा निर्णय घेण्यात आला. माझ्या मते, या कार्यासाठी सर्वात योग्य म्हणून Tcl/tk ही विकास भाषा म्हणून निवडली गेली. आणि म्हणून, मी या सामग्रीमध्ये समाधानाचे काही मनोरंजक पैलू सादर करू इच्छितो.
कार्य करण्यासाठी तुम्हाला tcl/tk आणि 1C वितरणाची आवश्यकता असेल. आणि मी थर्ड-पार्टी पॅकेजेस न वापरता मूलभूत tcl/tk डिलिव्हरीच्या क्षमतेचा जास्तीत जास्त फायदा घेण्याचे ठरवले असल्याने, मला आवृत्ती 8.6.7 आवश्यक आहे, ज्यामध्ये ttk समाविष्ट आहे - अतिरिक्त ग्राफिक घटकांसह पॅकेज, ज्यापैकी आम्हाला मुख्यतः ttk ची आवश्यकता आहे. ::TreeView, हे झाडांच्या संरचनेच्या स्वरूपात आणि टेबलच्या (सूची) स्वरूपात डेटा प्रदर्शित करण्यास अनुमती देते. तसेच, नवीन आवृत्तीमध्ये, अपवादांसह कार्य पुन्हा केले गेले आहे (बाह्य कमांड चालवताना प्रोजेक्टमध्ये वापरला जाणारा ट्राय कमांड).
प्रोजेक्टमध्ये अनेक फाईल्स असतात (जरी तुम्हाला एकामध्ये सर्वकाही करण्यापासून काहीही प्रतिबंधित करत नाही):
rac_gui.cfg - डीफॉल्ट कॉन्फिगरेशन
rac_gui.tcl - मुख्य लाँच स्क्रिप्ट
lib निर्देशिकेत फायली असतात ज्या स्टार्टअपवर स्वयंचलितपणे लोड होतात:
function.tcl - प्रक्रियेसह फाइल
gui.tcl - मुख्य ग्राफिकल इंटरफेस
images.tcl - base64 प्रतिमा लायब्ररी
rac_gui.tcl फाईल, खरेतर, इंटरप्रिटर सुरू करते, व्हेरिएबल्स सुरू करते, मॉड्यूल लोड करते, कॉन्फिग्स इ. टिप्पण्यांसह फाइलची सामग्री:
rac_gui.tcl
#!/bin/sh
exec wish "$0" -- "$@"
# Устанавливаем текущий каталог
set dir(root) [pwd]
# Устанавливаем рабочий каталог, если его нет то создаём
set dir(work) [file join $env(HOME) .rac_gui]
if {[file exists $dir(work)] == 0 } {
file mkdir $dir(work)
}
# каталог с модулями
set dir(lib) "[file join $dir(root) lib]"
# загружаем пользовательский конфиг, если он отсутствует, то копируем дефолтный
if {[file exists [file join $dir(work) rac_gui.cfg]] ==0} {
file copy [file join [pwd] rac_gui.cfg] [file join $dir(work) rac_gui.cfg]
}
source [file join $dir(work) rac_gui.cfg]
# Код проверки наличия rac и правильности указания пути в конфиге
# если программа не найдена то будет выведен диалог для указания корректного пути
# и этот путь будет записан в пользовательский конфиг
if {[file exists $rac_cmd] == 0} {
set rac_cmd [tk_getOpenFile -initialdir $env(HOME) -parent . -title "Укажите путь до rac" -initialfile rac]
file copy [file join $dir(work) rac_gui.cfg] [file join $dir(work) rac_gui.cfg.bak]
set orig_file [open [file join $dir(work) rac_gui.cfg.bak] "r"]
set file [open [file join $dir(work) rac_gui.cfg] "w"]
while {[gets $orig_file line] >=0 } {
if {[string match "set rac_cmd*" $line]} {
puts $file "set rac_cmd $rac_cmd"
} else {
puts $file $line
}
}
close $file
close $orig_file
#return "$host:$port"
file delete [file join $dir(work) 1c_srv.cfg.bak]
} else {
puts "Found $rac_cmd"
}
set cluster_user ""
set cluster_pwd ""
set agent_user ""
set agent_pwd ""
## LOAD FILE ##
# Загружаем модули кроме gui.tcl так как его надо загрузить последним
foreach modFile [lsort [glob -nocomplain [file join $dir(lib) *.tcl]]] {
if {[file tail $modFile] ne "gui.tcl"} {
source $modFile
puts "Loaded module $modFile"
}
}
source [file join $dir(lib) gui.tcl]
source [file join $dir(work) rac_gui.cfg]
# Читаем файл со списком серверов 1С
# и добавляем в дерево
if [file exists [file join $dir(work) 1c_srv.cfg]] {
set f [open [file join $dir(work) 1c_srv.cfg] "RDONLY"]
while {[gets $f line] >=0} {
.frm_tree.tree insert {} end -id "server::$line" -text "$line" -values "$line"
}
}आवश्यक असलेली प्रत्येक गोष्ट डाउनलोड केल्यानंतर आणि rac युटिलिटीची उपस्थिती तपासल्यानंतर, एक ग्राफिकल विंडो लॉन्च केली जाईल. प्रोग्राम इंटरफेसमध्ये तीन घटक असतात:
टूलबार, झाड आणि यादी
मी "झाड" ची सामग्री 1C मधील मानक विंडोज उपकरणांसारखीच बनविली आहे.
ही विंडो तयार करणारा मुख्य कोड फाईलमध्ये आहे
lib/gui.tcl
# установка размера и положения основного окна
# можно установить в переменную topLevelGeometry в конфиг программы
if {[info exists topLevelGeometry]} {
wm geometry . $topLevelGeometry
} else {
wm geometry . 1024x768
}
# Заголовок окна
wm title . "1C Rac GUI"
wm iconname . "1C Rac Gui"
# иконка окна (берется из файла lib/imges.tcl)
wm iconphoto . tcl
wm protocol . WM_DELETE_WINDOW Quit
wm overrideredirect . 0
wm positionfrom . user
ttk::style theme use clam
# Панель инсрументов
set frm_tool [frame .frm_tool]
pack $frm_tool -side left -fill y
ttk::panedwindow .panel -orient horizontal -style TPanedwindow
pack .panel -expand true -fill both
pack propagate .panel false
ttk::button $frm_tool.btn_add -command Add -image add_grey_32
ttk::button $frm_tool.btn_del -command Del -image del_grey_32
ttk::button $frm_tool.btn_edit -command Edit -image edit_grey_32
ttk::button $frm_tool.btn_quit -command Quit -image quit_grey_32
pack $frm_tool.btn_add $frm_tool.btn_del $frm_tool.btn_edit -side top -padx 5 -pady 5
pack $frm_tool.btn_quit -side bottom -padx 5 -pady 5
# Дерево с полосами прокрутки
set frm_tree [frame .frm_tree]
ttk::scrollbar $frm_tree.hsb1 -orient horizontal -command [list $frm_tree.tree xview]
ttk::scrollbar $frm_tree.vsb1 -orient vertical -command [list $frm_tree.tree yview]
set tree [ttk::treeview $frm_tree.tree -show tree
-xscrollcommand [list $frm_tree.hsb1 set] -yscrollcommand [list $frm_tree.vsb1 set]]
grid $tree -row 0 -column 0 -sticky nsew
grid $frm_tree.vsb1 -row 0 -column 1 -sticky nsew
grid $frm_tree.hsb1 -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_tree 0 -weight 1
grid rowconfigure $frm_tree 0 -weight 1
# назначение обработчика нажатия кнопкой мыши
bind $frm_tree.tree <ButtonRelease> "TreePress $frm_tree.tree"
# Список для данных (таблица)
set frm_work [frame .frm_work]
ttk::scrollbar $frm_work.hsb -orient horizontal -command [list $frm_work.tree_work xview]
ttk::scrollbar $frm_work.vsb -orient vertical -command [list $frm_work.tree_work yview]
set tree_work [
ttk::treeview $frm_work.tree_work
-show headings -columns "par val" -displaycolumns "par val"
-xscrollcommand [list $frm_work.hsb set]
-yscrollcommand [list $frm_work.vsb set]
]
# Установка цветов для чередования в таблице
$tree_work tag configure dark -background $color(dark_table_bg)
$tree_work tag configure light -background $color(light_table_bg)
# Размещение элементов на форме
grid $tree_work -row 0 -column 0 -sticky nsew
grid $frm_work.vsb -row 0 -column 1 -sticky nsew
grid $frm_work.hsb -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_work 0 -weight 1
grid rowconfigure $frm_work 0 -weight 1
pack $frm_tree $frm_work -side left -expand true -fill both
#.panel add $frm_tool -weight 1
.panel add $frm_tree -weight 1
.panel add $frm_work -weight 1
प्रोग्रामसह कार्य करण्यासाठी अल्गोरिदम खालीलप्रमाणे आहे:
1. प्रथम, तुम्हाला मुख्य क्लस्टर सर्व्हर जोडणे आवश्यक आहे (म्हणजे, क्लस्टर व्यवस्थापन सर्व्हर (लिनक्समध्ये, व्यवस्थापन “/opt/1C/v8.3/x86_64/ras क्लस्टर —डेमन”) कमांडसह लॉन्च केले जाते.
हे करण्यासाठी, “+” बटणावर क्लिक करा आणि उघडलेल्या विंडोमध्ये, सर्व्हर पत्ता आणि पोर्ट प्रविष्ट करा:
त्यानंतर, आमचा सर्व्हर त्यावर क्लिक करून ट्रीमध्ये दिसेल, क्लस्टरची सूची उघडेल किंवा कनेक्शन त्रुटी प्रदर्शित होईल.
2. क्लस्टरच्या नावावर क्लिक केल्यावर त्याच्यासाठी उपलब्ध फंक्शन्सची सूची उघडेल.
१.…
आणि असेच, i.e. नवीन क्लस्टर जोडण्यासाठी, सूचीमध्ये उपलब्ध असलेले कोणतेही एक निवडा आणि टूलबारमधील “+” बटण दाबा आणि नवीन जोडा संवाद प्रदर्शित होईल:
टूलबारमधील बटणे संदर्भानुसार कार्य करतात, उदा. झाड किंवा यादीतील कोणता घटक निवडला आहे यावर अवलंबून, एक किंवा दुसरी प्रक्रिया केली जाईल.
ऍड बटणाचे उदाहरण पाहू (“+”):
बटण निर्मिती कोड:
ttk::button $frm_tool.btn_add -command Add -image add_grey_32येथे आपण पाहतो की जेव्हा बटण दाबले जाते, तेव्हा "जोडा" प्रक्रिया कार्यान्वित होईल, त्याचा कोड:
proc Add {} {
global active_cluster host
# Определяем идентификатор выделенного элемента
set id [.frm_tree.tree selection]
# Определяем значение этого элемента
set values [.frm_tree.tree item [.frm_tree.tree selection] -values]
set key [lindex [split $id "::"] 0]
# в зависимости от того что выделили будет запущена нужная процедура
if {$key eq "" || $key eq "server"} {
set host [ Add::server ]
return
}
Add::$key .frm_tree.tree $host $values
}गुदगुल्याचा एक फायदा येथे आहे: आपण प्रक्रियेचे नाव म्हणून व्हेरिएबलचे मूल्य पास करू शकता:
Add::$key .frm_tree.tree $host $valuesम्हणजेच, उदाहरणार्थ, जर आपण मुख्य सर्व्हरकडे निर्देश केला आणि “+” दाबले, तर Add::server प्रक्रिया सुरू केली जाईल, जर क्लस्टरवर - Add::cluster वगैरे (मी कुठे लिहीन. आवश्यक "की" थोड्या खाली येतात), सूचीबद्ध कार्यपद्धती संदर्भासाठी योग्य ग्राफिक घटक काढतात.
जसे आपण आधीच लक्षात घेतले असेल की, फॉर्म शैलीमध्ये समान आहेत - हे आश्चर्यकारक नाही, कारण ते एका प्रक्रियेद्वारे प्रदर्शित केले जातात, अधिक अचूकपणे फॉर्मची मुख्य फ्रेम (विंडो, बटणे, प्रतिमा, लेबल), प्रक्रियेचे नाव. TopLevel जोडा
proc AddToplevel {lbl img {win_name .add}} {
set cmd "destroy $win_name"
if [winfo exists $win_name] {destroy $win_name}
toplevel $win_name
wm title $win_name $lbl
wm iconphoto $win_name tcl
# метка с иконкой
ttk::label $win_name.lbl -image $img
# фрейм с полями ввода
set frm [ttk::labelframe $win_name.frm -text $lbl -labelanchor nw]
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
# фрейм и кнопки
set frm_btn [frame $win_name.frm_btn -border 0]
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }
ttk::button $frm_btn.btn_cancel -command $cmd -image quit_grey_24
grid $win_name.lbl -row 0 -column 0 -sticky nw -padx 5 -pady 10
grid $frm -row 0 -column 1 -sticky nw -padx 5 -pady 5
grid $frm_btn -row 1 -column 1 -sticky se -padx 5 -pady 5
pack $frm_btn.btn_cancel -side right
pack $frm_btn.btn_ok -side right -padx 10
return $frm
}
कॉल पॅरामीटर्स: शीर्षक, लायब्ररीमधील चिन्हासाठी प्रतिमेचे नाव (lib/images.tcl) आणि पर्यायी विंडो नाव पॅरामीटर (डीफॉल्ट .add). अशा प्रकारे, मुख्य सर्व्हर आणि क्लस्टर जोडण्यासाठी वरील उदाहरणे घेतल्यास, कॉल त्यानुसार होईल:
AddToplevel "Добавление основного сервера" server_grey_64किंवा
AddToplevel "Добавление кластера" cluster_grey_64बरं, ही उदाहरणे पुढे चालू ठेवत, मी सर्व्हर किंवा क्लस्टरसाठी अॅड डायलॉग दाखवणारी प्रक्रिया दाखवतो.
जोडा::सर्व्हर
proc Add::server {} {
global default
# выводим основную форму
set frm [AddToplevel "Добавление основного сервера" server_grey_64]
# добавляем етки и поля ввода на эту форму
label $frm.lbl_host -text "Адрес сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
#set frm_btn [frame .add.frm_btn -border 0]
# переопределяем обработчик нажатия кнопки
.add.frm_btn.btn_ok configure -command {
set host [SaveMainServer [.add.frm.ent_host get] [.add.frm.ent_port get]]
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"
destroy .add
return $host
}
return $frm
}जोडा::क्लस्टर
proc Add::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes
agent_user agent_pwd cluster_user cluster_pwd auth_agent
if {$agent_user ne "" && $agent_pwd ne ""} {
set auth_agent "--agent-user=$agent_user --agent-pwd=$agent_pwd"
} else {
set auth_agent ""
}
# устанавливаем глобальные переменные ()
set lifetime_limit $default(lifetime_limit)
set expiration_timeout $default(expiration_timeout)
set session_fault_tolerance_level $default(session_fault_tolerance_level)
set max_memory_size $default(max_memory_size)
set max_memory_time_limit $default(max_memory_time_limit)
set errors_count_threshold $default(errors_count_threshold)
set security_level [lindex $default(security_level) 0]
set load_balancing_mode [lindex $default(load_balancing_mode) 0]
set frm [AddToplevel "Добавление кластера" cluster_grey_64]
label $frm.lbl_host -text "Адрес основного сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
label $frm.lbl_name -text "Название кластера"
entry $frm.ent_name
label $frm.lbl_secure_connect -text "Защищённое соединение"
ttk::combobox $frm.cb_security_level -textvariable security_level -values $default(security_level)
label $frm.lbl_expiration_timeout -text "Останавливать выключенные процессы через:"
entry $frm.ent_expiration_timeout -textvariable expiration_timeout
label $frm.lbl_session_fault_tolerance_level -text "Уровень отказоустойчивости"
entry $frm.ent_session_fault_tolerance_level -textvariable session_fault_tolerance_level
label $frm.lbl_load_balancing_mode -text "Режим распределения нагрузки"
ttk::combobox $frm.cb_load_balancing_mode -textvariable load_balancing_mode
-values $default(load_balancing_mode)
label $frm.lbl_errors_count_threshold -text "Допустимое отклонение количества ошибок сервера, %"
entry $frm.ent_errors_count_threshold -textvariable errors_count_threshold
label $frm.lbl_processes -text "Рабочие процессы:"
label $frm.lbl_lifetime_limit -text "Период перезапуска, сек."
entry $frm.ent_lifetime_limit -textvariable lifetime_limit
label $frm.lbl_max_memory_size -text "Допустимый объём памяти, КБ"
entry $frm.ent_max_memory_size -textvariable max_memory_size
label $frm.lbl_max_memory_time_limit -text "Интервал превышения допустимого объёма памяти, сек."
entry $frm.ent_max_memory_time_limit -textvariable max_memory_time_limit
label $frm.lbl_kill_problem_processes -justify left -anchor nw -text "Принудительно завершать проблемные процессы"
checkbutton $frm.check_kill_problem_processes -variable kill_problem_processes -onvalue yes -offvalue no
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_name -row 2 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_name -row 2 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_secure_connect -row 3 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_security_level -row 3 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_expiration_timeout -row 4 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_expiration_timeout -row 4 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_session_fault_tolerance_level -row 5 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_session_fault_tolerance_level -row 5 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_load_balancing_mode -row 6 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_load_balancing_mode -row 6 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_errors_count_threshold -row 7 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_errors_count_threshold -row 7 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_processes -row 8 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.lbl_lifetime_limit -row 9 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_lifetime_limit -row 9 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_size -row 10 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_size -row 10 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_time_limit -row 11 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_time_limit -row 11 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_kill_problem_processes -row 12 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.check_kill_problem_processes -row 12 -column 1 -sticky nw -padx 5 -pady 5
# переопределяем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
return $frm
}या प्रक्रियेच्या कोडची तुलना करताना, फरक उघड्या डोळ्यांना दिसतो; मी "ओके" बटण हँडलरवर लक्ष केंद्रित करेन. Tk मध्ये, पर्याय वापरून ग्राफिक घटकांचे गुणधर्म प्रोग्रामच्या अंमलबजावणीदरम्यान ओव्हरराइड केले जाऊ शकतात कॉन्फिगर करा. उदाहरणार्थ, बटण प्रदर्शित करण्यासाठी प्रारंभिक आदेश:
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }परंतु आमच्या फॉर्ममध्ये, कमांड आवश्यक कार्यक्षमतेवर अवलंबून असते:
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
वरील उदाहरणामध्ये, “क्लोज्ड” बटण क्लस्टर जोडण्याची प्रक्रिया सुरू करते.
येथे Tk मधील ग्राफिक घटकांसह कार्य करण्याच्या दिशेने विषयांतर करणे योग्य आहे - विविध डेटा इनपुट घटकांसाठी (एंट्री, कॉम्बोबॉक्स, चेकबटण इ.) एक पॅरामीटर मजकूर व्हेरिएबल म्हणून सादर केला गेला आहे:
entry $frm.ent_lifetime_limit -textvariable lifetime_limitहे व्हेरिएबल जागतिक नेमस्पेसमध्ये परिभाषित केले आहे आणि सध्या एंटर केलेले मूल्य समाविष्ट आहे. त्या. फील्डमधून प्रविष्ट केलेला मजकूर मिळविण्यासाठी, आपल्याला फक्त व्हेरिएबलशी संबंधित मूल्य वाचण्याची आवश्यकता आहे (अर्थात, घटक तयार करताना ते परिभाषित केले असल्यास).
प्रविष्ट केलेला मजकूर पुनर्प्राप्त करण्याची दुसरी पद्धत (एंट्री प्रकारातील घटकांसाठी) म्हणजे get कमांड वापरणे:
.add.frm.ent_name getया दोन्ही पद्धती वरील कोडमध्ये पाहिल्या जाऊ शकतात.
या बटणावर क्लिक केल्याने, या प्रकरणात, rac च्या दृष्टीने क्लस्टर जोडण्यासाठी व्युत्पन्न केलेल्या कमांड लाइनसह RunCommand प्रक्रिया सुरू होते:
/opt/1C/v8.3/x86_64/rac cluster insert --host=localhost --port=1540 --name=dsdsds --expiration-timeout=0 --lifetime-limit=0 --max-memory-size=0 --max-memory-time-limit=0 --security-level=0 --session-fault-tolerance-level=0 --load-balancing-mode=performance --errors-count-threshold=0 --kill-problem-processes=no localhost:1545आता आम्ही मुख्य कमांडवर आलो, जी आम्हाला आवश्यक असलेल्या पॅरामीटर्ससह rac लाँच नियंत्रित करते, कमांड्सचे आउटपुट लिस्ट आणि रिटर्नमध्ये पार्स करते, आवश्यक असल्यास:
RunCommand
proc RunCommand {root par} {
global dir rac_cmd cluster work_list_row_count agent_user agent_pwd cluster_user cluster_pwd
puts "$rac_cmd $par"
set work_list_row_count 0
# открываем канал в неблокирующем режиме
# $rac - команда с полным путём
# $par - сформированные ключи запуска и опции
set pipe [open "|$rac_cmd $par" "r"]
try {
set lst ""
set l ""
# вывод команды добавляем в список списков
while {[gets $pipe line]>=0} {
#puts $line
if {$line eq ""} {
lappend l $lst
set lst ""
} else {
lappend lst [string trim $line]
}
}
close $pipe
return $l
} on error {result options} {
# Запуск обработчика ошибок
ErrorParcing $result $options
return ""
}
}मुख्य सर्व्हर डेटा एंटर केल्यानंतर, तो ट्रीमध्ये जोडला जाईल, यासाठी, वरील Add:server प्रक्रियेमध्ये, खालील कोड जबाबदार आहे:
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"आता, ट्रीमधील सर्व्हरच्या नावावर क्लिक केल्यावर, आम्हाला त्या सर्व्हरद्वारे व्यवस्थापित केलेल्या क्लस्टरची सूची मिळते आणि क्लस्टरवर क्लिक केल्यावर, आम्हाला क्लस्टर घटकांची (सर्व्हर, इन्फोबेसेस इ.) यादी मिळते. हे TreePress प्रक्रियेमध्ये लागू केले आहे (file lib/function.tcl):
proc TreePress {tree} {
global host server active_cluster infobase
# определяем выделенный элемент
set id [$tree selection]
# устанавливаем нужные глобальные переменные
SetGlobalVarFromTreeItems $tree $id
# Определяем ключ и значение, т.е. именно тип выбранного элемента
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
# и в зависимости от того что выбрали будет запущена соответствующая процедура
# в пространстве имён Run
Run::$key $tree $host $values
}त्यानुसार, मुख्य सर्व्हरसाठी Run::server लाँच केले जाईल (क्लस्टरसाठी - Run::cluster, कार्यरत सर्व्हरसाठी - Run::work_server इ.). त्या. $key व्हेरिएबलचे मूल्य पर्यायाद्वारे निर्दिष्ट केलेल्या ट्री घटकाच्या नावाचा भाग आहे -आयडी.
चला प्रक्रियेकडे लक्ष द्या
रन::सर्व्हर
proc Run::server {tree host values} {
# получаем список кластеров требуемого сервера
set lst [RunCommand server::$host "cluster list $host"]
if {$lst eq ""} {return}
set l [lindex $lst 0]
#puts $lst
# удаляем лишнее из списка
.frm_work.tree_work delete [ .frm_work.tree_work children {}]
# читаем список
foreach cluster_list $lst {
# Заполняем список полученными значениями
InsertItemsWorkList $cluster_list
# обрабатываем вывод (список) для добавления данных в дерево
foreach i $cluster_list {
#puts $i
set cluster_list [split $i ":"]
if {[string trim [lindex $cluster_list 0]] eq "cluster"} {
set cluster_id [string trim [lindex $cluster_list 1]]
lappend cluster($cluster_id) $cluster_id
}
if {[string trim [lindex $cluster_list 0]] eq "name"} {
lappend cluster($cluster_id) [string trim [lindex $cluster_list 1]]
}
}
}
# добавляем кластеры в дерево
foreach x [array names cluster] {
set id [lindex $cluster($x) 0]
if { [$tree exists "cluster::$id"] == 0 } {
$tree insert "server::$host" end -id "cluster::$id" -text "[lindex $cluster($x) 1]" -values "$id"
# добавляем элементы в кластер
InsertClusterItems $tree $id
}
}
if { [$tree exists "agent_admins::$id"] == 0 } {
$tree insert "server::$host" end -id "agent_admins::$id" -text "Администраторы" -values "$id"
#InsertClusterItems $tree $id
}
}ही प्रक्रिया RunCommand कमांडद्वारे सर्व्हरकडून प्राप्त झालेल्या गोष्टींवर प्रक्रिया करते आणि झाडामध्ये सर्व प्रकारच्या गोष्टी जोडते - क्लस्टर्स, विविध रूट घटक (बेस, कार्यरत सर्व्हर, सत्र इ.). तुम्ही बारकाईने पाहिल्यास, तुम्हाला आत InsertItemsWorkList प्रक्रियेसाठी कॉल आढळेल. हे rac कन्सोल युटिलिटीच्या आउटपुटवर प्रक्रिया करून ग्राफिकल सूचीमध्ये घटक जोडण्यासाठी वापरले जाते, जे पूर्वी $lst व्हेरिएबलची सूची म्हणून परत आले होते. ही सूचींची सूची आहे ज्यात कोलनने विभक्त केलेल्या घटकांच्या जोड्या आहेत.
उदाहरणार्थ, क्लस्टर कनेक्शनची सूची:
svk@svk ~]$ /opt/1C/v8.3/x86_64/rac connection list --cluster=783d2170-56c3-11e8-c586-fc75165efbb2 localhost:1545
connection : dcf5991c-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:49:51
session-number : 0
blocked-by-ls : 0
connection : b993293a-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:48:52
session-number : 0
blocked-by-ls : 0
ग्राफिकल स्वरूपात ते असे काहीतरी दिसेल:
वरील प्रक्रिया हेडरसाठी घटकांची नावे आणि टेबल भरण्यासाठी डेटा निवडते:
InsertItemsWorklist
proc InsertItemsWorkList {lst} {
global work_list_row_count
# установка чередования цвета для строки
if [expr $work_list_row_count % 2] {
set tag dark
} else {
set tag light
}
# разбор строк на пары ключ - значение
foreach i $lst {
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
lappend column_list [string trim $param]
lappend value_list [string trim $value]
}
}
# заполнение таблицы
.frm_work.tree_work configure -columns $column_list -displaycolumns $column_list
.frm_work.tree_work insert {} end -values $value_list -tags $tag
.frm_work.tree_work column #0 -stretch
# установка заголовков
foreach j $column_list {
.frm_work.tree_work heading $j -text $j
}
incr work_list_row_count
}येथे, साध्या आदेशाऐवजी [split $str ":"], जी स्ट्रिंगला ":" द्वारे विभक्त केलेल्या घटकांमध्ये विभाजित करते आणि सूची देते, एक नियमित अभिव्यक्ती वापरली जाते, कारण काही घटकांमध्ये कोलन देखील असते.
InsertClusterItems प्रक्रिया (अनेक समानांपैकी एक) फक्त आवश्यक क्लस्टर घटकाच्या झाडावर संबंधित अभिज्ञापकांसह मूल घटकांची सूची जोडते.
क्लस्टर आयटम घाला
proc InsertClusterItems {tree id} {
set parent "cluster::$id"
$tree insert $parent end -id "infobases::$id" -text "Информационные базы" -values "$id"
$tree insert $parent end -id "servers::$id" -text "Рабочие серверы" -values "$id"
$tree insert $parent end -id "admins::$id" -text "Администраторы" -values "$id"
$tree insert $parent end -id "managers::$id" -text "Менеджеры кластера" -values $id
$tree insert $parent end -id "processes::$id" -text "Рабочие процессы" -values "workprocess-all"
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "sessions-all"
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "blocks-all"
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "connections-all"
$tree insert $parent end -id "profiles::$id" -text "Профили безопасности" -values $id
}
तत्सम कार्यपद्धती लागू करण्यासाठी तुम्ही आणखी दोन पर्यायांचा विचार करू शकता, जेथे तुम्ही ऑप्टिमाइझ कसे करू शकता आणि पुनरावृत्ती होणाऱ्या आज्ञांपासून मुक्त होऊ शकता हे स्पष्टपणे दिसेल:
या प्रक्रियेमध्ये, जोडणे आणि तपासण्याचे निराकरण केले जाते:
InsertBaseItems
proc InsertBaseItems {tree id} {
set parent "infobase::$id"
if { [$tree exists "sessions::$id"] == 0 } {
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "$id"
}
if { [$tree exists "locks::$id"] == 0 } {
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "$id"
}
if { [$tree exists "connections::$id"] == 0 } {
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "$id"
}
}
येथे अधिक योग्य दृष्टीकोन आहे:
प्रोफाइल आयटम घाला
proc InsertProfileItems {tree id} {
set parent "profile::$id"
set lst {
{dir "Виртуальные каталоги"}
{com "Разрешённые COM-классы"}
{addin "Внешние компоненты"}
{module "Внешние отчёты и обработки"}
{app "Разрешённые приложения"}
{inet "Ресурсы интернет"}
}
foreach i $lst {
append item [lindex $i 0] "::$id"
if { [$tree exists $item] == 0 } {
$tree insert $parent end -id $item -text [lindex $i 1] -values "$id"
}
unset item
}
}त्यांच्यातील फरक म्हणजे लूपचा वापर, ज्यामध्ये पुनरावृत्ती आदेश(चे) कार्यान्वित केले जातात. कोणता दृष्टिकोन वापरायचा हे विकसकाच्या निर्णयावर अवलंबून आहे.
आम्ही घटक जोडणे आणि डेटा पुनर्प्राप्त करणे समाविष्ट केले आहे, आता संपादनावर लक्ष केंद्रित करण्याची वेळ आली आहे. मुळात, समान पॅरामीटर्स संपादन आणि जोडण्यासाठी वापरले जातात (माहिती बेसचा अपवाद वगळता), समान संवाद फॉर्म वापरले जातात. जोडण्यासाठी कॉलिंग प्रक्रियेसाठी अल्गोरिदम असे दिसते:
जोडा::$key->AddToplevel
आणि यासारख्या संपादनासाठी:
संपादित करा::$key->Add::$key->AddTopLevel
उदाहरणार्थ, क्लस्टरचे संपादन करूया, म्हणजे. झाडातील क्लस्टरच्या नावावर क्लिक केल्यानंतर, टूलबार (पेन्सिल) मधील संपादन बटण दाबा आणि संबंधित फॉर्म स्क्रीनवर प्रदर्शित होईल:
संपादित करा::क्लस्टर
proc Edit::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes active_cluster
agent_user agent_pwd cluster_user cluster_pwd auth
if {$cluster_user ne "" && $cluster_pwd ne ""} {
set auth "--cluster-user=$cluster_user --cluster-pwd=$cluster_pwd"
} else {
set auth ""
}
# рисуем форму для кластера
set frm [Add::cluster $tree $host $values]
# меняем текст на метке
$frm configure -text "Редактирование кластера"
set active_cluster $values
# получаем данные по выделенному кластеру
set lst [RunCommand cluster::$values "cluster info --cluster=$active_cluster $host"]
# заполняем поля
FormFieldsDataInsert $frm $lst
# выключаем поля, редактирование которых запрещено
$frm.ent_host configure -state disable
$frm.ent_port configure -state disable
# переназначаем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster update
--cluster=$active_cluster $auth
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth $host"
$tree delete "cluster::$active_cluster"
Run::server $tree $host ""
destroy .add
}
}कोडमधील टिप्पण्यांवर आधारित, तत्वतः, सर्वकाही स्पष्ट आहे, बटण हँडलर कोड ओव्हरराइड केल्याशिवाय आणि एक FormFieldsDataInsert प्रक्रिया आहे जी डेटासह फील्ड भरते आणि व्हेरिएबल्स सुरू करते:
FormFieldsDataInsert
proc FormFieldsDataInsert {frm lst} {
foreach i [lindex $lst 0] {
# получаем список параметров и значений
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
# меняем символы
regsub -all -- "-" [string trim $param] "_" entry_name
# заполняем данными
if [winfo exists $frm.ent_$entry_name] {
$frm.ent_$entry_name delete 0 end
$frm.ent_$entry_name insert end [string trim $value """]
}
if [winfo exists $frm.cb_$entry_name] {
global $entry_name
set $entry_name [string trim $value """]
}
# для чекбоксов меняем значения
if [winfo exists $frm.check_$entry_name] {
global $entry_name
if {$value eq "0"} {
set $entry_name no
} elseif {$value eq "1"} {
set $entry_name yes
} else {
set $entry_name $value
}
}
}
}
}
या प्रक्रियेमध्ये, tcl चा आणखी एक फायदा समोर आला - इतर व्हेरिएबल्सची व्हॅल्यू व्हेरिएबल नाव म्हणून बदलली जातात. त्या. फॉर्म भरणे आणि व्हेरिएबल्सचे इनिशियलायझेशन स्वयंचलित करण्यासाठी, फील्ड आणि व्हेरिएबल्सची नावे rac युटिलिटीच्या कमांड लाइन स्विचेस आणि कमांड आउटपुट पॅरामीटर्सच्या नावांशी काही अपवाद आहेत - डॅशची जागा अंडरस्कोरने बदलली आहे. उदा अनुसूचित-नोकरी-नकार फील्डशी जुळते ent_scheduled_jobs_deny आणि व्हेरिएबल शेड्यूल्ड_नोकरी_नकार.
फील्डच्या रचनेत जोडणे आणि संपादित करण्याचे फॉर्म भिन्न असू शकतात, उदाहरणार्थ, माहिती बेससह कार्य करणे:
माहिती सुरक्षा जोडणे
माहिती सुरक्षा संपादित करणे
संपादन प्रक्रियेमध्ये Edit::infobase, आवश्यक फील्ड फॉर्ममध्ये जोडल्या जातात; कोड प्रचंड आहे, म्हणून मी ते येथे सादर करत नाही.
सादृश्यतेनुसार, इतर घटकांसाठी जोडणे, संपादित करणे, हटवणे या प्रक्रियेची अंमलबजावणी केली जाते.
युटिलिटीच्या ऑपरेशनमध्ये अमर्यादित संख्येने सर्व्हर, क्लस्टर, माहिती बेस इत्यादींचा समावेश असल्याने, कोणता क्लस्टर कोणत्या सर्व्हरचा किंवा माहिती सुरक्षा प्रणालीचा आहे हे निर्धारित करण्यासाठी, अनेक जागतिक चलने सादर केली गेली आहेत, ज्याची मूल्ये प्रत्येक सेट केली आहेत. जेव्हा तुम्ही झाडाच्या घटकांवर क्लिक कराल. त्या. प्रक्रिया आवर्तीपणे सर्व मूळ घटकांमधून चालते आणि व्हेरिएबल्स सेट करते:
GlobalVarFromTreeItems सेट करा
proc SetGlobalVarFromTreeItems {tree id} {
global host server active_cluster infobase
set parent [$tree parent $id]
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
switch -- $key {
server {set host $values}
work_server {set server $values}
cluster {set active_cluster $values}
infobase {set infobase $values}
}
if {$parent eq ""} {
return
} else {
SetGlobalVarFromTreeItems $tree $parent
}
}
1C क्लस्टर तुम्हाला अधिकृततेसह किंवा त्याशिवाय काम करण्याची परवानगी देतो. प्रशासकाचे दोन प्रकार आहेत - क्लस्टर एजंट प्रशासक आणि क्लस्टर प्रशासक. त्यानुसार, योग्य ऑपरेशनसाठी, प्रशासक लॉगिन आणि पासवर्ड असलेले आणखी 4 ग्लोबल व्हेरिएबल्स सादर केले गेले. त्या. क्लस्टरमध्ये प्रशासक खाते असल्यास, आपले लॉगिन आणि पासवर्ड प्रविष्ट करण्यासाठी एक संवाद प्रदर्शित केला जाईल, डेटा मेमरीमध्ये जतन केला जाईल आणि संबंधित क्लस्टरसाठी प्रत्येक कमांडमध्ये समाविष्ट केला जाईल.
ही त्रुटी हाताळण्याच्या प्रक्रियेची जबाबदारी आहे.
एररपार्सिंग
proc ErrorParcing {err opt} {
global cluster_user cluster_pwd agent_user agent_pwd
switch -regexp -- $err {
"Cluster administrator is not authenticated" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Central server administrator is not authenticated" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
"Администратор кластера не аутентифицирован" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Администратор центрального сервера не аутентифицирован" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
(.+) {
tk_messageBox -type ok -icon error -message "$err"
}
}
}त्या. कमांड काय परत करेल यावर अवलंबून, त्यानुसार प्रतिक्रिया होईल.
याक्षणी, सुमारे 95 टक्के कार्यक्षमता लागू केली गेली आहे, फक्त सुरक्षा प्रोफाइलसह कार्य अंमलात आणणे आणि त्याची चाचणी करणे बाकी आहे =). इतकंच. तुटलेल्या कथेबद्दल मी माफी मागतो.
कोड पारंपारिकपणे उपलब्ध आहे .
अद्यतन: मी सुरक्षा प्रोफाइलसह कार्य पूर्ण केले. आता कार्यक्षमता 100% लागू झाली आहे.
अद्यतन 2: इंग्रजी आणि रशियन भाषेत स्थानिकीकरण जोडले गेले आहे, win7 मधील कामाची चाचणी केली गेली आहे
स्त्रोत: www.habr.com