DPI မျက်နှာပြင်နှင့် FPGA ဘုတ်မှတစ်ဆင့် Raspberry Pi3 သို့ ဒုတိယ HDMI မော်နီတာ

ဤဗီဒီယိုတွင် ပြသထားသည်- GPIO ချိတ်ဆက်ကိရိယာမှတစ်ဆင့် HDMI မော်နီတာတစ်ခုနှင့် ချိတ်ဆက်ထားသည့် FPGA Mars Rover3rpi (Cyclone IV) ဘုတ်အား ချိတ်ဆက်ထားသည့် Raspberry Pi2 ဘုတ်တစ်ခု။ ဒုတိယမော်နီတာအား ပုံမှန် Raspberry Pi3 HDMI ချိတ်ဆက်ကိရိယာမှတစ်ဆင့် ချိတ်ဆက်ထားသည်။ ၎င်းသည် dual monitor စနစ်ကဲ့သို့အလုပ်လုပ်သည်။

အဲဒါကို ဘယ်လိုအကောင်အထည်ဖော်မလဲဆိုတာကို နောက်တစ်ခုပြောပြပါမယ်။

လူကြိုက်များသော Raspberry Pi3 ဘုတ်တွင် အမျိုးမျိုးသော တိုးချဲ့ဘုတ်များ- အာရုံခံကိရိယာများ၊ LED များ၊ stepper motor driver များနှင့် အခြားအရာများစွာကို သင်ချိတ်ဆက်နိုင်သည့် GPIO ချိတ်ဆက်ကိရိယာတစ်ခုပါရှိသည်။ connector ပေါ်ရှိ pin တစ်ခုစီ၏ သီးခြားလုပ်ဆောင်ချက်သည် port configuration ပေါ်တွင်မူတည်သည်။ GPIO ALT2 ဖွဲ့စည်းမှုပုံစံသည် သင့်အား ချိတ်ဆက်ကိရိယာအား DPI အင်တာဖေ့စ်မုဒ်၊ Display Parallel Interface သို့ ပြောင်းနိုင်စေပါသည်။ DPI မှတစ်ဆင့် VGA မော်နီတာများကို ချိတ်ဆက်ရန်အတွက် တိုးချဲ့ဘုတ်များရှိသည်။ သို့သော် ပထမဦးစွာ၊ VGA မော်နီတာများသည် HDMI ကဲ့သို့ သာမန်မဟုတ်တော့ဘဲ၊ ဒုတိယအချက်မှာ၊ ဒစ်ဂျစ်တယ်အင်တာနက်သည် analog ထက် ပိုကောင်းလာသည်။ ထို့အပြင်၊ ထိုကဲ့သို့သော VGA တိုးချဲ့ကတ်များရှိ DAC ကို အများအားဖြင့် R-2-R ကြိုးများပုံစံဖြင့် ပြုလုပ်ထားပြီး အရောင်တစ်ခုလျှင် 6 bits ထက် မပိုပါ။

ALT2 မုဒ်တွင် GPIO ချိတ်ဆက်ကိရိယာ၏ ပင်နံပါတ်များသည် အောက်ပါအတိုင်း အဓိပ္ပာယ်ရှိသည်။

ဤနေရာတွင် ကျွန်ုပ်သည် ချိတ်ဆက်ကိရိယာ၏ RGB pins များကို အနီ၊ အစိမ်းနှင့် အပြာတို့ကို အသီးသီး အရောင်ခြယ်ထားသည်။ အခြားအရေးကြီးသောအချက်ပြမှုများမှာ V-SYNC နှင့် H-SYNC sweep sync signals များအပြင် CLK ဖြစ်သည်။ CLK နာရီကြိမ်နှုန်းသည် ချိတ်ဆက်ကိရိယာသို့ ပစ်ဇယ်တန်ဖိုးများကို ထုတ်ပေးသည့် ကြိမ်နှုန်းဖြစ်ပြီး ရွေးချယ်ထားသည့် ဗီဒီယိုမုဒ်ပေါ်တွင် မူတည်သည်။

ဒစ်ဂျစ်တယ် HDMI မော်နီတာတစ်လုံးကို ချိတ်ဆက်ရန်၊ သင်သည် DPI အင်တာဖေ့စ်အချက်ပြမှုများကို ဖမ်းယူကာ ၎င်းတို့အား HDMI အချက်ပြမှုများအဖြစ် ပြောင်းလဲရန် လိုအပ်သည်။ ဥပမာအားဖြင့်၊ မည်သည့် FPGA ဘုတ်ကိုမဆို အသုံးပြု၍ လုပ်ဆောင်နိုင်သည်။ ထွက်လာသည့်အတိုင်း Mars Rover2rpi ဘုတ်သည် ဤရည်ရွယ်ချက်အတွက် သင့်လျော်သည်။ အမှန်မှာ၊ အထူးအဒက်တာမှတဆင့် ဤဘုတ်ပြားကို ချိတ်ဆက်ရန်အတွက် အဓိကရွေးချယ်မှုမှာ အောက်ပါအတိုင်းဖြစ်သည်-

ဤဘုတ်အား GPIO အပေါက်များ အရေအတွက် တိုးမြှင့်ရန်နှင့် Raspberry နှင့် နောက်ထပ် အရံပစ္စည်းများကို ချိတ်ဆက်ရန်အတွက် အသုံးပြုပါသည်။ တစ်ချိန်တည်းမှာပင်၊ ဤချိတ်ဆက်မှုပါရှိသော GPIO အချက်ပြမှု 4 ခုကို JTAG အချက်ပြမှုများကို အသုံးပြုသည်၊ ထို့ကြောင့် ဖြန့်ဖြူးမှုမှ ပရိုဂရမ်သည် FPGA firmware ကို FPGA သို့ တင်နိုင်စေရန်။ ထို့အတွက်ကြောင့်၊ ထိုသို့သော ပုံမှန်ချိတ်ဆက်မှုသည် ကျွန်ုပ်နှင့် မကိုက်ညီပါ၊ 4 DPI အချက်ပြမှုများ ထွက်သွားပါသည်။ ကံကောင်းစွာဖြင့်၊ ဘုတ်ပေါ်ရှိ အပိုဘီးများတွင် Raspberry နှင့်လိုက်ဖက်သော pinout တစ်ခုရှိသည်။ ဘုတ်ပြားကို ၉၀ ဒီဂရီ လှည့်နိုင်ပြီး ၎င်းကို ကျွန်ုပ်၏ Raspberry နှင့် ချိတ်ဆက်နိုင်စေရန်။

ဟုတ်ပါတယ်၊ သင်သည် ပြင်ပ JTAG ပရိုဂရမ်မာကို အသုံးပြုရလိမ့်မည်၊ သို့သော် ၎င်းသည် ပြဿနာမဟုတ်ပါ။

ပြဿနာလေးတစ်ခုရှိပါသေးတယ်။ FPGA ပင်နံပါတ်တိုင်းကို နာရီထည့်သွင်းမှုအဖြစ် အသုံးမပြုနိုင်ပါ။ ဤရည်ရွယ်ချက်အတွက် အသုံးပြုနိုင်သော သီးသန့်ပင်အနည်းငယ်သာရှိပါသည်။ ထို့ကြောင့် GPIO_0 CLK အချက်ပြမှုသည် FPGA clock input အဖြစ်သုံးနိုင်သည့် FPGA input သို့မရောက်ရှိကြောင်း ဤနေရာတွင် ပေါ်ထွက်ခဲ့ပါသည်။ ဒီလိုပါပဲ၊ ပို့စ်တစ်ခုကို ပဝါပေါ်တင်လိုက်တယ်။ ကျွန်ုပ်သည် ဘုတ်၏ GPIO_0 နှင့် KEY[1] အချက်ပြမှုကို ချိတ်ဆက်သည်-

အခု FPGA ပရောဂျက်အကြောင်း နည်းနည်းပြောပြမယ်။ HDMI အချက်ပြမှုများ ဖွဲ့စည်းရာတွင် အဓိကအခက်အခဲမှာ ကြိမ်နှုန်းများ အလွန်မြင့်မားသည်။ HDMI connector ၏ pinout ကိုကြည့်ပါ၊ RGB အချက်ပြမှုများသည် ယခုအခါ အမှတ်စဉ်ကွဲပြားသည့်အချက်ပြများဖြစ်ကြောင်း သင်တွေ့မြင်နိုင်သည်-

ကွဲပြားသောအချက်ပြစနစ်ကိုအသုံးပြုခြင်းသည် ဂီယာလိုင်းရှိ ဘုံမုဒ်ဆူညံသံများကို ကိုင်တွယ်ဖြေရှင်းနိုင်စေပါသည်။ ဤကိစ္စတွင်၊ အရောင်အချက်ပြမှုတစ်ခုစီ၏မူရင်းရှစ်ဘစ်ကုဒ်ကို 10-bit TMDS (အသွင်ကူးပြောင်းမှု-အနိမ့်ဆုံးအချက်ပြမှု) အဖြစ်သို့ပြောင်းသည်။ ၎င်းသည် အချက်ပြမှုမှ DC အစိတ်အပိုင်းကို ဖယ်ရှားရန်နှင့် differential လိုင်းတွင် အချက်ပြပြောင်းခြင်းကို လျှော့ချရန် အထူးကုဒ်နံပါတ်နည်းလမ်းဖြစ်သည်။ အမှတ်စဉ်မျဉ်းပေါ်တွင် အရောင်တစ်ဘိုက်ကို ထုတ်လွှင့်ရန် ယခု 10 bits ရှိသည်ဖြစ်သောကြောင့်၊ နံပါတ်စဉ်အလိုက် နာရီ၏အကြိမ်ရေသည် pixels ၏ နာရီကြိမ်နှုန်းထက် 10 ဆ ပိုမိုမြင့်မားရမည်ဖြစ်ပါသည်။ ဥပမာ ဗီဒီယိုမုဒ် 1280x720 60Hz ကိုယူပါက၊ ဤမုဒ်၏ pixel frequency သည် 74,25MHz ဖြစ်သည်။ အမှတ်စဉ်သည် 742,5 MHz ဖြစ်သင့်သည်။

သမားရိုးကျ FPGA များသည် ယေဘူယျအားဖြင့် ၎င်းကို မစွမ်းဆောင်နိုင်ပါ။ သို့သော် ကျွန်ုပ်တို့ကံကောင်းစေရန်၊ FPGA များတွင် DDIO ပင်များပါရှိသည်။ ၎င်းတို့သည် ယခင်အတိုင်းပင်၊ 2-to-1 အမှတ်စဉ်များဖြစ်သည့် ကောက်ချက်ချမှုများဖြစ်သည်။ ဆိုလိုသည်မှာ၊ ၎င်းတို့သည် နာရီကြိမ်နှုန်းများ မြင့်တက်ခြင်းနှင့် ကျဆင်းခြင်းတစ်လျှောက်တွင် ဘစ်နှစ်ခုကို ဆက်တိုက်ထုတ်ပေးနိုင်သည်။ ဆိုလိုသည်မှာ FPGA ပရောဂျက်တွင် သင်သည် 740 MHz မဟုတ်ဘဲ 370 MHz ကို အသုံးမပြုနိုင်သော်လည်း FPGA ရှိ DDIO အထွက်ဒြပ်စင်များကို အသုံးပြုရန် လိုအပ်သည်။ ဤတွင် 370 MHz သည် ရနိုင်သော ကြိမ်နှုန်းဖြစ်နေပြီဖြစ်သည်။ ကံမကောင်းစွာဖြင့်၊ 1280×720 မုဒ်သည် ကန့်သတ်ချက်ဖြစ်သည်။ Rover2rpi ဘုတ်ပေါ်တွင် ထည့်သွင်းထားသော ကျွန်ုပ်တို့၏ FPGA Cyclone IV တွင် ပိုမိုမြင့်မားသော resolution ကို မရရှိနိုင်ပါ။

ထို့ကြောင့်၊ ပရောဂျက်တွင်၊ ထည့်သွင်းသည့် pixel frequency CLK အား 5 ဖြင့် မြှောက်ထားသည့် PLL သို့ ဖြည့်သွင်းသည်။ ဤကြိမ်နှုန်းတွင် R, G, B bytes အား ဘစ်အတွဲများအဖြစ်သို့ ပြောင်းသည်။ ၎င်းသည် TMDS ကုဒ်ပြောင်းကိရိယာ လုပ်ဆောင်သည်။ Verilog HDL ရှိ အရင်းအမြစ်ကုဒ်သည် ဤကဲ့သို့ ဖြစ်သည်-

module hdmi(
	input wire pixclk,		// 74MHz
	input wire clk_TMDS2,	// 370MHz
	input wire hsync,
	input wire vsync,
	input wire active,
	input wire [7:0]red,
	input wire [7:0]green,
	input wire [7:0]blue,
	output wire TMDS_bh,
	output wire TMDS_bl,
	output wire TMDS_gh,
	output wire TMDS_gl,
	output wire TMDS_rh,
	output wire TMDS_rl
);

wire [9:0] TMDS_red, TMDS_green, TMDS_blue;
TMDS_encoder encode_R(.clk(pixclk), .VD(red  ), .CD({vsync,hsync}), .VDE(active), .TMDS(TMDS_red));
TMDS_encoder encode_G(.clk(pixclk), .VD(green), .CD({vsync,hsync}), .VDE(active), .TMDS(TMDS_green));
TMDS_encoder encode_B(.clk(pixclk), .VD(blue ), .CD({vsync,hsync}), .VDE(active), .TMDS(TMDS_blue));

reg [2:0] TMDS_mod5=0;  // modulus 5 counter
reg [4:0] TMDS_shift_bh=0, TMDS_shift_bl=0;
reg [4:0] TMDS_shift_gh=0, TMDS_shift_gl=0;
reg [4:0] TMDS_shift_rh=0, TMDS_shift_rl=0;

wire [4:0] TMDS_blue_l  = {TMDS_blue[9],TMDS_blue[7],TMDS_blue[5],TMDS_blue[3],TMDS_blue[1]};
wire [4:0] TMDS_blue_h  = {TMDS_blue[8],TMDS_blue[6],TMDS_blue[4],TMDS_blue[2],TMDS_blue[0]};
wire [4:0] TMDS_green_l = {TMDS_green[9],TMDS_green[7],TMDS_green[5],TMDS_green[3],TMDS_green[1]};
wire [4:0] TMDS_green_h = {TMDS_green[8],TMDS_green[6],TMDS_green[4],TMDS_green[2],TMDS_green[0]};
wire [4:0] TMDS_red_l   = {TMDS_red[9],TMDS_red[7],TMDS_red[5],TMDS_red[3],TMDS_red[1]};
wire [4:0] TMDS_red_h   = {TMDS_red[8],TMDS_red[6],TMDS_red[4],TMDS_red[2],TMDS_red[0]};

always @(posedge clk_TMDS2)
begin
	TMDS_shift_bh <= TMDS_mod5[2] ? TMDS_blue_h  : TMDS_shift_bh  [4:1];
	TMDS_shift_bl <= TMDS_mod5[2] ? TMDS_blue_l  : TMDS_shift_bl  [4:1];
	TMDS_shift_gh <= TMDS_mod5[2] ? TMDS_green_h : TMDS_shift_gh  [4:1];
	TMDS_shift_gl <= TMDS_mod5[2] ? TMDS_green_l : TMDS_shift_gl  [4:1];
	TMDS_shift_rh <= TMDS_mod5[2] ? TMDS_red_h   : TMDS_shift_rh  [4:1];
	TMDS_shift_rl <= TMDS_mod5[2] ? TMDS_red_l   : TMDS_shift_rl  [4:1];
	TMDS_mod5 <= (TMDS_mod5[2]) ? 3'd0 : TMDS_mod5+3'd1;
end

assign TMDS_bh = TMDS_shift_bh[0];
assign TMDS_bl = TMDS_shift_bl[0];
assign TMDS_gh = TMDS_shift_gh[0];
assign TMDS_gl = TMDS_shift_gl[0];
assign TMDS_rh = TMDS_shift_rh[0];
assign TMDS_rl = TMDS_shift_rl[0];

endmodule

module TMDS_encoder(
	input clk,
	input [7:0] VD,	// video data (red, green or blue)
	input [1:0] CD,	// control data
	input VDE,  	// video data enable, to choose between CD (when VDE=0) and VD (when VDE=1)
	output reg [9:0] TMDS = 0
);

wire [3:0] Nb1s = VD[0] + VD[1] + VD[2] + VD[3] + VD[4] + VD[5] + VD[6] + VD[7];
wire XNOR = (Nb1s>4'd4) || (Nb1s==4'd4 && VD[0]==1'b0);
wire [8:0] q_m = {~XNOR, q_m[6:0] ^ VD[7:1] ^ {7{XNOR}}, VD[0]};

reg [3:0] balance_acc = 0;
wire [3:0] balance = q_m[0] + q_m[1] + q_m[2] + q_m[3] + q_m[4] + q_m[5] + q_m[6] + q_m[7] - 4'd4;
wire balance_sign_eq = (balance[3] == balance_acc[3]);
wire invert_q_m = (balance==0 || balance_acc==0) ? ~q_m[8] : balance_sign_eq;
wire [3:0] balance_acc_inc = balance - ({q_m[8] ^ ~balance_sign_eq} & ~(balance==0 || balance_acc==0));
wire [3:0] balance_acc_new = invert_q_m ? balance_acc-balance_acc_inc : balance_acc+balance_acc_inc;
wire [9:0] TMDS_data = {invert_q_m, q_m[8], q_m[7:0] ^ {8{invert_q_m}}};
wire [9:0] TMDS_code = CD[1] ? (CD[0] ? 10'b1010101011 : 10'b0101010100) : (CD[0] ? 10'b0010101011 : 10'b1101010100);

always @(posedge clk) TMDS <= VDE ? TMDS_data : TMDS_code;
always @(posedge clk) balance_acc <= VDE ? balance_acc_new : 4'h0;

endmodule

ထို့နောက် output pairs များကို DDIO output သို့ ဖြည့်သွင်းပြီး အတက်အဆင်းတွင် တစ်ဘစ် signal ကို ဆက်တိုက်ထုတ်ပေးသည်။

DDIO ကိုယ်တိုင်ကို Verilog ကုဒ်ဖြင့် ဤကဲ့သို့ ဖော်ပြနိုင်သည်။

module ddio(
	input wire d0,
	input wire d1,
	input wire clk,
	output wire out
	);

reg r_d0;
reg r_d1;
always @(posedge clk)
begin
	r_d0 <= d0;
	r_d1 <= d1;
end
assign out = clk ? r_d0 : r_d1;
endmodule

ဒါပေမယ့် ဒီနည်းနဲ့တော့ အလုပ်ဖြစ်မှာ မဟုတ်ဘူး။ DDIO အထွက်ဒြပ်စင်များကို အမှန်တကယ်အသုံးပြုရန် သင်သည် Altera ၏ ALTDDIO_OUT megafunction ကို အသုံးပြုရန်လိုအပ်သည်။ ကျွန်ုပ်၏ ပရောဂျက်တွင်၊ စာကြည့်တိုက် အစိတ်အပိုင်း ALTDDIO_OUT ကို အသုံးပြုထားသည်။

အားလုံးက နည်းနည်း ဆန်းကျယ်ပုံရပေမယ့် အဆင်ပြေပါတယ်။

Verilog HDL တွင်ရေးထားသော source code တစ်ခုလုံးကို သင်ကြည့်ရှုနိုင်ပါသည်။ ဒီမှာ github မှာ.

FPGA အတွက် စုစည်းထားသော Firmware ကို Mars Rover2rpi ဘုတ်ပေါ်တွင် ထည့်သွင်းထားသည့် EPCS ချစ်ပ်ထဲသို့ ထည့်သွင်းထားသည်။ ထို့ကြောင့် FPGA ဘုတ်သို့ ပါဝါအသုံးပြုသောအခါ၊ FPGA သည် flash memory မှ အစပြုပြီး စတင်မည်ဖြစ်သည်။

ယခုကျွန်ုပ်တို့သည် Raspberry ကိုယ်တိုင်ဖွဲ့စည်းပုံအကြောင်းအနည်းငယ်ပြောရန်လိုသည်။

Debian Buster ကိုအခြေခံ၍ Raspberry PI OS (32 bit) တွင် စမ်းသပ်မှုများ ပြုလုပ်နေပါသည်
ထုတ်ဝေသည့်ရက်စွဲ- 2020-08-20၊ Kernel ဗားရှင်း- 5.4။

သင်အရာနှစ်ခုလုပ်ရန်လိုသည်-

• config.txt ဖိုင်ကို တည်းဖြတ်ပါ။
• မော်နီတာနှစ်ခုနှင့်အလုပ်လုပ်ရန် X server configuration ကိုဖန်တီးပါ။

/boot/config.txt ဖိုင်ကို တည်းဖြတ်သောအခါ၊ သင်သည်-

1. i2c, i2s, spi အသုံးပြုမှုကို ပိတ်ပါ။
2. ထပ်ဆင့် dtoverlay=dpi24 ဖြင့် DPI မုဒ်ကို ဖွင့်ပါ။
3. ဗီဒီယိုမုဒ် 1280×720 60Hz၊ DPI တစ်ခုလျှင် အမှတ်တစ်ခုလျှင် 24 bits သတ်မှတ်ပါ။
4. လိုအပ်သော framebuffers 2 အရေအတွက်ကို သတ်မှတ်ပါ (max_framebuffers=2၊ သို့မှသာ ဒုတိယစက်ပစ္စည်း /dev/fb1 ပေါ်လာပါမည်)

config.txt ဖိုင်၏ စာသားအပြည့်အစုံမှာ ဤကဲ့သို့ဖြစ်သည်။

# For more options and information see
# http://rpf.io/configtxt
# Some settings may impact device functionality. See link above for details

# uncomment if you get no picture on HDMI for a default "safe" mode
#hdmi_safe=1

# uncomment this if your display has a black border of unused pixels visible
# and your display can output without overscan
disable_overscan=1

# uncomment the following to adjust overscan. Use positive numbers if console
# goes off screen, and negative if there is too much border
#overscan_left=16
#overscan_right=16
#overscan_top=16
#overscan_bottom=16

# uncomment to force a console size. By default it will be display's size minus
# overscan.
#framebuffer_width=1280
#framebuffer_height=720

# uncomment if hdmi display is not detected and composite is being output
hdmi_force_hotplug=1

# uncomment to force a specific HDMI mode (this will force VGA)
#hdmi_group=1
#hdmi_mode=1

# uncomment to force a HDMI mode rather than DVI. This can make audio work in
# DMT (computer monitor) modes
#hdmi_drive=2

# uncomment to increase signal to HDMI, if you have interference, blanking, or
# no display
#config_hdmi_boost=4

# uncomment for composite PAL
#sdtv_mode=2

#uncomment to overclock the arm. 700 MHz is the default.
#arm_freq=800

# Uncomment some or all of these to enable the optional hardware interfaces
#dtparam=i2c_arm=on
#dtparam=i2s=on
#dtparam=spi=on

dtparam=i2c_arm=off
dtparam=spi=off
dtparam=i2s=off

dtoverlay=dpi24
overscan_left=0
overscan_right=0
overscan_top=0
overscan_bottom=0
framebuffer_width=1280
framebuffer_height=720
display_default_lcd=0
enable_dpi_lcd=1
dpi_group=2
dpi_mode=87
#dpi_group=1
#dpi_mode=4
dpi_output_format=0x6f027
dpi_timings=1280 1 110 40 220 720 1 5 5 20 0 0 0 60 0 74000000 3

# Uncomment this to enable infrared communication.
#dtoverlay=gpio-ir,gpio_pin=17
#dtoverlay=gpio-ir-tx,gpio_pin=18

# Additional overlays and parameters are documented /boot/overlays/README

# Enable audio (loads snd_bcm2835)
dtparam=audio=on

[pi4]
# Enable DRM VC4 V3D driver on top of the dispmanx display stack
#dtoverlay=vc4-fkms-v3d
max_framebuffers=2

[all]
#dtoverlay=vc4-fkms-v3d
max_framebuffers=2

၎င်းနောက်၊ framebuffer နှစ်ခုတွင် /dev/fb0 နှင့် /dev/fb1 နှစ်ခုတွင် monitor နှစ်ခုအသုံးပြုရန်အတွက် X server အတွက် configuration file တစ်ခုကို ဖန်တီးရန်လိုအပ်သည်။

ကျွန်ုပ်၏ config ဖိုင်သည် /usr/share/x11/xorg.conf.d/60-dualscreen.conf ဖြစ်သည်

Section "Device"
        Identifier      "LCD"
        Driver          "fbturbo"
        Option          "fbdev" "/dev/fb0"
        Option          "ShadowFB" "off"
        Option          "SwapbuffersWait" "true"
EndSection

Section "Device"
        Identifier      "HDMI"
        Driver          "fbturbo"
        Option          "fbdev" "/dev/fb1"
        Option          "ShadowFB" "off"
        Option          "SwapbuffersWait" "true"
EndSection

Section "Monitor"
        Identifier      "LCD-monitor"
        Option          "Primary" "true"
EndSection

Section "Monitor"
        Identifier      "HDMI-monitor"
        Option          "RightOf" "LCD-monitor"
EndSection

Section "Screen"
        Identifier      "screen0"
        Device          "LCD"
        Monitor         "LCD-monitor"
EndSection

Section "Screen"
        Identifier      "screen1"
        Device          "HDMI" 
	Monitor         "HDMI-monitor"
EndSection

Section "ServerLayout"
        Identifier      "default"
        Option          "Xinerama" "on"
        Option          "Clone" "off"
        Screen 0        "screen0"
        Screen 1        "screen1" RightOf "screen0"
EndSection

ကောင်းပြီ၊ မတပ်ဆင်ရသေးပါက Xinerama ကိုသင်ထည့်သွင်းရန်လိုအပ်သည်။ ထို့နောက် အထက်ဖော်ပြပါ သရုပ်ပြဗီဒီယိုတွင် ပြထားသည့်အတိုင်း ဒက်စတော့နေရာလွတ်ကို မော်နီတာနှစ်ခုအထိ အပြည့်အဝ တိုးချဲ့မည်ဖြစ်သည်။

ဒါပဲဖြစ်နိုင်ပါတယ်။ ယခုအခါ Raspberry Pi3 ပိုင်ရှင်များသည် မော်နီတာနှစ်လုံးကို အသုံးပြုနိုင်တော့မည်ဖြစ်သည်။

Mars Rover2rpi board ၏ ဖော်ပြချက် နှင့် ပုံကြမ်း သည် ဖြစ်နိုင်သည်။ ဒီမှာကြည့်ပါ။.

source: www.habr.com