Geophysics मा Wolfram Mathematica

ब्लगको लेखकलाई धन्यवाद एन्टोन एकिमेन्को उनको रिपोर्टको लागि

परिचय

यो नोट सम्मेलनको क्रममा लेखिएको हो Wolfram रूसी प्रौद्योगिकी सम्मेलन र मैले दिएको रिपोर्टको सारांश समावेश गर्दछ। घटना जुनमा सेन्ट पिटर्सबर्गमा भएको थियो। म कन्फरेन्स साइटबाट ब्लक काम गर्छु भन्ने कुरालाई ध्यानमा राख्दै, मैले यो कार्यक्रममा उपस्थित हुन मद्दत गर्न सकिन। 2016 र 2017 मा, मैले सम्मेलन रिपोर्टहरू सुनें, र यो वर्ष मैले एक प्रस्तुतीकरण दिए। पहिले, एउटा चाखलाग्दो (मलाई लाग्छ) विषय देखा पर्‍यो, जुन हामी विकास गर्दैछौं Kirill Belov, र दोस्रो, प्रतिबन्ध नीति सम्बन्धी रूसी संघको कानूनको लामो अध्ययन पछि, मैले काम गरेको उद्यममा, जति धेरै दुईवटा इजाजतपत्रहरू देखा पर्‍यो। वोल्फ्राम म्याथमेटिका.

मेरो भाषणको बिषयमा जानु भन्दा पहिले, म कार्यक्रमको राम्रो संगठनलाई नोट गर्न चाहन्छु। सम्मेलनको भ्रमण पृष्ठले कजान क्याथेड्रलको छवि प्रयोग गर्दछ। क्याथेड्रल सेन्ट पीटर्सबर्गको मुख्य आकर्षणहरू मध्ये एक हो र सम्मेलन भएको हलबाट धेरै स्पष्ट रूपमा देखिन्छ।

सेन्ट पीटर्सबर्ग स्टेट इकोनोमिक युनिभर्सिटीको प्रवेशद्वारमा, सहभागीहरूलाई विद्यार्थीहरूका सहायकहरूले भेटेका थिए - उनीहरूले तिनीहरूलाई हराउन अनुमति दिएनन्। दर्ताको क्रममा, साना स्मृति चिन्हहरू दिइयो (एक खेलौना - एक चम्किलो स्पाइक, कलम, वोल्फ्राम प्रतीकहरू सहित स्टिकरहरू)। लंच र कफी ब्रेक पनि सम्मेलन तालिकामा समावेश गरिएको थियो। मैले समूहको भित्तामा स्वादिष्ट कफी र पाईहरूको बारेमा पहिले नै नोट गरें - शेफहरू उत्कृष्ट छन्। यस परिचयात्मक भागको साथ, म घटना आफैं, यसको ढाँचा र स्थान पहिले नै सकारात्मक भावनाहरू ल्याउने कुरामा जोड दिन चाहन्छु।

म र किरिल बेलोभले तयार पारेको प्रतिवेदनलाई "उपयोगित भूभौतिकीमा समस्याहरू समाधान गर्न वोल्फ्राम गणितको प्रयोग" भनिन्छ। सिस्मिक डेटाको स्पेक्ट्रल विश्लेषण वा "जहाँ पुरातन नदीहरू बगेका थिए।" रिपोर्टको सामग्रीले दुई भागहरू समेट्छ: पहिलो, उपलब्ध एल्गोरिदमहरूको प्रयोग वोल्फ्राम म्याथमेटिका जियोफिजिकल डेटाको विश्लेषणको लागि, र दोस्रो, यो वोल्फ्राम म्याथेमेटिकामा जियोफिजिकल डाटा कसरी राख्ने भन्ने हो।

भूकम्पीय अन्वेषण

पहिले तपाईंले जियोफिजिक्समा छोटो भ्रमण गर्न आवश्यक छ। जियोफिजिक्स भनेको चट्टानको भौतिक गुणहरूको अध्ययन गर्ने विज्ञान हो। ठिक छ, चट्टानहरूमा विभिन्न गुणहरू भएकाले: विद्युतीय, चुम्बकीय, लोचदार, भूभौतिकीका सम्बन्धित विधिहरू छन्: विद्युतीय पूर्वाग्रह, चुम्बकीय पूर्वाक्षण, भूकम्पीय पूर्वाक्षण... यस लेखको सन्दर्भमा, हामी केवल भूकम्पीय सम्भावनाबारे थप विस्तारमा छलफल गर्नेछौं। सिस्मिक अन्वेषण तेल र ग्याँस खोज्ने मुख्य विधि हो। विधि लोचदार कम्पनहरूको उत्तेजना र अध्ययन क्षेत्र कम्पोज गर्ने चट्टानहरूबाट प्रतिक्रियाको पछिल्लो रेकर्डिङमा आधारित छ। कम्पनहरू जमिनमा उत्तेजित हुन्छन् (डाइनामाइट वा लोचदार कम्पनको गैर-विस्फोटक कम्पन स्रोतहरूसँग) वा समुद्रमा (एयर गनहरूसँग)। लोचदार कम्पनहरू चट्टानको मास मार्फत प्रसारित हुन्छन्, विभिन्न गुणहरू भएका तहहरूको सीमाहरूमा अपवर्तित र प्रतिबिम्बित हुँदै। प्रतिबिम्बित तरंगहरू सतहमा फर्कन्छन् र जमिनमा जियोफोनहरू (सामान्यतया कुण्डलमा निलम्बित चुम्बकको आन्दोलनमा आधारित इलेक्ट्रोडायनामिक उपकरणहरू) वा समुद्रमा हाइड्रोफोनहरू (पिजोइलेक्ट्रिक प्रभावमा आधारित) द्वारा रेकर्ड हुन्छन्। छालहरूको आगमनको समयमा, कसैले भूवैज्ञानिक तहहरूको गहिराइको न्याय गर्न सक्छ।

सिस्मिक पोत टोइङ उपकरण


एयर गनले लोचदार कम्पनहरूलाई उत्तेजित गर्छ


छालहरू चट्टान मास मार्फत जान्छ र हाइड्रोफोन द्वारा रेकर्ड गरिन्छ


सेन्ट पीटर्सबर्गको ब्लागोभेस्चेन्स्की पुल नजिकैको घाटमा भूभौतिक सर्वेक्षण अनुसन्धान पोत "इभान गुबकिन"

सिस्मिक सिग्नल मोडेल

चट्टानहरूमा विभिन्न भौतिक गुणहरू छन्। भूकम्पीय अन्वेषणको लागि, लोचदार गुणहरू मुख्य रूपमा महत्त्वपूर्ण हुन्छन् - लोचदार कम्पन र घनत्वको प्रसारको गति। यदि दुई तहहरूमा समान वा समान गुणहरू छन् भने, लहरले तिनीहरूको बीचको सीमालाई "ध्यान गर्दैन"। यदि तहहरूमा लहरको गति फरक छ भने, तब प्रतिबिम्ब तहहरूको सीमामा देखा पर्नेछ। गुणहरूमा जति ठूलो भिन्नता हुन्छ, त्यति नै तीव्र प्रतिबिम्ब हुन्छ। यसको तीव्रता प्रतिबिम्ब गुणांक (rc) द्वारा निर्धारण गरिनेछ:

जहाँ ρ चट्टानको घनत्व हो, ν तरंग गति हो, 1 र 2 ले माथिल्लो र तल्लो तहहरू संकेत गर्दछ।

एक सरल र प्रायः प्रयोग हुने सिस्मिक सिग्नल मोडेलहरू कन्भोलुसन मोडेल हो, जब रेकर्ड गरिएको सिस्मिक ट्रेसलाई प्रोबिङ पल्सको साथ परावर्तन गुणांकहरूको अनुक्रमको परिक्रमाको परिणामको रूपमा प्रतिनिधित्व गरिन्छ:

कहाँ s(t) - सिस्मिक ट्रेस, अर्थात् एक निश्चित रेकर्डिङ समयमा हाइड्रोफोन वा जियोफोन द्वारा रेकर्ड गरिएको सबै कुरा, w(t) - हावा बन्दुक द्वारा उत्पन्न संकेत, n(t) - अनियमित आवाज।

उदाहरणको रूपमा सिंथेटिक सिस्मिक ट्रेस गणना गरौं। हामी प्रारम्भिक संकेतको रूपमा भूकंपीय अन्वेषणमा व्यापक रूपमा प्रयोग हुने रिकर पल्स प्रयोग गर्नेछौं।

length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]

प्रारम्भिक भूकम्पीय आवेग


हामी 300 ms र 600 ms को गहिराईमा दुई सीमाहरू सेट गर्नेछौं, र प्रतिबिम्ब गुणांकहरू अनियमित संख्याहरू हुनेछन्।

rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]

प्रतिबिम्ब गुणांकहरूको अनुक्रम


सिस्मिक ट्रेसको गणना र प्रदर्शन गरौं। प्रतिबिम्ब गुणांकमा फरक-फरक चिन्हहरू भएकाले, हामीले सिस्मिक ट्रेसमा दुई वैकल्पिक प्रतिबिम्ब पाउँछौं।

traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]

सिमुलेटेड ट्र्याक


यस उदाहरणको लागि, यो आरक्षण गर्न आवश्यक छ - वास्तवमा, तहहरूको गहिराई निश्चित रूपमा, मिटरमा निर्धारण गरिन्छ, र भूकम्प ट्रेसको गणना समय डोमेनको लागि हुन्छ। यो मिटरमा गहिराई सेट गर्न र तहहरूमा गतिहरू थाहा पाएर आगमन समय गणना गर्न अझ सही हुनेछ। यस अवस्थामा, मैले तुरुन्तै समय अक्षमा तहहरू सेट गरें।

यदि हामी क्षेत्र अनुसन्धानको बारेमा कुरा गर्छौं भने, त्यस्ता अवलोकनहरूको परिणामको रूपमा ठूलो संख्यामा समान समय श्रृंखला (भूकंपीय निशान) रेकर्ड गरिएको छ। उदाहरण को लागी, 25 किमी लामो र 15 किमी चौडाई साइट को अध्ययन गर्दा, जहाँ, काम को परिणाम को रूप मा, प्रत्येक ट्रेस 25x25 मिटर (जस्तै सेल एक बिन भनिन्छ) मापन कोशिका को विशेषता गर्दछ, अन्तिम डाटा एरे 600000 ट्रेस समावेश हुनेछ। 1 ms को नमूना समय र 5 सेकेन्डको रेकर्डिङ समय संग, अन्तिम डाटा फाइल 11 GB भन्दा बढी हुनेछ, र मूल "कच्चा" सामग्री को भोल्युम सयौं गीगाबाइट हुन सक्छ।

तिनीहरूसँग कसरी काम गर्ने वोल्फ्राम म्याथमेटिका?

प्याकेज GeologyIO

प्याकेजको विकास सुरु भयो मुद्दा रूसी भाषी समर्थन समूहको VK पर्खालमा। समुदायको प्रतिक्रियाको लागि धन्यवाद, एक समाधान धेरै चाँडै फेला पर्यो। र परिणाम स्वरूप, यो एक गम्भीर विकास मा बढ्यो। अनुरूप Wolfram समुदाय भित्ता पोस्ट यो पनि मध्यस्थकर्ता द्वारा चिन्ह लगाइएको थियो। हाल, प्याकेजले निम्न डेटा प्रकारहरूसँग काम गर्न समर्थन गर्दछ जुन भूवैज्ञानिक उद्योगमा सक्रिय रूपमा प्रयोग गरिन्छ:

1. ZMAP र IRAP ढाँचाहरूमा नक्सा डेटाको आयात
2. LAS ढाँचा कुवाहरूमा मापनको आयात
3. सिस्मिक फाइल ढाँचाको इनपुट र आउटपुट SEGY

प्याकेज स्थापना गर्न, तपाईंले एसेम्बल प्याकेजको डाउनलोड पृष्ठमा निर्देशनहरू पालना गर्नुपर्छ, अर्थात्। कुनै पनि मा निम्न कोड कार्यान्वयन गर्नुहोस् गणित नोटबुक:

If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
    "https://wolfr.am/FiQ5oFih", 
    FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]

जस पछि प्याकेज पूर्वनिर्धारित फोल्डरमा स्थापित हुनेछ, जसमा निम्नानुसार प्राप्त गर्न सकिन्छ:

FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]

उदाहरणको रूपमा, हामी प्याकेजको मुख्य क्षमताहरू प्रदर्शन गर्नेछौं। कल परम्परागत रूपमा Wolfram भाषामा प्याकेजहरूको लागि गरिन्छ:

Get["GeologyIO`"]

प्याकेज प्रयोग गरी विकसित गरिएको छ Wolfram Workbench। यसले तपाइँलाई कागजातको साथ प्याकेजको मुख्य कार्यक्षमतालाई साथ दिन अनुमति दिन्छ, जुन प्रस्तुतीकरण ढाँचाको हिसाबले वोल्फ्राम म्याथेमेटिकाको कागजात भन्दा फरक छैन, र पहिलो परिचितको लागि परीक्षण फाइलहरूसँग प्याकेज प्रदान गर्न।

यस्तो फाइल, विशेष गरी, फाइल "Marmousi.segy" हो - यो फ्रान्सेली पेट्रोलियम संस्थान द्वारा विकसित गरिएको भौगोलिक खण्डको सिंथेटिक मोडेल हो। यो मोडेल प्रयोग गरेर, विकासकर्ताहरूले वेभ फिल्ड मोडलिङ, डाटा प्रोसेसिङ, सिस्मिक ट्रेस इन्भर्सन, इत्यादिका लागि आफ्नै एल्गोरिदमहरू परीक्षण गर्छन्। Marmousi मोडेल आफै भण्डारमा भण्डार गरिएको छ जहाँबाट प्याकेज आफै डाउनलोड गरिएको थियो। फाइल प्राप्त गर्न, निम्न कोड चलाउनुहोस्:

If[Not[FileExistsQ["Marmousi.segy"]], 
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]

परिणाम आयात गर्नुहोस् - SEGYData वस्तु


SEGY ढाँचाले अवलोकनहरूको बारेमा विभिन्न जानकारीहरू भण्डारण गर्न समावेश गर्दछ। पहिलो, यी पाठ टिप्पणीहरू हुन्। यसले कामको स्थान, मापन प्रदर्शन गर्ने कम्पनीहरूको नाम, आदि बारे जानकारी समावेश गर्दछ। हाम्रो मामला मा, यो हेडर TextHeader कुञ्जी संग अनुरोध द्वारा बोलाइन्छ। यहाँ छोटो पाठ हेडर छ:

Short[marmousi["TextHeader"]]

"मार्मौसी डाटा सेट इन्स्टिच्युटमा उत्पन्न भएको थियो ...न्युनतम वेग 1500 m/s र अधिकतम 5500 m/s)"

तपाईंले "ट्रेस" कुञ्जी प्रयोग गरेर भूकम्पीय ट्रेसहरू पहुँच गरेर वास्तविक भौगोलिक मोडेल प्रदर्शन गर्न सक्नुहुन्छ (प्याकेजको एक विशेषता भनेको कुञ्जीहरू केस-संवेदनशील छन्):

ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]

मोडल मार्मौसी


हाल, प्याकेजले तपाईंलाई ठूला फाइलहरूबाट भागहरूमा डाटा लोड गर्न अनुमति दिन्छ, यसले फाइलहरू प्रशोधन गर्न सम्भव बनाउँछ जसको आकार दसौं गिगाबाइटसम्म पुग्न सक्छ। प्याकेजको प्रकार्यहरूले .segy मा डाटा निर्यात गर्ने र फाइलको अन्त्यमा आंशिक रूपमा संलग्न गर्ने कार्यहरू पनि समावेश गर्दछ।

अलग रूपमा, .segy फाइलहरूको जटिल संरचनासँग काम गर्दा प्याकेजको कार्यक्षमतालाई ध्यान दिन लायक छ। किनकि यसले तपाईंलाई कुञ्जीहरू र अनुक्रमणिकाहरू प्रयोग गरेर व्यक्तिगत ट्रेसहरू र हेडरहरू पहुँच गर्न मात्र होइन, तर तिनीहरूलाई परिवर्तन गर्न र त्यसपछि फाइलमा लेख्न पनि अनुमति दिन्छ। GeologyIO को कार्यान्वयनका धेरै प्राविधिक विवरणहरू यस लेखको दायराभन्दा बाहिर छन् र सम्भवतः छुट्टै विवरणको योग्य छन्।

भूकम्पीय अन्वेषणमा वर्णक्रमीय विश्लेषणको सान्दर्भिकता

Wolfram Mathematica मा सिस्मिक डेटा आयात गर्ने क्षमताले तपाइँलाई प्रयोगात्मक डेटाको लागि निर्मित सिग्नल प्रोसेसिङ कार्यक्षमता प्रयोग गर्न अनुमति दिन्छ। प्रत्येक सिस्मिक ट्रेसले समय श्रृङ्खलालाई प्रतिनिधित्व गर्ने हुनाले, तिनीहरूलाई अध्ययन गर्ने मुख्य औजारहरू मध्ये एउटा स्पेक्ट्रल विश्लेषण हो। सिस्मिक डेटाको फ्रिक्वेन्सी कम्पोजिसनको विश्लेषण गर्नको लागि आवश्यक शर्तहरू मध्ये, हामी निम्नलाई नाम दिन सक्छौं, उदाहरणका लागि:

1. विभिन्न प्रकारका तरंगहरू फरक आवृत्ति संरचना द्वारा विशेषता छन्। यसले तपाईंलाई उपयोगी छालहरू हाइलाइट गर्न र हस्तक्षेप तरंगहरूलाई दबाउन अनुमति दिन्छ।
2. चट्टान गुणहरू जस्तै पोरोसिटी र संतृप्तिले आवृत्ति संरचनालाई असर गर्न सक्छ। यसले उत्कृष्ट गुणहरू भएका चट्टानहरू पहिचान गर्न सम्भव बनाउँछ।
3. विभिन्न मोटाई भएका तहहरूले विभिन्न फ्रिक्वेन्सी दायराहरूमा विसंगतिहरू निम्त्याउँछ।

तेस्रो बुँदा यस लेखको सन्दर्भमा मुख्य हो। तल फरक मोटाई संग एक तह को मामला मा भूकम्प ट्रेस गणना को लागी एक कोड टुक्रा छ - एक वेज मोडेल। यो मोडेल परम्परागत रूपमा भूकंपीय अन्वेषणमा हस्तक्षेप प्रभावहरू विश्लेषण गर्न अध्ययन गरिन्छ जब धेरै तहहरूबाट प्रतिबिम्बित छालहरू एकअर्कामा सुपरइम्पोज हुन्छन्।

nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]

पिन्च-आउट गठनको मोडेल


वेज भित्रको तरंग गति 4500 m/s, वेज बाहिर 4000 m/s, र घनत्व स्थिर 2200 g/cm³ मानिन्छ। यस्तो मोडेलको लागि, हामी प्रतिबिम्ब गुणांक र भूकम्प ट्रेसहरू गणना गर्छौं।

rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
	ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
		{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]

वेज मोडेलका लागि सिस्मिक ट्रेसहरू


यस चित्रमा देखाइएको सिस्मिक ट्रेसहरूको क्रमलाई सिस्मिक सेक्शन भनिन्छ। तपाईले देख्न सक्नुहुने रूपमा, यसको व्याख्या पनि सहज स्तरमा गर्न सकिन्छ, किनकि प्रतिबिम्बित तरंगहरूको ज्यामिति स्पष्ट रूपमा पहिले निर्दिष्ट गरिएको मोडेलसँग मेल खान्छ। यदि तपाइँ ट्रेसहरूलाई थप विस्तारमा विश्लेषण गर्नुहुन्छ भने, तपाइँले याद गर्नुहुनेछ कि 1 देखि लगभग 30 सम्मका ट्रेसहरू फरक छैनन् - गठनको छतबाट र तलबाट प्रतिबिम्ब एकअर्कालाई ओभरल्याप गर्दैन। 31 औं ट्रेसबाट सुरु हुँदै, प्रतिबिम्बहरू हस्तक्षेप गर्न थाल्छन्। र, यद्यपि मोडेलमा, प्रतिबिम्ब गुणांकहरू तेर्सो रूपमा परिवर्तन गर्दैनन् - भूकंपीय निशानहरूले गठनको मोटाई परिवर्तन हुँदा तिनीहरूको तीव्रता परिवर्तन गर्दछ।

गठनको माथिल्लो सीमाबाट प्रतिबिम्बको आयामलाई विचार गरौं। ६० औं रुटबाट सुरु हुँदै, प्रतिबिम्बको तीव्रता बढ्न थाल्छ र ७० औं रुटमा यो अधिकतम हुन्छ। यसरी छत र तहको तलबाट छालहरूको हस्तक्षेप आफैं प्रकट हुन्छ, जसले केही अवस्थामा भूकम्पीय रेकर्डमा महत्त्वपूर्ण विसंगतिहरू निम्त्याउँछ।

ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]

वेजको माथिल्लो किनारबाट प्रतिबिम्बित तरंगको आयामको ग्राफ


यो तार्किक छ कि जब सिग्नल कम-फ्रिक्वेन्सी छ, हस्तक्षेप ठूलो गठन मोटाई मा देखा पर्न थाल्छ, र एक उच्च आवृत्ति संकेत को मामला मा, हस्तक्षेप साना मोटाई मा हुन्छ। निम्न कोड स्निपेटले 35 Hz, 55 Hz र 85 Hz को फ्रिक्वेन्सीको साथ संकेत सिर्जना गर्दछ।

waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]

३५ हर्ट्ज, ५५ हर्ट्ज, ८५ हर्ट्जको फ्रिक्वेन्सीको साथ स्रोत संकेतहरूको सेट


सिस्मिक ट्रेसहरू गणना गरेर र परावर्तित तरंग एम्प्लिट्यूडहरूको ग्राफहरू प्लट गरेर, हामी देख्न सक्छौं कि विभिन्न फ्रिक्वेन्सीहरूको लागि विभिन्न गठन मोटाईहरूमा एक विसंगति अवलोकन गरिएको छ।

tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];

lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];

Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]

विभिन्न फ्रिक्वेन्सीको लागि वेजको माथिल्लो किनारबाट परावर्तित तरंगको आयामहरूको ग्राफहरू


भूकम्पीय अवलोकनको नतिजाबाट संरचनाको मोटाईको बारेमा निष्कर्ष निकाल्ने क्षमता अत्यन्त उपयोगी छ, किनभने तेल अन्वेषणको मुख्य कार्यहरू मध्ये एउटा इनार बिछ्याउने सबैभन्दा आशाजनक बिन्दुहरूको मूल्याङ्कन गर्नु हो (अर्थात, ती क्षेत्रहरू जहाँ गठन हुन्छ। गाढा)। थप रूपमा, भौगोलिक खण्डमा त्यहाँ वस्तुहरू हुन सक्छ जसको उत्पत्तिले गठनको मोटाईमा तीव्र परिवर्तन निम्त्याउँछ। यसले स्पेक्ट्रल विश्लेषणलाई उनीहरूको अध्ययनको लागि प्रभावकारी उपकरण बनाउँछ। लेखको अर्को भागमा हामी त्यस्ता भूवैज्ञानिक वस्तुहरूलाई थप विस्तारमा विचार गर्नेछौं।

प्रयोगात्मक डाटा। तपाईंले तिनीहरूलाई कहाँ पाउनुभयो र तिनीहरूमा के खोज्ने?

लेखमा विश्लेषण गरिएका सामग्रीहरू पश्चिमी साइबेरियामा प्राप्त गरिएका थिए। यो क्षेत्र, अपवाद बिना सबैलाई थाहा छ, हाम्रो देशको मुख्य तेल उत्पादन क्षेत्र हो। पछिल्लो शताब्दीको 60s मा क्षेत्रमा जम्मा को सक्रिय विकास सुरु भयो। तेल भण्डार खोज्ने मुख्य विधि भूकम्पीय अन्वेषण हो। यो क्षेत्र को उपग्रह छविहरू हेर्न रोचक छ। सानो मापनमा, तपाईंले ठूलो संख्यामा दलदल र तालहरू नोट गर्न सक्नुहुन्छ; नक्सालाई ठूलो गरेर, तपाईंले क्लस्टर इनार ड्रिलिंग साइटहरू देख्न सक्नुहुन्छ, र नक्सालाई सीमामा विस्तार गरेर, तपाईंले प्रोफाइलहरूको क्लियरिङहरू पनि छुट्याउन सक्नुहुन्छ जसमा भूकम्प अवलोकनहरू गरियो।

Yandex नक्सा को उपग्रह छवि - Noyabrsk शहर क्षेत्र


क्षेत्रहरू मध्ये एकमा राम्रो प्याडहरूको नेटवर्क


पश्चिमी साइबेरियाको तेल-वाहक चट्टानहरू गहिराइको विस्तृत दायरामा हुन्छन् - 1 किमी देखि 5 किमी सम्म। तेल युक्त चट्टानको मुख्य मात्रा जुरासिक र क्रेटासियस समयमा बनाइएको थियो। जुरासिक अवधि सायद धेरैलाई एउटै नामको फिल्मबाट थाहा छ। जुरासिक जलवायु आधुनिक भन्दा धेरै फरक थियो। इन्साइक्लोपीडिया ब्रिटानिकामा प्रत्येक हेलोजिकल युगको विशेषता पेलियोम्यापको श्रृंखला छ।

आजकल

जुरासिक अवधि


कृपया ध्यान दिनुहोस् कि जुरासिक समय मा, पश्चिमी साइबेरिया को क्षेत्र एक समुद्री तट थियो (नदीहरु र एक उथले समुद्र द्वारा पार गरिएको भूमि)। हावापानी सहज भएको हुनाले, हामी अनुमान गर्न सक्छौं कि त्यस समयको एक विशिष्ट परिदृश्य यस्तो देखिन्छ:

जुरासिक साइबेरिया


यस चित्रमा, हाम्रो लागि महत्त्वपूर्ण कुरा जनावर र चराहरू होइन, तर पृष्ठभूमिमा नदीको छवि हो। नदी उही भूवैज्ञानिक वस्तु हो जुन हामीले पहिले रोकेका थियौं। तथ्य यो हो कि नदीहरूको गतिविधिले राम्ररी क्रमबद्ध बालुवा ढुङ्गाहरू जम्मा गर्न अनुमति दिन्छ, जुन त्यसपछि तेलको लागि भण्डार हुनेछ। यी जलाशयहरूमा एक विचित्र, जटिल आकार (नदीको ओछ्यान जस्तै) हुन सक्छ र तिनीहरूको चर मोटाई हुन सक्छ - किनारको नजिक मोटाई सानो छ, तर च्यानलको केन्द्रको नजिक वा मध्य क्षेत्रहरूमा यो बढ्छ। त्यसोभए, जुरासिकमा बनेका नदीहरू अब करिब तीन किलोमिटरको गहिराइमा छन् र तेल भण्डारहरूको खोजीको वस्तु हुन्।

प्रयोगात्मक डेटा। प्रशोधन र दृश्यीकरण

लेखमा देखाइएको भूकम्पीय सामग्रीको सन्दर्भमा तुरुन्तै रिजर्भेसन गरौं - विश्लेषणको लागि प्रयोग गरिएको डाटाको मात्रा महत्त्वपूर्ण छ भन्ने तथ्यको कारण - लेखको पाठमा भूकम्पीय ट्रेसहरूको मूल सेटको एक अंश मात्र समावेश गरिएको छ। यसले कसैलाई माथिको गणनाहरू पुन: उत्पादन गर्न अनुमति दिनेछ।

भूकम्पीय डेटासँग काम गर्दा, एक भूभौतिकविद्ले सामान्यतया विशेष सफ्टवेयर प्रयोग गर्दछ (त्यहाँ धेरै उद्योग नेताहरू छन् जसको विकासहरू सक्रिय रूपमा प्रयोग गरिन्छ, उदाहरणका लागि Petrel वा Paradigm), जसले तपाईंलाई विभिन्न प्रकारका डाटा विश्लेषण गर्न अनुमति दिन्छ र एक सुविधाजनक ग्राफिकल इन्टरफेस छ। सबै सुविधाको बावजुद, यी प्रकारका सफ्टवेयरहरूमा पनि तिनीहरूको कमजोरीहरू छन् - उदाहरणका लागि, स्थिर संस्करणहरूमा आधुनिक एल्गोरिदमहरूको कार्यान्वयनले धेरै समय लिन्छ, र स्वचालित गणनाहरूका लागि सम्भावनाहरू सामान्यतया सीमित हुन्छन्। यस्तो अवस्थामा, कम्प्युटर गणित प्रणाली र उच्च-स्तर प्रोग्रामिङ भाषाहरू प्रयोग गर्न धेरै सुविधाजनक हुन्छ, जसले फराकिलो एल्गोरिदमिक आधारको प्रयोगलाई अनुमति दिन्छ र, एकै समयमा, धेरै दिनचर्या लिन्छन्। यो Wolfram Mathematica मा सिस्मिक डेटा संग काम गर्न को लागी प्रयोग गरिएको सिद्धान्त हो। डेटाको साथ अन्तरक्रियात्मक कार्यको लागि समृद्ध कार्यक्षमता लेख्न अनुपयुक्त छ - सामान्यतया स्वीकृत ढाँचाबाट लोड हुने सुनिश्चित गर्न, तिनीहरूमा इच्छित एल्गोरिदमहरू लागू गर्दै र तिनीहरूलाई बाहिरी ढाँचामा फिर्ता अपलोड गर्न यो महत्त्वपूर्ण छ।

प्रस्तावित योजना पछ्याउँदै, हामी मूल भूकम्पीय डेटा लोड गर्नेछौं र तिनीहरूलाई प्रदर्शन गर्नेछौं वोल्फ्राम म्याथमेटिका:

Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]

यसरी डाउनलोड र आयात गरिएको डाटा १० गुणा ५ किलोमिटरको क्षेत्रमा रेकर्ड गरिएका मार्गहरू हुन्। यदि डेटा त्रि-आयामी सिस्मिक सर्वेक्षण विधि प्रयोग गरी प्राप्त गरिन्छ (तरंगहरू व्यक्तिगत भूभौतिक प्रोफाइलहरूमा रेकर्ड गरिएका छैनन्, तर सम्पूर्ण क्षेत्रमा एकै साथ), यसले भूकम्पीय डेटा क्यूबहरू प्राप्त गर्न सम्भव हुन्छ। यी तीन-आयामी वस्तुहरू, ठाडो र तेर्सो खण्डहरू हुन् जसको भौगोलिक वातावरणको विस्तृत अध्ययन गर्न अनुमति दिन्छ। विचार गरिएको उदाहरणमा, हामी त्रि-आयामी डेटासँग काम गरिरहेका छौं। हामी पाठ हेडरबाट केहि जानकारी प्राप्त गर्न सक्छौं, जस्तै

StringPartition[seismic3DSEGY["textheader"], 80] // TableForm

C 1 यो भूविज्ञान प्याकेज परीक्षणको लागि डेमो फाइल हो
सी 2
सी 3
सी 4
C 5 मिति प्रयोगकर्ता नाम: WOLFRAM प्रयोगकर्ता
C 6 सर्वेक्षण नाम: कतै साइबेरियामा
C 7 फाइल प्रकार 3D सिस्मिक भोल्युम
सी 8
सी 9
C10 Z दायरा: पहिलो 2200M अन्तिम 2400M

यो डेटा सेट डेटा विश्लेषण को मुख्य चरणहरु को प्रदर्शन को लागी पर्याप्त हुनेछ। फाइलमा ट्रेसहरू क्रमिक रूपमा रेकर्ड गरिएका छन् र तिनीहरूमध्ये प्रत्येक निम्न चित्र जस्तो देखिन्छ - यो ठाडो अक्ष (गहिराई अक्ष) को साथ प्रतिबिम्बित छालहरूको आयामहरूको वितरण हो।

ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2, 
 PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
 LabelStyle -> Directive[Black, Italic], PlotRange -> All, 
 Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]

भूकम्पीय खण्ड ट्रेसहरू मध्ये एक


अध्ययन गरिएको क्षेत्रको प्रत्येक दिशामा कति ट्रेसहरू अवस्थित छन् भन्ने थाहा पाएर, तपाईंले तीन-आयामी डेटा एरे उत्पन्न गर्न सक्नुहुन्छ र यसलाई Image3D[] प्रकार्य प्रयोग गरेर प्रदर्शन गर्न सक्नुहुन्छ।

traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1;   (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1;   (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]

सिस्मिक डेटा क्यूबको XNUMXD छवि। (ठाडो अक्ष - गहिराई)


यदि रुचिको भौगोलिक विशेषताहरूले तीव्र भूकम्पीय विसंगतिहरू सिर्जना गर्दछ भने, त्यसपछि पारदर्शिताका साथ दृश्य उपकरणहरू प्रयोग गर्न सकिन्छ। रेकर्डिङका "अनमहत्त्वपूर्ण" क्षेत्रहरू अदृश्य बनाउन सकिन्छ, विसंगतिहरू मात्र देख्न सकिन्छ। Wolfram Mathematica मा यो प्रयोग गरेर गर्न सकिन्छ अस्पष्टता [ ] и Raster3D[].

data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]}, 
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]

ओपेसिटी [] र Raster3D[] प्रकार्यहरू प्रयोग गरेर सिस्मिक डेटा क्यूब छवि

सिंथेटिक उदाहरणमा जस्तै, मूल क्यूबको खण्डहरूमा चर राहतको साथ केही भौगोलिक सीमाहरू (तहहरू) पहिचान गर्न सकिन्छ।

वर्णक्रमीय विश्लेषणको लागि मुख्य उपकरण फोरियर रूपान्तरण हो। यसको मद्दतले, तपाइँ प्रत्येक ट्रेस वा ट्रेसहरूको समूहको आयाम-फ्रिक्वेन्सी स्पेक्ट्रम मूल्याङ्कन गर्न सक्नुहुन्छ। यद्यपि, डेटालाई फ्रिक्वेन्सी डोमेनमा स्थानान्तरण गरेपछि, कुन समयमा (कुन गहिराइमा पढ्नुहोस्) फ्रिक्वेन्सी परिवर्तनहरू बारे जानकारी हराएको छ। समय (गहिराइ) अक्षमा संकेत परिवर्तनहरू स्थानीयकरण गर्न सक्षम हुनको लागि, विन्डो गरिएको फूरियर रूपान्तरण र तरंग विघटन प्रयोग गरिन्छ। यस लेखले तरंग विघटन प्रयोग गर्दछ। वेभलेट विश्लेषण प्रविधि ९० को दशकमा भूकम्पीय अन्वेषणमा सक्रिय रूपमा प्रयोग हुन थाल्यो। विन्डो गरिएको फूरियर ट्रान्सफर्मको फाइदालाई राम्रो समय रिजोल्युसन मानिन्छ।

निम्न कोड टुक्रा प्रयोग गरेर, तपाईंले भूकम्पीय निशानहरू मध्ये एकलाई व्यक्तिगत कम्पोनेन्टहरूमा विघटन गर्न सक्नुहुन्छ:

cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]

कम्पोनेन्टहरूमा ट्रेसको विघटन


विभिन्न तरंग आगमन समयमा प्रतिबिम्ब ऊर्जा कसरी वितरण गरिन्छ भनेर मूल्याङ्कन गर्न, स्केलोग्राम (स्पेक्ट्रोग्रामको अनुरूप) प्रयोग गरिन्छ। एक नियमको रूपमा, व्यवहारमा सबै घटकहरू विश्लेषण गर्न आवश्यक छैन। सामान्यतया, कम, मध्य र उच्च आवृत्ति घटकहरू चयन गरिन्छ।

freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]

स्क्यालोग्राम। कार्य परिणाम वेभलेट स्क्यालोग्राम[]


Wolfram Language ले तरंग परिवर्तनको लागि प्रकार्य प्रयोग गर्दछ Continuous WaveletTransform[]। र ट्रेसहरूको सम्पूर्ण सेटमा यस प्रकार्यको अनुप्रयोग प्रकार्य प्रयोग गरेर गरिन्छ तालिका[]। यहाँ यो Wolfram Mathematica को एक बललाई ध्यान दिन लायक छ - समानान्तर प्रयोग गर्ने क्षमता। समानान्तरतालिका[]। माथिको उदाहरणमा, समानान्तरको लागि कुनै आवश्यकता छैन - डाटाको भोल्युम ठूलो छैन, तर सयौं हजारौं ट्रेसहरू भएको प्रयोगात्मक डेटा सेटहरूसँग काम गर्दा, यो एक आवश्यकता हो।

tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}]; 

प्रकार्य लागू गरेपछि Continuous WaveletTransform[] नयाँ डेटा सेटहरू चयन गरिएका फ्रिक्वेन्सीहरूसँग सम्बन्धित देखिन्छन्। माथिको उदाहरणमा, यी फ्रिक्वेन्सीहरू हुन्: 38Hz, 33Hz, 27Hz। आवृत्तिहरूको छनोट प्रायः परीक्षणको आधारमा गरिन्छ - तिनीहरूले विभिन्न आवृत्ति संयोजनहरूको लागि प्रभावकारी नक्साहरू प्राप्त गर्छन् र भूवैज्ञानिकको दृष्टिकोणबाट सबैभन्दा जानकारीपूर्ण चयन गर्छन्।

यदि तपाइँ सहकर्मीहरूसँग नतिजाहरू साझा गर्न वा ग्राहकलाई प्रदान गर्न आवश्यक छ भने, तपाइँ GeologyIO प्याकेजको SEGYExport[] प्रकार्य प्रयोग गर्न सक्नुहुन्छ।

outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];

यी तीनवटा क्यूबहरू (कम-फ्रिक्वेन्सी, मिड-फ्रिक्वेन्सी, र उच्च-फ्रिक्वेन्सी कम्पोनेन्टहरू) सँग, RGB ब्लेन्डिङ सामान्यतया डेटालाई सँगै कल्पना गर्न प्रयोग गरिन्छ। रातो, हरियो, नीलो - प्रत्येक घटक यसको आफ्नै रंग तोकिएको छ। Wolfram Mathematica मा यो प्रकार्य प्रयोग गरेर गर्न सकिन्छ कलर कम्बाइन[].

परिणाम तस्बिरहरू हो जसबाट भूवैज्ञानिक व्याख्या गर्न सकिन्छ। खण्डमा रेकर्ड गरिएका मेन्डरहरूले प्यालेओचनेलहरू चित्रण गर्न सम्भव बनाउँदछ, जुन जलाशयहरू हुने सम्भावना बढी हुन्छ र तेल भण्डारहरू समावेश गर्दछ। यस्तो नदी प्रणाली को आधुनिक analogues को खोज र विश्लेषण हामीलाई meanders को सबै भन्दा आशाजनक भागहरु निर्धारण गर्न अनुमति दिन्छ। च्यानलहरू आफैंमा राम्ररी क्रमबद्ध बालुवा ढुङ्गाको बाक्लो तहहरूद्वारा विशेषता हुन्छन् र तेलको लागि राम्रो भण्डार हो। "लेस" विसंगतिहरू बाहिरका क्षेत्रहरू आधुनिक फ्लडप्लेन निक्षेपहरू जस्तै छन्। फ्लडप्लेन निक्षेपहरू मुख्यतया माटोको चट्टानहरूले प्रतिनिधित्व गर्दछ र यी क्षेत्रहरूमा ड्रिलिंग प्रभावकारी हुनेछैन।

डाटा क्यूबको RGB टुक्रा। केन्द्रमा (केन्द्रको अलिकति बाँयामा) तपाईं घुमाउरो नदी ट्रेस गर्न सक्नुहुन्छ।

डाटा क्यूबको RGB टुक्रा। बायाँ छेउमा तपाईं घुमाउरो नदी ट्रेस गर्न सक्नुहुन्छ।


केही अवस्थामा, भूकम्पीय डेटाको गुणस्तरले महत्त्वपूर्ण रूपमा स्पष्ट छविहरूको लागि अनुमति दिन्छ। यो क्षेत्रीय कार्य पद्धतिमा निर्भर गर्दछ, आवाज घटाउने एल्गोरिथ्म द्वारा प्रयोग गरिएको उपकरण। यस्तो अवस्थामा, नदी प्रणालीका टुक्राहरू मात्र देखिँदैन, तर सम्पूर्ण विस्तारित प्यालेओ-नदीहरू पनि देखिन्छन्।

सिस्मिक डाटा क्यूब (तेर्सो स्लाइस) को तीनवटा कम्पोनेन्टहरूको RGB मिश्रण। गहिराई लगभग 2 किमी।

सेराटोभ नजिक भोल्गा नदी को उपग्रह छवि

निष्कर्षमा

Wolfram Mathematica ले भूकम्पीय डेटाको विश्लेषण गर्न र खनिजहरूको खोजीसँग सम्बन्धित लागू समस्याहरू समाधान गर्न सक्छ, र GeologyIO प्याकेजले यो प्रक्रियालाई अझ सुविधाजनक बनाउँछ। भूकम्पीय डेटाको संरचना यस्तो छ कि गणनाको गति बढाउन निर्मित विधिहरू प्रयोग गरेर (समानान्तरतालिका[], ParallelDo[],…) धेरै कुशल छ र तपाईंलाई ठूलो मात्रामा डाटा प्रशोधन गर्न अनुमति दिन्छ। धेरै हदसम्म, यो GeologyIO प्याकेज को डाटा भण्डारण सुविधाहरू द्वारा सुविधा दिइएको छ। वैसे, प्याकेज लागू भूकम्प अन्वेषण को क्षेत्रमा मात्र प्रयोग गर्न सकिन्छ। लगभग उस्तै प्रकारका डाटाहरू ग्राउन्ड पेनेट्रेटिंग राडार र सिस्मोलजीमा प्रयोग गरिन्छ। यदि तपाईंसँग नतिजा सुधार गर्ने बारे सुझावहरू छन् भने, वोल्फ्राम म्याथेमेटिका आर्सेनलबाट कुन संकेत विश्लेषण एल्गोरिदमहरू त्यस्ता डाटाहरूमा लागू हुन्छन्, वा तपाईंसँग कुनै आलोचनात्मक टिप्पणीहरू छन् भने, कृपया। एक टिप्पणी छोड्नुहोस्।

स्रोत: www.habr.com