Telegram v 2.0 वरून Mikrotik स्क्रिप्ट्सचे दूरस्थ सक्षमीकरण

सर्वांना उशीरा सुट्टीच्या शुभेच्छा. ही थीम चांगली आहे मी 2016 मध्ये जे लिहिले त्याची आवृत्ती येथे आहे.

सर्वसाधारणपणे, ऑपरेशनचे तत्त्व बदललेले नाही, फरक एवढाच आहे की आता ते विलंब न करता त्वरित कार्य करते.

आम्ही स्क्रिप्ट Mikrotik वर अपलोड करतो, BotID आणि ChatID आमच्या स्वतःमध्ये बदलतो आणि त्यासाठी वेळापत्रक तयार करतो. स्टार्टअपसाठी "प्रारंभ वेळ" पॅरामीटर सेट करा (स्टार्टअपवर स्क्रिप्ट चालवा.)
"मध्यांतर": 00:00:00
अन्यथा, सर्वकाही जसे होते.

टेलिग्राम-v2

:delay 10
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;
:local chatId 0;
:local messageId 0;


:local parse do={
  :local startLoc ([:find $content $variable -1] + [:len $variable] + 2);
  :local commaLoc ([:find $content "," $startLoc] - 1 + 1);
  :local braceLoc ([:find $content "}" $startLoc] - 1 + 1);
  :local endLoc $commaLoc;
  :local startSymbol [:pick $content $startLoc]
  :if ($braceLoc != 0 and ($commaLoc = 0 or $braceLoc < $commaLoc)) do={
    :set endLoc $braceLoc;
  };
  :if ($startSymbol = "{") do={
    :set endLoc ($braceLoc + 1);
  };
  :if ($quotas = true) do={
    :set startLoc ($startLoc + 1);
    :set endLoc ($endLoc - 1);
  }
  :if ($endLoc < $startLoc) do={
    :set endLoc ($startLoc + 1);
  };
  :local message [:pick $content $startLoc $endLoc]
  #:log info $message;
  :return $message;
}


:while ( true ) do={
  :do {
    #:log info "https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60";
    :tool fetch url=("https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60") dst-path="getUpdates";
    :local content [/file get [/file find name=getUpdates] contents] ;
    #:log info $content;
    :if ([:len $content] > 30) do={
      :set messageId ([$parse content=$content variable="update_id"] + 1)
      :local message [$parse content=$content variable="text" quotas=true]
      :local chat [$parse content=$content variable="chat"]
      :local chatId [$parse content=$chat variable="id"]      
      
      :if (($chatId = $myChatID) and ([/system script find name=$message] != "")) do={
        :system script run $message;
      } else={
        :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$chatId&text=$mtIdentity: Unknown command: $message") keep-result=no
      }
    }
  } on-error={}
};

काही वर्षांच्या वापरानंतर, एक बग सापडला: काही अज्ञात कारणास्तव, कमकुवत मिक्रोटिक स्क्रिप्ट थांबवते, परंतु अधिक शक्तिशाली लोकांवर ते न थांबता कार्य करते.

या हेतूंसाठी, मी वॉचडॉग क्रॅचवर फेकले. येथे आपण स्क्रिप्टचे नाव वर दर्शविलेल्या नावावर बदलतो. आणि रीस्टार्ट मध्यांतर 5 मिनिटांवर सेट करा. दर 5 मिनिटांनी आमचा "वॉचडॉग" स्क्रिप्ट तपासेल आणि जर ते कार्य करत नसेल तर ते ते चालवेल.

WatchDogT.me

:global scriptname "t.me"
:if ([:len [/system script job find script=$"scriptname"]] > 0) do={
:log info "$scriptname Already Running - killing old script before continuing"
:foreach counter in=[/system script job find script=$"scriptname"] do={
/system script job remove $counter
}
}
/system script run $scriptname

बरं, मिष्टान्नसाठी, स्क्रिप्ट मिक्रोटिक फोरममधून घेतली गेली होती.
लॉगमधून आमच्या कार्टवर महत्त्वाचे विषय पाठवते.

आम्ही शेड्यूल करण्यासाठी स्क्रिप्ट जोडतो आणि दर 5 मिनिटांनी रीस्टार्ट मध्यांतर निर्दिष्ट करतो, BotID आणि ChatID आमच्या स्वतःमध्ये बदलतो.

सूचना-लॉग

:global lastTime
:global output
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;

:local LogGet [ :toarray [ /log find topics~"critical" || message~"login failure" || message~"[Ff]ailure" ] ] ;
:local LogtLineCount [ :len $LogGet ] ;
if ($LogtLineCount > 0) do={
   :local currentTime "$[ /log get [ :pick $LogGet ($LogtLineCount -1) ] time ]";
   :if ([:len $currentTime] = 10 ) do={
      :set currentTime [ :pick $currentTime 0 10 ];
   }
   :set output "$currentTime - $[/log get [ :pick $LogGet ($LogtLineCount-1) ] message ]";
   :if (([:len $lastTime] < 1) || (([:len $lastTime] > 0) && ($lastTime != $currentTime))) do={
      :set lastTime $currentTime ;
         :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$myChatID&text="$mtIdentity" :  $output") keep-result=no
   }
}

आम्हाला परिणाम मिळतो:

स्त्रोत: www.habr.com