Zoals u weet spelen indexen een belangrijke rol in een DBMS, omdat ze snel naar de vereiste records kunnen zoeken. Daarom is het zo belangrijk om ze tijdig te onderhouden. Er is behoorlijk veel materiaal geschreven over analyse en optimalisatie, ook op internet. Dit onderwerp is bijvoorbeeld onlangs besproken in deze publicatie.
Hier zijn veel betaalde en gratis oplossingen voor. Er is bijvoorbeeld een kant-en-klaar beslissing, gebaseerd op een adaptieve indexoptimalisatiemethode.
Laten we vervolgens eens kijken naar het gratis hulpprogramma SQLIndexManager, geschreven door AlanDenton.
Het belangrijkste technische verschil tussen SQLIndexManager en een aantal andere analogen wordt door de auteur zelf gegeven hier и hier.
In dit artikel bekijken we het project en de operationele mogelijkheden van deze softwareoplossing van buitenaf.
Dit hulpprogramma bespreken hier.
In de loop van de tijd zijn de meeste opmerkingen en bugs gecorrigeerd.
Laten we nu verder gaan met het hulpprogramma SQLIndexManager zelf.
De applicatie is geschreven in C# .NET Framework 4.5 in Visual Studio 2017 en gebruikt DevExpress voor formulieren:
en ziet er zo uit:
Alle aanvragen worden gegenereerd in de volgende bestanden:
Index
Vraag
QueryEngine
Serverinfo
Wanneer u verbinding maakt met een database en query's verzendt naar het DBMS, wordt de applicatie als volgt ondertekend:
ApplicationName=”SQLIndexManager”
Wanneer u de applicatie start, wordt een modaal venster geopend waarin u een verbinding kunt toevoegen:
Hier werkt het laden van een volledige lijst van alle MS SQL Server-instanties die toegankelijk zijn via lokale netwerken nog niet.
U kunt ook een verbinding toevoegen via de meest linkse knop in het hoofdmenu:
Vervolgens worden de volgende query's naar het DBMS gestart:
Een lijst krijgen van beschikbare databases met hun korte eigenschappen
SELECT DatabaseName = t.[name]
, d.DataSize
, DataUsedSize = CAST(NULL AS BIGINT)
, d.LogSize
, LogUsedSize = CAST(NULL AS BIGINT)
, RecoveryModel = t.recovery_model_desc
, LogReuseWait = t.log_reuse_wait_desc
FROM sys.databases t WITH(NOLOCK)
LEFT JOIN (
SELECT [database_id]
, DataSize = SUM(CASE WHEN [type] = 0 THEN CAST(size AS BIGINT) END)
, LogSize = SUM(CASE WHEN [type] = 1 THEN CAST(size AS BIGINT) END)
FROM sys.master_files WITH(NOLOCK)
GROUP BY [database_id]
) d ON d.[database_id] = t.[database_id]
WHERE t.[state] = 0
AND t.[database_id] != 2
AND ISNULL(HAS_DBACCESS(t.[name]), 1) = 1
Na het uitvoeren van de bovenstaande scripts verschijnt er een venster met korte informatie over de databases van het geselecteerde exemplaar van MS SQL Server:
Vermeldenswaard is dat uitgebreide informatie wordt getoond op basis van rechten. Als er sysadmin, vervolgens kunt u gegevens uit de weergave selecteren sys.master_bestanden. Als dergelijke rechten niet bestaan, worden er eenvoudigweg minder gegevens geretourneerd om het verzoek niet te vertragen.
Hier moet u de gewenste databases selecteren en op de knop "OK" klikken.
Vervolgens wordt voor elke geselecteerde database het volgende script uitgevoerd om de status van de indexen te analyseren:
Analyse van de indexstatus
declare @Fragmentation float=15;
declare @MinIndexSize bigint=768;
declare @MaxIndexSize bigint=1048576;
declare @PreDescribeSize bigint=32768;
SET NOCOUNT ON
SET ARITHABORT ON
SET NUMERIC_ROUNDABORT OFF
IF OBJECT_ID('tempdb.dbo.#AllocationUnits') IS NOT NULL
DROP TABLE #AllocationUnits
CREATE TABLE #AllocationUnits (
ContainerID BIGINT PRIMARY KEY
, ReservedPages BIGINT NOT NULL
, UsedPages BIGINT NOT NULL
)
INSERT INTO #AllocationUnits (ContainerID, ReservedPages, UsedPages)
SELECT [container_id]
, SUM([total_pages])
, SUM([used_pages])
FROM sys.allocation_units WITH(NOLOCK)
GROUP BY [container_id]
HAVING SUM([total_pages]) BETWEEN @MinIndexSize AND @MaxIndexSize
IF OBJECT_ID('tempdb.dbo.#ExcludeList') IS NOT NULL
DROP TABLE #ExcludeList
CREATE TABLE #ExcludeList (ID INT PRIMARY KEY)
INSERT INTO #ExcludeList
SELECT [object_id]
FROM sys.objects WITH(NOLOCK)
WHERE [type] IN ('V', 'U')
AND ( [is_ms_shipped] = 1 )
IF OBJECT_ID('tempdb.dbo.#Partitions') IS NOT NULL
DROP TABLE #Partitions
SELECT [object_id]
, [index_id]
, [partition_id]
, [partition_number]
, [rows]
, [data_compression]
INTO #Partitions
FROM sys.partitions WITH(NOLOCK)
WHERE [object_id] > 255
AND [rows] > 0
AND [object_id] NOT IN (SELECT * FROM #ExcludeList)
IF OBJECT_ID('tempdb.dbo.#Indexes') IS NOT NULL
DROP TABLE #Indexes
CREATE TABLE #Indexes (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IndexName SYSNAME NULL
, PagesCount BIGINT NOT NULL
, UnusedPagesCount BIGINT NOT NULL
, PartitionNumber INT NOT NULL
, RowsCount BIGINT NOT NULL
, IndexType TINYINT NOT NULL
, IsAllowPageLocks BIT NOT NULL
, DataSpaceID INT NOT NULL
, DataCompression TINYINT NOT NULL
, IsUnique BIT NOT NULL
, IsPK BIT NOT NULL
, FillFactorValue INT NOT NULL
, IsFiltered BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Indexes
SELECT ObjectID = i.[object_id]
, IndexID = i.index_id
, IndexName = i.[name]
, PagesCount = a.ReservedPages
, UnusedPagesCount = CASE WHEN ABS(a.ReservedPages - a.UsedPages) > 32 THEN a.ReservedPages - a.UsedPages ELSE 0 END
, PartitionNumber = p.[partition_number]
, RowsCount = ISNULL(p.[rows], 0)
, IndexType = i.[type]
, IsAllowPageLocks = i.[allow_page_locks]
, DataSpaceID = i.[data_space_id]
, DataCompression = p.[data_compression]
, IsUnique = i.[is_unique]
, IsPK = i.[is_primary_key]
, FillFactorValue = i.[fill_factor]
, IsFiltered = i.[has_filter]
FROM #AllocationUnits a
JOIN #Partitions p ON a.ContainerID = p.[partition_id]
JOIN sys.indexes i WITH(NOLOCK) ON i.[object_id] = p.[object_id] AND p.[index_id] = i.[index_id]
WHERE i.[type] IN (0, 1, 2, 5, 6)
AND i.[object_id] > 255
DECLARE @files TABLE (ID INT PRIMARY KEY)
INSERT INTO @files
SELECT DISTINCT [data_space_id]
FROM sys.database_files WITH(NOLOCK)
WHERE [state] != 0
AND [type] = 0
IF @@ROWCOUNT > 0 BEGIN
DELETE FROM i
FROM #Indexes i
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
WHERE ISNULL(dds.[data_space_id], i.DataSpaceID) IN (SELECT * FROM @files)
END
DECLARE @DBID INT
, @DBNAME SYSNAME
SET @DBNAME = DB_NAME()
SELECT @DBID = [database_id]
FROM sys.databases WITH(NOLOCK)
WHERE [name] = @DBNAME
IF OBJECT_ID('tempdb.dbo.#Fragmentation') IS NOT NULL
DROP TABLE #Fragmentation
CREATE TABLE #Fragmentation (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, PartitionNumber INT NOT NULL
, Fragmentation FLOAT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Fragmentation (ObjectID, IndexID, PartitionNumber, Fragmentation)
SELECT i.ObjectID
, i.IndexID
, i.PartitionNumber
, r.[avg_fragmentation_in_percent]
FROM #Indexes i
CROSS APPLY sys.dm_db_index_physical_stats(@DBID, i.ObjectID, i.IndexID, i.PartitionNumber, 'LIMITED') r
WHERE i.PagesCount <= @PreDescribeSize
AND r.[index_level] = 0
AND r.[alloc_unit_type_desc] = 'IN_ROW_DATA'
AND i.IndexType IN (0, 1, 2)
IF OBJECT_ID('tempdb.dbo.#Columns') IS NOT NULL
DROP TABLE #Columns
CREATE TABLE #Columns (
ObjectID INT NOT NULL
, ColumnID INT NOT NULL
, ColumnName SYSNAME NULL
, SystemTypeID TINYINT NULL
, IsSparse BIT
, IsColumnSet BIT
, MaxLen INT
, PRIMARY KEY (ObjectID, ColumnID)
)
INSERT INTO #Columns
SELECT ObjectID = [object_id]
, ColumnID = [column_id]
, ColumnName = [name]
, SystemTypeID = [system_type_id]
, IsSparse = [is_sparse]
, IsColumnSet = [is_column_set]
, MaxLen = [max_length]
FROM sys.columns WITH(NOLOCK)
WHERE [object_id] IN (SELECT DISTINCT i.ObjectID FROM #Indexes i)
IF OBJECT_ID('tempdb.dbo.#IndexColumns') IS NOT NULL
DROP TABLE #IndexColumns
CREATE TABLE #IndexColumns (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, OrderID INT NOT NULL
, ColumnID INT NOT NULL
, IsIncluded BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, ColumnID)
)
INSERT INTO #IndexColumns
SELECT ObjectID = [object_id]
, IndexID = [index_id]
, OrderID = CASE WHEN [is_included_column] = 0 THEN [key_ordinal] ELSE [index_column_id] END
, ColumnID = [column_id]
, IsIncluded = ISNULL([is_included_column], 0)
FROM sys.index_columns ic WITH(NOLOCK)
WHERE EXISTS(
SELECT *
FROM #Indexes i
WHERE i.ObjectID = ic.[object_id]
AND i.IndexID = ic.[index_id]
AND i.IndexType IN (1, 2)
)
IF OBJECT_ID('tempdb.dbo.#Lob') IS NOT NULL
DROP TABLE #Lob
CREATE TABLE #Lob (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IsLobLegacy BIT
, IsLob BIT
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #Lob (ObjectID, IndexID, IsLobLegacy, IsLob)
SELECT c.ObjectID
, IndexID = ISNULL(i.IndexID, 1)
, IsLobLegacy = MAX(CASE WHEN c.SystemTypeID IN (34, 35, 99) THEN 1 END)
, IsLob = 0
FROM #Columns c
LEFT JOIN #IndexColumns i ON c.ObjectID = i.ObjectID AND c.ColumnID = i.ColumnID
WHERE c.SystemTypeID IN (34, 35, 99)
GROUP BY c.ObjectID
, i.IndexID
IF OBJECT_ID('tempdb.dbo.#Sparse') IS NOT NULL
DROP TABLE #Sparse
CREATE TABLE #Sparse (ObjectID INT PRIMARY KEY)
INSERT INTO #Sparse
SELECT DISTINCT ObjectID
FROM #Columns
WHERE IsSparse = 1
OR IsColumnSet = 1
IF OBJECT_ID('tempdb.dbo.#AggColumns') IS NOT NULL
DROP TABLE #AggColumns
CREATE TABLE #AggColumns (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IndexColumns NVARCHAR(MAX)
, IncludedColumns NVARCHAR(MAX)
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #AggColumns
SELECT t.ObjectID
, t.IndexID
, IndexColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 0
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
, IncludedColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 1
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
FROM (
SELECT DISTINCT ObjectID, IndexID
FROM #Indexes
WHERE IndexType IN (1, 2)
) t
SELECT i.ObjectID
, i.IndexID
, i.IndexName
, ObjectName = o.[name]
, SchemaName = s.[name]
, i.PagesCount
, i.UnusedPagesCount
, i.PartitionNumber
, i.RowsCount
, i.IndexType
, i.IsAllowPageLocks
, u.TotalWrites
, u.TotalReads
, u.TotalSeeks
, u.TotalScans
, u.TotalLookups
, u.LastUsage
, i.DataCompression
, f.Fragmentation
, IndexStats = STATS_DATE(i.ObjectID, i.IndexID)
, IsLobLegacy = ISNULL(lob.IsLobLegacy, 0)
, IsLob = ISNULL(lob.IsLob, 0)
, IsSparse = CAST(CASE WHEN p.ObjectID IS NULL THEN 0 ELSE 1 END AS BIT)
, IsPartitioned = CAST(CASE WHEN dds.[data_space_id] IS NOT NULL THEN 1 ELSE 0 END AS BIT)
, FileGroupName = fg.[name]
, i.IsUnique
, i.IsPK
, i.FillFactorValue
, i.IsFiltered
, a.IndexColumns
, a.IncludedColumns
FROM #Indexes i
JOIN sys.objects o WITH(NOLOCK) ON o.[object_id] = i.ObjectID
JOIN sys.schemas s WITH(NOLOCK) ON s.[schema_id] = o.[schema_id]
LEFT JOIN #AggColumns a ON a.ObjectID = i.ObjectID AND a.IndexID = i.IndexID
LEFT JOIN #Sparse p ON p.ObjectID = i.ObjectID
LEFT JOIN #Fragmentation f ON f.ObjectID = i.ObjectID AND f.IndexID = i.IndexID AND f.PartitionNumber = i.PartitionNumber
LEFT JOIN (
SELECT ObjectID = [object_id]
, IndexID = [index_id]
, TotalWrites = NULLIF([user_updates], 0)
, TotalReads = NULLIF([user_seeks] + [user_scans] + [user_lookups], 0)
, TotalSeeks = NULLIF([user_seeks], 0)
, TotalScans = NULLIF([user_scans], 0)
, TotalLookups = NULLIF([user_lookups], 0)
, LastUsage = (
SELECT MAX(dt)
FROM (
VALUES ([last_user_seek])
, ([last_user_scan])
, ([last_user_lookup])
, ([last_user_update])
) t(dt)
)
FROM sys.dm_db_index_usage_stats WITH(NOLOCK)
WHERE [database_id] = @DBID
) u ON i.ObjectID = u.ObjectID AND i.IndexID = u.IndexID
LEFT JOIN #Lob lob ON lob.ObjectID = i.ObjectID AND lob.IndexID = i.IndexID
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
JOIN sys.filegroups fg WITH(NOLOCK) ON ISNULL(dds.[data_space_id], i.DataSpaceID) = fg.[data_space_id]
WHERE o.[type] IN ('V', 'U')
AND (
f.Fragmentation >= @Fragmentation
OR
i.PagesCount > @PreDescribeSize
OR
i.IndexType IN (5, 6)
)
Zoals uit de query's zelf blijkt, worden tijdelijke tabellen vrij vaak gebruikt. Dit wordt gedaan zodat er geen hercompilaties plaatsvinden, en in het geval van een groot schema kan het plan parallel worden gegenereerd bij het invoegen van gegevens, aangezien het invoegen van tabelvariabelen slechts in één thread mogelijk is.
Na het uitvoeren van het bovenstaande script verschijnt een venster met een indextabel:
U kunt hier ook andere gedetailleerde informatie weergeven, zoals:
database
aantal secties
datum en tijd van de laatste oproep
compressie
bestandsgroep
en zo verder. д.
De luidsprekers zelf kunnen worden aangepast:
In de cellen van de kolom Herstellen kunt u selecteren welke actie tijdens de optimalisatie wordt uitgevoerd. Wanneer de scan is voltooid, wordt er bovendien een standaardactie geselecteerd op basis van de geselecteerde instellingen:
U moet de gewenste indexen selecteren voor verwerking.
Via het hoofdmenu kunt u het script opslaan (dezelfde knop start het indexoptimalisatieproces zelf):
en sla de tabel op in verschillende formaten (met dezelfde knop kunt u gedetailleerde instellingen openen voor het analyseren en optimaliseren van indexen):
U kunt de informatie ook bijwerken door op de derde knop links in het hoofdmenu naast het vergrootglas te klikken.
Met de knop met een vergrootglas kunt u de gewenste databases selecteren die u wilt bekijken.
Er bestaat momenteel geen alomvattend hulpsysteem. Druk daarom op de “?”-knop zal er eenvoudigweg voor zorgen dat er een modaal venster verschijnt met basisinformatie over het softwareproduct:
Naast alles wat hierboven is beschreven, heeft het hoofdmenu een zoekbalk:
Bij het starten van het indexoptimalisatieproces:
Onderaan het venster kunt u ook een logboek met uitgevoerde acties bekijken:
In het gedetailleerde instellingenvenster voor indexanalyse en -optimalisatie kunt u subtielere opties configureren:
Verzoeken voor de aanvraag:
maken het mogelijk om statistieken selectief bij te werken, niet alleen voor indexen, maar ook op verschillende manieren (volledig bijgewerkt of gedeeltelijk)
maken het niet alleen mogelijk om een database te selecteren, maar ook verschillende servers (dit is erg handig als er veel exemplaren van MS SQL Server zijn)
Voor meer flexibiliteit bij het gebruik wordt voorgesteld om de opdrachten in bibliotheken te verpakken en deze uit te voeren naar PowerShell-opdrachten, zoals bijvoorbeeld hier wordt gedaan:
maken het mogelijk om persoonlijke instellingen op te slaan en te wijzigen, zowel voor de gehele applicatie als eventueel voor elke instance van MS SQL Server en elke database
Uit punt 2 en 4 volgt dat u groepen per database en groepen per MS SQL Server instances wilt aanmaken, waarvoor de instellingen hetzelfde zijn
zoeken naar dubbele indexen (compleet en onvolledig, die enigszins verschillen of alleen verschillen in de opgenomen kolommen)
Omdat SQLIndexManager alleen wordt gebruikt voor MS SQL Server DBMS, is het noodzakelijk om dit bijvoorbeeld als volgt in de naam weer te geven: SQLIndexManager voor MS SQL Server
Verplaats alle niet-GUI-onderdelen van de applicatie naar afzonderlijke modules en herschrijf ze in .NET Core 2.1
Op het moment van schrijven wordt punt 6 van de wensen actief uitgewerkt en is er al ondersteuning in de vorm van het zoeken naar complete en soortgelijke duplicaten: