हामीले लिनक्स वातावरणमा 1C उत्पादनहरूले कसरी काम गर्छ भन्ने विषयमा छलफल गर्दा, एउटा कमजोरी पत्ता लाग्यो - 1C सर्भरहरूको क्लस्टर प्रबन्ध गर्नको लागि सुविधाजनक ग्राफिकल बहु-प्लेटफर्म उपकरणको अभाव। र यो र्याक कन्सोल उपयोगिताको लागि GUI लेखेर यो कमजोरी सच्याउने निर्णय गरियो। Tcl/tk विकास भाषाको रूपमा छनोट गरिएको थियो, मेरो विचारमा, यो कार्यको लागि सबैभन्दा उपयुक्त। र त्यसैले, म यस सामग्रीमा समाधानका केही रोचक पक्षहरू प्रस्तुत गर्न चाहन्छु।
काम गर्न तपाईलाई tcl/tk र 1C वितरण चाहिन्छ। र मैले तेस्रो-पक्ष प्याकेजहरू प्रयोग नगरी आधारभूत tcl/tk डेलिभरीको क्षमताहरूको अधिकतम प्रयोग गर्ने निर्णय गरेपछि, मलाई संस्करण 8.6.7 चाहिन्छ, जसमा ttk समावेश छ - अतिरिक्त ग्राफिक तत्वहरू भएको प्याकेज, जसमध्ये हामीलाई मुख्य रूपमा ttk चाहिन्छ। ::TreeView, यसले रूख संरचनाको रूपमा र तालिका (सूची) को रूपमा डेटा प्रदर्शन गर्न अनुमति दिन्छ। साथै, नयाँ संस्करणमा, अपवादहरू सहितको काम पुन: काम गरिएको छ (प्रयास आदेश, जुन बाह्य आदेशहरू चलाउँदा परियोजनामा प्रयोग गरिन्छ)।
परियोजनाले धेरै फाइलहरू समावेश गर्दछ (यद्यपि कुनै पनि कुराले तपाईंलाई एकमा सबै गर्नबाट रोक्दैन):
rac_gui.cfg - पूर्वनिर्धारित कन्फिगरेसन
rac_gui.tcl - मुख्य प्रक्षेपण स्क्रिप्ट
lib डाइरेक्टरीले फाइलहरू समावेश गर्दछ जुन स्वचालित रूपमा स्टार्टअपमा लोड हुन्छ:
function.tcl - प्रक्रियाहरूसँग फाइल
gui.tcl - मुख्य ग्राफिकल इन्टरफेस
images.tcl - base64 छवि पुस्तकालय
rac_gui.tcl फाइल, वास्तवमा, अनुवादक सुरु गर्छ, चर प्रारम्भ गर्दछ, मोड्युलहरू लोड गर्दछ, कन्फिगहरू, र यस्तै। टिप्पणी सहित फाइलको सामग्री:
rac_gui.tcl
#!/bin/sh
exec wish "$0" -- "$@"
# Устанавливаем текущий каталог
set dir(root) [pwd]
# Устанавливаем рабочий каталог, если его нет то создаём
set dir(work) [file join $env(HOME) .rac_gui]
if {[file exists $dir(work)] == 0 } {
file mkdir $dir(work)
}
# каталог с модулями
set dir(lib) "[file join $dir(root) lib]"
# загружаем пользовательский конфиг, если он отсутствует, то копируем дефолтный
if {[file exists [file join $dir(work) rac_gui.cfg]] ==0} {
file copy [file join [pwd] rac_gui.cfg] [file join $dir(work) rac_gui.cfg]
}
source [file join $dir(work) rac_gui.cfg]
# Код проверки наличия rac и правильности указания пути в конфиге
# если программа не найдена то будет выведен диалог для указания корректного пути
# и этот путь будет записан в пользовательский конфиг
if {[file exists $rac_cmd] == 0} {
set rac_cmd [tk_getOpenFile -initialdir $env(HOME) -parent . -title "Укажите путь до rac" -initialfile rac]
file copy [file join $dir(work) rac_gui.cfg] [file join $dir(work) rac_gui.cfg.bak]
set orig_file [open [file join $dir(work) rac_gui.cfg.bak] "r"]
set file [open [file join $dir(work) rac_gui.cfg] "w"]
while {[gets $orig_file line] >=0 } {
if {[string match "set rac_cmd*" $line]} {
puts $file "set rac_cmd $rac_cmd"
} else {
puts $file $line
}
}
close $file
close $orig_file
#return "$host:$port"
file delete [file join $dir(work) 1c_srv.cfg.bak]
} else {
puts "Found $rac_cmd"
}
set cluster_user ""
set cluster_pwd ""
set agent_user ""
set agent_pwd ""
## LOAD FILE ##
# Загружаем модули кроме gui.tcl так как его надо загрузить последним
foreach modFile [lsort [glob -nocomplain [file join $dir(lib) *.tcl]]] {
if {[file tail $modFile] ne "gui.tcl"} {
source $modFile
puts "Loaded module $modFile"
}
}
source [file join $dir(lib) gui.tcl]
source [file join $dir(work) rac_gui.cfg]
# Читаем файл со списком серверов 1С
# и добавляем в дерево
if [file exists [file join $dir(work) 1c_srv.cfg]] {
set f [open [file join $dir(work) 1c_srv.cfg] "RDONLY"]
while {[gets $f line] >=0} {
.frm_tree.tree insert {} end -id "server::$line" -text "$line" -values "$line"
}
}आवश्यक पर्ने सबै डाउनलोड गरेपछि र र्याक उपयोगिताको उपस्थितिको लागि जाँच गरिसकेपछि, ग्राफिकल विन्डो सुरु हुनेछ। कार्यक्रम इन्टरफेस तीन तत्वहरु मिलेर बनेको छ:
उपकरणपट्टी, रूख र सूची
मैले "रुख" को सामग्रीहरू 1C बाट मानक विन्डोज उपकरणहरूसँग सम्भव भएसम्म समान बनाएको छु।
यो सञ्झ्याल बनाउने मुख्य कोड फाइलमा समावेश छ
lib/gui.tcl
# установка размера и положения основного окна
# можно установить в переменную topLevelGeometry в конфиг программы
if {[info exists topLevelGeometry]} {
wm geometry . $topLevelGeometry
} else {
wm geometry . 1024x768
}
# Заголовок окна
wm title . "1C Rac GUI"
wm iconname . "1C Rac Gui"
# иконка окна (берется из файла lib/imges.tcl)
wm iconphoto . tcl
wm protocol . WM_DELETE_WINDOW Quit
wm overrideredirect . 0
wm positionfrom . user
ttk::style theme use clam
# Панель инсрументов
set frm_tool [frame .frm_tool]
pack $frm_tool -side left -fill y
ttk::panedwindow .panel -orient horizontal -style TPanedwindow
pack .panel -expand true -fill both
pack propagate .panel false
ttk::button $frm_tool.btn_add -command Add -image add_grey_32
ttk::button $frm_tool.btn_del -command Del -image del_grey_32
ttk::button $frm_tool.btn_edit -command Edit -image edit_grey_32
ttk::button $frm_tool.btn_quit -command Quit -image quit_grey_32
pack $frm_tool.btn_add $frm_tool.btn_del $frm_tool.btn_edit -side top -padx 5 -pady 5
pack $frm_tool.btn_quit -side bottom -padx 5 -pady 5
# Дерево с полосами прокрутки
set frm_tree [frame .frm_tree]
ttk::scrollbar $frm_tree.hsb1 -orient horizontal -command [list $frm_tree.tree xview]
ttk::scrollbar $frm_tree.vsb1 -orient vertical -command [list $frm_tree.tree yview]
set tree [ttk::treeview $frm_tree.tree -show tree
-xscrollcommand [list $frm_tree.hsb1 set] -yscrollcommand [list $frm_tree.vsb1 set]]
grid $tree -row 0 -column 0 -sticky nsew
grid $frm_tree.vsb1 -row 0 -column 1 -sticky nsew
grid $frm_tree.hsb1 -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_tree 0 -weight 1
grid rowconfigure $frm_tree 0 -weight 1
# назначение обработчика нажатия кнопкой мыши
bind $frm_tree.tree <ButtonRelease> "TreePress $frm_tree.tree"
# Список для данных (таблица)
set frm_work [frame .frm_work]
ttk::scrollbar $frm_work.hsb -orient horizontal -command [list $frm_work.tree_work xview]
ttk::scrollbar $frm_work.vsb -orient vertical -command [list $frm_work.tree_work yview]
set tree_work [
ttk::treeview $frm_work.tree_work
-show headings -columns "par val" -displaycolumns "par val"
-xscrollcommand [list $frm_work.hsb set]
-yscrollcommand [list $frm_work.vsb set]
]
# Установка цветов для чередования в таблице
$tree_work tag configure dark -background $color(dark_table_bg)
$tree_work tag configure light -background $color(light_table_bg)
# Размещение элементов на форме
grid $tree_work -row 0 -column 0 -sticky nsew
grid $frm_work.vsb -row 0 -column 1 -sticky nsew
grid $frm_work.hsb -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_work 0 -weight 1
grid rowconfigure $frm_work 0 -weight 1
pack $frm_tree $frm_work -side left -expand true -fill both
#.panel add $frm_tool -weight 1
.panel add $frm_tree -weight 1
.panel add $frm_work -weight 1
कार्यक्रम संग काम को लागी एल्गोरिथ्म निम्नानुसार छ:
1. पहिले, तपाईंले मुख्य क्लस्टर सर्भर थप्न आवश्यक छ (अर्थात, क्लस्टर व्यवस्थापन सर्भर (लिनक्समा, व्यवस्थापन "/opt/1C/v8.3/x86_64/ras क्लस्टर —डेमन") आदेशको साथ सुरू गरिएको छ)।
यो गर्नको लागि, "+" बटनमा क्लिक गर्नुहोस् र खुल्ने विन्डोमा, सर्भर ठेगाना र पोर्ट प्रविष्ट गर्नुहोस्:
त्यसपछि, हाम्रो सर्भर रूखमा क्लिक गरेर देखा पर्नेछ, क्लस्टरहरूको सूची खुल्नेछ वा जडान त्रुटि प्रदर्शित हुनेछ।
2. क्लस्टर नाममा क्लिक गर्दा यसको लागि उपलब्ध प्रकार्यहरूको सूची खुल्नेछ।
१…
र यस्तै, i.e. नयाँ क्लस्टर थप्नको लागि, सूचीमा उपलब्ध कुनै पनि चयन गर्नुहोस् र उपकरणपट्टीमा "+" बटन थिच्नुहोस् र नयाँ थप्नुहोस् संवाद प्रदर्शित हुनेछ:
उपकरणपट्टीका बटनहरूले सन्दर्भको आधारमा कार्यहरू प्रदर्शन गर्दछ, अर्थात्। रूख वा सूचीको कुन तत्व चयन गरिएको छ भन्ने आधारमा, एक वा अर्को प्रक्रिया प्रदर्शन गरिनेछ।
थप बटनको उदाहरण हेरौं (“+”):
बटन उत्पादन कोड:
ttk::button $frm_tool.btn_add -command Add -image add_grey_32यहाँ हामी देख्छौं कि जब बटन थिचिन्छ, "थप्नुहोस्" प्रक्रिया कार्यान्वयन हुनेछ, यसको कोड:
proc Add {} {
global active_cluster host
# Определяем идентификатор выделенного элемента
set id [.frm_tree.tree selection]
# Определяем значение этого элемента
set values [.frm_tree.tree item [.frm_tree.tree selection] -values]
set key [lindex [split $id "::"] 0]
# в зависимости от того что выделили будет запущена нужная процедура
if {$key eq "" || $key eq "server"} {
set host [ Add::server ]
return
}
Add::$key .frm_tree.tree $host $values
}यहाँ टिकल को फाइदाहरु मध्ये एक छ: तपाइँ एक प्रक्रिया नाम को रूप मा एक चर को मान पास गर्न सक्नुहुन्छ:
Add::$key .frm_tree.tree $host $valuesत्यो हो, उदाहरणका लागि, यदि हामीले मुख्य सर्भरमा देखाउँछौं र "+" थिच्छौं, त्यसपछि Add::सर्भर प्रक्रिया सुरु हुनेछ, यदि क्लस्टरमा - Add::cluster र यस्तै अन्य (म कहाँ लेख्छु। आवश्यक "कुञ्जीहरू" थोरै तलबाट आउँछन्), सूचीबद्ध प्रक्रियाहरूले सन्दर्भमा उपयुक्त ग्राफिक तत्वहरू तान्छन्।
तपाईंले पहिले नै याद गर्नुभएको हुन सक्छ, फारमहरू शैलीमा समान छन् - यो अचम्मको कुरा होइन, किनभने तिनीहरू एक प्रक्रियाद्वारा प्रदर्शित हुन्छन्, अधिक सटीक रूपमा फारमको मुख्य फ्रेम (विन्डो, बटन, छवि, लेबल), प्रक्रियाको नाम। शीर्ष स्तर थप्नुहोस्
proc AddToplevel {lbl img {win_name .add}} {
set cmd "destroy $win_name"
if [winfo exists $win_name] {destroy $win_name}
toplevel $win_name
wm title $win_name $lbl
wm iconphoto $win_name tcl
# метка с иконкой
ttk::label $win_name.lbl -image $img
# фрейм с полями ввода
set frm [ttk::labelframe $win_name.frm -text $lbl -labelanchor nw]
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
# фрейм и кнопки
set frm_btn [frame $win_name.frm_btn -border 0]
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }
ttk::button $frm_btn.btn_cancel -command $cmd -image quit_grey_24
grid $win_name.lbl -row 0 -column 0 -sticky nw -padx 5 -pady 10
grid $frm -row 0 -column 1 -sticky nw -padx 5 -pady 5
grid $frm_btn -row 1 -column 1 -sticky se -padx 5 -pady 5
pack $frm_btn.btn_cancel -side right
pack $frm_btn.btn_ok -side right -padx 10
return $frm
}
कल प्यारामिटरहरू: शीर्षक, पुस्तकालयबाट आइकनको लागि छवि नाम (lib/images.tcl) र एक वैकल्पिक विन्डो नाम प्यारामिटर (पूर्वनिर्धारित .add)। यसैले, यदि हामीले मुख्य सर्भर र क्लस्टर थप्नको लागि माथिका उदाहरणहरू लियौं भने, कल तदनुसार हुनेछ:
AddToplevel "Добавление основного сервера" server_grey_64वा
AddToplevel "Добавление кластера" cluster_grey_64ठिक छ, यी उदाहरणहरूसँग जारी राख्दै, म सर्भर वा क्लस्टरका लागि संवादहरू थप्न प्रदर्शन गर्ने प्रक्रियाहरू देखाउनेछु।
थप्नुहोस्::सर्भर
proc Add::server {} {
global default
# выводим основную форму
set frm [AddToplevel "Добавление основного сервера" server_grey_64]
# добавляем етки и поля ввода на эту форму
label $frm.lbl_host -text "Адрес сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
#set frm_btn [frame .add.frm_btn -border 0]
# переопределяем обработчик нажатия кнопки
.add.frm_btn.btn_ok configure -command {
set host [SaveMainServer [.add.frm.ent_host get] [.add.frm.ent_port get]]
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"
destroy .add
return $host
}
return $frm
}थप्नुहोस्::क्लस्टर
proc Add::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes
agent_user agent_pwd cluster_user cluster_pwd auth_agent
if {$agent_user ne "" && $agent_pwd ne ""} {
set auth_agent "--agent-user=$agent_user --agent-pwd=$agent_pwd"
} else {
set auth_agent ""
}
# устанавливаем глобальные переменные ()
set lifetime_limit $default(lifetime_limit)
set expiration_timeout $default(expiration_timeout)
set session_fault_tolerance_level $default(session_fault_tolerance_level)
set max_memory_size $default(max_memory_size)
set max_memory_time_limit $default(max_memory_time_limit)
set errors_count_threshold $default(errors_count_threshold)
set security_level [lindex $default(security_level) 0]
set load_balancing_mode [lindex $default(load_balancing_mode) 0]
set frm [AddToplevel "Добавление кластера" cluster_grey_64]
label $frm.lbl_host -text "Адрес основного сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
label $frm.lbl_name -text "Название кластера"
entry $frm.ent_name
label $frm.lbl_secure_connect -text "Защищённое соединение"
ttk::combobox $frm.cb_security_level -textvariable security_level -values $default(security_level)
label $frm.lbl_expiration_timeout -text "Останавливать выключенные процессы через:"
entry $frm.ent_expiration_timeout -textvariable expiration_timeout
label $frm.lbl_session_fault_tolerance_level -text "Уровень отказоустойчивости"
entry $frm.ent_session_fault_tolerance_level -textvariable session_fault_tolerance_level
label $frm.lbl_load_balancing_mode -text "Режим распределения нагрузки"
ttk::combobox $frm.cb_load_balancing_mode -textvariable load_balancing_mode
-values $default(load_balancing_mode)
label $frm.lbl_errors_count_threshold -text "Допустимое отклонение количества ошибок сервера, %"
entry $frm.ent_errors_count_threshold -textvariable errors_count_threshold
label $frm.lbl_processes -text "Рабочие процессы:"
label $frm.lbl_lifetime_limit -text "Период перезапуска, сек."
entry $frm.ent_lifetime_limit -textvariable lifetime_limit
label $frm.lbl_max_memory_size -text "Допустимый объём памяти, КБ"
entry $frm.ent_max_memory_size -textvariable max_memory_size
label $frm.lbl_max_memory_time_limit -text "Интервал превышения допустимого объёма памяти, сек."
entry $frm.ent_max_memory_time_limit -textvariable max_memory_time_limit
label $frm.lbl_kill_problem_processes -justify left -anchor nw -text "Принудительно завершать проблемные процессы"
checkbutton $frm.check_kill_problem_processes -variable kill_problem_processes -onvalue yes -offvalue no
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_name -row 2 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_name -row 2 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_secure_connect -row 3 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_security_level -row 3 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_expiration_timeout -row 4 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_expiration_timeout -row 4 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_session_fault_tolerance_level -row 5 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_session_fault_tolerance_level -row 5 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_load_balancing_mode -row 6 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_load_balancing_mode -row 6 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_errors_count_threshold -row 7 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_errors_count_threshold -row 7 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_processes -row 8 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.lbl_lifetime_limit -row 9 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_lifetime_limit -row 9 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_size -row 10 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_size -row 10 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_time_limit -row 11 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_time_limit -row 11 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_kill_problem_processes -row 12 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.check_kill_problem_processes -row 12 -column 1 -sticky nw -padx 5 -pady 5
# переопределяем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
return $frm
}यी प्रक्रियाहरूको कोड तुलना गर्दा, भिन्नता नाङ्गो आँखामा देखिन्छ; म "ठीक" बटन ह्यान्डलरमा ध्यान केन्द्रित गर्नेछु। Tk मा, ग्राफिक तत्वहरूको गुणहरू विकल्प प्रयोग गरेर कार्यक्रम कार्यान्वयनको क्रममा ओभरराइड गर्न सकिन्छ कन्फिगर। उदाहरणका लागि, बटन प्रदर्शन गर्न प्रारम्भिक आदेश:
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }तर हाम्रो फारमहरूमा, आदेश आवश्यक कार्यक्षमतामा निर्भर गर्दछ:
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
माथिको उदाहरणमा, "क्लोज्ड" बटनले क्लस्टर थप्ने प्रक्रिया सुरु गर्छ।
यहाँ यो Tk मा ग्राफिक तत्वहरु संग काम गर्न को लागी एक विषयवस्तु बनाउन लायक छ - विभिन्न डेटा इनपुट तत्वहरु (प्रविष्टि, कम्बोबक्स, चेकबटन, आदि) को लागी एक पाठ चर को रूप मा एक प्यारामिटर पेश गरिएको छ:
entry $frm.ent_lifetime_limit -textvariable lifetime_limitयो चर ग्लोबल नेमस्पेसमा परिभाषित गरिएको छ र हाल प्रविष्ट गरिएको मान समावेश गर्दछ। ती। फिल्डबाट प्रविष्ट गरिएको पाठ प्राप्त गर्नको लागि, तपाईंले केवल चरसँग सम्बन्धित मान पढ्न आवश्यक छ (अवश्य पनि, यो तत्व सिर्जना गर्दा परिभाषित गरिएको छ)।
प्रविष्ट गरिएको पाठ पुन: प्राप्त गर्ने दोस्रो विधि (प्रविष्टि प्रकारका तत्वहरूको लागि) प्राप्त आदेश प्रयोग गर्नु हो:
.add.frm.ent_name getयी दुवै विधिहरू माथिको कोडमा देख्न सकिन्छ।
यो बटन क्लिक गर्नाले, यस अवस्थामा, रनकमान्ड प्रक्रिया सुरु गर्दछ रैकको सर्तमा क्लस्टर थप्नको लागि उत्पन्न आदेश रेखासँग:
/opt/1C/v8.3/x86_64/rac cluster insert --host=localhost --port=1540 --name=dsdsds --expiration-timeout=0 --lifetime-limit=0 --max-memory-size=0 --max-memory-time-limit=0 --security-level=0 --session-fault-tolerance-level=0 --load-balancing-mode=performance --errors-count-threshold=0 --kill-problem-processes=no localhost:1545अब हामी मुख्य कमाण्डमा आउँछौं, जसले हामीलाई चाहिने प्यारामिटरहरूसँग र्याकको सुरुवात नियन्त्रण गर्दछ, आवश्यक भएमा आदेशहरूको आउटपुटलाई सूची र फिर्ताहरूमा पार्स गर्दछ:
RunCommand
proc RunCommand {root par} {
global dir rac_cmd cluster work_list_row_count agent_user agent_pwd cluster_user cluster_pwd
puts "$rac_cmd $par"
set work_list_row_count 0
# открываем канал в неблокирующем режиме
# $rac - команда с полным путём
# $par - сформированные ключи запуска и опции
set pipe [open "|$rac_cmd $par" "r"]
try {
set lst ""
set l ""
# вывод команды добавляем в список списков
while {[gets $pipe line]>=0} {
#puts $line
if {$line eq ""} {
lappend l $lst
set lst ""
} else {
lappend lst [string trim $line]
}
}
close $pipe
return $l
} on error {result options} {
# Запуск обработчика ошибок
ErrorParcing $result $options
return ""
}
}मुख्य सर्भर डाटा प्रविष्ट गरेपछि, यो रूखमा थपिनेछ, यसको लागि, माथिको Add:server प्रक्रियामा, निम्न कोड जिम्मेवार छ:
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"अब, रूखमा रहेको सर्भरको नाममा क्लिक गरेर, हामीले त्यो सर्भरद्वारा व्यवस्थित क्लस्टरहरूको सूची पाउँछौं, र क्लस्टरमा क्लिक गरेर, हामीले क्लस्टर तत्वहरू (सर्भरहरू, इन्फोबेसहरू, आदि) को सूची प्राप्त गर्छौं। यो TreePress प्रक्रियामा लागू गरिएको छ (file lib/function.tcl):
proc TreePress {tree} {
global host server active_cluster infobase
# определяем выделенный элемент
set id [$tree selection]
# устанавливаем нужные глобальные переменные
SetGlobalVarFromTreeItems $tree $id
# Определяем ключ и значение, т.е. именно тип выбранного элемента
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
# и в зависимости от того что выбрали будет запущена соответствующая процедура
# в пространстве имён Run
Run::$key $tree $host $values
}तदनुसार, रन::सर्भर मुख्य सर्भरको लागि सुरु हुनेछ (एक क्लस्टरको लागि - रन:: क्लस्टर, काम गर्ने सर्भरको लागि - रन::वर्क_सर्भर, इत्यादि)। ती। $key चरको मान विकल्पद्वारा निर्दिष्ट गरिएको रूख तत्वको नामको अंश हो -आईडी.
प्रक्रियामा ध्यान दिऔं
चलाउनुहोस्::सर्भर
proc Run::server {tree host values} {
# получаем список кластеров требуемого сервера
set lst [RunCommand server::$host "cluster list $host"]
if {$lst eq ""} {return}
set l [lindex $lst 0]
#puts $lst
# удаляем лишнее из списка
.frm_work.tree_work delete [ .frm_work.tree_work children {}]
# читаем список
foreach cluster_list $lst {
# Заполняем список полученными значениями
InsertItemsWorkList $cluster_list
# обрабатываем вывод (список) для добавления данных в дерево
foreach i $cluster_list {
#puts $i
set cluster_list [split $i ":"]
if {[string trim [lindex $cluster_list 0]] eq "cluster"} {
set cluster_id [string trim [lindex $cluster_list 1]]
lappend cluster($cluster_id) $cluster_id
}
if {[string trim [lindex $cluster_list 0]] eq "name"} {
lappend cluster($cluster_id) [string trim [lindex $cluster_list 1]]
}
}
}
# добавляем кластеры в дерево
foreach x [array names cluster] {
set id [lindex $cluster($x) 0]
if { [$tree exists "cluster::$id"] == 0 } {
$tree insert "server::$host" end -id "cluster::$id" -text "[lindex $cluster($x) 1]" -values "$id"
# добавляем элементы в кластер
InsertClusterItems $tree $id
}
}
if { [$tree exists "agent_admins::$id"] == 0 } {
$tree insert "server::$host" end -id "agent_admins::$id" -text "Администраторы" -values "$id"
#InsertClusterItems $tree $id
}
}यो प्रक्रियाले RunCommand आदेश मार्फत सर्भरबाट प्राप्त भएको कुरालाई प्रशोधन गर्दछ र रूखमा सबै प्रकारका चीजहरू थप्छ - क्लस्टरहरू, विभिन्न मूल तत्वहरू (आधारहरू, काम गर्ने सर्भरहरू, सत्रहरू, र यस्तै)। यदि तपाईंले नजिकबाट हेर्नुभयो भने, तपाईंले InsertItemsWorkList प्रक्रिया भित्र कल देख्नुहुनेछ। यो rac कन्सोल उपयोगिताको आउटपुट प्रशोधन गरेर ग्राफिकल सूचीमा तत्वहरू थप्न प्रयोग गरिन्छ, जुन पहिले $lst चरमा सूचीको रूपमा फर्काइएको थियो। यो बृहदान्त्रद्वारा विभाजित तत्वहरूको जोडी समावेश सूचीहरूको सूची हो।
उदाहरणका लागि, क्लस्टर जडानहरूको सूची:
svk@svk ~]$ /opt/1C/v8.3/x86_64/rac connection list --cluster=783d2170-56c3-11e8-c586-fc75165efbb2 localhost:1545
connection : dcf5991c-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:49:51
session-number : 0
blocked-by-ls : 0
connection : b993293a-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:48:52
session-number : 0
blocked-by-ls : 0
ग्राफिकल रूप मा यो केहि यस्तो देखिनेछ:
माथिको प्रक्रियाले तालिका भर्नको लागि हेडर र डेटाका लागि तत्वहरूको नाम चयन गर्दछ:
InsertItemsWorklist
proc InsertItemsWorkList {lst} {
global work_list_row_count
# установка чередования цвета для строки
if [expr $work_list_row_count % 2] {
set tag dark
} else {
set tag light
}
# разбор строк на пары ключ - значение
foreach i $lst {
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
lappend column_list [string trim $param]
lappend value_list [string trim $value]
}
}
# заполнение таблицы
.frm_work.tree_work configure -columns $column_list -displaycolumns $column_list
.frm_work.tree_work insert {} end -values $value_list -tags $tag
.frm_work.tree_work column #0 -stretch
# установка заголовков
foreach j $column_list {
.frm_work.tree_work heading $j -text $j
}
incr work_list_row_count
}यहाँ, एउटा साधारण आदेश [स्प्लिट $str ":"] को सट्टा, जसले स्ट्रिङलाई ":" द्वारा छुट्याएका तत्वहरूमा विभाजन गर्छ र सूची फर्काउँछ, रेगुलर एक्सप्रेशन प्रयोग गरिन्छ, किनकि केही तत्वहरूमा कोलोन पनि हुन्छ।
InsertClusterItems प्रक्रिया (धेरै समानहरू मध्ये एक) ले आवश्यक क्लस्टर तत्वको रूखमा सम्बन्धित पहिचानकर्ताहरूसँग बाल तत्वहरूको सूची थप्छ।
ClusterItems घुसाउनुहोस्
proc InsertClusterItems {tree id} {
set parent "cluster::$id"
$tree insert $parent end -id "infobases::$id" -text "Информационные базы" -values "$id"
$tree insert $parent end -id "servers::$id" -text "Рабочие серверы" -values "$id"
$tree insert $parent end -id "admins::$id" -text "Администраторы" -values "$id"
$tree insert $parent end -id "managers::$id" -text "Менеджеры кластера" -values $id
$tree insert $parent end -id "processes::$id" -text "Рабочие процессы" -values "workprocess-all"
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "sessions-all"
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "blocks-all"
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "connections-all"
$tree insert $parent end -id "profiles::$id" -text "Профили безопасности" -values $id
}
तपाईं समान प्रक्रिया लागू गर्नका लागि दुई थप विकल्पहरू विचार गर्न सक्नुहुन्छ, जहाँ यो स्पष्ट रूपमा देखिनेछ कि तपाइँ कसरी अनुकूलन गर्न सक्नुहुन्छ र दोहोर्याइएको आदेशहरूबाट छुटकारा पाउन सक्नुहुन्छ:
यस प्रक्रियामा, थप्ने र जाँच हेड-अन हल गरिन्छ:
InsertBaseItems
proc InsertBaseItems {tree id} {
set parent "infobase::$id"
if { [$tree exists "sessions::$id"] == 0 } {
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "$id"
}
if { [$tree exists "locks::$id"] == 0 } {
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "$id"
}
if { [$tree exists "connections::$id"] == 0 } {
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "$id"
}
}
यहाँ थप सही दृष्टिकोण छ:
प्रोफाइल वस्तुहरू घुसाउनुहोस्
proc InsertProfileItems {tree id} {
set parent "profile::$id"
set lst {
{dir "Виртуальные каталоги"}
{com "Разрешённые COM-классы"}
{addin "Внешние компоненты"}
{module "Внешние отчёты и обработки"}
{app "Разрешённые приложения"}
{inet "Ресурсы интернет"}
}
foreach i $lst {
append item [lindex $i 0] "::$id"
if { [$tree exists $item] == 0 } {
$tree insert $parent end -id $item -text [lindex $i 1] -values "$id"
}
unset item
}
}तिनीहरू बीचको भिन्नता लूपको प्रयोग हो, जसमा दोहोर्याइएको आदेश (हरू) कार्यान्वयन गरिन्छ। कुन दृष्टिकोण प्रयोग गर्ने विकासकर्ताको विवेकमा छ।
हामीले तत्वहरू थप्ने र डेटा पुन: प्राप्त गर्ने कुरालाई कभर गरेका छौं, अब यो सम्पादनमा ध्यान केन्द्रित गर्ने समय हो। किनकि, मूलतः, एउटै प्यारामिटरहरू सम्पादन र थप्नका लागि प्रयोग गरिन्छ (सूचना आधारको अपवादको साथ), एउटै संवाद फारमहरू प्रयोग गरिन्छ। थप्नका लागि कल प्रक्रियाहरूको लागि एल्गोरिथ्म यस्तो देखिन्छ:
थप्नुहोस्::$key->AddToplevel
र यो जस्तै सम्पादन को लागी:
सम्पादन गर्नुहोस्::$key->Add::$key->AddTopLevel
उदाहरणका लागि, क्लस्टर सम्पादन गरौं, अर्थात्। रूखमा रहेको क्लस्टरको नाममा क्लिक गरिसकेपछि, टूलबार (पेन्सिल) मा रहेको सम्पादन बटन थिच्नुहोस् र सम्बन्धित फारम स्क्रिनमा देखा पर्नेछ:
सम्पादन:: क्लस्टर
proc Edit::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes active_cluster
agent_user agent_pwd cluster_user cluster_pwd auth
if {$cluster_user ne "" && $cluster_pwd ne ""} {
set auth "--cluster-user=$cluster_user --cluster-pwd=$cluster_pwd"
} else {
set auth ""
}
# рисуем форму для кластера
set frm [Add::cluster $tree $host $values]
# меняем текст на метке
$frm configure -text "Редактирование кластера"
set active_cluster $values
# получаем данные по выделенному кластеру
set lst [RunCommand cluster::$values "cluster info --cluster=$active_cluster $host"]
# заполняем поля
FormFieldsDataInsert $frm $lst
# выключаем поля, редактирование которых запрещено
$frm.ent_host configure -state disable
$frm.ent_port configure -state disable
# переназначаем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster update
--cluster=$active_cluster $auth
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth $host"
$tree delete "cluster::$active_cluster"
Run::server $tree $host ""
destroy .add
}
}कोडमा भएका टिप्पणीहरूमा आधारित, सिद्धान्तमा, बटन ह्यान्डलर कोड ओभरराइड गरिएको बाहेक सबै कुरा स्पष्ट छ र त्यहाँ एक FormFieldsDataInsert प्रक्रिया छ जसले डाटासँग फिल्डहरू भर्छ र चरहरू प्रारम्भ गर्दछ:
FormFieldsDataInsert
proc FormFieldsDataInsert {frm lst} {
foreach i [lindex $lst 0] {
# получаем список параметров и значений
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
# меняем символы
regsub -all -- "-" [string trim $param] "_" entry_name
# заполняем данными
if [winfo exists $frm.ent_$entry_name] {
$frm.ent_$entry_name delete 0 end
$frm.ent_$entry_name insert end [string trim $value """]
}
if [winfo exists $frm.cb_$entry_name] {
global $entry_name
set $entry_name [string trim $value """]
}
# для чекбоксов меняем значения
if [winfo exists $frm.check_$entry_name] {
global $entry_name
if {$value eq "0"} {
set $entry_name no
} elseif {$value eq "1"} {
set $entry_name yes
} else {
set $entry_name $value
}
}
}
}
}
यस प्रक्रियामा, tcl को अर्को फाइदा देखा पर्यो - अन्य चरहरूको मानहरू चर नामहरूको रूपमा प्रतिस्थापित गरिन्छ। ती। फारमहरू भर्ने र चरहरूको प्रारम्भिकतालाई स्वचालित गर्न, क्षेत्रहरू र चरहरूको नामहरू rac उपयोगिताको कमाण्ड लाइन स्विचहरू र केही अपवादका साथ आदेश आउटपुट प्यारामिटरहरूको नामसँग मेल खान्छ - ड्यासलाई अन्डरस्कोरले प्रतिस्थापन गर्दछ। जस्तै अनुसूचित-कार्य-अस्वीकार क्षेत्रसँग मेल खान्छ ent_scheduled_jobs_deny र चर अनुसूचित_कार्य_ अस्वीकार.
थप्न र सम्पादन गर्नका लागि फारमहरू क्षेत्रहरूको संरचनामा फरक हुन सक्छ, उदाहरणका लागि, सूचना आधारसँग काम गर्दै:
सूचना सुरक्षा थप्दै
जानकारी सुरक्षा सम्पादन
सम्पादन प्रक्रियामा Edit::infobase, आवश्यक क्षेत्रहरू फारममा थपिन्छन्; कोड ठूलो छ, त्यसैले म यसलाई यहाँ प्रस्तुत गर्दिन।
समानता अनुसार, थप्ने, सम्पादन गर्ने, मेटाउने प्रक्रियाहरू अन्य तत्वहरूको लागि लागू गरिन्छ।
चूंकि उपयोगिताको सञ्चालनले असीमित संख्यामा सर्भरहरू, क्लस्टरहरू, सूचना आधारहरू, इत्यादि समावेश गर्दछ, कुन क्लस्टर कुन सर्भर वा सूचना सुरक्षा प्रणालीसँग सम्बन्धित छ भनेर निर्धारण गर्न, धेरै विश्वव्यापी चरहरू प्रस्तुत गरिएका छन्, जसका मानहरू प्रत्येक सेट गरिएका छन्। तपाईंले रूखका तत्वहरूमा क्लिक गर्दा। ती। प्रक्रिया पुनरावर्ती सबै अभिभावक तत्वहरू मार्फत चल्छ र चर सेट गर्दछ:
GlobalVarFromTreeItems सेट गर्नुहोस्
proc SetGlobalVarFromTreeItems {tree id} {
global host server active_cluster infobase
set parent [$tree parent $id]
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
switch -- $key {
server {set host $values}
work_server {set server $values}
cluster {set active_cluster $values}
infobase {set infobase $values}
}
if {$parent eq ""} {
return
} else {
SetGlobalVarFromTreeItems $tree $parent
}
}
1C क्लस्टरले तपाईंलाई प्राधिकरण बिना वा बिना काम गर्न अनुमति दिन्छ। त्यहाँ दुई प्रकारका प्रशासकहरू छन् - क्लस्टर एजेन्ट प्रशासक र क्लस्टर प्रशासक। तदनुसार, सही सञ्चालनको लागि, प्रशासक लगइन र पासवर्ड सहित 4 थप ग्लोबल चरहरू प्रस्तुत गरियो। ती। यदि क्लस्टरमा प्रशासक खाता छ भने, तपाइँको लगइन र पासवर्ड प्रविष्ट गर्न एक संवाद प्रदर्शन गरिनेछ, डाटा मेमोरीमा बचत गरिनेछ र सम्बन्धित क्लस्टरको लागि प्रत्येक आदेशमा सम्मिलित गरिनेछ।
यो त्रुटि ह्यान्डलिंग प्रक्रियाको जिम्मेवारी हो।
त्रुटिपार्सिङ
proc ErrorParcing {err opt} {
global cluster_user cluster_pwd agent_user agent_pwd
switch -regexp -- $err {
"Cluster administrator is not authenticated" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Central server administrator is not authenticated" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
"Администратор кластера не аутентифицирован" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Администратор центрального сервера не аутентифицирован" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
(.+) {
tk_messageBox -type ok -icon error -message "$err"
}
}
}ती। कमाण्ड रिटर्न के आधारमा, प्रतिक्रिया तदनुसार हुनेछ।
हाल, कार्यक्षमता को लगभग 95 प्रतिशत लागू गरिएको छ, सबै बाँकी छ सुरक्षा प्रोफाइल संग काम लागू गर्न र यसलाई परीक्षण =)। यति नै। म टुटेको कथाको लागि माफी चाहन्छु।
कोड परम्परागत रूपमा उपलब्ध छ .
अपडेट: मैले सुरक्षा प्रोफाइलहरूसँग काम गरिसकेँ। अब कार्यक्षमता 100% लागू भएको छ।
अपडेट 2: अंग्रेजी र रूसीमा स्थानीयकरण थपिएको छ, win7 मा काम परीक्षण गरिएको छ
स्रोत: www.habr.com