Semasa kami menyelidiki topik tentang cara produk 1C berfungsi dalam persekitaran Linux, satu kelemahan ditemui - kekurangan alat berbilang platform grafik yang mudah untuk mengurus kelompok pelayan 1C. Dan ia telah memutuskan untuk membetulkan kelemahan ini dengan menulis GUI untuk utiliti konsol rac. Tcl/tk dipilih sebagai bahasa pembangunan sebagai, pada pendapat saya, yang paling sesuai untuk tugasan ini. Oleh itu, saya ingin membentangkan beberapa aspek menarik penyelesaian dalam bahan ini.
Untuk bekerja, anda memerlukan pengedaran tcl/tk dan 1C. Dan kerana saya memutuskan untuk memanfaatkan sepenuhnya keupayaan penghantaran tcl/tk asas tanpa menggunakan pakej pihak ketiga, saya memerlukan versi 8.6.7, yang termasuk ttk - pakej dengan elemen grafik tambahan, yang mana kami memerlukan ttk. ::TreeView, ia membenarkan paparan data dalam bentuk struktur pokok dan dalam bentuk jadual (senarai). Juga, dalam versi baharu, kerja dengan pengecualian telah diolah semula (arahan cuba, yang digunakan dalam projek semasa menjalankan arahan luaran).
Projek ini terdiri daripada beberapa fail (walaupun tiada yang menghalang anda daripada melakukan segala-galanya dalam satu):
rac_gui.cfg - konfigurasi lalai
rac_gui.tcl - skrip pelancaran utama
Direktori lib mengandungi fail yang dimuatkan secara automatik pada permulaan:
function.tcl - fail dengan prosedur
gui.tcl - antara muka grafik utama
images.tcl - perpustakaan imej base64
Fail rac_gui.tcl, sebenarnya, memulakan penterjemah, memulakan pembolehubah, memuatkan modul, konfigurasi dan sebagainya. Kandungan fail dengan ulasan:
rac_gui.tcl
#!/bin/sh
exec wish "$0" -- "$@"
# Устанавливаем текущий каталог
set dir(root) [pwd]
# Устанавливаем рабочий каталог, если его нет то создаём
set dir(work) [file join $env(HOME) .rac_gui]
if {[file exists $dir(work)] == 0 } {
file mkdir $dir(work)
}
# каталог с модулями
set dir(lib) "[file join $dir(root) lib]"
# загружаем пользовательский конфиг, если он отсутствует, то копируем дефолтный
if {[file exists [file join $dir(work) rac_gui.cfg]] ==0} {
file copy [file join [pwd] rac_gui.cfg] [file join $dir(work) rac_gui.cfg]
}
source [file join $dir(work) rac_gui.cfg]
# Код проверки наличия rac и правильности указания пути в конфиге
# если программа не найдена то будет выведен диалог для указания корректного пути
# и этот путь будет записан в пользовательский конфиг
if {[file exists $rac_cmd] == 0} {
set rac_cmd [tk_getOpenFile -initialdir $env(HOME) -parent . -title "Укажите путь до rac" -initialfile rac]
file copy [file join $dir(work) rac_gui.cfg] [file join $dir(work) rac_gui.cfg.bak]
set orig_file [open [file join $dir(work) rac_gui.cfg.bak] "r"]
set file [open [file join $dir(work) rac_gui.cfg] "w"]
while {[gets $orig_file line] >=0 } {
if {[string match "set rac_cmd*" $line]} {
puts $file "set rac_cmd $rac_cmd"
} else {
puts $file $line
}
}
close $file
close $orig_file
#return "$host:$port"
file delete [file join $dir(work) 1c_srv.cfg.bak]
} else {
puts "Found $rac_cmd"
}
set cluster_user ""
set cluster_pwd ""
set agent_user ""
set agent_pwd ""
## LOAD FILE ##
# Загружаем модули кроме gui.tcl так как его надо загрузить последним
foreach modFile [lsort [glob -nocomplain [file join $dir(lib) *.tcl]]] {
if {[file tail $modFile] ne "gui.tcl"} {
source $modFile
puts "Loaded module $modFile"
}
}
source [file join $dir(lib) gui.tcl]
source [file join $dir(work) rac_gui.cfg]
# Читаем файл со списком серверов 1С
# и добавляем в дерево
if [file exists [file join $dir(work) 1c_srv.cfg]] {
set f [open [file join $dir(work) 1c_srv.cfg] "RDONLY"]
while {[gets $f line] >=0} {
.frm_tree.tree insert {} end -id "server::$line" -text "$line" -values "$line"
}
}Selepas memuat turun semua yang diperlukan dan menyemak kehadiran utiliti rac, tetingkap grafik akan dilancarkan. Antara muka program terdiri daripada tiga elemen:
Bar alat, pokok dan senarai
Saya membuat kandungan "pokok" sama seperti yang mungkin dengan peralatan Windows standard dari 1C.
Kod utama yang membentuk tetingkap ini terkandung dalam fail
lib/gui.tcl
# установка размера и положения основного окна
# можно установить в переменную topLevelGeometry в конфиг программы
if {[info exists topLevelGeometry]} {
wm geometry . $topLevelGeometry
} else {
wm geometry . 1024x768
}
# Заголовок окна
wm title . "1C Rac GUI"
wm iconname . "1C Rac Gui"
# иконка окна (берется из файла lib/imges.tcl)
wm iconphoto . tcl
wm protocol . WM_DELETE_WINDOW Quit
wm overrideredirect . 0
wm positionfrom . user
ttk::style theme use clam
# Панель инсрументов
set frm_tool [frame .frm_tool]
pack $frm_tool -side left -fill y
ttk::panedwindow .panel -orient horizontal -style TPanedwindow
pack .panel -expand true -fill both
pack propagate .panel false
ttk::button $frm_tool.btn_add -command Add -image add_grey_32
ttk::button $frm_tool.btn_del -command Del -image del_grey_32
ttk::button $frm_tool.btn_edit -command Edit -image edit_grey_32
ttk::button $frm_tool.btn_quit -command Quit -image quit_grey_32
pack $frm_tool.btn_add $frm_tool.btn_del $frm_tool.btn_edit -side top -padx 5 -pady 5
pack $frm_tool.btn_quit -side bottom -padx 5 -pady 5
# Дерево с полосами прокрутки
set frm_tree [frame .frm_tree]
ttk::scrollbar $frm_tree.hsb1 -orient horizontal -command [list $frm_tree.tree xview]
ttk::scrollbar $frm_tree.vsb1 -orient vertical -command [list $frm_tree.tree yview]
set tree [ttk::treeview $frm_tree.tree -show tree
-xscrollcommand [list $frm_tree.hsb1 set] -yscrollcommand [list $frm_tree.vsb1 set]]
grid $tree -row 0 -column 0 -sticky nsew
grid $frm_tree.vsb1 -row 0 -column 1 -sticky nsew
grid $frm_tree.hsb1 -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_tree 0 -weight 1
grid rowconfigure $frm_tree 0 -weight 1
# назначение обработчика нажатия кнопкой мыши
bind $frm_tree.tree <ButtonRelease> "TreePress $frm_tree.tree"
# Список для данных (таблица)
set frm_work [frame .frm_work]
ttk::scrollbar $frm_work.hsb -orient horizontal -command [list $frm_work.tree_work xview]
ttk::scrollbar $frm_work.vsb -orient vertical -command [list $frm_work.tree_work yview]
set tree_work [
ttk::treeview $frm_work.tree_work
-show headings -columns "par val" -displaycolumns "par val"
-xscrollcommand [list $frm_work.hsb set]
-yscrollcommand [list $frm_work.vsb set]
]
# Установка цветов для чередования в таблице
$tree_work tag configure dark -background $color(dark_table_bg)
$tree_work tag configure light -background $color(light_table_bg)
# Размещение элементов на форме
grid $tree_work -row 0 -column 0 -sticky nsew
grid $frm_work.vsb -row 0 -column 1 -sticky nsew
grid $frm_work.hsb -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_work 0 -weight 1
grid rowconfigure $frm_work 0 -weight 1
pack $frm_tree $frm_work -side left -expand true -fill both
#.panel add $frm_tool -weight 1
.panel add $frm_tree -weight 1
.panel add $frm_work -weight 1
Algoritma untuk bekerja dengan program adalah seperti berikut:
1. Mula-mula, anda perlu menambah pelayan kluster utama (iaitu, pelayan pengurusan kluster (dalam Linux, pengurusan dilancarkan dengan arahan “/opt/1C/v8.3/x86_64/ras cluster —daemon”)).
Untuk melakukan ini, klik pada butang "+" dan dalam tetingkap yang terbuka, masukkan alamat pelayan dan port:
Selepas itu, pelayan kami akan muncul dalam pepohon dengan mengklik padanya, senarai kluster akan dibuka atau ralat sambungan akan dipaparkan.
2. Mengklik pada nama kluster akan membuka senarai fungsi yang tersedia untuknya.
3. ...
Dan seterusnya, i.e. untuk menambah kluster baharu, pilih mana-mana yang tersedia dalam senarai dan tekan butang “+” dalam bar alat dan dialog tambah baharu akan dipaparkan:
Butang dalam bar alat melaksanakan fungsi bergantung pada konteks, i.e. Bergantung pada elemen pokok atau senarai yang dipilih, satu atau prosedur lain akan dilakukan.
Mari lihat contoh butang tambah (“+”):
Kod penjanaan butang:
ttk::button $frm_tool.btn_add -command Add -image add_grey_32Di sini kita melihat bahawa apabila butang ditekan, prosedur "Tambah" akan dilaksanakan, kodnya:
proc Add {} {
global active_cluster host
# Определяем идентификатор выделенного элемента
set id [.frm_tree.tree selection]
# Определяем значение этого элемента
set values [.frm_tree.tree item [.frm_tree.tree selection] -values]
set key [lindex [split $id "::"] 0]
# в зависимости от того что выделили будет запущена нужная процедура
if {$key eq "" || $key eq "server"} {
set host [ Add::server ]
return
}
Add::$key .frm_tree.tree $host $values
}Berikut ialah salah satu kelebihan tickle: anda boleh lulus nilai pembolehubah sebagai nama prosedur:
Add::$key .frm_tree.tree $host $valuesIaitu, sebagai contoh, jika kita menunjuk pada pelayan utama dan tekan "+", maka prosedur Add::server akan dilancarkan, jika di cluster - Add::cluster dan seterusnya (saya akan menulis tentang di mana "kunci" yang diperlukan datang dari sedikit di bawah), prosedur yang disenaraikan melukis elemen grafik yang sesuai dengan konteks.
Seperti yang anda mungkin telah perhatikan, borang adalah serupa dalam gaya - ini tidak menghairankan, kerana ia dipaparkan oleh satu prosedur, lebih tepatnya bingkai utama borang (tetingkap, butang, imej, label), nama prosedur AddTopLevel
proc AddToplevel {lbl img {win_name .add}} {
set cmd "destroy $win_name"
if [winfo exists $win_name] {destroy $win_name}
toplevel $win_name
wm title $win_name $lbl
wm iconphoto $win_name tcl
# метка с иконкой
ttk::label $win_name.lbl -image $img
# фрейм с полями ввода
set frm [ttk::labelframe $win_name.frm -text $lbl -labelanchor nw]
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
# фрейм и кнопки
set frm_btn [frame $win_name.frm_btn -border 0]
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }
ttk::button $frm_btn.btn_cancel -command $cmd -image quit_grey_24
grid $win_name.lbl -row 0 -column 0 -sticky nw -padx 5 -pady 10
grid $frm -row 0 -column 1 -sticky nw -padx 5 -pady 5
grid $frm_btn -row 1 -column 1 -sticky se -padx 5 -pady 5
pack $frm_btn.btn_cancel -side right
pack $frm_btn.btn_ok -side right -padx 10
return $frm
}
Parameter panggilan: tajuk, nama imej untuk ikon daripada pustaka (lib/images.tcl) dan parameter nama tetingkap pilihan (default .add). Oleh itu, jika kita mengambil contoh di atas untuk menambah pelayan dan kluster utama, panggilan akan sewajarnya:
AddToplevel "Добавление основного сервера" server_grey_64atau
AddToplevel "Добавление кластера" cluster_grey_64Nah, meneruskan dengan contoh ini, saya akan menunjukkan prosedur yang memaparkan dialog tambah untuk pelayan atau kelompok.
Tambah::pelayan
proc Add::server {} {
global default
# выводим основную форму
set frm [AddToplevel "Добавление основного сервера" server_grey_64]
# добавляем етки и поля ввода на эту форму
label $frm.lbl_host -text "Адрес сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
#set frm_btn [frame .add.frm_btn -border 0]
# переопределяем обработчик нажатия кнопки
.add.frm_btn.btn_ok configure -command {
set host [SaveMainServer [.add.frm.ent_host get] [.add.frm.ent_port get]]
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"
destroy .add
return $host
}
return $frm
}Tambah::kluster
proc Add::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes
agent_user agent_pwd cluster_user cluster_pwd auth_agent
if {$agent_user ne "" && $agent_pwd ne ""} {
set auth_agent "--agent-user=$agent_user --agent-pwd=$agent_pwd"
} else {
set auth_agent ""
}
# устанавливаем глобальные переменные ()
set lifetime_limit $default(lifetime_limit)
set expiration_timeout $default(expiration_timeout)
set session_fault_tolerance_level $default(session_fault_tolerance_level)
set max_memory_size $default(max_memory_size)
set max_memory_time_limit $default(max_memory_time_limit)
set errors_count_threshold $default(errors_count_threshold)
set security_level [lindex $default(security_level) 0]
set load_balancing_mode [lindex $default(load_balancing_mode) 0]
set frm [AddToplevel "Добавление кластера" cluster_grey_64]
label $frm.lbl_host -text "Адрес основного сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
label $frm.lbl_name -text "Название кластера"
entry $frm.ent_name
label $frm.lbl_secure_connect -text "Защищённое соединение"
ttk::combobox $frm.cb_security_level -textvariable security_level -values $default(security_level)
label $frm.lbl_expiration_timeout -text "Останавливать выключенные процессы через:"
entry $frm.ent_expiration_timeout -textvariable expiration_timeout
label $frm.lbl_session_fault_tolerance_level -text "Уровень отказоустойчивости"
entry $frm.ent_session_fault_tolerance_level -textvariable session_fault_tolerance_level
label $frm.lbl_load_balancing_mode -text "Режим распределения нагрузки"
ttk::combobox $frm.cb_load_balancing_mode -textvariable load_balancing_mode
-values $default(load_balancing_mode)
label $frm.lbl_errors_count_threshold -text "Допустимое отклонение количества ошибок сервера, %"
entry $frm.ent_errors_count_threshold -textvariable errors_count_threshold
label $frm.lbl_processes -text "Рабочие процессы:"
label $frm.lbl_lifetime_limit -text "Период перезапуска, сек."
entry $frm.ent_lifetime_limit -textvariable lifetime_limit
label $frm.lbl_max_memory_size -text "Допустимый объём памяти, КБ"
entry $frm.ent_max_memory_size -textvariable max_memory_size
label $frm.lbl_max_memory_time_limit -text "Интервал превышения допустимого объёма памяти, сек."
entry $frm.ent_max_memory_time_limit -textvariable max_memory_time_limit
label $frm.lbl_kill_problem_processes -justify left -anchor nw -text "Принудительно завершать проблемные процессы"
checkbutton $frm.check_kill_problem_processes -variable kill_problem_processes -onvalue yes -offvalue no
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_name -row 2 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_name -row 2 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_secure_connect -row 3 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_security_level -row 3 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_expiration_timeout -row 4 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_expiration_timeout -row 4 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_session_fault_tolerance_level -row 5 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_session_fault_tolerance_level -row 5 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_load_balancing_mode -row 6 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_load_balancing_mode -row 6 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_errors_count_threshold -row 7 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_errors_count_threshold -row 7 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_processes -row 8 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.lbl_lifetime_limit -row 9 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_lifetime_limit -row 9 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_size -row 10 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_size -row 10 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_time_limit -row 11 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_time_limit -row 11 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_kill_problem_processes -row 12 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.check_kill_problem_processes -row 12 -column 1 -sticky nw -padx 5 -pady 5
# переопределяем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
return $frm
}Apabila membandingkan kod prosedur ini, perbezaannya dapat dilihat dengan mata kasar; Dalam Tk, sifat elemen grafik boleh ditindih semasa pelaksanaan program menggunakan pilihan mengkonfigurasi. Sebagai contoh, arahan awal untuk memaparkan butang:
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }Tetapi dalam borang kami, arahan bergantung pada fungsi yang diperlukan:
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
Dalam contoh di atas, butang "tersumbat" memulakan prosedur untuk menambah kelompok.
Di sini adalah bernilai membuat penyelewengan ke arah bekerja dengan elemen grafik dalam Tk - untuk pelbagai elemen input data (masuk, kotak kombo, butang semak, dll.) parameter telah diperkenalkan sebagai pembolehubah teks:
entry $frm.ent_lifetime_limit -textvariable lifetime_limitPembolehubah ini ditakrifkan dalam ruang nama global dan mengandungi nilai yang dimasukkan pada masa ini. Itu. untuk mendapatkan teks yang dimasukkan dari medan, anda hanya perlu membaca nilai yang sepadan dengan pembolehubah (sudah tentu, dengan syarat ia ditakrifkan semasa mencipta elemen).
Kaedah kedua untuk mendapatkan semula teks yang dimasukkan (untuk elemen jenis entri) adalah dengan menggunakan arahan get:
.add.frm.ent_name getKedua-dua kaedah ini boleh dilihat dalam kod di atas.
Mengklik butang ini, dalam kes ini, melancarkan prosedur RunCommand dengan baris arahan yang dijana untuk menambah kelompok dari segi rac:
/opt/1C/v8.3/x86_64/rac cluster insert --host=localhost --port=1540 --name=dsdsds --expiration-timeout=0 --lifetime-limit=0 --max-memory-size=0 --max-memory-time-limit=0 --security-level=0 --session-fault-tolerance-level=0 --load-balancing-mode=performance --errors-count-threshold=0 --kill-problem-processes=no localhost:1545Sekarang kita sampai ke arahan utama, yang mengawal pelancaran rac dengan parameter yang kita perlukan, juga menghuraikan output arahan ke dalam senarai dan pulangan, jika diperlukan:
RunCommand
proc RunCommand {root par} {
global dir rac_cmd cluster work_list_row_count agent_user agent_pwd cluster_user cluster_pwd
puts "$rac_cmd $par"
set work_list_row_count 0
# открываем канал в неблокирующем режиме
# $rac - команда с полным путём
# $par - сформированные ключи запуска и опции
set pipe [open "|$rac_cmd $par" "r"]
try {
set lst ""
set l ""
# вывод команды добавляем в список списков
while {[gets $pipe line]>=0} {
#puts $line
if {$line eq ""} {
lappend l $lst
set lst ""
} else {
lappend lst [string trim $line]
}
}
close $pipe
return $l
} on error {result options} {
# Запуск обработчика ошибок
ErrorParcing $result $options
return ""
}
}Selepas memasukkan data pelayan utama, ia akan ditambahkan pada pokok, untuk ini, dalam prosedur Add:server di atas, kod berikut bertanggungjawab:
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"Sekarang, dengan mengklik pada nama pelayan dalam pepohon, kami mendapat senarai kluster yang diuruskan oleh pelayan itu, dan dengan mengklik pada kluster, kami mendapat senarai elemen kluster (pelayan, pangkalan maklumat, dll.). Ini dilaksanakan dalam prosedur TreePress (file lib/function.tcl):
proc TreePress {tree} {
global host server active_cluster infobase
# определяем выделенный элемент
set id [$tree selection]
# устанавливаем нужные глобальные переменные
SetGlobalVarFromTreeItems $tree $id
# Определяем ключ и значение, т.е. именно тип выбранного элемента
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
# и в зависимости от того что выбрали будет запущена соответствующая процедура
# в пространстве имён Run
Run::$key $tree $host $values
}Sehubungan itu, Run::server akan dilancarkan untuk pelayan utama (untuk kluster - Run::cluster, untuk pelayan yang berfungsi - Run::work_server, dsb.). Itu. nilai pembolehubah $key adalah sebahagian daripada nama elemen pokok yang ditentukan oleh pilihan -ID.
Mari kita perhatikan prosedur
Jalankan::server
proc Run::server {tree host values} {
# получаем список кластеров требуемого сервера
set lst [RunCommand server::$host "cluster list $host"]
if {$lst eq ""} {return}
set l [lindex $lst 0]
#puts $lst
# удаляем лишнее из списка
.frm_work.tree_work delete [ .frm_work.tree_work children {}]
# читаем список
foreach cluster_list $lst {
# Заполняем список полученными значениями
InsertItemsWorkList $cluster_list
# обрабатываем вывод (список) для добавления данных в дерево
foreach i $cluster_list {
#puts $i
set cluster_list [split $i ":"]
if {[string trim [lindex $cluster_list 0]] eq "cluster"} {
set cluster_id [string trim [lindex $cluster_list 1]]
lappend cluster($cluster_id) $cluster_id
}
if {[string trim [lindex $cluster_list 0]] eq "name"} {
lappend cluster($cluster_id) [string trim [lindex $cluster_list 1]]
}
}
}
# добавляем кластеры в дерево
foreach x [array names cluster] {
set id [lindex $cluster($x) 0]
if { [$tree exists "cluster::$id"] == 0 } {
$tree insert "server::$host" end -id "cluster::$id" -text "[lindex $cluster($x) 1]" -values "$id"
# добавляем элементы в кластер
InsertClusterItems $tree $id
}
}
if { [$tree exists "agent_admins::$id"] == 0 } {
$tree insert "server::$host" end -id "agent_admins::$id" -text "Администраторы" -values "$id"
#InsertClusterItems $tree $id
}
}Prosedur ini memproses apa yang diterima daripada pelayan melalui arahan RunCommand dan menambah semua jenis perkara pada pokok - kelompok, pelbagai elemen akar (asas, pelayan yang berfungsi, sesi, dan sebagainya). Jika anda melihat dengan teliti, anda akan melihat panggilan ke prosedur InsertItemsWorkList di dalam. Ia digunakan untuk menambah elemen pada senarai grafik dengan memproses output utiliti konsol rac, yang sebelum ini dikembalikan sebagai senarai kepada pembolehubah $lst. Ini ialah senarai senarai yang mengandungi pasangan elemen yang dipisahkan oleh titik bertindih.
Sebagai contoh, senarai sambungan kluster:
svk@svk ~]$ /opt/1C/v8.3/x86_64/rac connection list --cluster=783d2170-56c3-11e8-c586-fc75165efbb2 localhost:1545
connection : dcf5991c-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:49:51
session-number : 0
blocked-by-ls : 0
connection : b993293a-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:48:52
session-number : 0
blocked-by-ls : 0
Dalam bentuk grafik ia akan kelihatan seperti ini:
Prosedur di atas memilih nama elemen untuk pengepala dan data untuk mengisi jadual:
InsertItemsWorkList
proc InsertItemsWorkList {lst} {
global work_list_row_count
# установка чередования цвета для строки
if [expr $work_list_row_count % 2] {
set tag dark
} else {
set tag light
}
# разбор строк на пары ключ - значение
foreach i $lst {
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
lappend column_list [string trim $param]
lappend value_list [string trim $value]
}
}
# заполнение таблицы
.frm_work.tree_work configure -columns $column_list -displaycolumns $column_list
.frm_work.tree_work insert {} end -values $value_list -tags $tag
.frm_work.tree_work column #0 -stretch
# установка заголовков
foreach j $column_list {
.frm_work.tree_work heading $j -text $j
}
incr work_list_row_count
}Di sini, bukannya perintah mudah [split $str ":"], yang membahagikan rentetan kepada elemen yang dipisahkan oleh ":" dan mengembalikan senarai, ungkapan biasa digunakan, kerana sesetengah elemen juga mengandungi titik bertindih.
Prosedur InsertClusterItems (salah satu daripada beberapa yang serupa) hanya menambah senarai elemen anak dengan pengecam yang sepadan dengan pepohon elemen gugusan yang diperlukan
InsertClusterItems
proc InsertClusterItems {tree id} {
set parent "cluster::$id"
$tree insert $parent end -id "infobases::$id" -text "Информационные базы" -values "$id"
$tree insert $parent end -id "servers::$id" -text "Рабочие серверы" -values "$id"
$tree insert $parent end -id "admins::$id" -text "Администраторы" -values "$id"
$tree insert $parent end -id "managers::$id" -text "Менеджеры кластера" -values $id
$tree insert $parent end -id "processes::$id" -text "Рабочие процессы" -values "workprocess-all"
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "sessions-all"
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "blocks-all"
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "connections-all"
$tree insert $parent end -id "profiles::$id" -text "Профили безопасности" -values $id
}
Anda boleh mempertimbangkan dua lagi pilihan untuk melaksanakan prosedur yang serupa, di mana ia akan dapat dilihat dengan jelas bagaimana anda boleh mengoptimumkan dan menyingkirkan arahan berulang:
Dalam prosedur ini, menambah dan menyemak diselesaikan secara langsung:
InsertBaseItems
proc InsertBaseItems {tree id} {
set parent "infobase::$id"
if { [$tree exists "sessions::$id"] == 0 } {
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "$id"
}
if { [$tree exists "locks::$id"] == 0 } {
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "$id"
}
if { [$tree exists "connections::$id"] == 0 } {
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "$id"
}
}
Berikut ialah pendekatan yang lebih tepat:
InsertProfileItems
proc InsertProfileItems {tree id} {
set parent "profile::$id"
set lst {
{dir "Виртуальные каталоги"}
{com "Разрешённые COM-классы"}
{addin "Внешние компоненты"}
{module "Внешние отчёты и обработки"}
{app "Разрешённые приложения"}
{inet "Ресурсы интернет"}
}
foreach i $lst {
append item [lindex $i 0] "::$id"
if { [$tree exists $item] == 0 } {
$tree insert $parent end -id $item -text [lindex $i 1] -values "$id"
}
unset item
}
}Perbezaan di antara mereka ialah penggunaan gelung, di mana perintah berulang dilaksanakan. Pendekatan mana yang hendak digunakan adalah mengikut budi bicara pembangun.
Kami telah membincangkan penambahan elemen dan mendapatkan semula data, kini tiba masanya untuk memberi tumpuan kepada pengeditan. Oleh kerana, pada asasnya, parameter yang sama digunakan untuk mengedit dan menambah (dengan pengecualian pangkalan maklumat), borang dialog yang sama digunakan. Algoritma untuk memanggil prosedur untuk menambah kelihatan seperti ini:
Tambah::$key->AddToplevel
Dan untuk mengedit seperti ini:
Edit::$key->Add::$key->AddTopLevel
Sebagai contoh, mari kita ambil pengeditan kelompok, i.e. Setelah mengklik pada nama kluster dalam pokok, tekan butang edit dalam bar alat (pensel) dan borang yang sepadan akan dipaparkan pada skrin:
Edit::kluster
proc Edit::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes active_cluster
agent_user agent_pwd cluster_user cluster_pwd auth
if {$cluster_user ne "" && $cluster_pwd ne ""} {
set auth "--cluster-user=$cluster_user --cluster-pwd=$cluster_pwd"
} else {
set auth ""
}
# рисуем форму для кластера
set frm [Add::cluster $tree $host $values]
# меняем текст на метке
$frm configure -text "Редактирование кластера"
set active_cluster $values
# получаем данные по выделенному кластеру
set lst [RunCommand cluster::$values "cluster info --cluster=$active_cluster $host"]
# заполняем поля
FormFieldsDataInsert $frm $lst
# выключаем поля, редактирование которых запрещено
$frm.ent_host configure -state disable
$frm.ent_port configure -state disable
# переназначаем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster update
--cluster=$active_cluster $auth
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth $host"
$tree delete "cluster::$active_cluster"
Run::server $tree $host ""
destroy .add
}
}Berdasarkan ulasan dalam kod, pada dasarnya, semuanya jelas, kecuali kod pengendali butang ditindih dan terdapat prosedur FormFieldsDataInsert yang mengisi medan dengan data dan memulakan pembolehubah:
FormFieldsDataInsert
proc FormFieldsDataInsert {frm lst} {
foreach i [lindex $lst 0] {
# получаем список параметров и значений
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
# меняем символы
regsub -all -- "-" [string trim $param] "_" entry_name
# заполняем данными
if [winfo exists $frm.ent_$entry_name] {
$frm.ent_$entry_name delete 0 end
$frm.ent_$entry_name insert end [string trim $value """]
}
if [winfo exists $frm.cb_$entry_name] {
global $entry_name
set $entry_name [string trim $value """]
}
# для чекбоксов меняем значения
if [winfo exists $frm.check_$entry_name] {
global $entry_name
if {$value eq "0"} {
set $entry_name no
} elseif {$value eq "1"} {
set $entry_name yes
} else {
set $entry_name $value
}
}
}
}
}
Dalam prosedur ini, satu lagi kelebihan tcl muncul - nilai pembolehubah lain digantikan sebagai nama pembolehubah. Itu. untuk mengautomasikan pengisian borang dan permulaan pembolehubah, nama medan dan pembolehubah sepadan dengan suis baris arahan utiliti rac dan nama parameter output arahan dengan beberapa pengecualian - sempang digantikan dengan garis bawah. Cth kerja-berjadual-menafikan sepadan dengan padang ent_scheduled_jobs_deny dan berubah-ubah scheduled_jobs_deny.
Borang untuk menambah dan mengedit mungkin berbeza dalam komposisi medan, contohnya, bekerja dengan pangkalan maklumat:
Menambah keselamatan maklumat
Mengedit keselamatan maklumat
Dalam prosedur penyuntingan Edit::infobase, medan yang diperlukan ditambahkan pada borang; oleh itu saya tidak membentangkannya di sini.
Dengan analogi, prosedur untuk menambah, mengedit, memadam dilaksanakan untuk elemen lain.
Memandangkan operasi utiliti itu membayangkan bilangan pelayan, kluster, pangkalan maklumat, dsb. yang tidak terhad, untuk menentukan kluster mana kepunyaan pelayan atau sistem keselamatan maklumat, beberapa pembolehubah global telah diperkenalkan, nilai yang ditetapkan setiap satu. masa anda klik pada unsur pokok. Itu. prosedur secara rekursif berjalan melalui semua elemen induk dan menetapkan pembolehubah:
SetGlobalVarFromTreeItems
proc SetGlobalVarFromTreeItems {tree id} {
global host server active_cluster infobase
set parent [$tree parent $id]
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
switch -- $key {
server {set host $values}
work_server {set server $values}
cluster {set active_cluster $values}
infobase {set infobase $values}
}
if {$parent eq ""} {
return
} else {
SetGlobalVarFromTreeItems $tree $parent
}
}
Kelompok 1C membolehkan anda bekerja dengan atau tanpa kebenaran. Terdapat dua jenis pentadbir—pentadbir ejen kluster dan pentadbir kluster. Sehubungan itu, untuk operasi yang betul, 4 lagi pembolehubah global telah diperkenalkan yang mengandungi log masuk pentadbir dan kata laluan. Itu. jika terdapat akaun pentadbir dalam kluster, dialog akan dipaparkan untuk memasukkan log masuk dan kata laluan anda, data akan disimpan dalam ingatan dan dimasukkan ke dalam setiap arahan untuk kluster yang sepadan.
Ini adalah tanggungjawab prosedur pengendalian ralat.
ErrorParcing
proc ErrorParcing {err opt} {
global cluster_user cluster_pwd agent_user agent_pwd
switch -regexp -- $err {
"Cluster administrator is not authenticated" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Central server administrator is not authenticated" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
"Администратор кластера не аутентифицирован" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Администратор центрального сервера не аутентифицирован" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
(.+) {
tk_messageBox -type ok -icon error -message "$err"
}
}
}Itu. bergantung pada apa yang dipulangkan oleh arahan, tindak balas akan sesuai.
Pada masa ini, kira-kira 95 peratus fungsi telah dilaksanakan, yang tinggal hanyalah melaksanakan kerja dengan profil keselamatan dan mengujinya =). Itu sahaja. Saya minta maaf atas cerita yang renyuk.
Kod ini tersedia secara tradisional .
Kemas kini: Saya selesai bekerja dengan profil keselamatan. Kini fungsinya 100% dilaksanakan.
Kemas kini 2: penyetempatan ke dalam bahasa Inggeris dan Rusia telah ditambah, kerja dalam win7 telah diuji
Sumber: www.habr.com