Waves စမတ်အကောင့်များ၏ အသုံးချမှုများ- လေလံပွဲများမှ အပိုဆုအစီအစဉ်များအထိ

Blockchain သည် မကြာခဏ cryptocurrencies နှင့်သာ ဆက်စပ်မှုရှိသော်လည်း DLT နည်းပညာကို အသုံးပြုသည့် နယ်ပယ်များသည် ပိုမိုကျယ်ပြန့်သည်။ blockchain ကိုအသုံးပြုခြင်းအတွက်အလားအလာအရှိဆုံးနယ်ပယ်တစ်ခုသည်အလိုအလျောက်လုပ်ဆောင်သောစမတ်စာချုပ်ဖြစ်ပြီး၎င်းထဲသို့ဝင်သောပါတီများအကြားယုံကြည်မှုမလိုအပ်ပါ။

RIDE - စမတ်ကျသော စာချုပ်များအတွက် ဘာသာစကား

Waves သည် စမတ်စာချုပ်များအတွက် အထူးဘာသာစကားကို တီထွင်ခဲ့သည် – RIDE။ ၎င်း၏စာရွက်စာတမ်းအပြည့်အစုံမှာတည်ရှိသည်။ ဒီမှာ. ဒီမှာ- ဤအကြောင်းအရာအပေါ်ဆောင်းပါး Habr တွင်

RIDE စာချုပ်သည် ကြိုတင်ဖော်ပြချက်တစ်ခုဖြစ်ပြီး အထွက်အဖြစ် "မှန်" သို့မဟုတ် "မှား" ပြန်ပေးသည်။ ထို့ကြောင့်၊ ငွေပေးငွေယူကို blockchain တွင်မှတ်တမ်းတင်ထားသည် သို့မဟုတ် ငြင်းပယ်ခံရသည်။ စမတ်စာချုပ်သည် သတ်မှတ်ထားသော အခြေအနေများ ပြည့်စုံစေရန် အပြည့်အဝ အာမခံပါသည်။ RIDE တွင် စာချုပ်တစ်ခုမှ ငွေပေးငွေယူများ ပြုလုပ်ခြင်းကို လောလောဆယ် မဖြစ်နိုင်ပါ။

ယနေ့ခေတ်တွင် Waves စမတ်ကန်ထရိုက်များ အမျိုးအစားနှစ်မျိုးရှိသည်- စမတ်အကောင့်များနှင့် စမတ်ပိုင်ဆိုင်မှုများ။ စမတ်အကောင့်သည် ပုံမှန်အသုံးပြုသူအကောင့်တစ်ခုဖြစ်သော်လည်း ငွေပေးငွေယူအားလုံးကို ထိန်းချုပ်သည့် ၎င်းအတွက် script တစ်ခုသတ်မှတ်ထားသည်။ စမတ်အကောင့် script သည် ဤကဲ့သို့သောပုံရသည်၊ ဥပမာ-

match tx {
  case t: TransferTransaction | MassTransferTransaction => false
  case _ => true
}

tx သည် လွှဲပြောင်းပေးချေမှုတစ်ခုမဟုတ်မှသာ ပုံစံတူယန္တရားကို အသုံးပြု၍ ခွင့်ပြုပေးသော ငွေပေးငွေယူကို လုပ်ဆောင်နေသည်။ ငွေပေးငွေယူအမျိုးအစားကို စစ်ဆေးရန် RIDE တွင် ပုံစံတူကို အသုံးပြုသည်။ ရှိပြီးသားအကောင့်အားလုံးကို smart account script တွင် လုပ်ဆောင်နိုင်ပါသည်။ ငွေပေးငွေယူအမျိုးအစားများ.

script သည် variable များကိုကြေငြာနိုင်သည်၊ "if-then-else" constructs များနှင့် အခြေအနေများကို အပြည့်အဝစစ်ဆေးရန်အတွက် အခြားနည်းလမ်းများကို အသုံးပြုနိုင်သည်။ စာချုပ်များမစတင်မီ ခန့်မှန်းရလွယ်ကူသော သက်သေပြနိုင်သော ပြီးပြည့်စုံမှုနှင့် ရှုပ်ထွေးမှု (ကုန်ကျစရိတ်) ရှိစေရန် သေချာစေရန်၊ RIDE တွင် loops သို့မဟုတ် jump statement များမပါဝင်ပါ။

Waves အကောင့်များ၏ အခြားအင်္ဂါရပ်များမှာ အကောင့်၏အခြေအနေ၊ ဆိုလိုသည်မှာ “ပြည်နယ်” ရှိနေခြင်းဖြစ်သည်။ ဒေတာလွှဲပြောင်းမှုများ (DataTransaction) ကို အသုံးပြု၍ အကောင့်အခြေအနေသို့ အကန့်အသတ်မရှိအတွဲများ (သော့၊ တန်ဖိုး) ကို ရေးနိုင်သည်။ ထို့နောက် ဤအချက်အလက်ကို REST API မှတစ်ဆင့် နှင့် smart စာချုပ်တွင် တိုက်ရိုက် နှစ်မျိုးလုံး လုပ်ဆောင်နိုင်သည်။

ငွေပေးငွေယူတစ်ခုစီတွင် ပါဝင်သူ၏ လက်မှတ်၊ လိုအပ်သော ငွေပေးငွေယူ ID စသည်တို့ကို ထည့်သွင်းနိုင်သည့် အထောက်အထားများစွာ ပါဝင်နိုင်သည်။

မှတဆင့် RIDE နှင့်အလုပ်လုပ်သည်။ ဒီမှာ စာချုပ်၏ စုစည်းထားသော မြင်ကွင်းကို သင်မြင်နိုင်သည် (ပြုစုထားလျှင်) အကောင့်အသစ်များ ဖန်တီးပြီး ၎င်းအတွက် script များ သတ်မှတ်ပေးသည့်အပြင် command line မှတဆင့် ငွေပေးငွေယူများ ပေးပို့နိုင်သည်။

အကောင့်ဖန်တီးခြင်း၊ ၎င်းတွင် စမတ်ကျသည့်စာချုပ်ကို ထည့်သွင်းခြင်းနှင့် ငွေပေးငွေယူပေးပို့ခြင်းအပါအဝင် သံသရာတစ်ခုလုံးအတွက်၊ REST API နှင့် အပြန်အလှန်တုံ့ပြန်ရန်အတွက် စာကြည့်တိုက်ကိုလည်း သင်အသုံးပြုနိုင်သည် (ဥပမာ၊ C#၊ C၊ Java၊ JavaScript၊ Python၊ Rust၊ Elixir) . IDE နှင့် စတင်အလုပ်လုပ်ရန် NEW ခလုတ်ကို နှိပ်ပါ။

စမတ်စာချုပ်များကို အသုံးပြုရန် ဖြစ်နိုင်ခြေများ ကျယ်ပြန့်သည်- အချို့သော လိပ်စာများသို့ ငွေပေးငွေယူများကို တားမြစ်ခြင်းမှ (“black list”) မှ ရှုပ်ထွေးသော dApps များအထိ။

ယခု စီးပွားရေးလုပ်ငန်းတွင် စမတ်စာချုပ်များအသုံးပြုခြင်း၏ သီးခြားဥပမာများကို ကြည့်ကြပါစို့- လေလံပွဲများ၊ အာမခံနှင့် သစ္စာစောင့်သိမှုပရိုဂရမ်များ ဖန်တီးသည့်အခါ။

လေလံပွဲ

အောင်မြင်သောလေလံပွဲအတွက် အခြေအနေများထဲမှတစ်ခုမှာ ပွင့်လင်းမြင်သာမှုဖြစ်သည်- ပါဝင်သူများသည် လေလံဆွဲရန် မဖြစ်နိုင်ကြောင်း ယုံကြည်ရပါမည်။ အလောင်းအစားအားလုံးနှင့် ပတ်သက်သည့် မပြောင်းလဲနိုင်သော ဒေတာနှင့် ၎င်းတို့ကို ပါဝင်သူအားလုံးထံ ရရှိနိုင်သည့် blockchain ကြောင့် ၎င်းကို အောင်မြင်နိုင်သည်။

Waves blockchain တွင်၊ DataTransaction မှတဆင့်လေလံအကောင့်အခြေအနေတွင်လေလံများကိုမှတ်တမ်းတင်နိုင်သည်။

ပိတ်ဆို့နံပါတ်များကို အသုံးပြု၍ လေလံပွဲ၏အစနှင့်အဆုံးအချိန်ကိုလည်း သင်သတ်မှတ်နိုင်သည်- Waves blockchain ရှိ ပိတ်ဆို့ထုတ်လုပ်သည့်အကြိမ်ရေသည် ခန့်မှန်းခြေအားဖြင့် ညီမျှသည် 60 စက္ကန့်။

1. အင်္ဂလိပ်လို ကြီးကြီးမြင့်မား စျေးနှုန်းလေလံ

အင်္ဂလိပ်လေလံပွဲ၌ ပါဝင်သူများသည် အချင်းချင်း ပြိုင်ဆိုင်မှုဖြင့် လေလံတင်ကြသည်။ လောင်းကြေးအသစ်တစ်ခုစီသည် ယခင်တစ်ခုထက်ပိုရပါမည်။ နောက်ဆုံးလေလံထက် ကျော်လွန်ရန် လေလံဆွဲသူမရှိတော့သည့်အခါ လေလံပွဲပြီးဆုံးသည်။ ဤကိစ္စတွင်၊ အမြင့်ဆုံးလေလံဆွဲသူသည် ဖော်ပြထားသော ပမာဏကို ပေးရမည်။

ရောင်းချသူသည် စာရေးတံအတွက် အနိမ့်ဆုံးစျေးနှုန်းကို သတ်မှတ်ပေးသည့် လေလံရွေးချယ်ခွင့်လည်း ရှိပြီး နောက်ဆုံးစျေးနှုန်းထက် ၎င်းကို ကျော်လွန်ရမည်ဖြစ်သည်။ မဟုတ်ရင် စျေးမရောင်းရသေးဘူး။

ဤဥပမာတွင်၊ ကျွန်ုပ်တို့သည် လေလံပွဲအတွက် အထူးဖန်တီးထားသော အကောင့်တစ်ခုနှင့် လုပ်ဆောင်နေပါသည်။ လေလံပွဲကြာချိန်သည် တုံး 3000 ဖြစ်ပြီး စာရေး၏အစဈေးမှာ 0,001 WAVES ဖြစ်သည်။ ပါဝင်သူတစ်ဦးသည် သော့ “စျေးနှုန်း” နှင့် ၎င်းတို့၏ လေလံတန်ဖိုးကို DataTransaction ပေးပို့ခြင်းဖြင့် လေလံတင်နိုင်သည်။

လေလံအသစ်၏စျေးနှုန်းသည် ဤသော့အတွက် လက်ရှိစျေးနှုန်းထက် ပိုမြင့်ရမည်ဖြစ်ပြီး ပါဝင်သူတွင် အနည်းဆုံး [new_bid + commission] တိုကင်များ ရှိရပါမည်။ လေလံဆွဲသူ၏လိပ်စာကို DataTransaction ရှိ "ပေးပို့သူ" အကွက်တွင် မှတ်တမ်းတင်ထားရမည်ဖြစ်ပြီး လက်ရှိလေလံပိတ်ဆို့သည့်အမြင့်သည် လေလံကာလအတွင်း ဖြစ်ရပါမည်။

လေလံပွဲအပြီးတွင် ပါဝင်သူသည် အမြင့်ဆုံးစျေးနှုန်းကို သတ်မှတ်ပါက၊ သက်ဆိုင်သောအများကြီးအတွက် သတ်မှတ်ထားသောစျေးနှုန်းနှင့် ငွေကြေးအတွဲအတွက် ပေးချေရန် ExchangeTransaction ပေးပို့နိုင်ပါသည်။

let startHeight = 384120
let finishHeight = startHeight + 3000
let startPrice = 100000
 
#извлекаем из транзакции адрес отправителя
let this = extract(tx.sender)
let token = base58'8jfD2JBLe23XtCCSQoTx5eAW5QCU6Mbxi3r78aNQLcNf'
 
match tx {
case d : DataTransaction =>
  #проверяем, задана ли в стейте цена
  let currentPrice = if isDefined(getInteger(this, "price"))
 
                      #извлекаем цену из стейта
                      then extract(getInteger(this, "price"))
                      else startPrice
 
  #извлекаем цену из транзакции
  let newPrice = extract(getInteger(d.data, "price"))
  let priceIsBigger = newPrice > currentPrice
  let fee = 700000
  let hasMoney = wavesBalance(tx.sender) + fee >= newPrice
 
  #убеждаемся, что в текущей транзакции два поля и что отправитель совпадает с указанным в транзакции
  let correctFields = size(d.data) == 2 &&      
      d.sender == addressFromString(extract(getString(d.data,"sender")))
  startHeight <= height && height <= finishHeight && priceIsBigger && hasMoney && correctFields
case e : ExchangeTransaction =>
  let senderIsWinner = e.sender == addressFromString(extract(getString(this, "sender"))) #убеждаемся, что лот обменивает тот, кто его выиграл
  let correctAssetPair = e.sellOrder.assetPair.amountAsset == token && ! isDefined(e.sellOrder.assetPair.priceAsset)
  let correctAmount = e.amount == 1
  let correctPrice = e.price == extract(getInteger(this, "price"))
 
  height > finishHeight && senderIsWinner && correctAssetPair && correctAmount && correctPrice
case _ => false
}

2. ဒတ်ခ်ျလေလံပွဲများ၏စျေးနှုန်းများကျဆင်း

ဒတ်ချ်လေလံတွင်၊ ဝယ်သူပေးဆောင်လိုသည့်ထက် ပိုမိုမြင့်မားသောစျေးနှုန်းဖြင့် ကနဦးကမ်းလှမ်းသည်။ ပါဝင်သူများထဲမှ တစ်ဦးမှ လက်ရှိပေါက်ဈေးဖြင့် ပစ္စည်းဝယ်ယူရန် သဘောတူသည်အထိ စျေးနှုန်းသည် တစ်ဆင့်ပြီးတစ်ဆင့် ကျဆင်းသွားပါသည်။

ဤဥပမာတွင်၊ မြစ်ဝကျွန်းပေါ်ဒေသ လျော့နည်းသွားသောအခါတွင် ကျွန်ုပ်တို့သည် ယခင်ပုံစံအတိုင်း တူညီသောကိန်းသေများကို အသုံးပြုပါသည်။ အကောင့် script သည် ပါဝင်သူသည် အလောင်းအစားပြုလုပ်ရန် ပထမဆုံးသူဟုတ်မဟုတ် စစ်ဆေးပါသည်။ မဟုတ်ပါက၊ DataTransaction ကို blockchain မှ လက်မခံပါ။

let startHeight = 384120
let finishHeight = startHeight + 3000
let startPrice = 100000000
let delta = 100
 
#извлекаем из транзакции адрес отправителя
let this = extract(tx.sender)
let token = base58'8jfD2JBLe23XtCCSQoTx5eAW5QCU6Mbxi3r78aNQLcNf'
match tx {
case d : DataTransaction =>
  let currentPrice = startPrice - delta * (height - startHeight)
 
  #извлекаем из поступившей дата-транзакции поле "price"
  let newPrice = extract(getInteger(d.data, "price"))
 
  #убеждаемся, что в стейте текущего аккаунта не содержится поля "sender"
  let noBetsBefore = !isDefined(getInteger(this, "sender"))
  let fee = 700000
  let hasMoney = wavesBalance(tx.sender) + fee >= newPrice
 
  #убеждаемся, что в текущей транзакции только два поля
  let correctFields = size(d.data) == 2 && newPrice == currentPrice && d.sender == addressFromString(extract(getString(d.data, "sender")))
  startHeight <= height && height <= finishHeight && noBetsBefore && hasMoney && correctFields
case e : ExchangeTransaction =>
 
  #убеждаемся, что отправитель текущей транзакции указан в стейте аккаунта по ключу sender
  let senderIsWinner = e.sender == addressFromString(extract(getString(this, "sender")))
 
  #убеждаемся, что аmount ассета указан корректно, и что прайс-ассет - waves
  let correctAssetPair = e.sellOrder.assetPair.amountAsset == token && ! isDefined(e.sellOrder.assetPair.priceAsset)
  let correctAmount = e.amount == 1
  let correctPrice = e.price == extract(getInteger(this, "price"))
  height > finishHeight && senderIsWinner && correctAssetPair && correctAmount && correctPrice
case _ => false
}

3. လေလံ “အားလုံးပေးချေ”

“All-pay” သည် မည်သူမည်ဝါဖြစ်သည်ကို မခွဲခြားဘဲ ပါဝင်သူအားလုံး လေလံပေးချေသည့် လေလံပွဲဖြစ်သည်။ ပါဝင်သူအသစ်တိုင်းသည် လေလံတစ်ခုပေးချေပြီး အမြင့်ဆုံးလေလံကိုပြုလုပ်သောပါဝင်သူသည် များစွာအနိုင်ရရှိမည်ဖြစ်သည်။

ကျွန်ုပ်တို့၏ဥပမာတွင်၊ လေလံတွင်ပါဝင်သူတိုင်းသည် (သော့၊ တန်ဖိုး)* = (“အနိုင်ရသူ”၊ လိပ်စာ)၊(“စျေးနှုန်း”၊ ဈေးနှုန်း) ဖြင့် ဒေတာလွှဲပြောင်းမှုမှတစ်ဆင့် လေလံတင်ထားသည်။ ဤပါဝင်သူသည် ၎င်း၏လက်မှတ်ဖြင့် လွှဲပြောင်းလွှဲပြောင်းမှုတစ်ခုရှိနှင့်ပြီး ၎င်း၏လေလံသည် ယခင်အားလုံးထက် ပိုမိုမြင့်မားမှသာ ထိုသို့သော Data Transaction ကို အတည်ပြုပါသည်။ EndHeight မရောက်မချင်း လေလံပွဲသည် ဆက်လက်ရှိနေပါသည်။

let startHeight = 1000
let endHeight = 2000
let this = extract(tx.sender)
let token = base58'8jfD2JBLe23XtCCSQoTx5eAW5QCU6Mbxi3r78aNQLcNf'
match tx {
 case d: DataTransaction =>
   #извлекаем из поступившей дата-транзакции поле "price"
   let newPrice = extract(getInteger(d.data, "price"))
 
   #извлекаем из пруфов транзакции публичный ключ аккаунта
   let pk = d.proofs[1]
   let address = addressFromPublicKey(pk)
 
   #извлекаем транзакцию доказательство из пруфов поступившей дата транзакции
   let proofTx = extract(transactionById(d.proofs[2]))
   
   height > startHeight && height < endHeight
   && size(d.data) == 2
   #убеждаемся, что адрес победителя, извлеченный из текущей транзакции, совпадает с адресом, извлеченным из пруфов
   && extract(getString(d.data, "winner")) == toBase58String(address.bytes)
   && newPrice > extract(getInteger(this, "price"))
   #проверяем, что транзакция подписана
   && sigVerify(d.bodyBytes, d.proofs[0], d.proofs[1])
   #проверяем корректность транзакции, указанной в пруфах
   && match proofTx {
     case tr : TransferTransaction =>
       tr.sender == address &&
       tr.amount == newPrice
     case _ => false
   }
 case t: TransferTransaction =>
 sigVerify(tx.bodyBytes, tx.proofs[0], tx.senderPublicKey)
 || (
   height > endHeight
   && extract(getString(this, "winner")) == toBase58String((addressFromRecipient(t.recipient)).bytes)
   && t.assetId == token
   && t.amount == 1
 )
 case _ => sigVerify(tx.bodyBytes, tx.proofs[0], tx.senderPublicKey)
}

အာမခံ / Crowdfunding

အသုံးပြုသူများ၏ ပိုင်ဆိုင်မှုများအား ငွေကြေးဆုံးရှုံးမှုမှ အာမခံရန် လိုအပ်သည့် အခြေအနေတစ်ခုကို သုံးသပ်ကြည့်ကြပါစို့။ ဥပမာအားဖြင့်၊ အသုံးပြုသူတစ်ဦးသည် တိုကင်တန်ဖိုးကျဆင်းသွားပါက ဤတိုကင်များအတွက် ပေးဆောင်ထားသည့် ပမာဏအပြည့်အစုံကို ပြန်လည်ရရှိနိုင်မည်ဖြစ်ပြီး ကျိုးကြောင်းဆီလျော်သော အာမခံပမာဏကို ပေးဆောင်လိုကြောင်း အာမခံချက်ရယူလိုပါသည်။

၎င်းကိုအကောင်အထည်ဖော်ရန် "အာမခံတိုကင်များ" ကိုထုတ်ပေးရန်လိုအပ်သည်။ ထို့နောက် အချို့သောအခြေအနေများနှင့် ကိုက်ညီသည့် ExchangeTransactions များကိုသာ မူဝါဒကိုင်ဆောင်သူ၏အကောင့်တွင် ထည့်သွင်းပြီး script ကို ထည့်သွင်းထားသည်။

နှစ်ဆအသုံးစရိတ်ကို တားဆီးရန်၊ အသုံးပြုသူအား (သော့၊ တန်ဖိုး) = (purchaseTransactionId၊ sellOrderId) ဖြင့် မူဝါဒကိုင်ဆောင်သူ၏အကောင့်သို့ DataTransaction ကို ကြိုတင်ပေးပို့ရန်နှင့် အသုံးပြုပြီးသားသော့ဖြင့် DataTransactions ပေးပို့ခြင်းကို တားမြစ်ရန် လိုအပ်ပါသည်။

ထို့ကြောင့်၊ အသုံးပြုသူ၏အထောက်အထားများတွင် အာမခံတိုကင်ဝယ်ယူမှု၏ ငွေပေးငွေယူ ID ပါဝင်ရပါမည်။ ငွေကြေးအတွဲသည် ဝယ်ယူမှုတွင်ရှိသည့်အတိုင်း ဖြစ်ရပါမည်။ ကုန်ကျစရိတ်သည် ဝယ်ယူချိန်တွင် သတ်မှတ်ထားသော အာမခံစျေးနှုန်းနှင့် အနုတ်လက္ခဏာဆောင်သော စျေးနှုန်းနှင့် ညီမျှရပါမည်။

နောက်ပိုင်းတွင် အာမခံအကောင့်သည် အသုံးပြုသူထံမှ အာမခံတိုကင်များကို သူဝယ်ယူခဲ့သည့်ထက် မနိမ့်သောစျေးနှုန်းဖြင့် ဝယ်ယူကြောင်း နားလည်သဘောပေါက်သည်- အာမခံအကောင့်သည် ExchangeTransaction တစ်ခုကို ဖန်တီးသည်၊ အသုံးပြုသူသည် အမှာစာကို လက်မှတ်ရေးထိုးသည် (ငွေပေးငွေယူမှန်ကန်ပါက)၊ အာမခံအကောင့်သည် ဒုတိယအမှာစာနှင့် ငွေပေးငွေယူတစ်ခုလုံးကို လက်မှတ်ရေးထိုးပြီး blockchain သို့ ပေးပို့သည်။

ဝယ်ယူမှုမဖြစ်ပေါ်ပါက၊ အသုံးပြုသူသည် script တွင်ဖော်ပြထားသောစည်းမျဉ်းများနှင့်အညီ ExchangeTransaction တစ်ခုကိုဖန်တီးနိုင်ပြီး blockchain သို့ငွေပေးငွေယူပေးပို့နိုင်သည်။ ဤနည်းဖြင့် အသုံးပြုသူသည် အာမခံတိုကင်များဝယ်ယူမှုတွင် အသုံးပြုသည့်ငွေကို ပြန်ပေးနိုင်သည်။

let insuranceToken = base58'8jfD2JBLe23XtCCSQoTx5eAW5QCU6Mbxi3r78aNQLcNf'
 
#извлекаем из транзакции адрес отправителя
let this = extract(tx.sender)
let freezePeriod = 150000
let insurancePrice = 10000
match tx {
 
 #убеждаемся, что, если поступила дата-транзакция, то у нее ровно одно поле и в стейте еще нет такого ключа
 case d : DataTransaction => size(d.data) == 1 && !isDefined(getBinary(this, d.data[0].key))
 case e : ExchangeTransaction =>
 
   #если у транзакции нет седьмого пруфа, проверяем корректность подписи
   if !isDefined(e.proofs[7]) then
     sigVerify(e.bodyBytes, e.proofs[0], e.senderPublicKey)
   else
     #если у транзакции есть седьмой пруф, извлекаем из него транзакцию и узнаём её высоту
     let purchaseTx = transactionById(e.proofs[7])
     let purchaseTxHeight = extract(transactionHeightById(e.proofs[7]))
    
     #обрабатываем транзакцию из пруфа
     match purchaseTx {
       case purchase : ExchangeTransaction =>
         let correctSender = purchase.sender == e.sellOrder.sender
         let correctAssetPair = e.sellOrder.assetPair.amountAsset == insuranceToken &&
                                purchase.sellOrder.assetPair.amountAsset == insuranceToken &&
                                e.sellOrder.assetPair.priceAsset == purchase.sellOrder.assetPair.priceAsset
         let correctPrice = e.price == purchase.price - insurancePrice && e.amount == purchase.amount
         let correctHeight = height > purchaseTxHeight + freezePeriod
 
         #убеждаемся, что в транзакции-пруфе указан верный ID текущей транзакции
         let correctProof = extract(getBinary(this, toBase58String(purchase.id))) == e.sellOrder.id
         correctSender && correctAssetPair && correctPrice && correctHeight && correctProof
     case _ => false
   }
 case _ => sigVerify(tx.bodyBytes, tx.proofs[0], tx.senderPublicKey)
}

အာမခံ တိုကင်တစ်ခုကို ပြင်ပအဖွဲ့အစည်းများထံ လွှဲပြောင်းခြင်းကို တားမြစ်ရန်၊ ဥပမာ၊ စမတ်ပစ္စည်းတစ်ခုအဖြစ် ဖန်တီးနိုင်သည်။

လိုအပ်သောပမာဏကို မစုဆောင်းပါက ပိုင်ရှင်များထံ ပြန်ပေးမည့် crowdfunding တိုကင်များအတွက်လည်း ဤအစီအစဉ်ကို အကောင်အထည်ဖော်နိုင်သည်။

ငွေလွှဲခွန်

ပိုင်ဆိုင်မှုအမျိုးအစားများစွာဖြင့် ငွေပေးငွေယူတစ်ခုစီအတွက် အခွန်ကောက်ခံရန် လိုအပ်သည့်ကိစ္စများတွင် စမတ်စာချုပ်များသည်လည်း သက်ဆိုင်ပါသည်။ ၎င်းကို ထည့်သွင်းပြီး ပိုင်ဆိုင်မှုအသစ်ဖြင့် လုပ်ဆောင်နိုင်သည်။ စပွန်ဆာ စမတ်ပိုင်ဆိုင်မှုများဖြင့် ငွေပေးငွေယူများအတွက်-

1. ကျွန်ုပ်တို့သည် သတ်မှတ်ထားသောစျေးနှုန်းဖြင့် သုံးစွဲသူများထံ ပေးပို့မည့် FeeCoin ကိုထုတ်ပေးပါသည်- 0,01 WAVES = 0,001 FeeCoin။

2. FeeCoin နှင့် ငွေလဲနှုန်းအတွက် ပံ့ပိုးကူညီမှု သတ်မှတ်ပါ- 0,001 WAVES = 0,001 FeeCoin ။

3. စမတ်ပိုင်ဆိုင်မှုအတွက် အောက်ပါ script ကို သတ်မှတ်ပါ-

let feeAssetId = base58'8jfD2JBLe23XtCCSQoTx5eAW5QCU6Mbxi3r78aNQLcNf'
let taxDivisor = 10
 
match tx {
  case t: TransferTransaction =>
    t.feeAssetId == feeAssetId && t.fee == t.amount / taxDivisor
  case e: ExchangeTransaction | MassTransferTransaction => false
  case _ => true
}

ယခု တစ်စုံတစ်ယောက်သည် N စမတ်ပိုင်ဆိုင်မှုများကို လွှဲပြောင်းသည့်အခါတိုင်း၊ ၎င်းတို့သည် သင့်ထံမှ N/taxDivisor WAVES (10 *N/taxDivisor WAVES) ဖြင့် သင့်ထံမှဝယ်ယူနိုင်သည့် N/taxDivisor ပမာဏဖြင့် FeeCoin ပေးမည်ဖြစ်ပြီး သင်မိုင်းတွင်း N/taxDivisor WAVES ကို ပေးမည်ဖြစ်သည်။ ရလဒ်အနေဖြင့် သင်၏အမြတ်ငွေ (အခွန်) သည် 9*N / taxDivisor WAVES ဖြစ်လိမ့်မည်။

စမတ်ပိုင်ဆိုင်မှု script နှင့် MassTransferTransaction ကို အသုံးပြု၍ အခွန်ကောက်ခံခြင်းကိုလည်း လုပ်ဆောင်နိုင်သည်-

let taxDivisor = 10
 
match tx {
  case t : MassTransferTransaction =>
    let twoTransfers = size(t.transfers) == 2
    let issuerIsRecipient = t.transfers[0].recipient == addressFromString("3MgkTXzD72BTfYpd9UW42wdqTVg8HqnXEfc")
    let taxesPaid = t.transfers[0].amount >= t.transfers[1].amount / taxDivisor
    twoTransfers && issuerIsRecipient && taxesPaid
  case _ => false
}

ငွေပြန်အမ်းခြင်းနှင့် သစ္စာရှိမှုအစီအစဉ်များ

Cashback သည် ဝယ်ယူသူမှ ကုန်ပစ္စည်း သို့မဟုတ် ဝန်ဆောင်မှုတစ်ခုပေါ်တွင် အသုံးပြုသည့်ပမာဏ၏ တစ်စိတ်တစ်ပိုင်းကို ပြန်လည်ရရှိသည့် သစ္စာစောင့်သိမှုပရိုဂရမ်အမျိုးအစားတစ်ခုဖြစ်သည်။

စမတ်အကောင့်ကို အသုံးပြု၍ ဤအမှုကို အကောင်အထည်ဖော်သည့်အခါ၊ အာမခံကိစ္စတွင် ကျွန်ုပ်တို့ပြုလုပ်ခဲ့သည့်အတိုင်း အထောက်အထားများကို စစ်ဆေးရပါမည်။ နှစ်ဆအသုံးစရိတ်ကို တားဆီးရန်၊ အသုံးပြုသူသည် ငွေသားပြန်မရရှိမီ (သော့၊ တန်ဖိုး) = (purchaseTransactionId၊ cashbackTransactionId) ဖြင့် DataTransaction ကို ပေးပို့ရပါမည်။

DataTransaction ကိုအသုံးပြုပြီး ရှိပြီးသားသော့များကိုလည်း ပိတ်ပင်ထားရပါမည်။ cashbackDivisor - cashback ရှယ်ယာဖြင့်ပိုင်းခြားထားသောယူနစ်။ အဲဒါတွေ။ cashback share သည် 0.1 ဖြစ်ပါက cashbackDivisor 1/0.1 = 10။

let cashbackToken = base58'8jfD2JBLe23XtCCSQoTx5eAW5QCU6Mbxi3r78aNQLcNf'
 
#извлекаем из транзакции адрес отправителя
let this = extract(tx.sender)
let cashbackDivisor = 10
match tx {
 
 #убеждаемся, что, если поступила дата-транзакция, то у нее ровно одно поле и в стейте еще нет такого ключа
 case d : DataTransaction => size(d.data) == 1 && !isDefined(getBinary(this, d.data[0].key))
 case e : TransferTransaction =>
 
   #если у транзакции нет седьмого пруфа, проверяем корректность подписи
   if !isDefined(e.proofs[7]) then
     sigVerify(e.bodyBytes, e.proofs[0], e.senderPublicKey)
   else
 
     #если у транзакции есть седьмой пруф, извлекаем из него транзакцию и узнаём её высоту
     let purchaseTx = transactionById(e.proofs[7])
     let purchaseTxHeight = extract(transactionHeightById(e.proofs[7]))
    
     #обрабатываем транзакцию из пруфа
     match purchaseTx {
       case purchase : TransferTransaction =>
         let correctSender = purchase.sender == e.sender
         let correctAsset = e.assetId == cashbackToken
         let correctPrice = e.amount == purchase.amount / cashbackDivisor
 
         #убеждаемся, что в транзакции-пруфе указан верный ID текущей транзакции
         let correctProof = extract(getBinary(this, toBase58String(purchase.id))) == e.id
         correctSender && correctAsset && correctPrice && correctProof
     case _ => false
   }
 case _ => sigVerify(tx.bodyBytes, tx.proofs[0], tx.senderPublicKey)
}

အနုမြူ လဲလှယ်မှု

Atomic swap သည် အသုံးပြုသူများအား လဲလှယ်မှုတစ်ခု၏အကူအညီမပါဘဲ ပိုင်ဆိုင်မှုများကို ဖလှယ်နိုင်စေပါသည်။ အက်တမ်လဲလှယ်မှုဖြင့်၊ ငွေပေးငွေယူတွင်ပါဝင်သူနှစ်ဦးစလုံးသည် အချိန်အတိုင်းအတာတစ်ခုအတွင်း ၎င်းကိုအတည်ပြုရန် လိုအပ်သည်။

အရောင်းအ၀ယ်ပြုလုပ်ရန် ချထားပေးသည့်အချိန်အတွင်း အနည်းဆုံးပါဝင်သူ တစ်ဦးမှ မှန်ကန်သော အတည်ပြုချက်မပေးခဲ့ပါက၊ ငွေပေးငွေယူကို ပယ်ဖျက်ပြီး လဲလှယ်မှု ဖြစ်ပေါ်မည်မဟုတ်ပါ။

ကျွန်ုပ်တို့၏ဥပမာတွင်၊ ကျွန်ုပ်တို့သည် အောက်ပါ smart account script ကို အသုံးပြုပါမည်-

let Bob = Address(base58'3NBVqYXrapgJP9atQccdBPAgJPwHDKkh6A8')
let Alice = Address(base58'3PNX6XwMeEXaaP1rf5MCk8weYeF7z2vJZBg')
 
let beforeHeight = 100000
 
let secret = base58'BN6RTYGWcwektQfSFzH8raYo9awaLgQ7pLyWLQY4S4F5'
match tx {
  case t: TransferTransaction =>
    let txToBob = t.recipient == Bob && sha256(t.proofs[0]) == secret && 20 + beforeHeight >= height
    let backToAliceAfterHeight = height >= 21 + beforeHeight && t.recipient == Alice
    txToBob || backToAliceAfterHeight
  case _ => false
}

နောက်ဆောင်းပါးတွင် ရွေးချယ်စရာများ၊ အနာဂတ်များနှင့် ငွေတောင်းခံလွှာများကဲ့သို့သော ဘဏ္ဍာရေးတူရိယာများတွင် စမတ်အကောင့်များအသုံးပြုမှုကို လေ့လာပါမည်။

source: www.habr.com