🥇औद्योगिक निन्जाच्या पावलावर पाऊल ठेवून: पॉझिटिव्ह हॅक डेज 9 मध्ये PLC कसे हॅक केले गेले

शेवटच्या PHDays 9 मध्ये आम्ही गॅस पंपिंग प्लांट हॅक करण्यासाठी एक स्पर्धा आयोजित केली - स्पर्धा औद्योगिक निन्जा. साइटवर वेगवेगळ्या सुरक्षा मापदंडांसह (कोणतेही सुरक्षा, कमी सुरक्षा, उच्च सुरक्षा) तीन स्टँड होते, त्याच औद्योगिक प्रक्रियेचे अनुकरण करत: दाबाखाली असलेली हवा फुग्यात टाकली गेली (आणि नंतर सोडली गेली).

भिन्न सुरक्षा मापदंड असूनही, स्टँडची हार्डवेअर रचना समान होती: सीमेन्स सिमॅटिक पीएलसी S7-300 मालिका; आपत्कालीन डिफ्लेशन बटण आणि दाब मोजण्याचे साधन (पीएलसी डिजिटल इनपुट (डीआय) शी कनेक्ट केलेले); फुगवणे आणि हवेच्या डिफ्लेशनसाठी कार्यरत वाल्व (पीएलसी (डीओ) च्या डिजिटल आउटपुटशी जोडलेले) - खालील आकृती पहा.

PLC ने, प्रेशर रीडिंगवर अवलंबून आणि त्याच्या प्रोग्रामनुसार, बॉल डिफ्लेट किंवा फुगवण्याचा निर्णय घेतला (संबंधित वाल्व्ह उघडले आणि बंद केले). तथापि, सर्व स्टँडमध्ये मॅन्युअल कंट्रोल मोड होता, ज्यामुळे कोणत्याही निर्बंधांशिवाय वाल्व्हची स्थिती नियंत्रित करणे शक्य झाले.

हा मोड सक्षम करण्याच्या जटिलतेमध्ये स्टँड भिन्न आहेत: असुरक्षित स्टँडवर हे करणे सर्वात सोपे होते आणि उच्च सुरक्षा स्टँडवर ते त्याचप्रमाणे अधिक कठीण होते.

सहापैकी पाच समस्या दोन दिवसांत सुटल्या; प्रथम स्थानावरील सहभागीने 233 गुण मिळवले (त्याने स्पर्धेच्या तयारीसाठी एक आठवडा घालवला). तीन विजेते: I स्थान - a1exdandy, II - Rubikoid, III - Ze.

तथापि, PHDays दरम्यान, सहभागींपैकी कोणीही तिन्ही स्टँडवर मात करू शकला नाही, म्हणून आम्ही ऑनलाइन स्पर्धा घेण्याचे ठरवले आणि जूनच्या सुरुवातीला सर्वात कठीण कार्य प्रकाशित केले. सहभागींना एका महिन्याच्या आत कार्य पूर्ण करायचे होते, ध्वज शोधायचा होता आणि समाधानाचे तपशीलवार आणि मनोरंजक पद्धतीने वर्णन करायचे होते.

कटच्या खाली आम्ही महिन्याभरात पाठवलेल्या कामाच्या सर्वोत्तम समाधानाचे विश्लेषण प्रकाशित करतो, ते डिजिटल सिक्युरिटी कंपनीच्या अॅलेक्सी कोव्रीझ्निख (a1exdandy) यांना आढळले, ज्याने PHDays दरम्यान स्पर्धेत प्रथम क्रमांक पटकावला. खाली आम्ही त्याचा मजकूर आमच्या टिप्पण्यांसह सादर करतो.

प्रारंभिक विश्लेषण

तर, कार्यामध्ये खालील फायलींसह संग्रहण समाविष्ट आहे:

block_upload_traffic.pcapng
DB100.bin
hints.txt

hints.txt फाइलमध्ये कार्य सोडवण्यासाठी आवश्यक माहिती आणि सूचना आहेत. त्याची सामग्री येथे आहेतः

पेट्रोविचने मला काल सांगितले की तुम्ही PlcSim वरून Step7 मध्ये ब्लॉक लोड करू शकता.

सीमेन्स सिमॅटिक S7-300 मालिका PLC स्टँडवर वापरली गेली.

PlcSim एक PLC एमुलेटर आहे जो तुम्हाला Siemens S7 PLC साठी प्रोग्राम चालवण्यास आणि डीबग करण्यास अनुमती देतो.

DB100.bin फाइलमध्ये DB100 PLC डेटा ब्लॉक आहे असे दिसते: 00000000: 0100 0102 6e02 0401 0206 0100 0101 0102 ....n......... 00000010: 1002 0501 0202 2002 . ..... ......... 0501: 0206 0100 0102 00000020 0102 7702 0401 0206a0100 ..w............. 0103: 0102 0 02 00000030 0501 0202 ................ 1602: 0501 0206 0100 0104 0102 00000040 7502a0401 0206 u............... 0100: 0105 0102 0 02 0501 00000050 ०१०२ ३४०२............४. 0202: 1602 0501 0206 0100 0106 0102 3402 4 ......... & ..... 00000060: 0401C0206 0100 0107 0102 2602 0501 0202 00000070 एल ......... 4. .. 02 : 0501 0206 0100 0108 0102a3302 0401 3 00000080................ 0206: 0100 0109 0102 0a 02 0501 0202 1602 .......... 00000090a0501: 0206 0100b 010 0102 3702 0401 0206 7 ......".....F... 000000b0: 0100 010 0102c 2202 0501 0202........4602 .... .. 0501c000000: 0d 0206 0100a010 0102 3302 0401 0206 0100 ................ 3d000000: 0 010e 0102 0d02 0501 0202 1602 0501 0206 000000 0 0100 010 0102. .... 6e02: 0401 0206 0100 010 000000 0 0102 1102 ........#...... 0501f0202: 2302 0501 0206 0100 000000 0..... 0110..... ..... 0102: 3502 0401 0206 0100 0111 0102 5 00000100 ......%......... 1202: 0501 0202 2502 0501 0206 0100..... 0112 00000110..... .....&. 0102: 3302 0401 0206c0100 0113 0102 2602 ....L......

नावाप्रमाणेच, block_upload_traffic.pcapng फाईलमध्ये PLC वर ब्लॉक अपलोड ट्रॅफिकचा डंप आहे.

हे लक्षात घेण्यासारखे आहे की कॉन्फरन्स दरम्यान स्पर्धेच्या ठिकाणी हा ट्रॅफिक डंप प्राप्त करणे थोडे कठीण होते. हे करण्यासाठी, TeslaSCADA2 साठी प्रोजेक्ट फाइलमधील स्क्रिप्ट समजून घेणे आवश्यक होते. त्यावरून हे समजणे शक्य होते की RC4 वापरून एन्क्रिप्ट केलेला डंप कुठे आहे आणि तो डिक्रिप्ट करण्यासाठी कोणती की वापरावी लागेल. S7 प्रोटोकॉल क्लायंट वापरून साइटवरील डेटा ब्लॉक्सचे डंप प्राप्त केले जाऊ शकतात. यासाठी मी Snap7 पॅकेजमधील डेमो क्लायंट वापरला.

ट्रॅफिक डंपमधून सिग्नल प्रोसेसिंग ब्लॉक्स काढणे

डंपची सामग्री पाहता, आपण समजू शकता की त्यात सिग्नल प्रोसेसिंग ब्लॉक्स ओबी 1, एफसी 1, एफसी 2 आणि एफसी 3 आहेत:

हे ब्लॉक्स काढलेच पाहिजेत. हे केले जाऊ शकते, उदाहरणार्थ, खालील स्क्रिप्टसह, यापूर्वी pcapng फॉरमॅटमधून pcap मध्ये रहदारी रूपांतरित केली आहे:

#!/usr/bin/env python2

import struct
from scapy.all import *

packets = rdpcap('block_upload_traffic.pcap')
s7_hdr_struct = '>BBHHHHBB'
s7_hdr_sz = struct.calcsize(s7_hdr_struct)
tpkt_cotp_sz = 7
names = iter(['OB1.bin', 'FC1.bin', 'FC2.bin', 'FC3.bin'])
buf = ''

for packet in packets:
    if packet.getlayer(IP).src == '10.0.102.11':
        tpkt_cotp_s7 = str(packet.getlayer(TCP).payload)
        if len(tpkt_cotp_s7) < tpkt_cotp_sz + s7_hdr_sz:
            continue
        s7 = tpkt_cotp_s7[tpkt_cotp_sz:]
        s7_hdr = s7[:s7_hdr_sz]
        param_sz = struct.unpack(s7_hdr_struct, s7_hdr)[4]
        s7_param = s7[12:12+param_sz]
        s7_data = s7[12+param_sz:]
        if s7_param in ('x1ex00', 'x1ex01'):  # upload
            buf += s7_data[4:]
        elif s7_param == 'x1f':
            with open(next(names), 'wb') as f:
                f.write(buf)
            buf = ''

परिणामी ब्लॉक्सचे परीक्षण केल्यावर, तुमच्या लक्षात येईल की ते नेहमी बाइट्स 70 70 (pp) ने सुरू होतात. आता तुम्हाला त्यांचे विश्लेषण कसे करायचे ते शिकण्याची गरज आहे. असाइनमेंट इशारा सूचित करतो की यासाठी तुम्हाला PlcSim वापरण्याची आवश्यकता आहे.

ब्लॉक्समधून मानवी-वाचनीय सूचना मिळवणे

प्रथम, सिमॅटिक मॅनेजर सॉफ्टवेअर वापरून अनेक ब्लॉक्स (= Q 7) पुनरावृत्ती सूचनांसह लोड करून S0.0-PlcSim प्रोग्राम करण्याचा प्रयत्न करूया, आणि एमुलेटरमध्ये प्राप्त केलेले PLC example.plc फाइलमध्ये सेव्ह करूया. फाईलची सामग्री पाहून, आपण स्वाक्षरी 70 70 द्वारे डाउनलोड केलेल्या ब्लॉक्सची सुरुवात सहजपणे निर्धारित करू शकता, जे आम्ही आधी शोधले होते. ब्लॉक्सच्या आधी, वरवर पाहता, ब्लॉकचा आकार 4-बाइट लिटल-एंडियन व्हॅल्यू म्हणून लिहिलेला आहे.

आम्हाला पीएलसी फाइल्सच्या संरचनेबद्दल माहिती मिळाल्यानंतर, पीएलसी एस7 प्रोग्राम्स वाचण्यासाठी खालील कृती योजना दिसून आली:

सिमॅटिक मॅनेजर वापरून, आम्ही S7-PlcSim मध्ये एक ब्लॉक स्ट्रक्चर तयार करतो जसे आम्हाला डंपमधून मिळाले होते. ब्लॉकचे आकार जुळले पाहिजेत (हे ब्लॉक्सना आवश्यक निर्देशांसह भरून प्राप्त केले जाते) आणि त्यांचे अभिज्ञापक (OB1, FC1, FC2, FC3).
पीएलसी फाईलमध्ये सेव्ह करा.
आम्ही परिणामी फाइलमधील ब्लॉक्सची सामग्री ट्रॅफिक डंपमधील ब्लॉक्ससह पुनर्स्थित करतो. ब्लॉक्सची सुरुवात स्वाक्षरीद्वारे निश्चित केली जाते.
आम्ही परिणामी फाइल S7-PlcSim मध्ये लोड करतो आणि सिमॅटिक मॅनेजरमधील ब्लॉक्सची सामग्री पाहतो.

ब्लॉक बदलले जाऊ शकतात, उदाहरणार्थ, खालील कोडसह:

with open('original.plc', 'rb') as f:
    plc = f.read()
blocks = []
for fname in ['OB1.bin', 'FC1.bin', 'FC2.bin', 'FC3.bin']:
    with open(fname, 'rb') as f:
        blocks.append(f.read())

i = plc.find(b'pp')
for block in blocks:
    plc = plc[:i] + block + plc[i+len(block):]
    i = plc.find(b'pp', i + 1)

with open('target.plc', 'wb') as f:
    f.write(plc)

अलेक्सीने कदाचित अधिक कठीण, परंतु तरीही योग्य मार्ग स्वीकारला. आम्ही असे गृहीत धरले की सहभागी NetToPlcSim प्रोग्राम वापरतील जेणेकरुन PlcSim नेटवर्कवर संप्रेषण करू शकतील, Snap7 द्वारे PlcSim वर ब्लॉक्स अपलोड करू शकतील आणि नंतर विकास वातावरणाचा वापर करून PlcSim वरून हे ब्लॉक्स एक प्रकल्प म्हणून डाउनलोड करू शकतील.

परिणामी फाइल S7-PlcSim मध्ये उघडून, तुम्ही सिमॅटिक मॅनेजर वापरून ओव्हरराईट केलेले ब्लॉक्स वाचू शकता. मुख्य उपकरण नियंत्रण कार्ये ब्लॉक FC1 मध्ये रेकॉर्ड केली जातात. विशेष लक्षात ठेवा #TEMP0 व्हेरिएबल, जे चालू केल्यावर M2.2 आणि M2.3 बिट मेमरी मूल्यांवर आधारित PLC नियंत्रण मॅन्युअल मोडवर सेट करते असे दिसते. #TEMP0 मूल्य फंक्शन FC3 द्वारे सेट केले आहे.

समस्येचे निराकरण करण्यासाठी, तुम्हाला FC3 फंक्शनचे विश्लेषण करणे आणि काय करणे आवश्यक आहे हे समजून घेणे आवश्यक आहे जेणेकरून ते तार्किक परत येईल.

स्पर्धा स्थळावरील लो सिक्युरिटी स्टँडवरील PLC सिग्नल प्रोसेसिंग ब्लॉक्सची मांडणी अशाच प्रकारे करण्यात आली होती, परंतु #TEMP0 व्हेरिएबलचे मूल्य सेट करण्यासाठी, DB1 ब्लॉकमध्ये माझी निन्जा मार्ग लिहिणे पुरेसे होते. ब्लॉकमधील मूल्य तपासणे सोपे होते आणि ब्लॉक प्रोग्रामिंग भाषेचे सखोल ज्ञान आवश्यक नव्हते. अर्थात, उच्च सुरक्षा स्तरावर, मॅन्युअल नियंत्रण मिळवणे अधिक कठीण होईल आणि STL भाषेची गुंतागुंत समजून घेणे आवश्यक आहे (S7 PLC प्रोग्राम करण्याचा एक मार्ग).

रिव्हर्स ब्लॉक FC3

STL प्रतिनिधित्वातील FC3 ब्लॉकची सामग्री:

      L     B#16#0
      T     #TEMP13
      T     #TEMP15
      L     P#DBX 0.0
      T     #TEMP4
      CLR   
      =     #TEMP14
M015: L     #TEMP4
      LAR1  
      OPN   DB   100
      L     DBLG
      TAR1  
      <=D   
      JC    M016
      L     DW#16#0
      T     #TEMP0
      L     #TEMP6
      L     W#16#0
      <>I   
      JC    M00d
      L     P#DBX 0.0
      LAR1  
M00d: L     B [AR1,P#0.0]
      T     #TEMP5
      L     W#16#1
      ==I   
      JC    M007
      L     #TEMP5
      L     W#16#2
      ==I   
      JC    M008
      L     #TEMP5
      L     W#16#3
      ==I   
      JC    M00f
      L     #TEMP5
      L     W#16#4
      ==I   
      JC    M00e
      L     #TEMP5
      L     W#16#5
      ==I   
      JC    M011
      L     #TEMP5
      L     W#16#6
      ==I   
      JC    M012
      JU    M010
M007: +AR1  P#1.0
      L     P#DBX 0.0
      LAR2  
      L     B [AR1,P#0.0]
      L     C#8
      *I    
      +AR2  
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M003
      JU    M001
      JU    M002
      JU    M004
M003: JU    M005
M001: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP0
      JU    M006
M002: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP1
      JU    M006
M004: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP2
      JU    M006
M00f: +AR1  P#1.0
      L     B [AR1,P#0.0]
      L     C#8
      *I    
      T     #TEMP11
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      TAR1  #TEMP4
      OPN   DB   101
      L     P#DBX 0.0
      LAR1  
      L     #TEMP11
      +AR1  
      LAR2  #TEMP9
      L     B [AR2,P#0.0]
      T     B [AR1,P#0.0]
      L     #TEMP4
      LAR1  
      JU    M006
M008: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP3
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M009
      JU    M00b
      JU    M00a
      JU    M00c
M009: JU    M005
M00b: L     #TEMP3
      T     #TEMP0
      JU    M006
M00a: L     #TEMP3
      T     #TEMP1
      JU    M006
M00c: L     #TEMP3
      T     #TEMP2
      JU    M006
M00e: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      AW    
      INVI  
      T     #TEMP12
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      OW    
      L     #TEMP12
      AW    
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #TEMP0
      L     MB   101
      T     #TEMP1
      L     MB   102
      T     #TEMP2
      L     #TEMP4
      LAR1  
      JU    M006
M011: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      -I    
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #TEMP0
      L     MB   101
      T     #TEMP1
      L     MB   102
      T     #TEMP2
      L     #TEMP4
      LAR1  
      JU    M006
M012: L     #TEMP15
      INC   1
      T     #TEMP15
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      ==I   
      JCN   M013
      JU    M014
M013: L     P#DBX 0.0
      LAR1  
      T     #TEMP4
      L     B#16#0
      T     #TEMP6
      JU    M006
M014: L     #TEMP4
      LAR1  
      L     #TEMP13
      L     L#1
      +I    
      T     #TEMP13
      JU    M006
M006: L     #TEMP0
      T     MB   100
      L     #TEMP1
      T     MB   101
      L     #TEMP2
      T     MB   102
      +AR1  P#1.0
      L     #TEMP6
      +     1
      T     #TEMP6
      JU    M005
M010: L     P#DBX 0.0
      LAR1  
      L     0
      T     #TEMP6
      TAR1  #TEMP4
M005: TAR1  #TEMP4
      CLR   
      =     #TEMP16
      L     #TEMP13
      L     L#20
      ==I   
      S     #TEMP16
      L     #TEMP15
      ==I   
      A     #TEMP16
      JC    M017
      L     #TEMP13
      L     L#20
      <I    
      S     #TEMP16
      L     #TEMP15
      ==I   
      A     #TEMP16
      JC    M018
      JU    M019
M017: SET   
      =     #TEMP14
      JU    M016
M018: CLR   
      =     #TEMP14
      JU    M016
M019: CLR   
      O     #TEMP14
      =     #RET_VAL
      JU    M015
M016: CLR   
      O     #TEMP14
      =     #RET_VAL

कोड बराच मोठा आहे आणि STL बद्दल अपरिचित असलेल्या व्यक्तीला तो क्लिष्ट वाटू शकतो. या लेखाच्या चौकटीत प्रत्येक सूचनांचे विश्लेषण करण्यात काही अर्थ नाही; STL भाषेच्या तपशीलवार सूचना आणि क्षमता संबंधित मॅन्युअलमध्ये आढळू शकतात: S7-300 आणि S7-400 प्रोग्रामिंगसाठी स्टेटमेंट लिस्ट (STL).. येथे मी प्रक्रिया केल्यानंतर समान कोड सादर करेन - लेबले आणि व्हेरिएबल्सचे नाव बदलणे आणि ऑपरेशन अल्गोरिदम आणि काही STL भाषा रचनांचे वर्णन करणार्या टिप्पण्या जोडणे. मला ताबडतोब लक्षात घ्या की प्रश्नातील ब्लॉकमध्ये व्हर्च्युअल मशीन आहे जे DB100 ब्लॉकमध्ये स्थित काही बायकोड कार्यान्वित करते, ज्याची सामग्री आम्हाला माहित आहे. व्हर्च्युअल मशीन सूचनांमध्ये ऑपरेटिंग कोडचे 1 बाइट आणि वितर्कांचे बाइट्स, प्रत्येक वितर्कासाठी एक बाइट असते. सर्व विचारात घेतलेल्या सूचनांमध्ये दोन युक्तिवाद आहेत; मी त्यांची मूल्ये X आणि Y म्हणून टिप्पण्यांमध्ये नियुक्त केली आहेत.

प्रक्रिया केल्यानंतर कोड]

# Инициализация различных переменных
      L     B#16#0
      T     #CHECK_N        # Счетчик успешно пройденных проверок
      T     #COUNTER_N      # Счетчик общего количества проверок
      L     P#DBX 0.0
      T     #POINTER        # Указатель на текущую инструкцию
      CLR   
      =     #PRE_RET_VAL

# Основной цикл работы интерпретатора байт-кода
LOOP: L     #POINTER
      LAR1  
      OPN   DB   100
      L     DBLG
      TAR1  
      <=D                   # Проверка выхода указателя за пределы программы
      JC    FINISH
      L     DW#16#0
      T     #REG0
      L     #TEMP6
      L     W#16#0
      <>I   
      JC    M00d
      L     P#DBX 0.0
      LAR1  

# Конструкция switch - case для обработки различных опкодов
M00d: L     B [AR1,P#0.0]
      T     #OPCODE
      L     W#16#1
      ==I   
      JC    OPCODE_1
      L     #OPCODE
      L     W#16#2
      ==I   
      JC    OPCODE_2
      L     #OPCODE
      L     W#16#3
      ==I   
      JC    OPCODE_3
      L     #OPCODE
      L     W#16#4
      ==I   
      JC    OPCODE_4
      L     #OPCODE
      L     W#16#5
      ==I   
      JC    OPCODE_5
      L     #OPCODE
      L     W#16#6
      ==I   
      JC    OPCODE_6
      JU    OPCODE_OTHER

# Обработчик опкода 01: загрузка значения из DB101[X] в регистр Y
# OP01(X, Y): REG[Y] = DB101[X]
OPCODE_1: +AR1  P#1.0
      L     P#DBX 0.0
      LAR2  
      L     B [AR1,P#0.0]   # Загрузка аргумента X (индекс в DB101)
      L     C#8
      *I    
      +AR2  
      +AR1  P#1.0
      L     B [AR1,P#0.0]   # Загрузка аргумента Y (индекс регистра)
      JL    M003            # Аналог switch - case на основе значения Y
      JU    M001            # для выбора необходимого регистра для записи.
      JU    M002            # Подобные конструкции используются и в других
      JU    M004            # операциях ниже для аналогичных целей
M003: JU    LOOPEND
M001: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG0           # Запись значения DB101[X] в REG[0]
      JU    PRE_LOOPEND
M002: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG1           # Запись значения DB101[X] в REG[1]
      JU    PRE_LOOPEND
M004: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG2           # Запись значения DB101[X] в REG[2]
      JU    PRE_LOOPEND

# Обработчик опкода 02: загрузка значения X в регистр Y
# OP02(X, Y): REG[Y] = X
OPCODE_2: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP3
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M009
      JU    M00b
      JU    M00a
      JU    M00c
M009: JU    LOOPEND
M00b: L     #TEMP3
      T     #REG0
      JU    PRE_LOOPEND
M00a: L     #TEMP3
      T     #REG1
      JU    PRE_LOOPEND
M00c: L     #TEMP3
      T     #REG2
      JU    PRE_LOOPEND

# Опкод 03 не используется в программе, поэтому пропустим его
...

# Обработчик опкода 04: сравнение регистров X и Y
# OP04(X, Y): REG[0] = 0; REG[X] = (REG[X] == REG[Y])
OPCODE_4: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7          # первый аргумент - X
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          # REG[X]
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9          # REG[X]
      LAR2  #TEMP10         # REG[Y]
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      AW    
      INVI  
      T     #TEMP12         # ~(REG[Y] & REG[X])
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      OW    
      L     #TEMP12
      AW                    # (~(REG[Y] & REG[X])) & (REG[Y] | REG[X]) - аналог проверки на равенство
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #REG0
      L     MB   101
      T     #REG1
      L     MB   102
      T     #REG2
      L     #POINTER
      LAR1  
      JU    PRE_LOOPEND

# Обработчик опкода 05: вычитание регистра Y из X
# OP05(X, Y): REG[0] = 0; REG[X] = REG[X] - REG[Y]
OPCODE_5: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          # REG[X]
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      -I                    # ACCU1 = ACCU2 - ACCU1, REG[X] - REG[Y]
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #REG0
      L     MB   101
      T     #REG1
      L     MB   102
      T     #REG2
      L     #POINTER
      LAR1  
      JU    PRE_LOOPEND

# Обработчик опкода 06: инкремент #CHECK_N при равенстве регистров X и Y
# OP06(X, Y): #CHECK_N += (1 if REG[X] == REG[Y] else 0)
OPCODE_6: L     #COUNTER_N
      INC   1
      T     #COUNTER_N
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7          #  REG[X]     
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          #  REG[X]  
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9          # REG[Y]
      LAR2  #TEMP10         # REG[X]
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      ==I   
      JCN   M013
      JU    M014
M013: L     P#DBX 0.0
      LAR1  
      T     #POINTER
      L     B#16#0
      T     #TEMP6
      JU    PRE_LOOPEND
M014: L     #POINTER
      LAR1  
# Инкремент значения #CHECK_N
      L     #CHECK_N
      L     L#1
      +I    
      T     #CHECK_N
      JU    PRE_LOOPEND

PRE_LOOPEND: L     #REG0
      T     MB   100
      L     #REG1
      T     MB   101
      L     #REG2
      T     MB   102
      +AR1  P#1.0
      L     #TEMP6
      +     1
      T     #TEMP6
      JU    LOOPEND

OPCODE_OTHER: L     P#DBX 0.0
      LAR1  
      L     0
      T     #TEMP6
      TAR1  #POINTER

LOOPEND: TAR1  #POINTER
      CLR   
      =     #TEMP16
      L     #CHECK_N
      L     L#20
      ==I   
      S     #TEMP16
      L     #COUNTER_N
      ==I   
      A     #TEMP16
# Все проверки пройдены, если #CHECK_N == #COUNTER_N == 20
      JC    GOOD
      L     #CHECK_N
      L     L#20
      <I    
      S     #TEMP16
      L     #COUNTER_N
      ==I   
      A     #TEMP16
      JC    FAIL
      JU    M019
GOOD: SET   
      =     #PRE_RET_VAL
      JU    FINISH
FAIL: CLR   
      =     #PRE_RET_VAL
      JU    FINISH
M019: CLR   
      O     #PRE_RET_VAL
      =     #RET_VAL
      JU    LOOP
FINISH: CLR   
      O     #PRE_RET_VAL
      =     #RET_VAL

व्हर्च्युअल मशीनच्या सूचनांची कल्पना आल्यावर, DB100 ब्लॉकमध्ये बायकोड पार्स करण्यासाठी एक लहान डिसेम्बलर लिहू:

import string
alph = string.ascii_letters + string.digits

with open('DB100.bin', 'rb') as f:
    m = f.read()

pc = 0

while pc < len(m):
    op = m[pc]
    if op == 1:
        print('R{} = DB101[{}]'.format(m[pc + 2], m[pc + 1]))
        pc += 3
    elif op == 2:
        c = chr(m[pc + 1])
        c = c if c in alph else '?'
        print('R{} = {:02x} ({})'.format(m[pc + 2], m[pc + 1], c))
        pc += 3
    elif op == 4:
        print('R0 = 0; R{} = (R{} == R{})'.format(
            m[pc + 1], m[pc + 1], m[pc + 2]))
        pc += 3
    elif op == 5:
        print('R0 = 0; R{} = R{} - R{}'.format(
            m[pc + 1], m[pc + 1], m[pc + 2]))
        pc += 3
    elif op == 6:
        print('CHECK (R{} == R{})n'.format(
            m[pc + 1], m[pc + 2]))
        pc += 3
    else:
        print('unk opcode {}'.format(op))
        break

परिणामी, आम्हाला खालील आभासी मशीन कोड मिळतो:

व्हर्च्युअल मशीन कोड

R1 = DB101[0]
R2 = 6e (n)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[1]
R2 = 10 (?)
R0 = 0; R1 = R1 - R2
R2 = 20 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[2]
R2 = 77 (w)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[3]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[4]
R2 = 75 (u)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[5]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[6]
R2 = 34 (4)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[7]
R2 = 26 (?)
R0 = 0; R1 = R1 - R2
R2 = 4c (L)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[8]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[9]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[10]
R2 = 37 (7)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[11]
R2 = 22 (?)
R0 = 0; R1 = R1 - R2
R2 = 46 (F)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[12]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[13]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[14]
R2 = 6d (m)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[15]
R2 = 11 (?)
R0 = 0; R1 = R1 - R2
R2 = 23 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[16]
R2 = 35 (5)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[17]
R2 = 12 (?)
R0 = 0; R1 = R1 - R2
R2 = 25 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[18]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[19]
R2 = 26 (?)
R0 = 0; R1 = R1 - R2
R2 = 4c (L)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

तुम्ही बघू शकता, हा प्रोग्राम डीबी 101 वरून विशिष्ट मूल्याच्या समानतेसाठी प्रत्येक वर्ण तपासतो. सर्व चेक पास करण्याची अंतिम ओळ आहे: n0w u 4r3 7h3 m4573r. जर ही ओळ ब्लॉक DB101 मध्ये ठेवली असेल, तर मॅन्युअल PLC नियंत्रण सक्रिय केले जाईल आणि फुगा फुटणे किंवा डिफ्लेट करणे शक्य होईल. 

इतकंच! अॅलेक्सीने औद्योगिक निन्जासाठी योग्य उच्च पातळीचे ज्ञान प्रदर्शित केले :) आम्ही विजेत्याला संस्मरणीय बक्षिसे पाठवली. सर्व सहभागींना खूप खूप धन्यवाद!

स्त्रोत: www.habr.com

इंडस्ट्रियल निन्जाच्या पावलावर पाऊल ठेवून: पॉझिटिव्ह हॅक डेज 9 वर पीएलसी कसे हॅक केले गेले

प्रारंभिक विश्लेषण

ट्रॅफिक डंपमधून सिग्नल प्रोसेसिंग ब्लॉक्स काढणे

ब्लॉक्समधून मानवी-वाचनीय सूचना मिळवणे

रिव्हर्स ब्लॉक FC3

एक टिप्पणी जोडा Отменить ответ