🥇CMake နှင့် C++ သည် ထာဝရညီအစ်ကိုများဖြစ်သည်

ဖွံ့ဖြိုးတိုးတက်မှုကာလအတွင်း၊ ကွန်ပလီမာများပြောင်းလဲခြင်း၊ တည်ဆောက်မုဒ်များ၊ မှီခိုဗားရှင်းများ၊ တည်ငြိမ်သောခွဲခြမ်းစိတ်ဖြာမှုများပြုလုပ်ခြင်း၊ စွမ်းဆောင်ရည်ကိုတိုင်းတာခြင်း၊ လွှမ်းခြုံမှုစုဆောင်းခြင်း၊ စာရွက်စာတမ်းများထုတ်ပေးခြင်းစသည်ဖြင့် နှစ်သက်သည်။ ပြီးတော့ ကျွန်တော် CMake ကို ကျွန်တော် အရမ်းကြိုက်တယ် ဘာလို့လဲဆိုတော့ ဒါက ကျွန်တော်လိုချင်တာမှန်သမျှ လုပ်ပေးနိုင်လို့ပါ။

CMake ကို လူတော်တော်များများက ဝေဖန်ကြပြီး မကြာခဏ ထိုက်တန်ပေမယ့် အဲဒါကိုကြည့်ရင် အရာအားလုံးက အရမ်းဆိုးတာတော့ မဟုတ်ပါဘူး၊ လုံးဝမဆိုးပါဘူး။ပြီးတော့ ဖွံ့ဖြိုးတိုးတက်ရေးရဲ့ ဦးတည်ချက်က အတော်လေး အပြုသဘောဆောင်ပါတယ်။

ဤမှတ်စုတွင်၊ အောက်ပါလုပ်ဆောင်ချက်များကိုရရှိရန် CMake စနစ်တွင် C++ တွင် ခေါင်းစီးစာကြည့်တိုက်ကို ရိုးရှင်းစွာ စုစည်းနည်းကို ပြောပြလိုပါသည်။

စည်းဝေးပွဲ;
Autorun စမ်းသပ်မှုများ;
ကုဒ်လွှမ်းခြုံတိုင်းတာခြင်း
တပ်ဆင်ခြင်း;
အလိုအလျောက်စာရွက်စာတမ်းများ;
အွန်လိုင်း sandbox မျိုးဆက်;
အငြိမ်မနေ။

C-make ရဲ့ အားသာချက်တွေကို နားလည်ပြီးသူတိုင်း ရိုးရိုးရှင်းရှင်း လုပ်နိုင်မှာပါ။ ပရောဂျက် နမူနာကို ဒေါင်းလုဒ်လုပ်ပါ။ ၎င်းကို စတင်အသုံးပြုပါ။

အတွင်းမှစီမံကိန်း

စီမံကိန်းဖွဲ့စည်းပုံ

.
├── CMakeLists.txt
├── README.en.md
├── README.md
├── doc
│   ├── CMakeLists.txt
│   └── Doxyfile.in
├── include
│   └── mylib
│       └── myfeature.hpp
├── online
│   ├── CMakeLists.txt
│   ├── mylib-example.cpp
│   └── wandbox.py
└── test
    ├── CMakeLists.txt
    ├── mylib
    │   └── myfeature.cpp
    └── test_main.cpp

CMake script များကို မည်ကဲ့သို့ စုစည်းရမည်ကို အဓိကအားဖြင့် ဆွေးနွေးသွားမည် ဖြစ်သောကြောင့် ၎င်းတို့ကို အသေးစိတ် ဆွေးနွေးပါမည်။ ကျန်ဖိုင်များကို မည်သူမဆို တိုက်ရိုက်ကြည့်ရှုနိုင်ပါသည်။ နမူနာပရောဂျက်စာမျက်နှာပေါ်တွင်.

ပင်မ CMake ဖိုင် (./CMakeLists.txt)

စီမံကိန်းအချက်အလက်

ပထမဦးစွာ၊ သင်သည် CMake စနစ်၏လိုအပ်သောဗားရှင်းကိုတောင်းဆိုရန်လိုအပ်သည်။ CMake သည် ပြောင်းလဲနေပြီး မတူညီသောအခြေအနေများတွင် အမိန့်ပေးလက်မှတ်များနှင့် အပြုအမူများ ပြောင်းလဲနေသည်။ CMake မှကျွန်ုပ်တို့လိုချင်သောအရာကိုချက်ချင်းနားလည်နိုင်ရန်၊ ၎င်းအတွက်ကျွန်ုပ်တို့၏လိုအပ်ချက်များကိုချက်ချင်းမှတ်တမ်းတင်ရန်လိုအပ်သည်။

cmake_minimum_required(VERSION 3.13)

ထို့နောက် ကျွန်ုပ်တို့၏ ပရောဂျက်၊ ၎င်း၏အမည်၊ ဗားရှင်း၊ အသုံးပြုသော ဘာသာစကားများ စသည်ဖြင့် သတ်မှတ်ပေးပါမည်။ (ကြည့်ပါ။ команду project).

ဤကိစ္စတွင်ကျွန်ုပ်တို့သည်ဘာသာစကားကိုညွှန်ပြသည်။ CXX (၎င်းသည် C++ ကိုဆိုလိုသည်) သို့မှသာ CMake သည် C language compiler ကိုရှာဖွေရာတွင် အားမကိုးဘဲ (ပုံမှန်အားဖြင့်၊ CMake တွင် ဘာသာစကားနှစ်မျိုးပါဝင်သည်- C နှင့် C++)။

project(Mylib VERSION 1.0 LANGUAGES CXX)

ဤနေရာတွင် ကျွန်ုပ်တို့၏ပရောဂျက်ကို ပရောဂျက်ခွဲတစ်ခုအနေဖြင့် အခြားပရောဂျက်တစ်ခုတွင် ထည့်သွင်းထားခြင်းရှိမရှိ ချက်ချင်းစစ်ဆေးနိုင်ပါသည်။ ဒါက အနာဂတ်မှာ အများကြီး အထောက်အကူပြုပါလိမ့်မယ်။

get_directory_property(IS_SUBPROJECT PARENT_DIRECTORY)

ပရောဂျက် ရွေးချယ်မှုများ

ငါတို့သည်ရွေးချယ်စရာနှစ်ခုပေးလိမ့်မည်။

ပထမရွေးချယ်မှုမှာ MYLIB_TESTING - ယူနစ်စမ်းသပ်မှုများကိုပိတ်ရန်။ စစ်ဆေးမှုများနှင့် ကိုက်ညီကြောင်း ကျွန်ုပ်တို့သေချာပါက ၎င်းသည် လိုအပ်နိုင်သည်၊ သို့သော် ကျွန်ုပ်တို့သည် ဥပမာအားဖြင့် ကျွန်ုပ်တို့၏ပရောဂျက်ကို ထည့်သွင်းရန် သို့မဟုတ် ထုပ်ပိုးရန်သာလိုပါသည်။ သို့မဟုတ် ကျွန်ုပ်တို့၏ပရောဂျက်ကို ပရောဂျက်ခွဲတစ်ခုအနေဖြင့် ပါဝင်သည် - ဤအခြေအနေတွင်၊ ကျွန်ုပ်တို့၏ပရောဂျက်အသုံးပြုသူများသည် ကျွန်ုပ်တို့၏စမ်းသပ်မှုများကို လုပ်ဆောင်ရန် စိတ်မဝင်စားပါ။ သင်အသုံးပြုသော မှီခိုအားထားမှုကို သင်မစမ်းသပ်ဘူးလား။

option(MYLIB_TESTING "Включить модульное тестирование" ON)

ထို့အပြင်၊ ကျွန်ုပ်တို့သည် သီးခြားရွေးချယ်မှုကို ပြုလုပ်ပါမည်။ MYLIB_COVERAGE စမ်းသပ်မှုများဖြင့် ကုဒ်လွှမ်းခြုံမှုကို တိုင်းတာရန်အတွက်၊ သို့သော် ၎င်းသည် နောက်ထပ်ကိရိယာများ လိုအပ်မည်ဖြစ်ရာ ၎င်းကို ပြတ်သားစွာ ဖွင့်ထားရန် လိုအပ်မည်ဖြစ်သည်။

option(MYLIB_COVERAGE "Включить измерение покрытия кода тестами" OFF)

စုစည်းမှု ရွေးချယ်စရာများ

ဟုတ်ပါတယ်၊ ကျွန်ုပ်တို့သည် အလွန်မိုက်သော ပရိုဂရမ်မာများဖြစ်သောကြောင့် ကျွန်ုပ်တို့သည် compile-time diagnostics ၏အမြင့်ဆုံးအဆင့်ကို compiler မှလိုချင်ပါသည်။ မောက်စ်တစ်လုံးမှ ချော်ထွက်မည်မဟုတ်ပါ။

add_compile_options(
    -Werror

    -Wall
    -Wextra
    -Wpedantic

    -Wcast-align
    -Wcast-qual
    -Wconversion
    -Wctor-dtor-privacy
    -Wenum-compare
    -Wfloat-equal
    -Wnon-virtual-dtor
    -Wold-style-cast
    -Woverloaded-virtual
    -Wredundant-decls
    -Wsign-conversion
    -Wsign-promo
)

C++ ဘာသာစကားစံနှုန်းကို အပြည့်အဝလိုက်နာရန်အတွက် တိုးချဲ့မှုများကိုလည်း ပိတ်ပါမည်။ ၎င်းတို့ကို CMake တွင် မူရင်းအတိုင်း ဖွင့်ထားသည်။

if(NOT CMAKE_CXX_EXTENSIONS)
    set(CMAKE_CXX_EXTENSIONS OFF)
endif()

မူလတန်းရည်မှန်းချက်

ကျွန်ုပ်တို့၏စာကြည့်တိုက်တွင် header files များသာပါဝင်ပြီး ဆိုလိုသည်မှာ ကျွန်ုပ်တို့တွင် static သို့မဟုတ် dynamic libraries များပုံစံတွင် မည်သည့်အိတ်ခန်းမှ မရှိပါ။ အခြားတစ်ဖက်တွင်၊ ကျွန်ုပ်တို့၏စာကြည့်တိုက်ကို ပြင်ပတွင်အသုံးပြုရန်အတွက်၊ ၎င်းကိုထည့်သွင်းရန် လိုအပ်သည်၊ ၎င်းကို စနစ်တွင်သိရှိနိုင်ပြီး သင့်ပရောဂျက်နှင့်ချိတ်ဆက်ထားရန် လိုအပ်ပြီး တစ်ချိန်တည်းမှာပင် ဤတူညီသောခေါင်းစီးများအပြင် နောက်ထပ်အချို့လည်း ဖြစ်နိုင်သည်၊ အဲဒါကို တွယ်တာတတ်ပါတယ်။

ဤရည်ရွယ်ချက်အတွက်၊ ကျွန်ုပ်တို့သည် အင်တာဖေ့စ်စာကြည့်တိုက်တစ်ခုကို ဖန်တီးသည်။

add_library(mylib INTERFACE)

ကျွန်ုပ်တို့သည် ကျွန်ုပ်တို့၏ အင်တာဖေ့စ်ဒစ်ဂျစ်တိုက်တွင် ခေါင်းစီးများကို ချိတ်ထားသည်။

ခေတ်မီ၊ ဖက်ရှင်ကျကျ၊ လူငယ်အသုံးပြုမှု CMake သည် ခေါင်းစီးများ၊ ဂုဏ်သတ္တိများ စသည်တို့ကို ဆိုလိုသည်။ တစ်ခုတည်းသောပစ်မှတ်မှတဆင့်ကူးစက်။ ဒီလောက်ဆို လုံလောက်ပါပြီ။ target_link_libraries(target PRIVATE dependency)နှင့် ပစ်မှတ်နှင့်ဆက်စပ်နေသော ခေါင်းစီးများအားလုံး dependency၊ ပစ်မှတ်နှင့်သက်ဆိုင်သော အရင်းအမြစ်များအတွက် ရနိုင်ပါမည်။ target. ပြီးတော့ မင်းဘာမှ မလိုဘူး။ [target_]include_directories. ၎င်းကို ခွဲခြမ်းစိတ်ဖြာမှုတွင် အောက်ပါအတိုင်း သရုပ်ပြပါမည်။ ယူနစ်စမ်းသပ်မှုများအတွက် CMake script.

ဒါခေါ်တာကို သတိထားရကျိုးနပ်တယ်။ выражения-генераторы: $<...>.

ဤအမိန့်သည် ကျွန်ုပ်တို့၏အင်တာဖေ့စ်ဒစ်ဂျစ်တိုက်နှင့် ကျွန်ုပ်တို့လိုအပ်သော ခေါင်းစီးများကို ဆက်စပ်ပေးကာ ကျွန်ုပ်တို့၏စာကြည့်တိုက်သည် တူညီသော CMake အထက်တန်းအဆင့်အတွင်း မည်သည့်ပစ်မှတ်နှင့်မဆို ချိတ်ဆက်ထားမည်ဆိုလျှင်၊ လမ်းညွှန်မှ ခေါင်းစီးများကို ၎င်းနှင့် ဆက်စပ်နေမည်ဖြစ်ပါသည်။ ${CMAKE_CURRENT_SOURCE_DIR}/includeနှင့် ကျွန်ုပ်တို့၏စာကြည့်တိုက်ကို စနစ်တွင်ထည့်သွင်းပြီး command ကိုအသုံးပြု၍ အခြားပရောဂျက်သို့ချိတ်ဆက်ပါက၊ find_packageထို့နောက် လမ်းညွှန်မှ ခေါင်းစီးများသည် ၎င်းနှင့် ဆက်စပ်နေမည်ဖြစ်သည်။ include တပ်ဆင်မှုလမ်းညွှန်နှင့်ဆက်စပ်။

target_include_directories(mylib INTERFACE
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:include>
)

ဘာသာစကားစံနှုန်းတစ်ခု သတ်မှတ်ကြပါစို့။ ဟုတ်ပါတယ်၊ နောက်ဆုံးတစ်ခု။ တစ်ချိန်တည်းမှာပင်၊ ကျွန်ုပ်တို့သည် စံနှုန်းကိုသာမက ကျွန်ုပ်တို့၏ စာကြည့်တိုက်ကို အသုံးပြုမည့်သူများထံသို့လည်း တိုးချဲ့ပေးပါသည်။ သတ်မှတ်ထားသောပိုင်ဆိုင်မှုတွင် အမျိုးအစားတစ်ခုရှိသည်ဟူသောအချက်ကြောင့် ၎င်းသည် အောင်မြင်သည်။ INTERFACE (CM ။ target_compile_features အမိန့်).

target_compile_features(mylib INTERFACE cxx_std_17)

ကျွန်ုပ်တို့၏စာကြည့်တိုက်အတွက် နံမည်တစ်ခုဖန်တီးကြပါစို့။ ထို့အပြင်၊ အလှအပအတွက်၊ ၎င်းသည် အထူး "namespace" တွင်ရှိလိမ့်မည်။ ကျွန်ုပ်တို့၏စာကြည့်တိုက်တွင် မတူညီသော module များပေါ်လာပြီး ၎င်းတို့ကို တစ်ခုနှင့်တစ်ခု သီးခြားချိတ်ဆက်မိသည့်အခါ ၎င်းသည် အသုံးဝင်မည်ဖြစ်သည်။ ဥပမာ Busta မှာလိုပါပဲ။.

add_library(Mylib::mylib ALIAS mylib)

ustanovka

ကျွန်ုပ်တို့၏ ခေါင်းစီးများကို စနစ်ထဲသို့ ထည့်သွင်းခြင်း။ အရာအားလုံးကဒီမှာရိုးရှင်းပါတယ်။ ခေါင်းစီးများအားလုံးပါသည့် ဖိုင်တွဲသည် လမ်းညွှန်ထဲသို့ ရောက်သွားသင့်သည်ဟု ကျွန်ုပ်တို့ပြောပါသည်။ include တပ်ဆင်တည်နေရာနှင့်ဆက်စပ်။

install(DIRECTORY include/mylib DESTINATION include)

ထို့နောက်၊ ကျွန်ုပ်တို့သည် ပြင်ပပရောဂျက်များတွင် command ကိုခေါ်ဆိုနိုင်စေရန်အတွက် တည်ဆောက်စနစ်အား အသိပေးအပ်ပါသည်။ find_package(Mylib) ပန်းတိုင်တစ်ခုရယူပါ။ Mylib::mylib.

install(TARGETS mylib EXPORT MylibConfig)
install(EXPORT MylibConfig NAMESPACE Mylib:: DESTINATION share/Mylib/cmake)

နောက်စာလုံးကို ဤနည်းဖြင့် နားလည်ရပါမည်။ Third-party ပရောဂျက်တစ်ခုတွင် ကျွန်ုပ်တို့သည် command ကိုခေါ်သည်။ find_package(Mylib 1.2.3 REQUIRED)နှင့် ထည့်သွင်းထားသည့် ဒစ်ဂျစ်တိုက်၏ အစစ်အမှန်ဗားရှင်းသည် ဗားရှင်းနှင့် ကိုက်ညီမှုမရှိပါ။ 1.2.3CMake သည် အမှားအယွင်းတစ်ခုကို အလိုအလျောက်ထုတ်ပေးလိမ့်မည်။ ဆိုလိုသည်မှာ သင်သည် ဗားရှင်းများကို ကိုယ်တိုင်ခြေရာခံရန် မလိုအပ်ပါ။

include(CMakePackageConfigHelpers)
write_basic_package_version_file("${PROJECT_BINARY_DIR}/MylibConfigVersion.cmake"
    VERSION
        ${PROJECT_VERSION}
    COMPATIBILITY
        AnyNewerVersion
)
install(FILES "${PROJECT_BINARY_DIR}/MylibConfigVersion.cmake" DESTINATION share/Mylib/cmake)

စမ်းသပ်မှုများ

အကယ်၍ စမ်းသပ်မှုများကို ပြတ်သားစွာ အသုံးပြု၍ မရပါ။ သက်ဆိုင်ရာ ရွေးချယ်မှု သို့မဟုတ် ကျွန်ုပ်တို့၏ပရောဂျက်သည် ပရောဂျက်ခွဲတစ်ခုဖြစ်သည်၊ ဆိုလိုသည်မှာ ၎င်းသည် command ကိုအသုံးပြု၍ အခြား CMake ပရောဂျက်နှင့် ချိတ်ဆက်ထားသည်။ add_subdirectory၊ ကျွန်ုပ်တို့သည် အထက်အောက် လမ်းကြောင်းအတိုင်း ဆက်လက်မရွေ့ဘဲ၊ စမ်းသပ်မှုများ ပြုလုပ်ခြင်းနှင့် လုပ်ဆောင်ခြင်းအတွက် ညွှန်ကြားချက်များကို ဖော်ပြသည့် script သည် ရိုးရှင်းစွာ မလည်ပတ်နိုင်ပါ။

if(NOT MYLIB_TESTING)
    message(STATUS "Тестирование проекта Mylib выключено")
elseif(IS_SUBPROJECT)
    message(STATUS "Mylib не тестируется в режиме подмодуля")
else()
    add_subdirectory(test)
endif()

စာရွက်စာတမ်းများ

ပရောဂျက်ခွဲတစ်ခုအတွက် စာရွက်စာတမ်းများကိုလည်း ထုတ်ပေးမည်မဟုတ်ပါ။

if(NOT IS_SUBPROJECT)
    add_subdirectory(doc)
endif()

အွန်လိုင်း sandbox

အလားတူ ပရောဂျက်ခွဲတွင်လည်း အွန်လိုင်း sandbox လည်း ရှိမည်မဟုတ်ပါ။

if(NOT IS_SUBPROJECT)
    add_subdirectory(online)
endif()

စမ်းသပ်မှု script (test/CMakeLists.txt)

စမ်းသပ်ခြင်း

ပထမဦးစွာ၊ ကျွန်ုပ်တို့သည် လိုအပ်သော စမ်းသပ်မှုဘောင်ပါရှိသည့် ပက်ကေ့ဂျ်တစ်ခုကို ရှာတွေ့သည် (သင်အကြိုက်ဆုံးတစ်ခုနှင့် အစားထိုးပါ)။

find_package(doctest 2.3.3 REQUIRED)

စမ်းသပ်မှုများဖြင့် ကျွန်ုပ်တို့၏ executable file ကို ဖန်တီးကြပါစို့။ အများအားဖြင့် ကျွန်ုပ်သည် လုပ်ဆောင်ချက်ပါဝင်မည့်ဖိုင်ကိုသာ executable binary သို့ တိုက်ရိုက်ထည့်ပါသည်။ main.

add_executable(mylib-unit-tests test_main.cpp)

ပြီးတော့ စာမေးပွဲတွေကိုယ်တိုင်က နောက်ပိုင်းမှာ ဖော်ပြထားတဲ့ ဖိုင်တွေကို ငါထည့်တယ်။ ဒါပေမယ့် မင်းအဲလိုလုပ်စရာမလိုဘူး။

target_sources(mylib-unit-tests PRIVATE mylib/myfeature.cpp)

ကျွန်ုပ်တို့သည် မှီခိုမှုကို ချိတ်ဆက်သည်။ ကျွန်ုပ်တို့သည် ကျွန်ုပ်တို့၏ binary သို့ လိုအပ်သော CMake ပစ်မှတ်များကိုသာ ချိတ်ဆက်ထားပြီး command ကို မခေါ်ဆိုကြောင်း ကျေးဇူးပြု၍ သတိပြုပါ။ target_include_directories. စာမေးပွဲမူဘောင်မှ ခေါင်းစဉ်များနှင့် ကျွန်ုပ်တို့ထံမှ သိရသည်။ Mylib::mylibထို့အပြင် တည်ဆောက်မှုဘောင်များ (ကျွန်ုပ်တို့၏ကိစ္စတွင်၊ ဤသည်မှာ C++ ဘာသာစကားစံနှုန်းဖြစ်သည်) သည် ဤပန်းတိုင်များနှင့်အတူ ရောက်ရှိလာပါသည်။

target_link_libraries(mylib-unit-tests
    PRIVATE
        Mylib::mylib
        doctest::doctest
)

နောက်ဆုံးတွင်၊ ကျွန်ုပ်တို့သည် စမ်းသပ်မှုများနှင့် ညီမျှသည့် "build" ကို ဖန်တီးပြီး ဤပစ်မှတ်ကို ပုံသေတည်ဆောက်မှုသို့ ထည့်ပါ (ဤအရာအတွက် တာဝန်ရှိသည် ALL) ဆိုလိုသည်မှာ default build သည် tests များကို run ရန် အစပျိုးပေးသည်၊ ဆိုလိုသည်မှာ ၎င်းတို့ကို run ရန် ဘယ်သောအခါမှ မမေ့နိုင်ပါ။

add_custom_target(check ALL COMMAND mylib-unit-tests)

လွှမ်းခြုံ

ထို့နောက်၊ သင့်လျော်သောရွေးချယ်မှုကို သတ်မှတ်ထားပါက၊ ကျွန်ုပ်တို့သည် ကုဒ်လွှမ်းခြုံမှုအတိုင်းအတာကို ဖွင့်ထားသည်။ ကျွန်ုပ်သည် အသေးစိတ်အချက်အလက်များကို ရေးမည်မဟုတ်ပါ၊ အဘယ်ကြောင့်ဆိုသော် ၎င်းတို့သည် CMake ထက် လွှမ်းခြုံမှုကို တိုင်းတာသည့်ကိရိယာနှင့် ပိုမိုသက်ဆိုင်သောကြောင့်ဖြစ်သည်။ ရလဒ်များအပေါ်အခြေခံ၍ ပန်းတိုင်တစ်ခုဖန်တီးမည်ဖြစ်ကြောင်း သတိပြုရန်သာအရေးကြီးပါသည်။ coverageလွှမ်းခြုံမှုကို စတင်တိုင်းတာရန် အဆင်ပြေသည်။

find_program(GCOVR_EXECUTABLE gcovr)
if(MYLIB_COVERAGE AND GCOVR_EXECUTABLE)
    message(STATUS "Измерение покрытия кода тестами включено")

    target_compile_options(mylib-unit-tests PRIVATE --coverage)
    target_link_libraries(mylib-unit-tests PRIVATE gcov)

    add_custom_target(coverage
        COMMAND
            ${GCOVR_EXECUTABLE}
                --root=${PROJECT_SOURCE_DIR}/include/
                --object-directory=${CMAKE_CURRENT_BINARY_DIR}
        DEPENDS
            check
    )
elseif(MYLIB_COVERAGE AND NOT GCOVR_EXECUTABLE)
    set(MYLIB_COVERAGE OFF)
    message(WARNING "Для замеров покрытия кода тестами требуется программа gcovr")
endif()

စာရွက်စာတမ်းများအတွက် Script (doc/CMakeLists.txt)

Doxygen ကိုတွေ့တယ်။.

find_package(Doxygen)

ထို့နောက်၊ အသုံးပြုသူသည် ဘာသာစကား ပြောင်းလဲနိုင်သော သတ်မှတ်ခြင်း ရှိ၊ မရှိ စစ်ဆေးပါ။ ဟုတ်တယ်၊ အဲဒါကို ငါတို့မထိဘူး၊ မဟုတ်ရင် ငါတို့ ရုရှားကို ယူတယ်။ ထို့နောက် ကျွန်ုပ်တို့သည် Doxygen စနစ်ဖိုင်များကို ပြင်ဆင်သတ်မှတ်သည်။ ဘာသာစကား အပါအဝင် လိုအပ်သော variable များအားလုံးသည် configuration လုပ်ငန်းစဉ်အတွင်း ထိုနေရာကို သွားပါ (ကြည့်ပါ။ команду configure_file).

ပြီးရင် ဂိုးဖန်တီးပေးတယ်။ docစာရွက်စာတမ်းများကို စတင်ထုတ်ပေးပါမည်။ စာရွက်စာတမ်းများကို ဖန်တီးခြင်းသည် ဖွံ့ဖြိုးတိုးတက်မှုလုပ်ငန်းစဉ်တွင် အကြီးမားဆုံးလိုအပ်ချက်မဟုတ်သောကြောင့် ပစ်မှတ်ကို ပုံသေဖြင့်ဖွင့်မည်မဟုတ်ပါ၊ ၎င်းကို ပြတ်သားစွာစတင်ရပါမည်။

if (Doxygen_FOUND)
    if (NOT MYLIB_DOXYGEN_LANGUAGE)
        set(MYLIB_DOXYGEN_LANGUAGE Russian)
    endif()
    message(STATUS "Doxygen documentation will be generated in ${MYLIB_DOXYGEN_LANGUAGE}")
    configure_file(Doxyfile.in Doxyfile)
    add_custom_target(doc COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile)
endif ()

အွန်လိုင်း sandbox အတွက် Script (online/CMakeLists.txt)

ဤတွင် ကျွန်ုပ်တို့သည် တတိယ Python ကိုရှာပြီး ပစ်မှတ်တစ်ခုကို ဖန်တီးပါ။ wandboxဝန်ဆောင်မှု API နှင့် သက်ဆိုင်သည့် တောင်းဆိုချက်ကို ထုတ်ပေးသည်။ ကောက်ကွက်လွှတ်လိုက်၏။ တုံ့ပြန်မှုသည် အပြီးသတ် sandbox သို့ လင့်ခ်တစ်ခုပါလာသည်။

find_program(PYTHON3_EXECUTABLE python3)
if(PYTHON3_EXECUTABLE)
    set(WANDBOX_URL "https://wandbox.org/api/compile.json")

    add_custom_target(wandbox
        COMMAND
            ${PYTHON3_EXECUTABLE} wandbox.py mylib-example.cpp "${PROJECT_SOURCE_DIR}" include |
            curl -H "Content-type: application/json" -d @- ${WANDBOX_URL}
        WORKING_DIRECTORY
            ${CMAKE_CURRENT_SOURCE_DIR}
        DEPENDS
            mylib-unit-tests
    )
else()
    message(WARNING "Для создания онлайн-песочницы требуется интерпретатор ЯП python 3-й версии")
endif()

အပြင်မှာ ပရောဂျက်

ကဲ ဒါတွေအားလုံး အသုံးပြုပုံကို ကြည့်ရအောင်။

အစည်းအဝေး

ဤပရောဂျက်ကို CMake တည်ဆောက်မှုစနစ်ရှိ အခြားပရောဂျက်များကဲ့သို့ပင် တည်ဆောက်ရာတွင် အဆင့်နှစ်ဆင့်ပါရှိသည်-

မျိုးဆက်

cmake -S путь/к/исходникам -B путь/к/сборочной/директории [опции ...]

CMake ဗားရှင်းဟောင်းကြောင့် အထက်ဖော်ပြပါ command သည် အလုပ်မလုပ်ပါက၊ ချန်လှပ်ကြည့်ပါ။ -S:
cmake путь/к/исходникам -B путь/к/сборочной/директории [опции ...]

ရွေးချယ်စရာများအကြောင်း နောက်ထပ်.

စီမံကိန်းကိုတည်ဆောက်ခြင်း။

cmake --build путь/к/сборочной/директории [--target target]

ပရိသတ် ပန်းတိုင်များအကြောင်း နောက်ထပ်.

ရွေးစရာများ

MYLIB_COVERAGE

cmake -S ... -B ... -DMYLIB_COVERAGE=ON [прочие опции ...]

ပစ်မှတ် ပါဝင်သည်။ coverageစမ်းသပ်မှုများဖြင့် ကုဒ်အကျုံးဝင်မှုကို စတင်တိုင်းတာနိုင်သည်။

MYLIB_TESTING

cmake -S ... -B ... -DMYLIB_TESTING=OFF [прочие опции ...]

ယူနစ်စမ်းသပ်တည်ဆောက်မှုနှင့် ပစ်မှတ်ကို ပိတ်ရန် စွမ်းရည်ကို ပံ့ပိုးပေးသည်။ check. ရလဒ်အနေဖြင့် စမ်းသပ်မှုများဖြင့် ကုဒ်လွှမ်းခြုံမှုတိုင်းတာခြင်းအား ပိတ်သွားသည် (ကြည့်ရှုပါ။ MYLIB_COVERAGE).

ပရောဂျက်ကို command ကိုအသုံးပြု၍ ပရောဂျက်ခွဲတစ်ခုအဖြစ် အခြားပရောဂျက်တစ်ခုသို့ ချိတ်ဆက်ထားပါက စမ်းသပ်ခြင်းကိုလည်း အလိုအလျောက်ပိတ်ပါသည်။ add_subdirectory.

MYLIB_DOXYGEN_LANGUAGE

cmake -S ... -B ... -DMYLIB_DOXYGEN_LANGUAGE=English [прочие опции ...]

ပစ်မှတ်ထုတ်ပေးသောစာရွက်စာတမ်း၏ဘာသာစကားကိုပြောင်းသည်။ doc ပေးထားသောသူထံသို့။ ရရှိနိုင်သော ဘာသာစကားများစာရင်းကို ကြည့်ပါ။ Doxygen စနစ် ဝဘ်ဆိုဒ်.

ရုရှားဘာသာစကားကို မူရင်းအတိုင်း ဖွင့်ထားသည်။

ညီလာခံရည်မှန်းချက်များ

ပုံမှန်အားဖြင့်

cmake --build path/to/build/directory
cmake --build path/to/build/directory --target all

ပစ်မှတ်ကို မသတ်မှတ်ပါက (ပစ်မှတ်နှင့် ညီမျှသည်။ all) တတ်နိုင်သမျှ စုဆောင်းပြီး ပစ်မှတ်ကိုလည်း ခေါ်သည်။ check.

mylib-ယူနစ်-စမ်းသပ်မှုများ

cmake --build path/to/build/directory --target mylib-unit-tests

ယူနစ်စမ်းသပ်မှုများကို စုစည်းသည်။ မူရင်းအတိုင်း ဖွင့်ထားသည်။

စစ်ဆေးခြင်း

cmake --build путь/к/сборочной/директории --target check

စုဆောင်းထားသော (မစုဆောင်းရသေးပါက) ယူနစ်စမ်းသပ်မှုများကို လုပ်ဆောင်သည်။ မူရင်းအတိုင်း ဖွင့်ထားသည်။

ဒါ့အပြင်။ ကြည့်ရှုပါ mylib-unit-tests.

လွှမ်းခြုံ

cmake --build путь/к/сборочной/директории --target coverage

ပရိုဂရမ်ကို အသုံးပြု၍ စမ်းသပ်မှုများဖြင့် ကုဒ်အကျုံးဝင်မှုအတွက် ယူနစ်စစ်ဆေးမှုများ (မလုပ်ဆောင်ရသေးပါက) လုပ်ဆောင်နေခြင်းကို ပိုင်းခြားစိတ်ဖြာပါ။ gcovr.

အပေါ်ယံ အိတ်ဇောသည် ဤကဲ့သို့ ဖြစ်သည်-

------------------------------------------------------------------------------
                           GCC Code Coverage Report
Directory: /path/to/cmakecpptemplate/include/
------------------------------------------------------------------------------
File                                       Lines    Exec  Cover   Missing
------------------------------------------------------------------------------
mylib/myfeature.hpp                            2       2   100%   
------------------------------------------------------------------------------
TOTAL                                          2       2   100%
------------------------------------------------------------------------------

ရွေးချယ်ခွင့်ကို ဖွင့်ထားမှသာ ပစ်မှတ်ကို ရနိုင်သည်။ MYLIB_COVERAGE.

ဒါ့အပြင်။ ကြည့်ရှုပါ check.

doc

cmake --build путь/к/сборочной/директории --target doc

စနစ်အသုံးပြု၍ ကုဒ်မှတ်တမ်းပြုစုခြင်းကို စတင်သည်။ အောက်ဆီဂျင်.

wandbox

cmake --build путь/к/сборочной/директории --target wandbox

ဝန်ဆောင်မှုမှ တုံ့ပြန်မှုသည် ဤကဲ့သို့ ဖြစ်သည်-

{
    "permlink" :    "QElvxuMzHgL9fqci",
    "status" :  "0",
    "url" : "https://wandbox.org/permlink/QElvxuMzHgL9fqci"
}

ဤဝန်ဆောင်မှုကိုအသုံးပြုသည်။ ကောက်ကွက်. ၎င်းတို့၏ဆာဗာများ မည်မျှပြောင်းလွယ်သည်ကို ကျွန်ုပ်မသိသော်လည်း ဤအခွင့်အရေးကို အလွဲသုံးစားမပြုသင့်ဟု ကျွန်ုပ်ထင်ပါသည်။

ဥပမာ

လွှမ်းခြုံမှုအတိုင်းအတာဖြင့် ပရောဂျက်ကို အမှားရှာမုဒ်တွင် တည်ဆောက်ပါ။

cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DCMAKE_BUILD_TYPE=Debug -DMYLIB_COVERAGE=ON
cmake --build путь/к/сборочной/директории --target coverage --parallel 16

ပဏာမ တပ်ဆင်ခြင်းနှင့် စမ်းသပ်ခြင်းမရှိဘဲ ပရောဂျက်တစ်ခုကို တပ်ဆင်ခြင်း။

cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DMYLIB_TESTING=OFF -DCMAKE_INSTALL_PREFIX=путь/к/установойной/директории
cmake --build путь/к/сборочной/директории --target install

ပေးထားသော compiler ဖြင့် ထွက်ရှိသည့်မုဒ်တွင် တည်ဆောက်ပါ။

cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DCMAKE_BUILD_TYPE=Release -DCMAKE_CXX_COMPILER=g++-8 -DCMAKE_PREFIX_PATH=путь/к/директории/куда/установлены/зависимости
cmake --build путь/к/сборочной/директории --parallel 4

စာရွက်စာတမ်းများကို အင်္ဂလိပ်လိုထုတ်ပေးခြင်း။

cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DCMAKE_BUILD_TYPE=Release -DMYLIB_DOXYGEN_LANGUAGE=English
cmake --build путь/к/сборочной/директории --target doc

တူရိယာ

ပါးစပ် 3.13

တကယ်တော့၊ CMake ဗားရှင်း 3.13 သည် ဤအကူအညီတွင်ဖော်ပြထားသော console command အချို့ကို လုပ်ဆောင်ရန်သာ လိုအပ်ပါသည်။ CMake scripts များ၏ syntax ၏ရှုထောင့်မှကြည့်လျှင် ဗားရှင်း 3.8 သည် အခြားနည်းလမ်းများဖြင့် မျိုးဆက်ကိုခေါ်ဆိုပါက လုံလောက်ပါသည်။
စမ်းသပ်စာကြည့်တိုက် doctest

စမ်းသပ်ခြင်းကို ပိတ်နိုင်သည် (ကြည့်ပါ။ опцию MYLIB_TESTING).
အောက်ဆီဂျင်

စာရွက်စာတမ်းထုတ်ပေးမည့် ဘာသာစကားကို ပြောင်းရန်၊ ရွေးချယ်ခွင့်တစ်ခု ပေးထားသည်။ MYLIB_DOXYGEN_LANGUAGE.
ဘာသာစကား စကားပြန် Python ကို 3

အလိုအလျောက်မျိုးဆက်အတွက် အွန်လိုင်းသဲပုံးများ.

အငြိမ်မနေ

CMake နှင့် ကောင်းမွန်သော ကိရိယာအချို့ဖြင့်၊ အားစိုက်ထုတ်မှုအနည်းဆုံးဖြင့် တည်ငြိမ်မှုခွဲခြမ်းစိတ်ဖြာမှုကို ပေးနိုင်ပါသည်။

Cppcheck

CMake တွင် static analysis tool တစ်ခုအတွက် built-in ပံ့ပိုးမှုရှိသည်။ Cppcheck.

ဒီလိုလုပ်ဖို့သင် option ကိုအသုံးပြုရန်လိုအပ်သည်။ CMAKE_CXX_CPPCHECK:

cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DCMAKE_BUILD_TYPE=Debug -DCMAKE_CXX_CPPCHECK="cppcheck;--enable=all;-Iпуть/к/исходникам/include"

၎င်းပြီးနောက်၊ အရင်းအမြစ်ကို စုစည်းပြီး ပြန်လည်စုစည်းလိုက်တိုင်း static analysis ကို အလိုအလျောက် စတင်ပါမည်။ ဘာမှ ထပ်လုပ်စရာ မလိုဘူး။

ခုတ်ထစ်ခြင်း။

အံ့သြဖွယ်ကိရိယာ၏အကူအညီဖြင့် scan-build အချိန်တိုအတွင်း တည်ငြိမ်မှုခွဲခြမ်းစိတ်ဖြာမှုကိုလည်း သင်လုပ်ဆောင်နိုင်သည်-

scan-build cmake -S путь/к/исходникам -B путь/к/сборочной/директории -DCMAKE_BUILD_TYPE=Debug
scan-build cmake --build путь/к/сборочной/директории

ဤတွင်၊ Cppcheck နှင့်မတူဘဲ၊ သင်သည်အချိန်တိုင်းတည်ဆောက်မှုကိုလုပ်ဆောင်ရန်လိုအပ်သည်။ scan-build.

afterword

CMake သည် အရသာနှင့် အရောင်တိုင်းအတွက် လုပ်ဆောင်နိုင်စွမ်းကို အကောင်အထည်ဖော်ခွင့်ပြုသည့် အလွန်အားကောင်းပြီး လိုက်လျောညီထွေရှိသော စနစ်တစ်ခုဖြစ်သည်။ အထားအသိုက တခါတရံမှာ လိုချင်စရာတွေ အများကြီးကျန်ခဲ့ပေမယ့်၊ မာရ်နတ်က သူခြယ်သထားသလောက် မကြောက်သေးဘူး။ လူ့အဖွဲ့အစည်းနှင့် ကျန်းမာရေးအတွက် CMake တည်ဆောက်မှုစနစ်ကို အသုံးပြုပါ။

→ ပရောဂျက် နမူနာကို ဒေါင်းလုဒ်လုပ်ပါ။

source: www.habr.com

CMake နှင့် C++ သည် ထာဝရညီအစ်ကိုများဖြစ်သည်။