1C RAC အတွက် GUI သို့မဟုတ် Tcl/Tk အကြောင်း ထပ်မံရေးသားခြင်း။

Linux ပတ်၀န်းကျင်တွင် 1C ထုတ်ကုန်များ မည်သို့အလုပ်လုပ်ပုံ၏ ခေါင်းစဉ်ကို ကျွန်ုပ်တို့ အသေးစိပ်လေ့လာသောအခါတွင် အားနည်းချက်တစ်ခု တွေ့ရှိခဲ့သည် - 1C ဆာဗာများ အစုအဝေးကို စီမံခန့်ခွဲရန်အတွက် အဆင်ပြေသော ဂရပ်ဖစ်အစုံ-ပလပ်ဖောင်းတူးလ်မရှိခြင်း။ ထို့အပြင် rac console utility အတွက် GUI ကိုရေးခြင်းဖြင့် ဤအားနည်းချက်ကို ပြင်ရန် ဆုံးဖြတ်ခဲ့သည်။ ကျွန်တော့်အမြင်အရ၊ ဤလုပ်ငန်းအတွက် အသင့်တော်ဆုံးဖြစ်သောကြောင့် Tcl/tk ကို ဖွံ့ဖြိုးတိုးတက်ရေးဘာသာစကားအဖြစ် ရွေးချယ်ခဲ့သည်။ ဒါကြောင့် ဒီပစ္စည်းမှာ ဖြေရှင်းချက်ရဲ့ စိတ်ဝင်စားစရာကောင်းတဲ့ ကဏ္ဍတချို့ကို တင်ပြချင်ပါတယ်။

အလုပ်လုပ်ရန် သင်သည် tcl/tk နှင့် 1C ဖြန့်ဝေမှုများ လိုအပ်ပါသည်။ ပြင်ပကုမ္ပဏီ ပက်ကေ့ဂျ်များကို အသုံးမပြုဘဲ အခြေခံ tcl/tk ပေးပို့ခြင်း၏ စွမ်းရည်အများစုကို အသုံးပြုရန် ဆုံးဖြတ်လိုက်သောကြောင့်၊ ttk ပါ၀င်သော ဗားရှင်း 8.6.7 - ကျွန်ုပ်တို့ အဓိကလိုအပ်သည့် ttk အပိုဂရပ်ဖစ်ဒြပ်စင်များပါရှိသော ပက်ကေ့ဂျ်ကို လိုအပ်ပါသည်။ ::TreeView၊ ၎င်းသည် သစ်ပင်ဖွဲ့စည်းပုံပုံစံနှင့် ဇယား (စာရင်း) ပုံစံဖြင့် ဒေတာကို ပြသခွင့်ပြုသည်။ ထို့အပြင်၊ ဗားရှင်းအသစ်တွင်၊ ခြွင်းချက်များနှင့် အလုပ်အား ပြန်လည်လုပ်ဆောင်ခဲ့သည် (ပြင်ပ command များကို လုပ်ဆောင်သည့်အခါ ပရောဂျက်တွင် အသုံးပြုသည့် try command ကို အသုံးပြုသည်)။

ပရောဂျက်တွင် ဖိုင်များစွာပါ၀င်သည် (တစ်စုံတစ်ခုထဲတွင် အရာအားလုံးလုပ်ဆောင်ရန် မည်သည့်အရာကမှ သင့်ကိုတားဆီးထားခြင်းမရှိသော်လည်း)

rac_gui.cfg - ပုံသေ config
rac_gui.tcl - ပင်မလွှင့်တင်သည့် ဇာတ်ညွှန်း
lib directory တွင် startup တွင် အလိုအလျောက် load လုပ်သည့် ဖိုင်များ ပါရှိသည်။
function.tcl - လုပ်ထုံးလုပ်နည်းများနှင့်အတူဖိုင်
gui.tcl - ပင်မဂရပ်ဖစ် အင်တာဖေ့စ်
images.tcl - base64 ရုပ်ပုံစာကြည့်တိုက်

rac_gui.tcl ဖိုင်သည် အမှန်တကယ်အားဖြင့် စကားပြန်ကို စတင်သည်၊ ကိန်းရှင်များကို အစပြုသည်၊ မော်ဂျူးများကို ဖွင့်သည်၊ ပြင်ဆင်မှုများ၊ စသည်ဖြင့်။ မှတ်ချက်များနှင့်အတူ ဖိုင်၏ အကြောင်းအရာများ

rac_gui.tcl

#!/bin/sh
exec wish "$0" -- "$@"

# Устанавливаем текущий каталог
set dir(root) [pwd]
# Устанавливаем рабочий каталог, если его нет то создаём
set dir(work) [file join $env(HOME) .rac_gui]
if {[file exists $dir(work)] == 0 } {
    file mkdir $dir(work)    
}
# каталог с модулями
set dir(lib) "[file join $dir(root) lib]"

# загружаем пользовательский конфиг, если он отсутствует, то копируем дефолтный
if {[file exists [file join $dir(work) rac_gui.cfg]] ==0} {
    file copy [file join [pwd] rac_gui.cfg] [file join $dir(work) rac_gui.cfg]
} 
source [file join $dir(work) rac_gui.cfg]
# Код проверки наличия rac и правильности указания пути в конфиге
# если программа не найдена то будет выведен диалог для указания корректного пути
# и этот путь будет записан в пользовательский конфиг
if {[file exists $rac_cmd] == 0} {
    set rac_cmd [tk_getOpenFile -initialdir $env(HOME) -parent . -title "Укажите путь до rac" -initialfile rac]
    file copy [file join $dir(work) rac_gui.cfg] [file join $dir(work) rac_gui.cfg.bak] 
    set orig_file [open [file join $dir(work) rac_gui.cfg.bak] "r"]
    set file [open [file join $dir(work) rac_gui.cfg] "w"]
    while {[gets $orig_file line] >=0 } {
        if {[string match "set rac_cmd*" $line]} {
            puts $file "set rac_cmd $rac_cmd"
        } else {
            puts $file $line
        }
    }
    close $file
    close $orig_file
    #return "$host:$port"
    file delete [file join $dir(work) 1c_srv.cfg.bak] 
} else {
    puts "Found $rac_cmd"
}

set cluster_user ""
set cluster_pwd ""
set agent_user ""
set agent_pwd ""
## LOAD FILE ##
# Загружаем модули кроме gui.tcl так как его надо загрузить последним
foreach modFile [lsort [glob -nocomplain [file join $dir(lib) *.tcl]]] {
    if {[file tail $modFile] ne "gui.tcl"} {
        source $modFile
        puts "Loaded module $modFile"
    }
}
source [file join $dir(lib) gui.tcl]
source [file join $dir(work) rac_gui.cfg]

# Читаем файл со списком серверов 1С
# и добавляем в дерево
if [file exists [file join $dir(work) 1c_srv.cfg]] {
    set f [open [file join $dir(work) 1c_srv.cfg] "RDONLY"]
    while {[gets $f line] >=0} {
        .frm_tree.tree insert {} end -id "server::$line" -text "$line" -values "$line"
    }    
}

လိုအပ်သည့်အရာအားလုံးကို ဒေါင်းလုဒ်လုပ်ပြီး rac utility ၏ပါဝင်မှုကို စစ်ဆေးပြီးနောက်၊ ဂရပ်ဖစ်ဝင်းဒိုးတစ်ခု စတင်ပါမည်။ ပရိုဂရမ်အင်တာဖေ့စ်တွင် ဒြပ်စင်သုံးခုပါဝင်သည်-

ကိရိယာဘား၊ သစ်ပင်နှင့် စာရင်း

ကျွန်ုပ်သည် “သစ်ပင်” ၏ အကြောင်းအရာများကို 1C မှ ပုံမှန် Windows စက်ကိရိယာများနှင့် တတ်နိုင်သမျှ ဆင်တူအောင် ပြုလုပ်ထားသည်။

ဤဝင်းဒိုးကိုဖွဲ့စည်းသည့် အဓိကကုဒ်သည် ဖိုင်တွင်ပါရှိသည်။
lib/gui.tcl

# установка размера и положения основного окна
# можно установить в переменную topLevelGeometry в конфиг программы
if {[info exists topLevelGeometry]} {
    wm geometry . $topLevelGeometry
} else {
    wm geometry . 1024x768
}
# Заголовок окна
wm title . "1C Rac GUI"
wm iconname . "1C Rac Gui"
# иконка окна (берется из файла lib/imges.tcl)
wm iconphoto . tcl
wm protocol . WM_DELETE_WINDOW Quit
wm overrideredirect . 0
wm positionfrom . user

ttk::style theme use clam

# Панель инсрументов
set frm_tool [frame .frm_tool]
pack $frm_tool -side left -fill y 
ttk::panedwindow .panel -orient horizontal -style TPanedwindow
pack .panel -expand true -fill both
pack propagate .panel false

ttk::button $frm_tool.btn_add  -command Add  -image add_grey_32
ttk::button $frm_tool.btn_del  -command Del -image del_grey_32
ttk::button $frm_tool.btn_edit  -command Edit -image edit_grey_32
ttk::button $frm_tool.btn_quit -command Quit -image quit_grey_32

pack $frm_tool.btn_add $frm_tool.btn_del $frm_tool.btn_edit -side top -padx 5 -pady 5
pack $frm_tool.btn_quit  -side bottom -padx 5 -pady 5

# Дерево с полосами прокрутки
set frm_tree [frame .frm_tree]

ttk::scrollbar $frm_tree.hsb1 -orient horizontal -command [list $frm_tree.tree xview]
ttk::scrollbar $frm_tree.vsb1 -orient vertical -command [list $frm_tree.tree yview]
set tree [ttk::treeview $frm_tree.tree -show tree 
-xscrollcommand [list $frm_tree.hsb1 set] -yscrollcommand [list $frm_tree.vsb1 set]]

grid $tree -row 0 -column 0 -sticky nsew
grid $frm_tree.vsb1 -row 0 -column 1 -sticky nsew
grid $frm_tree.hsb1 -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_tree 0 -weight 1
grid rowconfigure $frm_tree 0 -weight 1

# назначение обработчика нажатия кнопкой мыши
bind $frm_tree.tree <ButtonRelease> "TreePress $frm_tree.tree"

# Список для данных (таблица)
set frm_work [frame .frm_work]
ttk::scrollbar $frm_work.hsb -orient horizontal -command [list $frm_work.tree_work xview]
ttk::scrollbar $frm_work.vsb -orient vertical -command [list $frm_work.tree_work yview]
set tree_work [
    ttk::treeview $frm_work.tree_work 
    -show headings  -columns "par val" -displaycolumns "par val"
    -xscrollcommand [list $frm_work.hsb set] 
    -yscrollcommand [list $frm_work.vsb set]
]
# Установка цветов для чередования в таблице
$tree_work tag configure dark -background $color(dark_table_bg)
$tree_work tag configure light -background $color(light_table_bg)

# Размещение элементов на форме
grid $tree_work -row 0 -column 0 -sticky nsew
grid $frm_work.vsb -row 0 -column 1 -sticky nsew
grid $frm_work.hsb -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_work 0 -weight 1
grid rowconfigure $frm_work 0 -weight 1
pack $frm_tree $frm_work -side left -expand true -fill both

#.panel add $frm_tool -weight 1
.panel add $frm_tree -weight 1 
.panel add $frm_work -weight 1

ပရိုဂရမ်နှင့်အလုပ်လုပ်ရန် algorithm မှာ အောက်ပါအတိုင်းဖြစ်သည်။

1. ပထမဦးစွာ၊ သင်သည် ပင်မ အစုအဝေးဆာဗာကို ပေါင်းထည့်ရန် လိုအပ်သည် (ဆိုလိုသည်မှာ၊ အစုအဝေး စီမံခန့်ခွဲမှု ဆာဗာ (Linux တွင် စီမံခန့်ခွဲမှုသည် “/opt/1C/v8.3/x86_64/ras cluster —daemon”))))။

၎င်းကိုလုပ်ဆောင်ရန် “+” ခလုတ်ကိုနှိပ်ပြီး ပွင့်လာသောဝင်းဒိုးတွင် ဆာဗာလိပ်စာနှင့် ဆိပ်ကမ်းကို ထည့်သွင်းပါ-

ထို့နောက်တွင်၊ ကျွန်ုပ်တို့၏ဆာဗာသည် ၎င်းကိုနှိပ်ခြင်းဖြင့် သစ်ပင်တွင် ပေါ်လာမည်ဖြစ်ပြီး၊ အစုအဖွဲ့များစာရင်းပွင့်လာမည် သို့မဟုတ် ချိတ်ဆက်မှုအမှားအယွင်းတစ်ခု ပြသမည်ဖြစ်သည်။

2. အစုအဝေးအမည်ကို ကလစ်နှိပ်ခြင်းဖြင့် ၎င်းအတွက်ရရှိနိုင်သည့် လုပ်ဆောင်ချက်များစာရင်းကို ဖွင့်ပေးမည်ဖြစ်သည်။

3.

ပြီးတော့၊ i.e. အစုအဝေးအသစ်တစ်ခုထည့်ရန်၊ စာရင်းတွင်ရနိုင်သောမည်သည့်အရာကိုမဆိုရွေးချယ်ပြီး ကိရိယာဘားရှိ “+” ခလုတ်ကို နှိပ်ပြီး ပေါင်းထည့်သည့် ဒိုင်ယာလော့ဂ်အသစ်ကို ပြသပါမည်-

ကိရိယာဘားရှိ ခလုတ်များသည် အကြောင်းအရာပေါ်မူတည်၍ လုပ်ဆောင်ချက်များကို လုပ်ဆောင်သည် ၊ ဆိုလိုသည်မှာ၊ သစ်ပင် သို့မဟုတ် စာရင်း၏ မည်သည့်ဒြပ်စင် သို့မဟုတ် စာရင်းကို ရွေးချယ်ထားသည်အပေါ်မူတည်၍ လုပ်ငန်းစဉ်တစ်ခု သို့မဟုတ် အခြားတစ်ခု လုပ်ဆောင်မည်ဖြစ်သည်။

Add ခလုတ် (“+” ၏ ဥပမာကို ကြည့်ကြပါစို့။

ခလုတ်မျိုးဆက်ကုဒ်-

ttk::button $frm_tool.btn_add  -command Add  -image add_grey_32

ဤနေရာတွင် ခလုတ်ကို နှိပ်လိုက်သောအခါ၊ "Add" လုပ်ငန်းစဉ်သည် ၎င်း၏ကုဒ်ကို လုပ်ဆောင်လိမ့်မည်ဖြစ်သည်

proc Add {} {
    global active_cluster host
    # Определяем идентификатор выделенного элемента
    set id  [.frm_tree.tree selection] 
    # Определяем значение этого элемента
    set values [.frm_tree.tree item [.frm_tree.tree selection] -values]
    set key [lindex [split $id "::"] 0]
    # в зависимости от того что выделили будет запущена нужная процедура
    if {$key eq "" || $key eq "server"} {
        set host [ Add::server ]
        return
    }
    Add::$key .frm_tree.tree $host $values
}

ဤသည်မှာ tickle ၏ အားသာချက်များထဲမှ တစ်ခုဖြစ်သည်- သင်သည် လုပ်ထုံးလုပ်နည်းအမည်တစ်ခုအနေဖြင့် variable တစ်ခု၏တန်ဖိုးကို ကျော်သွားနိုင်သည်။

Add::$key .frm_tree.tree $host $values

ဥပမာအားဖြင့်၊ အကယ်၍ ကျွန်ုပ်တို့သည် ပင်မဆာဗာကို ညွှန်ပြပြီး “+” ကို နှိပ်ပါက၊ ထို့နောက် အစုအဝေးတွင် ရှိပါက Add:: server လုပ်ထုံးလုပ်နည်းကို စတင်လိမ့်မည် - Add::cluster စသည်ဖြင့် (ကျွန်ုပ်သည် မည်သည့်နေရာတွင် ရှိသည်ကို ရေးပါမည်။ လိုအပ်သော "သော့များ" သည် အောက်ဖော်ပြပါ အနည်းငယ်မှ ဆင်းသက်လာသည်)၊ ဖော်ပြထားသော လုပ်ထုံးလုပ်နည်းများသည် အကြောင်းအရာနှင့် သင့်လျော်သော ဂရပ်ဖစ်ဒြပ်စင်များကို ဆွဲထုတ်ပါသည်။

သင်သတိပြုမိပြီးသားဖြစ်သည့်အတိုင်း ဖောင်ပုံစံများသည် ပုံစံတူဖြစ်သည် - လုပ်ထုံးလုပ်နည်းတစ်ခုဖြင့် ၎င်းတို့ကိုပြသထားသောကြောင့် အံ့သြစရာမဟုတ်ပါ၊ ဖောင်၏ပင်မဘောင် (ပြတင်းပေါက်၊ ခလုတ်များ၊ ပုံ၊ အညွှန်း)၊ လုပ်ထုံးလုပ်နည်းအမည်၊ AddTopLevel

proc AddToplevel {lbl img {win_name .add}} {
    set cmd "destroy $win_name"
    if [winfo exists $win_name] {destroy $win_name}
    toplevel $win_name
    wm title $win_name $lbl
    wm iconphoto $win_name tcl
    # метка с иконкой
    ttk::label $win_name.lbl -image $img
    # фрейм с полями ввода
    set frm [ttk::labelframe $win_name.frm -text $lbl -labelanchor nw]
    
    grid columnconfigure $frm 0 -weight 1
    grid rowconfigure $frm 0 -weight 1
    # фрейм и кнопки
    set frm_btn [frame $win_name.frm_btn -border 0]
    ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }
    ttk::button $frm_btn.btn_cancel -command $cmd -image quit_grey_24 
    grid $win_name.lbl -row 0 -column 0 -sticky nw -padx 5 -pady 10
    grid $frm -row 0 -column 1 -sticky nw -padx 5 -pady 5
    grid $frm_btn -row 1 -column 1 -sticky se -padx 5 -pady 5
    pack  $frm_btn.btn_cancel  -side right
    pack  $frm_btn.btn_ok  -side right -padx 10
    return $frm
}

ခေါ်ဆိုမှုကန့်သတ်ချက်များ- ခေါင်းစဉ်၊ စာကြည့်တိုက်မှ အိုင်ကွန်အတွက် ပုံအမည် (lib/images.tcl) နှင့် ရွေးချယ်နိုင်သော ဝင်းဒိုးအမည် ကန့်သတ်ချက်တစ်ခု (မူလ .add)။ ထို့ကြောင့်၊ ကျွန်ုပ်တို့သည် ပင်မဆာဗာနှင့် အစုအဝေးကို ပေါင်းထည့်ရန်အတွက် အထက်ဖော်ပြပါ ဥပမာများကို ယူပါက၊ ခေါ်ဆိုမှုသည် လျော်ညီလိမ့်မည်-

AddToplevel "Добавление основного сервера" server_grey_64

သို့မဟုတ်

AddToplevel "Добавление кластера" cluster_grey_64

ကောင်းပြီ၊ ဤနမူနာများနှင့်အတူ ဆက်လက်၍ ဆာဗာ သို့မဟုတ် အစုအဝေးအတွက် ထည့်သွင်းသည့် ဒိုင်ယာလော့ခ်များကို ပြသသည့် လုပ်ထုံးလုပ်နည်းများကို ကျွန်ုပ်ပြပါမည်။

Add::ဆာဗာ

proc Add::server {} {
    global default
    # выводим основную форму
    set frm [AddToplevel "Добавление основного сервера" server_grey_64]
    # добавляем етки и поля ввода на эту форму
    label $frm.lbl_host -text "Адрес сервера"
    entry  $frm.ent_host
    label $frm.lbl_port -text "Порт"
    entry $frm.ent_port 
    $frm.ent_port  insert end $default(port)
    grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
    grid columnconfigure $frm 0 -weight 1
    grid rowconfigure $frm 0 -weight 1
    #set frm_btn [frame .add.frm_btn -border 0]
    # переопределяем обработчик нажатия кнопки
    .add.frm_btn.btn_ok configure -command {
        set host [SaveMainServer [.add.frm.ent_host get] [.add.frm.ent_port get]]
        .frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"
        destroy .add
        return $host
    }
    return $frm
}

ထည့်ပါ::အစုအဝေး

proc Add::cluster {tree host values} {
    global default lifetime_limit expiration_timeout session_fault_tolerance_level
    global max_memory_size max_memory_time_limit errors_count_threshold security_level
    global load_balancing_mode kill_problem_processes 
    agent_user agent_pwd cluster_user cluster_pwd auth_agent
    if {$agent_user ne "" && $agent_pwd ne ""} {
        set auth_agent "--agent-user=$agent_user --agent-pwd=$agent_pwd"
    } else {
        set auth_agent ""
    }
    # устанавливаем глобальные переменные ()
    set lifetime_limit $default(lifetime_limit)
    set expiration_timeout $default(expiration_timeout)
    set session_fault_tolerance_level $default(session_fault_tolerance_level)
    set max_memory_size $default(max_memory_size)
    set max_memory_time_limit $default(max_memory_time_limit)
    set errors_count_threshold $default(errors_count_threshold)
    set security_level [lindex $default(security_level) 0]
    set load_balancing_mode [lindex $default(load_balancing_mode) 0]
    
    set frm [AddToplevel "Добавление кластера" cluster_grey_64]
    
    label $frm.lbl_host -text "Адрес основного сервера"
    entry  $frm.ent_host
    label $frm.lbl_port -text "Порт"
    entry $frm.ent_port 
    $frm.ent_port  insert end $default(port)
    label $frm.lbl_name -text "Название кластера"
    entry  $frm.ent_name
    label $frm.lbl_secure_connect -text "Защищённое соединение"
    ttk::combobox $frm.cb_security_level -textvariable security_level -values $default(security_level)
    label $frm.lbl_expiration_timeout -text "Останавливать выключенные процессы через:"
    entry  $frm.ent_expiration_timeout -textvariable expiration_timeout
    label $frm.lbl_session_fault_tolerance_level -text "Уровень отказоустойчивости"
    entry  $frm.ent_session_fault_tolerance_level -textvariable session_fault_tolerance_level
    label $frm.lbl_load_balancing_mode -text "Режим распределения нагрузки"
    ttk::combobox $frm.cb_load_balancing_mode -textvariable load_balancing_mode 
    -values $default(load_balancing_mode)
    label $frm.lbl_errors_count_threshold -text "Допустимое отклонение количества ошибок сервера, %"
    entry  $frm.ent_errors_count_threshold -textvariable errors_count_threshold
    label $frm.lbl_processes -text "Рабочие процессы:"
    label $frm.lbl_lifetime_limit -text "Период перезапуска, сек."
    entry  $frm.ent_lifetime_limit -textvariable lifetime_limit
    label $frm.lbl_max_memory_size -text "Допустимый объём памяти, КБ"
    entry  $frm.ent_max_memory_size -textvariable max_memory_size
    label $frm.lbl_max_memory_time_limit -text "Интервал превышения допустимого объёма памяти, сек."
    entry  $frm.ent_max_memory_time_limit -textvariable max_memory_time_limit
    label $frm.lbl_kill_problem_processes -justify left -anchor nw -text "Принудительно завершать проблемные процессы"
    checkbutton $frm.check_kill_problem_processes -variable kill_problem_processes -onvalue yes -offvalue no    
    
    grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_name -row 2 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_name -row 2 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_secure_connect -row 3 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.cb_security_level -row 3 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_expiration_timeout -row 4 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_expiration_timeout -row 4 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_session_fault_tolerance_level -row 5 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_session_fault_tolerance_level -row 5 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_load_balancing_mode -row 6 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.cb_load_balancing_mode -row 6 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_errors_count_threshold -row 7 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_errors_count_threshold -row 7 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_processes -row 8 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.lbl_lifetime_limit -row 9 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_lifetime_limit -row 9 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_max_memory_size -row 10 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_max_memory_size -row 10 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_max_memory_time_limit -row 11 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.ent_max_memory_time_limit -row 11 -column 1 -sticky nsew -padx 5 -pady 5
    grid $frm.lbl_kill_problem_processes -row 12 -column 0 -sticky nw -padx 5 -pady 5
    grid $frm.check_kill_problem_processes -row 12 -column 1 -sticky nw -padx 5 -pady 5
    # переопределяем обработчик
    .add.frm_btn.btn_ok configure -command {
        RunCommand "" "cluster insert 
        --host=[.add.frm.ent_host get] 
        --port=[.add.frm.ent_port get] 
        --name=[.add.frm.ent_name get] 
        --expiration-timeout=$expiration_timeout 
        --lifetime-limit=$lifetime_limit 
        --max-memory-size=$max_memory_size 
        --max-memory-time-limit=$max_memory_time_limit 
        --security-level=$security_level 
        --session-fault-tolerance-level=$session_fault_tolerance_level 
        --load-balancing-mode=$load_balancing_mode 
        --errors-count-threshold=$errors_count_threshold 
        --kill-problem-processes=$kill_problem_processes 
        $auth_agent $host"
        Run::server $tree $host ""
        destroy .add
    }
    return $frm
}

ဤလုပ်ထုံးလုပ်နည်းများ၏ကုဒ်ကို နှိုင်းယှဉ်သောအခါ၊ ခြားနားချက်ကို သာမန်မျက်စိဖြင့်မြင်နိုင်သည်၊ "Ok" ခလုတ်ကိုင်တွယ်သူကို ကျွန်ုပ်အာရုံစိုက်ပါမည်။ Tk တွင်၊ ရွေးချယ်စရာကို အသုံးပြု၍ ပရိုဂရမ်လုပ်ဆောင်နေစဉ်အတွင်း ဂရပ်ဖစ်ဒြပ်စင်များ၏ ဂုဏ်သတ္တိများကို လွှမ်းမိုးနိုင်သည်။ configuration. ဥပမာအားဖြင့်၊ ခလုတ်ကိုပြသရန် ကနဦး command

ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }

သို့သော် ကျွန်ုပ်တို့၏ပုံစံများတွင်၊ command သည် လိုအပ်သောလုပ်ဆောင်နိုင်စွမ်းပေါ်တွင်မူတည်သည်-

  .add.frm_btn.btn_ok configure -command {
        RunCommand "" "cluster insert 
        --host=[.add.frm.ent_host get] 
        --port=[.add.frm.ent_port get] 
        --name=[.add.frm.ent_name get] 
        --expiration-timeout=$expiration_timeout 
        --lifetime-limit=$lifetime_limit 
        --max-memory-size=$max_memory_size 
        --max-memory-time-limit=$max_memory_time_limit 
        --security-level=$security_level 
        --session-fault-tolerance-level=$session_fault_tolerance_level 
        --load-balancing-mode=$load_balancing_mode 
        --errors-count-threshold=$errors_count_threshold 
        --kill-problem-processes=$kill_problem_processes 
        $auth_agent $host"
        Run::server $tree $host ""
        destroy .add
    }

အထက်ဖော်ပြပါနမူနာတွင်၊ "clogged" ခလုတ်သည် အစုအဝေးတစ်ခုထည့်ခြင်းလုပ်ငန်းစဉ်ကို စတင်သည်။

ဤနေရာတွင် Tk ရှိ ဂရပ်ဖစ်ဒြပ်စင်များနှင့် လုပ်ဆောင်ရန် လွန်စွာတန်ဖိုးရှိသည် - အမျိုးမျိုးသော ဒေတာထည့်သွင်းသည့်ဒြပ်စင်များ (ဝင်ရောက်မှု၊ ကွန်ဘိုဘောက်စ်၊ ချက်ခလုတ်စသည်ဖြင့်) ပါရာမီတာကို စာသားပြောင်းလဲမှုအဖြစ် မိတ်ဆက်ခဲ့သည်-

entry  $frm.ent_lifetime_limit -textvariable lifetime_limit

ဤကိန်းရှင်သည် ကမ္ဘာလုံးဆိုင်ရာ namespace တွင်သတ်မှတ်ထားပြီး လက်ရှိထည့်သွင်းထားသောတန်ဖိုးများပါရှိသည်။ အဲဒါတွေ။ အကွက်မှထည့်သွင်းထားသောစာသားကိုရရန်အတွက်၊ သင်သည် variable နှင့်သက်ဆိုင်သောတန်ဖိုးကိုဖတ်ရန်သာလိုသည် (ဟုတ်ပါတယ်၊ ဒြပ်စင်ကိုဖန်တီးသောအခါတွင်၎င်းကိုသတ်မှတ်ထားသည်)။

ထည့်သွင်းထားသော စာသားကို ပြန်လည်ရယူရန် ဒုတိယနည်းလမ်း ( entry type ၏ element များအတွက်) မှာ get command ကို အသုံးပြုရန်ဖြစ်သည် ။

.add.frm.ent_name get

ဤနည်းလမ်းနှစ်ခုလုံးကို အထက်ဖော်ပြပါ ကုဒ်တွင် ကြည့်ရှုနိုင်ပါသည်။

ဤခလုတ်ကိုနှိပ်ခြင်းဖြင့်၊ ဤကိစ္စတွင်၊ rac နှင့်ပတ်သက်သော အစုအဝေးကိုထည့်ရန်အတွက် ထုတ်လုပ်ထားသော command line ဖြင့် RunCommand လုပ်ထုံးလုပ်နည်းကို စတင်သည်-

/opt/1C/v8.3/x86_64/rac cluster insert  --host=localhost  --port=1540  --name=dsdsds  --expiration-timeout=0  --lifetime-limit=0  --max-memory-size=0  --max-memory-time-limit=0  --security-level=0  --session-fault-tolerance-level=0  --load-balancing-mode=performance  --errors-count-threshold=0  --kill-problem-processes=no   localhost:1545

ယခုကျွန်ုပ်တို့သည်ကျွန်ုပ်တို့လိုအပ်သော parameters များနှင့်အတူ rac ၏ပစ်လွှတ်မှုကိုထိန်းချုပ်သည့် main command သို့ရောက်ရှိလာပြီး လိုအပ်ပါက၊ command များ၏ output ကို lists and returns အဖြစ် ခွဲခြမ်းစိတ်ဖြာသည်-

RunCommand

proc RunCommand {root par} {
    global dir rac_cmd cluster work_list_row_count agent_user agent_pwd cluster_user cluster_pwd
    puts "$rac_cmd $par"
    set work_list_row_count 0
    # открываем канал в неблокирующем режиме
    # $rac - команда с полным путём
    # $par - сформированные ключи запуска и опции    
    set pipe [open "|$rac_cmd $par" "r"]
    try {
        set lst ""
        set l ""
        # вывод команды добавляем в список списков
        while {[gets $pipe line]>=0} {
            #puts $line
            if {$line eq ""} {
                lappend l $lst
                set lst ""
            } else {
                lappend lst [string trim $line]
            }
        }
        close $pipe
        return $l
    } on error {result options} {
        # Запуск обработчика ошибок
        ErrorParcing $result $options
        return ""
    }
}

ပင်မဆာဗာဒေတာကိုဖြည့်သွင်းပြီးနောက်၊ ၎င်းကိုသစ်ပင်ထဲသို့ထည့်လိမ့်မည်၊ ဤအတွက်၊ အထက်ဖော်ပြပါ Add-server လုပ်ထုံးလုပ်နည်းတွင်၊ အောက်ပါကုဒ်သည် တာဝန်ရှိသည်-

.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"

ယခုအခါ၊ သစ်ပင်ရှိ ဆာဗာအမည်ကို နှိပ်ခြင်းဖြင့်၊ ထိုဆာဗာမှ စီမံခန့်ခွဲသည့် အစုအဝေးများစာရင်းကို ကျွန်ုပ်တို့ရရှိပြီး အစုအဝေးတစ်ခုကို နှိပ်ခြင်းဖြင့်၊ အစုအဝေးဒြပ်စင်များစာရင်း (ဆာဗာများ၊ အင်ဖိုဘေ့စ်များ စသည်) ကို ရရှိပါသည်။ ၎င်းကို TreePress လုပ်ထုံးလုပ်နည်း (file lib/function.tcl) တွင် အကောင်အထည်ဖော်သည်-

proc TreePress {tree} {
   global host server active_cluster infobase
   # определяем выделенный элемент
    set id  [$tree selection]
   # устанавливаем нужные глобальные переменные
    SetGlobalVarFromTreeItems $tree $id
   # Определяем ключ и значение, т.е. именно тип выбранного элемента
    set values [$tree item $id -values]
    set key [lindex [split $id "::"] 0]
   # и в зависимости от того что выбрали будет запущена соответствующая процедура 
   # в пространстве имён Run
    Run::$key $tree $host $values
}

ထို့ကြောင့်၊ Run::ဆာဗာသည် ပင်မဆာဗာအတွက် (အစုအဝေးတစ်ခုအတွက် - Run::cluster၊ အလုပ်လုပ်သောဆာဗာတစ်ခုအတွက် - Run::work_server စသည်ဖြင့်) ကို စတင်ပါမည်။ အဲဒါတွေ။ $key variable ၏တန်ဖိုးသည် option မှသတ်မှတ်ထားသောသစ်ပင်ဒြပ်စင်အမည်၏တစ်စိတ်တစ်ပိုင်းဖြစ်သည်။ -အိုင်ဒီ.

လုပ်ထုံးလုပ်နည်းကို အာရုံစိုက်ကြည့်ရအောင်

Run::ဆာဗာ

proc Run::server {tree host values} {
    # получаем список кластеров требуемого сервера
    set lst [RunCommand server::$host "cluster list $host"]
    if {$lst eq ""} {return}
    set l [lindex $lst 0]
    #puts $lst
    # удаляем лишнее из списка
    .frm_work.tree_work delete  [ .frm_work.tree_work children {}]
    # читаем список
    foreach cluster_list $lst {
        # Заполняем список полученными значениями
        InsertItemsWorkList $cluster_list
        # обрабатываем вывод (список) для добавления данных в дерево
        foreach i $cluster_list {
            #puts $i
            set cluster_list [split $i ":"]
            if  {[string trim [lindex $cluster_list 0]] eq "cluster"} {
                set cluster_id [string trim [lindex $cluster_list 1]]
                lappend cluster($cluster_id) $cluster_id
            }
            if  {[string trim [lindex $cluster_list 0]] eq "name"} {
                lappend  cluster($cluster_id) [string trim [lindex $cluster_list 1]]
            }
        }
    }
    # добавляем кластеры в дерево
    foreach x [array names cluster] {
        set id [lindex $cluster($x) 0]
        if { [$tree exists "cluster::$id"] == 0 } {
            $tree insert "server::$host" end -id "cluster::$id" -text "[lindex $cluster($x) 1]" -values "$id"
            # добавляем элементы в кластер
            InsertClusterItems $tree $id
        }
    }
    if { [$tree exists "agent_admins::$id"] == 0 } {
        $tree insert "server::$host" end -id "agent_admins::$id" -text "Администраторы" -values "$id"
        #InsertClusterItems $tree $id
    }
}

ဤလုပ်ငန်းစဉ်သည် RunCommand အမိန့်ဖြင့် ဆာဗာမှရရှိသည့်အရာကို လုပ်ဆောင်ပြီး သစ်ပင်-အစုအဝေးများ၊ အမျိုးမျိုးသော အမြစ်ဒြပ်စင်များ (အခြေစိုက်စခန်းများ၊ လုပ်ဆောင်နေသော ဆာဗာများ၊ ဆက်ရှင်များနှင့် အခြားအရာများ) သို့ အရာအားလုံးကို ပေါင်းထည့်သည်။ အနီးကပ်ကြည့်ရှုပါက၊ အတွင်းတွင် InsertItemsWorkList လုပ်ထုံးလုပ်နည်းသို့ ဖုန်းခေါ်ဆိုသည်ကို သတိပြုမိပါလိမ့်မည်။ ၎င်းကို ယခင်က $lst variable သို့ စာရင်းအဖြစ် ပြန်ပေးခဲ့သည့် rac console utility ၏ output ကို လုပ်ဆောင်ခြင်းဖြင့် graphical list တစ်ခုသို့ အစိတ်အပိုင်းများကို ပေါင်းထည့်ရန် အသုံးပြုသည်။ ဤသည်မှာ ကော်လံဖြင့် ပိုင်းခြားထားသော ဒြပ်စင်အတွဲများပါရှိသော စာရင်းများဖြစ်သည်။

ဥပမာ၊ အစုအဝေးချိတ်ဆက်မှုစာရင်း-

svk@svk ~]$ /opt/1C/v8.3/x86_64/rac connection list --cluster=783d2170-56c3-11e8-c586-fc75165efbb2 localhost:1545
connection     : dcf5991c-7d24-11e8-1690-fc75165efbb2
conn-id        : 0
host           : svk.home
process        : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase       : 00000000-0000-0000-0000-000000000000
application    : "JobScheduler"
connected-at   : 2018-07-01T14:49:51
session-number : 0
blocked-by-ls  : 0

connection     : b993293a-7d24-11e8-1690-fc75165efbb2
conn-id        : 0
host           : svk.home
process        : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase       : 00000000-0000-0000-0000-000000000000
application    : "JobScheduler"
connected-at   : 2018-07-01T14:48:52
session-number : 0
blocked-by-ls  : 0

ဂရပ်ဖစ်ပုံစံဖြင့် ၎င်းသည် ဤကဲ့သို့သောပုံပေါ်လိမ့်မည်-

အထက်ပါလုပ်ထုံးလုပ်နည်းသည် ဇယားကိုဖြည့်ရန် ခေါင်းစီးနှင့်ဒေတာအတွက် အစိတ်အပိုင်းများ၏အမည်များကို ရွေးချယ်သည်-

InsertItemsWorkList

proc InsertItemsWorkList {lst} {
    global work_list_row_count
    # установка чередования цвета для строки
    if [expr $work_list_row_count % 2] {
        set tag dark
    } else {
        set tag light
    }
    # разбор строк на пары ключ - значение
    foreach i $lst {
        if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
            lappend column_list [string trim $param]
            lappend value_list [string trim $value]
        }
    }
     # заполнение таблицы
    .frm_work.tree_work configure -columns $column_list -displaycolumns $column_list
    .frm_work.tree_work insert {} end  -values $value_list -tags $tag
    .frm_work.tree_work column #0 -stretch
    # установка заголовков
    foreach j $column_list {
        .frm_work.tree_work heading $j -text $j
    }
    incr work_list_row_count
}

ဤနေရာတွင်၊ string ကို ":" ခြားထားသော ဒြပ်စင်များအဖြစ် ပိုင်းခြားပြီး စာရင်းကို ပြန်ပေးသည့် ရိုးရှင်းသော command [split $str ":"] အစား၊ အချို့သောဒြပ်စင်များသည် ကော်လံတစ်ခုပါ၀င်သောကြောင့် ပုံမှန်အသုံးအနှုန်းကို အသုံးပြုပါသည်။

InsertClusterItems လုပ်ထုံးလုပ်နည်း (အလားတူများစွာထဲမှတစ်ခု) သည် လိုအပ်သော အစုအဝေးဒြပ်စင်၏သစ်ပင်သို့ သက်ဆိုင်ရာ identifiers များနှင့်အတူ ကလေးဒြပ်စင်များစာရင်းကို ရိုးရှင်းစွာထည့်သည်။
InsertClusterItems

proc InsertClusterItems {tree id} {
    set parent "cluster::$id"
    $tree insert $parent end -id "infobases::$id" -text "Информационные базы" -values "$id"
    $tree insert $parent end -id "servers::$id" -text "Рабочие серверы" -values "$id"
    $tree insert $parent end -id "admins::$id" -text "Администраторы" -values "$id"
    $tree insert $parent end -id "managers::$id" -text "Менеджеры кластера" -values $id
    $tree insert $parent end -id "processes::$id" -text "Рабочие процессы" -values "workprocess-all"
    $tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "sessions-all"
    $tree insert $parent end -id "locks::$id" -text "Блокировки" -values "blocks-all"
    $tree insert $parent end -id "connections::$id" -text "Соединения" -values "connections-all"
    $tree insert $parent end -id "profiles::$id" -text "Профили безопасности" -values $id
}

အလားတူလုပ်ထုံးလုပ်နည်းတစ်ခုကို အကောင်အထည်ဖော်ရန်အတွက် နောက်ထပ်ရွေးချယ်စရာနှစ်ခုကို သင်ထည့်သွင်းစဉ်းစားနိုင်သည်၊ ၎င်းသည် ထပ်တလဲလဲသောအမိန့်များကို ပိုမိုကောင်းမွန်အောင်လုပ်ဆောင်နိုင်ပုံတို့ကို ရှင်းလင်းစွာမြင်နိုင်သည်-

ဤလုပ်ထုံးလုပ်နည်းတွင်၊ ထည့်သွင်းခြင်းနှင့် စစ်ဆေးခြင်းကို ထိပ်တိုက်ဖြေရှင်းနိုင်သည်-

InsertBaseItems

proc InsertBaseItems {tree id} {
    set parent "infobase::$id"
    if { [$tree exists "sessions::$id"] == 0 } {
        $tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "$id"
    }
    if { [$tree exists "locks::$id"] == 0 } {
        $tree insert $parent end -id "locks::$id" -text "Блокировки" -values "$id"
    }
    if { [$tree exists "connections::$id"] == 0 } {
        $tree insert $parent end -id "connections::$id" -text "Соединения" -values "$id"
    }
}

ဤသည်မှာ ပိုမိုမှန်ကန်သောချဉ်းကပ်မှုဖြစ်သည်-

ပရိုဖိုင်အကြောင်းအရာများကို ထည့်သွင်းပါ။

proc InsertProfileItems {tree id} {
    set parent "profile::$id"
    set lst {
        {dir "Виртуальные каталоги"}
        {com "Разрешённые COM-классы"}
        {addin "Внешние компоненты"}
        {module "Внешние отчёты и обработки"}
        {app "Разрешённые приложения"}
        {inet "Ресурсы интернет"}
    }
    foreach i $lst {
        append item [lindex $i 0] "::$id"
        if { [$tree exists $item] == 0 } {
            $tree insert $parent end -id $item -text [lindex $i 1] -values "$id"
        }
        unset item 
    }
}

၎င်းတို့အကြား ခြားနားချက်မှာ ထပ်ခါတလဲလဲ အမိန့်(များ)ကို လုပ်ဆောင်သည့် ကွင်းပတ်အသုံးပြုမှု ဖြစ်သည်။ မည်သည့်နည်းလမ်းကို အသုံးပြုရန်မှာ developer ၏ ဆုံးဖြတ်ချက်အရဖြစ်သည်။

ဒြပ်စင်များ ပေါင်းထည့်ခြင်းနှင့် ဒေတာရယူခြင်းတို့ကို အကျုံးဝင်ခဲ့ပြီး ယခုအခါ တည်းဖြတ်ခြင်းကို အာရုံစိုက်ရန် အချိန်ကျရောက်ပြီဖြစ်သည်။ အခြေခံအားဖြင့် တူညီသောဘောင်များကို တည်းဖြတ်ခြင်းနှင့် ပေါင်းထည့်ခြင်းအတွက် (အချက်အလက်အခြေခံမှလွဲ၍) တူညီသော ဒိုင်ယာလော့ခ်ပုံစံများကို အသုံးပြုပါသည်။ ပေါင်းထည့်ခြင်းအတွက် ခေါ်ဆိုခြင်းဆိုင်ရာ algorithm သည် ဤကဲ့သို့ ဖြစ်သည်-

Add::$key->AddToplevel

ဤကဲ့သို့ တည်းဖြတ်ခြင်းအတွက်၊

တည်းဖြတ်ရန်-:$key->Add::$key->AddTopLevel

ဥပမာ၊ အစုအဖွဲ့တစ်ခုကို တည်းဖြတ်ကြပါစို့၊ ဥပမာ၊ သစ်ပင်ရှိ အစုအဝေး၏အမည်ကို နှိပ်လိုက်ပြီးနောက်၊ ကိရိယာဘား (ခဲတံ) ရှိ တည်းဖြတ်ခလုတ်ကို နှိပ်လိုက်သည်နှင့် သက်ဆိုင်သည့်ပုံစံကို စခရင်ပေါ်တွင် ပြသပါမည်-

တည်းဖြတ်::အစုအဝေး

proc Edit::cluster {tree host values} {
    global default lifetime_limit expiration_timeout session_fault_tolerance_level
    global max_memory_size max_memory_time_limit errors_count_threshold security_level
    global load_balancing_mode kill_problem_processes active_cluster 
    agent_user agent_pwd cluster_user cluster_pwd auth
    if {$cluster_user ne "" && $cluster_pwd ne ""} {
        set auth "--cluster-user=$cluster_user --cluster-pwd=$cluster_pwd"
    } else {
        set auth ""
    }
    # рисуем форму для кластера
    set frm [Add::cluster $tree $host $values]
    # меняем текст на метке
    $frm configure -text "Редактирование кластера"
    
    set active_cluster $values
    # получаем данные по выделенному кластеру
    set lst [RunCommand cluster::$values "cluster info --cluster=$active_cluster $host"]
    # заполняем поля
    FormFieldsDataInsert $frm $lst
    # выключаем поля, редактирование которых запрещено
    $frm.ent_host configure -state disable
    $frm.ent_port configure -state disable
    # переназначаем обработчик
    .add.frm_btn.btn_ok configure -command {
        RunCommand "" "cluster update 
        --cluster=$active_cluster $auth 
        --name=[.add.frm.ent_name get] 
        --expiration-timeout=$expiration_timeout 
        --lifetime-limit=$lifetime_limit 
        --max-memory-size=$max_memory_size 
        --max-memory-time-limit=$max_memory_time_limit 
        --security-level=$security_level 
        --session-fault-tolerance-level=$session_fault_tolerance_level 
        --load-balancing-mode=$load_balancing_mode 
        --errors-count-threshold=$errors_count_threshold 
        --kill-problem-processes=$kill_problem_processes 
        $auth $host"
        $tree delete "cluster::$active_cluster"
        Run::server $tree $host ""
        destroy .add
    }
}

ကုဒ်ရှိ မှတ်ချက်များအပေါ် အခြေခံ၍ မူအရ၊ ခလုတ်ကိုင်တွယ်သူကုဒ်ကို လွှမ်းမိုးထားပြီး ကွက်လပ်များကို ဒေတာဖြည့်ပေးပြီး ကိန်းရှင်များကို စတင်လုပ်ဆောင်သည့် FormFieldsDataInsert လုပ်ထုံးလုပ်နည်းမှလွဲ၍ အရာအားလုံး ရှင်းလင်းပြတ်သားပါသည်။

FormFieldsDataInsert

proc FormFieldsDataInsert {frm lst} {
    foreach i [lindex $lst 0] {
        # получаем список параметров и значений
        if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
            # меняем символы
            regsub -all -- "-" [string trim $param] "_" entry_name
            # заполняем данными
            if [winfo exists $frm.ent_$entry_name] {
                $frm.ent_$entry_name delete 0 end
                $frm.ent_$entry_name insert end [string trim $value """]
            }
            if [winfo exists $frm.cb_$entry_name] {
                global $entry_name
                set $entry_name [string trim $value """]
            }
            # для чекбоксов меняем значения
            if [winfo exists $frm.check_$entry_name] {
                global $entry_name
                if {$value eq "0"} {
                    set $entry_name no
                } elseif {$value eq "1"} {
                    set $entry_name yes
                } else {
                    set $entry_name $value
                }
            }
        }
    }
}

ဤလုပ်ထုံးလုပ်နည်းတွင်၊ tcl ၏နောက်ထပ်အားသာချက်တစ်ခုပေါ်လာသည် - အခြား variable များ၏တန်ဖိုးများကို variable အမည်များအဖြစ်အစားထိုးသည်။ အဲဒါတွေ။ ပုံစံများဖြည့်စွက်ခြင်းနှင့် variable များ၏အစပြုခြင်းကို အလိုအလျောက်လုပ်ဆောင်ရန်၊ ကွက်လပ်များနှင့် variable များ၏အမည်များသည် rac utility ၏ command line switches များနှင့် ခြွင်းချက်အချို့ဖြင့် command output parameters အမည်များ - dash ကို underscore ဖြင့်အစားထိုးသည်။ ဥပမာ scheduled-jobs-deny ကွင်းနှင့်ကိုက်ညီသည်။ ent_scheduled_jobs_deny နှင့် ပြောင်းလဲနိုင်သည်။ scheduled_jobs_deny.

ပေါင်းထည့်ခြင်းနှင့် တည်းဖြတ်ခြင်းအတွက် ဖောင်ပုံစံများသည် အကွက်များ၏ ဖွဲ့စည်းမှုတွင် ကွဲပြားနိုင်သည်၊ ဥပမာ၊ အချက်အလက်အခြေခံတစ်ခုဖြင့် လုပ်ဆောင်သည်-

သတင်းအချက်အလက်လုံခြုံရေးကို ထည့်သွင်းခြင်း။

အချက်အလက်လုံခြုံရေးကို တည်းဖြတ်ခြင်း။

တည်းဖြတ်ခြင်းလုပ်ငန်းစဉ်တွင် Edit::infobase၊ လိုအပ်သောအကွက်များကို ဖောင်တွင်ထည့်သည်၊ ကုဒ်သည် တောက်ပနေသောကြောင့် ဤနေရာတွင် ကျွန်ုပ်မတင်ပြပါ။

ဥပမာအားဖြင့်၊ ပေါင်းထည့်ခြင်း၊ တည်းဖြတ်ခြင်း၊ ဖျက်ခြင်းအတွက် လုပ်ထုံးလုပ်နည်းများကို အခြားဒြပ်စင်များအတွက် လုပ်ဆောင်ပါသည်။

utility ၏ လုပ်ဆောင်ချက်သည် အကန့်အသတ်မရှိသော ဆာဗာများ၊ အစုအဝေးများ၊ သတင်းအချက်အလက် အခြေစိုက်စခန်းများ စသည်တို့ကို ရည်ညွှန်းထားသောကြောင့် မည်သည့်ဆာဗာ သို့မဟုတ် သတင်းအချက်အလက် လုံခြုံရေးစနစ်၏ အစုအဝေးကို ပိုင်ဆိုင်ကြောင်း ဆုံးဖြတ်ရန်အတွက် ကမ္ဘာလုံးဆိုင်ရာ ကိန်းရှင်များစွာကို မိတ်ဆက်ခဲ့ပြီး၊ တစ်ခုစီတွင် သတ်မှတ်ထားသည့် တန်ဖိုးများ၊ သစ်ပင်၏ဒြပ်စင်များကိုသင်ကလစ်နှိပ်ပါ။ အဲဒါတွေ။ လုပ်ထုံးလုပ်နည်းသည် ပင်မဒြပ်စင်များအားလုံးမှတဆင့် ထပ်ခါတလဲလဲလည်ပတ်ပြီး ကိန်းရှင်များကို သတ်မှတ်သည်-

SetGlobalVarFromTreeItems

proc SetGlobalVarFromTreeItems {tree id} {
    global host server active_cluster infobase
    set parent [$tree parent $id]
    set values [$tree item $id -values]
    set key [lindex [split $id "::"] 0]
    switch -- $key {
        server {set host $values}
        work_server {set server $values}
        cluster {set active_cluster $values}
        infobase {set infobase $values}
    }
    if {$parent eq ""} {
        return
    } else {
        SetGlobalVarFromTreeItems $tree $parent
    }
}

1C အစုအဝေးသည် သင့်အား ခွင့်ပြုချက်ဖြင့် သို့မဟုတ် အလုပ်မလုပ်ဘဲ ခွင့်ပြုထားသည်။ စီမံခန့်ခွဲသူ အမျိုးအစား နှစ်မျိုး ရှိသည် - အစုလိုက် ကိုယ်စားလှယ် စီမံခန့်ခွဲသူ နှင့် အစုလိုက် စီမံခန့်ခွဲသူ ဟူ၍ နှစ်မျိုး ရှိသည်။ ထို့ကြောင့်၊ မှန်ကန်သောလုပ်ဆောင်ချက်အတွက်၊ စီမံခန့်ခွဲသူဝင်ရောက်ခြင်းနှင့် စကားဝှက်များပါရှိသော နောက်ထပ် ကမ္ဘာလုံးဆိုင်ရာ ကိန်းရှင် ၄ ခုကို မိတ်ဆက်ပေးခဲ့သည်။ အဲဒါတွေ။ အစုအဝေးတွင် စီမံခန့်ခွဲသူအကောင့်တစ်ခုရှိနေပါက၊ သင်၏ဝင်ရောက်မှုနှင့် စကားဝှက်ကိုထည့်သွင်းရန် ဒိုင်ယာလော့ခ်တစ်ခုပြသမည်ဖြစ်ပြီး ဒေတာများကို မှတ်ဉာဏ်တွင်သိမ်းဆည်းမည်ဖြစ်ပြီး သက်ဆိုင်ရာအစုအဝေးအတွက် အမိန့်တစ်ခုစီတွင် ထည့်သွင်းမည်ဖြစ်သည်။

ဤသည်မှာ အမှားအယွင်းကို ကိုင်တွယ်ခြင်း၏ တာဝန်ဖြစ်သည်။

ErrorParcing

proc ErrorParcing {err opt} {
    global cluster_user cluster_pwd agent_user agent_pwd
        switch -regexp -- $err {
        "Cluster administrator is not authenticated" {
            AuthorisationDialog "Администратор кластера"
            .auth_win.frm_btn.btn_ok configure -command {
                set cluster_user [.auth_win.frm.ent_name get]
                set cluster_pwd [.auth_win.frm.ent_pwd get]
                destroy .auth_win
            }
            #RunCommand $root $par
        }
        "Central server administrator is not authenticated" {
            AuthorisationDialog "Администратор агента кластера"
            .auth_win.frm_btn.btn_ok configure -command {
                set agent_user [.auth_win.frm.ent_name get]
                set agent_pwd [.auth_win.frm.ent_pwd get]
                destroy .auth_win
            }
        }
        "Администратор кластера не аутентифицирован" {
            AuthorisationDialog "Администратор кластера"
            .auth_win.frm_btn.btn_ok configure -command {
                set cluster_user [.auth_win.frm.ent_name get]
                set cluster_pwd [.auth_win.frm.ent_pwd get]
                destroy .auth_win
            }
            #RunCommand $root $par
        }
        "Администратор центрального сервера не аутентифицирован" {
            AuthorisationDialog "Администратор агента кластера"
            .auth_win.frm_btn.btn_ok configure -command {
                set agent_user [.auth_win.frm.ent_name get]
                set agent_pwd [.auth_win.frm.ent_pwd get]
                destroy .auth_win
            }
        }
        (.+) {
            tk_messageBox -type ok -icon error -message "$err"
        }
    }
}

အဲဒါတွေ။ အမိန့်ပြန်ပေးသည့်အပေါ်မူတည်၍ တုံ့ပြန်မှုသည် လျော်ညီမည်ဖြစ်သည်။

လောလောဆယ်တွင်၊ လုပ်ဆောင်နိုင်စွမ်း၏ 95 ရာခိုင်နှုန်းခန့်ကို အကောင်အထည် ဖော်ထားပြီး ကျန်အားလုံးမှာ လုံခြုံရေးပရိုဖိုင်များဖြင့် အလုပ်လုပ်ပြီး စမ်းသပ်ရန် =)။ ဒါပါပဲ။ ရှုပ်ယှက်ခတ်နေတဲ့ ဇာတ်လမ်းအတွက် တောင်းပန်ပါတယ်။

ကုဒ်ကို ရှေးယခင်ကတည်းက ရရှိနိုင်သည်။ ဒီမှာ.

အပ်ဒိတ်- ကျွန်ုပ်သည် လုံခြုံရေးပရိုဖိုင်များဖြင့် လုပ်ဆောင်ပြီးပါပြီ။ ယခုလုပ်ဆောင်ချက်ကို 100% အကောင်အထည်ဖော်နိုင်ပါပြီ။

အပ်ဒိတ် 2- အင်္ဂလိပ်နှင့် ရုရှားဘာသာသို့ နယ်ပယ်ချဲ့ထွင်ခြင်းကို ထည့်သွင်းထားပြီး၊ win7 တွင် အလုပ်လုပ်ခြင်းကို စမ်းသပ်ပြီးဖြစ်သည်။


source: www.habr.com